binding/mdsal-binding-java-api-generator/src/main/java/org/opendaylight/mdsal/binding/java/api/generator/ClassTemplate.xtend

   1 /*
   2  * Copyright (c) 2014 Cisco Systems, Inc. and others.  All rights reserved.
   3  *
   4  * This program and the accompanying materials are made available under the
   5  * terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6  * and is available at http://www.eclipse.org/legal/epl-v10.html
   7  */
   8 package org.opendaylight.mdsal.binding.java.api.generator
   9
  10 import static java.util.Objects.requireNonNull
  11 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.BINARY_TYPE
  12 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.BOOLEAN_TYPE
  13 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.EMPTY_TYPE
  14 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.INSTANCE_IDENTIFIER
  15 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.INT16_TYPE
  16 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.INT32_TYPE
  17 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.INT64_TYPE
  18 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.INT8_TYPE
  19 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.STRING_TYPE
  20 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.UINT16_TYPE
  21 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.UINT32_TYPE
  22 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.UINT64_TYPE
  23 import static org.opendaylight.mdsal.binding.model.util.BaseYangTypes.UINT8_TYPE
  24 import static org.opendaylight.mdsal.binding.model.util.BindingTypes.SCALAR_TYPE_OBJECT
  25 import static org.opendaylight.mdsal.binding.model.util.Types.BOOLEAN
  26 import static org.opendaylight.mdsal.binding.model.util.Types.STRING;
  27 import static extension org.apache.commons.text.StringEscapeUtils.escapeJava
  28
  29 import com.google.common.base.MoreObjects
  30 import com.google.common.base.Preconditions
  31 import com.google.common.collect.ImmutableList
  32 import com.google.common.collect.Lists
  33 import edu.umd.cs.findbugs.annotations.SuppressFBWarnings
  34 import java.beans.ConstructorProperties
  35 import java.util.ArrayList
  36 import java.util.Base64;
  37 import java.util.Collection
  38 import java.util.Comparator
  39 import java.util.List
  40 import java.util.Map
  41 import java.util.Set
  42 import javax.management.ConstructorParameters
  43 import org.gaul.modernizer_maven_annotations.SuppressModernizer
  44 import org.opendaylight.mdsal.binding.model.api.ConcreteType
  45 import org.opendaylight.mdsal.binding.model.api.Constant
  46 import org.opendaylight.mdsal.binding.model.api.Enumeration
  47 import org.opendaylight.mdsal.binding.model.api.GeneratedProperty
  48 import org.opendaylight.mdsal.binding.model.api.GeneratedTransferObject
  49 import org.opendaylight.mdsal.binding.model.api.Restrictions
  50 import org.opendaylight.mdsal.binding.model.api.Type
  51 import org.opendaylight.mdsal.binding.model.util.TypeConstants
  52 import org.opendaylight.mdsal.binding.spec.naming.BindingMapping
  53 import org.opendaylight.yangtools.yang.common.Empty
  54 import org.opendaylight.yangtools.yang.model.api.type.BitsTypeDefinition
  55
  56 /**
  57  * Template for generating JAVA class.
  58  */
  59 @SuppressModernizer
  60 class ClassTemplate extends BaseTemplate {
  61     static val Comparator<GeneratedProperty> PROP_COMPARATOR = Comparator.comparing([prop | prop.name])
  62     static val VALUEOF_TYPES = Set.of(
  63         BOOLEAN_TYPE,
  64         INT8_TYPE,
  65         INT16_TYPE,
  66         INT32_TYPE,
  67         INT64_TYPE,
  68         UINT8_TYPE,
  69         UINT16_TYPE,
  70         UINT32_TYPE,
  71         UINT64_TYPE)
  72
  73     protected val List<GeneratedProperty> properties
  74     protected val List<GeneratedProperty> finalProperties
  75     protected val List<GeneratedProperty> parentProperties
  76     protected val List<GeneratedProperty> allProperties
  77     protected val Restrictions restrictions
  78
  79     /**
  80      * List of enumeration which are generated as JAVA enum type.
  81      */
  82     protected val List<Enumeration> enums
  83
  84     /**
  85      * List of constant instances which are generated as JAVA public static final attributes.
  86      */
  87     protected val List<Constant> consts
  88
  89     protected val GeneratedTransferObject genTO
  90
  91     val AbstractRangeGenerator<?> rangeGenerator
  92
  93     /**
  94      * Creates instance of this class with concrete <code>genType</code>.
  95      *
  96      * @param genType generated transfer object which will be transformed to JAVA class source code
  97      */
  98     new(GeneratedTransferObject genType) {
  99         this(new TopLevelJavaGeneratedType(genType), genType)
 100     }
 101
 102     /**
 103      * Creates instance of this class with concrete <code>genType</code>.
 104      *
 105      * @param genType generated transfer object which will be transformed to JAVA class source code
 106      */
 107     new(AbstractJavaGeneratedType javaType, GeneratedTransferObject genType) {
 108         super(javaType, genType)
 109         this.genTO = genType
 110         this.properties = genType.properties
 111         this.finalProperties = GeneratorUtil.resolveReadOnlyPropertiesFromTO(genTO.properties)
 112         this.parentProperties = GeneratorUtil.getPropertiesOfAllParents(genTO)
 113         this.restrictions = genType.restrictions
 114
 115         val sorted = new ArrayList();
 116         sorted.addAll(properties);
 117         sorted.addAll(parentProperties);
 118         sorted.sort(PROP_COMPARATOR);
 119
 120         this.allProperties = sorted
 121         this.enums = genType.enumerations
 122         this.consts = genType.constantDefinitions
 123
 124         if (restrictions !== null && restrictions.rangeConstraint.present) {
 125             rangeGenerator = requireNonNull(AbstractRangeGenerator.forType(TypeUtils.encapsulatedValueType(genType)))
 126         } else {
 127             rangeGenerator = null
 128         }
 129     }
 130
 131     /**
 132      * Generates JAVA class source code (class body only).
 133      *
 134      * @return string with JAVA class body source code
 135      */
 136     def CharSequence generateAsInnerClass() {
 137         return generateBody(true)
 138     }
 139
 140     override protected body() {
 141         generateBody(false);
 142     }
 143
 144     /**
 145      * Template method which generates class body.
 146      *
 147      * @param isInnerClass boolean value which specify if generated class is|isn't inner
 148      * @return string with class source code in JAVA format
 149      */
 150     def protected generateBody(boolean isInnerClass) '''
 151         «type.formatDataForJavaDoc.wrapToDocumentation»
 152         «annotationDeclaration»
 153         «generateClassDeclaration(isInnerClass)» {
 154             «suidDeclaration»
 155             «innerClassesDeclarations»
 156             «enumDeclarations»
 157             «constantsDeclarations»
 158             «generateFields»
 159
 160             «IF restrictions !== null»
 161                 «IF restrictions.lengthConstraint.present»
 162                     «LengthGenerator.generateLengthChecker("_value", TypeUtils.encapsulatedValueType(genTO),
 163                         restrictions.lengthConstraint.get, this)»
 164                 «ENDIF»
 165                 «IF restrictions.rangeConstraint.present»
 166                     «rangeGenerator.generateRangeChecker("_value", restrictions.rangeConstraint.get, this)»
 167                 «ENDIF»
 168             «ENDIF»
 169
 170             «constructors»
 171
 172             «defaultInstance»
 173
 174             «propertyMethods»
 175
 176             «IF (genTO.isTypedef() && genTO.getBaseType instanceof BitsTypeDefinition)»
 177                 «generateGetValueForBitsTypeDef»
 178             «ENDIF»
 179
 180             «generateHashCode»
 181
 182             «generateEquals»
 183
 184             «generateToString(genTO.toStringIdentifiers)»
 185         }
 186
 187     '''
 188
 189     def private propertyMethods() {
 190         if (properties.empty) {
 191             return ""
 192         }
 193         isScalarTypeObject ? scalarTypeObjectValue(properties.get(0)) : defaultProperties
 194     }
 195
 196     def private isScalarTypeObject() {
 197         for (impl : genTO.implements) {
 198             if (SCALAR_TYPE_OBJECT.identifier.equals(impl.identifier)) {
 199                 return true
 200             }
 201         }
 202         return false
 203     }
 204
 205     def private defaultProperties() '''
 206         «FOR field : properties SEPARATOR "\n"»
 207             «field.getterMethod»
 208             «IF !field.readOnly»
 209                 «field.setterMethod»
 210             «ENDIF»
 211         «ENDFOR»
 212     '''
 213
 214     def private scalarTypeObjectValue(GeneratedProperty field) '''
 215         @«OVERRIDE.importedName»
 216         public «field.returnType.importedName» «BindingMapping.SCALAR_TYPE_OBJECT_GET_VALUE_NAME»() {
 217             return «field.fieldName»«field.cloneCall»;
 218         }
 219     '''
 220
 221     /**
 222      * Template method which generates the method <code>getValue()</code> for typedef,
 223      * which base type is BitsDefinition.
 224      *
 225      * @return string with the <code>getValue()</code> method definition in JAVA format
 226      */
 227     def protected generateGetValueForBitsTypeDef() '''
 228
 229         public boolean[] getValue() {
 230             return new boolean[]{
 231             «FOR property: genTO.properties SEPARATOR ','»
 232                  «property.fieldName»
 233             «ENDFOR»
 234             };
 235         }
 236     '''
 237
 238     /**
 239      * Template method which generates inner classes inside this interface.
 240      *
 241      * @return string with the source code for inner classes in JAVA format
 242      */
 243     def protected innerClassesDeclarations() '''
 244         «IF !type.enclosedTypes.empty»
 245             «FOR innerClass : type.enclosedTypes SEPARATOR "\n"»
 246                 «generateInnerClass(innerClass)»
 247             «ENDFOR»
 248         «ENDIF»
 249     '''
 250
 251     def protected constructors() '''
 252         «IF genTO.unionType»
 253             «genUnionConstructor»
 254         «ELSEIF genTO.typedef && allProperties.size == 1 && allProperties.get(0).name.equals(TypeConstants.VALUE_PROP)»
 255             «typedefConstructor»
 256             «legacyConstructor»
 257         «ELSE»
 258             «allValuesConstructor»
 259             «legacyConstructor»
 260         «ENDIF»
 261
 262         «IF !allProperties.empty»
 263             «copyConstructor»
 264         «ENDIF»
 265         «IF properties.empty && !parentProperties.empty »
 266             «parentConstructor»
 267         «ENDIF»
 268     '''
 269
 270     def allValuesConstructor() '''
 271     public «type.name»(«allProperties.asArgumentsDeclaration») {
 272         «IF !parentProperties.empty»
 273             super(«parentProperties.asArguments»);
 274         «ENDIF»
 275         «FOR p : allProperties»
 276             «generateRestrictions(type, p.fieldName, p.returnType)»
 277         «ENDFOR»
 278
 279         «FOR p : properties»
 280             «val fieldName = p.fieldName»
 281             «IF p.returnType.name.endsWith("[]")»
 282                 this.«fieldName» = «fieldName» == null ? null : «fieldName».clone();
 283             «ELSE»
 284                 this.«fieldName» = «fieldName»;
 285             «ENDIF»
 286         «ENDFOR»
 287     }
 288     '''
 289
 290     def private typedefConstructor() '''
 291     @«ConstructorParameters.importedName»("«TypeConstants.VALUE_PROP»")
 292     @«ConstructorProperties.importedName»("«TypeConstants.VALUE_PROP»")
 293     public «type.name»(«allProperties.asArgumentsDeclaration») {
 294         «IF !parentProperties.empty»
 295             super(«parentProperties.asArguments»);
 296         «ENDIF»
 297         «FOR p : allProperties»
 298             «generateRestrictions(type, p.fieldName, p.returnType)»
 299         «ENDFOR»
 300         «/*
 301          * If we have patterns, we need to apply them to the value field. This is a sad consequence of how this code is
 302          * structured.
 303          */»
 304         «CODEHELPERS.importedName».requireValue(_value);
 305         «genPatternEnforcer("_value")»
 306
 307         «FOR p : properties»
 308             «val fieldName = p.fieldName»
 309             this.«fieldName» = «fieldName»«p.cloneCall»;
 310         «ENDFOR»
 311     }
 312     '''
 313
 314     def private legacyConstructor() {
 315         if (!hasUintProperties) {
 316             return ""
 317         }
 318
 319         val compatUint = CODEHELPERS.importedName + ".compatUint("
 320         return '''
 321
 322             /**
 323              * Utility migration constructor.
 324              *
 325              «FOR prop : allProperties»
 326              * @param «prop.fieldName» «prop.name»«IF prop.isUintType» in legacy Java type«ENDIF»
 327              «ENDFOR»
 328              * @deprecated Use {#link «type.name»(«FOR prop : allProperties SEPARATOR ", "»«prop.returnType.importedJavadocName»«ENDFOR»)} instead.
 329              */
 330             @Deprecated(forRemoval = true)
 331             public «type.getName»(«FOR prop : allProperties SEPARATOR ", "»«prop.legacyType.importedName» «prop.fieldName»«ENDFOR») {
 332                 this(«FOR prop : allProperties SEPARATOR ", "»«IF prop.isUintType»«compatUint»«prop.fieldName»)«ELSE»«prop.fieldName»«ENDIF»«ENDFOR»);
 333             }
 334         '''
 335     }
 336
 337     def protected genUnionConstructor() '''
 338     «FOR p : allProperties»
 339         «val List<GeneratedProperty> other = new ArrayList(properties)»
 340         «IF other.remove(p)»
 341             «genConstructor(p, other)»
 342         «ENDIF»
 343     «ENDFOR»
 344     '''
 345
 346     def protected genConstructor(GeneratedProperty property, Iterable<GeneratedProperty> other) '''
 347     public «type.name»(«property.returnType.importedName + " " + property.name») {
 348         «IF !parentProperties.empty»
 349             super(«parentProperties.asArguments»);
 350         «ENDIF»
 351
 352         «val fieldName = property.fieldName»
 353         «generateRestrictions(type, fieldName, property.returnType)»
 354
 355         this.«fieldName» = «property.name»;
 356         «FOR p : other»
 357             this.«p.fieldName» = null;
 358         «ENDFOR»
 359     }
 360     '''
 361
 362     def private genPatternEnforcer(String ref) '''
 363         «FOR c : consts»
 364             «IF c.name == TypeConstants.PATTERN_CONSTANT_NAME»
 365             «CODEHELPERS.importedName».checkPattern(«ref», «Constants.MEMBER_PATTERN_LIST», «Constants.MEMBER_REGEX_LIST»);
 366             «ENDIF»
 367         «ENDFOR»
 368     '''
 369
 370     def private static paramValue(Type returnType, String paramName) {
 371         if (returnType instanceof ConcreteType) {
 372             return paramName
 373         } else {
 374             return paramName + ".getValue()"
 375         }
 376     }
 377
 378     def generateRestrictions(Type type, String paramName, Type returnType) '''
 379         «val restrictions = type.restrictions»
 380         «IF restrictions !== null»
 381             «IF restrictions.lengthConstraint.present || restrictions.rangeConstraint.present»
 382             if («paramName» != null) {
 383                 «IF restrictions.lengthConstraint.present»
 384                     «LengthGenerator.generateLengthCheckerCall(paramName, paramValue(returnType, paramName))»
 385                 «ENDIF»
 386                 «IF restrictions.rangeConstraint.present»
 387                     «rangeGenerator.generateRangeCheckerCall(paramName, paramValue(returnType, paramName))»
 388                 «ENDIF»
 389             }
 390             «ENDIF»
 391         «ENDIF»
 392     '''
 393
 394     def protected copyConstructor() '''
 395     /**
 396      * Creates a copy from Source Object.
 397      *
 398      * @param source Source object
 399      */
 400     public «type.name»(«type.name» source) {
 401         «IF !parentProperties.empty»
 402             super(source);
 403         «ENDIF»
 404         «FOR p : properties»
 405             «val fieldName = p.fieldName»
 406             this.«fieldName» = source.«fieldName»;
 407         «ENDFOR»
 408     }
 409     '''
 410
 411     def protected parentConstructor() '''
 412     /**
 413      * Creates a new instance from «genTO.superType.importedName»
 414      *
 415      * @param source Source object
 416      */
 417     public «type.name»(«genTO.superType.importedName» source) {
 418         super(source);
 419         «genPatternEnforcer("getValue()")»
 420     }
 421     '''
 422
 423     def protected defaultInstance() '''
 424         «IF genTO.typedef && !allProperties.empty && !genTO.unionType»
 425             «val prop = allProperties.get(0)»
 426             «val propType = prop.returnType»
 427             «IF !(INSTANCE_IDENTIFIER.identifier.equals(propType.identifier))»
 428             public static «genTO.name» getDefaultInstance(final String defaultValue) {
 429                 «IF allProperties.size > 1»
 430                     «bitsArgs»
 431                 «ELSEIF VALUEOF_TYPES.contains(propType)»
 432                     return new «genTO.name»(«propType.importedName».valueOf(defaultValue));
 433                 «ELSEIF STRING_TYPE.equals(propType)»
 434                     return new «genTO.name»(defaultValue);
 435                 «ELSEIF BINARY_TYPE.equals(propType)»
 436                     return new «genTO.name»(«Base64.importedName».getDecoder().decode(defaultValue));
 437                 «ELSEIF EMPTY_TYPE.equals(propType)»
 438                     «Preconditions.importedName».checkArgument(defaultValue.isEmpty(), "Invalid value %s", defaultValue);
 439                     return new «genTO.name»(«Empty.importedName».getInstance());
 440                 «ELSE»
 441                     return new «genTO.name»(new «propType.importedName»(defaultValue));
 442                 «ENDIF»
 443             }
 444             «ENDIF»
 445         «ENDIF»
 446     '''
 447
 448     @SuppressFBWarnings(value = "DLS_DEAD_LOCAL_STORE", justification = "FOR with SEPARATOR, not needing for value")
 449     def protected bitsArgs() '''
 450         «JU_LIST.importedName»<«STRING.importedName»> properties = «Lists.importedName».newArrayList(«allProperties.propsAsArgs»);
 451         if (!properties.contains(defaultValue)) {
 452             throw new «IllegalArgumentException.importedName»("invalid default parameter");
 453         }
 454         int i = 0;
 455         return new «genTO.name»(
 456         «FOR prop : allProperties SEPARATOR ","»
 457             properties.get(i++).equals(defaultValue) ? «BOOLEAN.importedName».TRUE : null
 458         «ENDFOR»
 459         );
 460     '''
 461
 462     def protected propsAsArgs(Iterable<GeneratedProperty> properties) '''
 463         «FOR prop : properties SEPARATOR ","»
 464             "«prop.name»"
 465         «ENDFOR»
 466     '''
 467
 468     /**
 469      * Template method which generates JAVA class declaration.
 470      *
 471      * @param isInnerClass boolean value which specify if generated class is|isn't inner
 472      * @return string with class declaration in JAVA format
 473      */
 474     def protected generateClassDeclaration(boolean isInnerClass) '''
 475         public«
 476         IF (isInnerClass)»«
 477             " static final "»«
 478         ELSEIF (type.abstract)»«
 479             " abstract "»«
 480         ELSE»«
 481             " "»«
 482         ENDIF»class «type.name»«
 483         IF (genTO.superType !== null)»«
 484             " extends "»«genTO.superType.importedName»«
 485         ENDIF»
 486         «IF (!type.implements.empty)»«
 487             " implements "»«
 488             FOR type : type.implements SEPARATOR ", "»«
 489                 type.importedName»«
 490             ENDFOR»«
 491         ENDIF
 492     »'''
 493
 494     /**
 495      * Template method which generates JAVA enum type.
 496      *
 497      * @return string with inner enum source code in JAVA format
 498      */
 499     def protected enumDeclarations() '''
 500         «IF !enums.empty»
 501             «FOR e : enums SEPARATOR "\n"»
 502                 «new EnumTemplate(javaType.getEnclosedType(e.identifier), e).generateAsInnerClass»
 503             «ENDFOR»
 504         «ENDIF»
 505     '''
 506
 507     def protected suidDeclaration() '''
 508         «IF genTO.SUID !== null»
 509             private static final long serialVersionUID = «genTO.SUID.value»L;
 510         «ENDIF»
 511     '''
 512
 513     def protected annotationDeclaration() '''
 514         «IF genTO.getAnnotations !== null»
 515             «FOR e : genTO.getAnnotations»
 516                 @«e.getName»
 517             «ENDFOR»
 518         «ENDIF»
 519     '''
 520
 521     /**
 522      * Template method which generates JAVA constants.
 523      *
 524      * @return string with constants in JAVA format
 525      */
 526     def protected constantsDeclarations() '''
 527         «IF !consts.empty»
 528             «FOR c : consts»
 529                 «IF c.name == TypeConstants.PATTERN_CONSTANT_NAME»
 530                     «val cValue = c.value as Map<String, String>»
 531                     «val jurPatternRef = JUR_PATTERN.importedName»
 532                     public static final «JU_LIST.importedName»<String> «TypeConstants.PATTERN_CONSTANT_NAME» = «ImmutableList.importedName».of(«
 533                     FOR v : cValue.keySet SEPARATOR ", "»"«v.escapeJava»"«ENDFOR»);
 534                     «IF cValue.size == 1»
 535                         private static final «jurPatternRef» «Constants.MEMBER_PATTERN_LIST» = «jurPatternRef».compile(«TypeConstants.PATTERN_CONSTANT_NAME».get(0));
 536                         private static final String «Constants.MEMBER_REGEX_LIST» = "«cValue.values.iterator.next.escapeJava»";
 537                     «ELSE»
 538                         private static final «jurPatternRef»[] «Constants.MEMBER_PATTERN_LIST» = «CODEHELPERS.importedName».compilePatterns(«TypeConstants.PATTERN_CONSTANT_NAME»);
 539                         private static final String[] «Constants.MEMBER_REGEX_LIST» = { «
 540                         FOR v : cValue.values SEPARATOR ", "»"«v.escapeJava»"«ENDFOR» };
 541                     «ENDIF»
 542                 «ELSE»
 543                     «emitConstant(c)»
 544                 «ENDIF»
 545             «ENDFOR»
 546         «ENDIF»
 547     '''
 548
 549     /**
 550      * Template method which generates JAVA class attributes.
 551      *
 552      * @return string with the class attributes in JAVA format
 553      */
 554     def protected generateFields() '''
 555         «IF !properties.empty»
 556             «FOR f : properties»
 557                 private«IF isReadOnly(f)» final«ENDIF» «f.returnType.importedName» «f.fieldName»;
 558             «ENDFOR»
 559         «ENDIF»
 560     '''
 561
 562     protected def isReadOnly(GeneratedProperty field) {
 563         return field.readOnly
 564     }
 565
 566     /**
 567      * Template method which generates the method <code>hashCode()</code>.
 568      *
 569      * @return string with the <code>hashCode()</code> method definition in JAVA format
 570      */
 571     def protected generateHashCode() {
 572         val size = genTO.hashCodeIdentifiers.size
 573         if (size == 0) {
 574             return ""
 575         }
 576         return '''
 577             @«OVERRIDE.importedName»
 578             public int hashCode() {
 579                 «IF size != 1»
 580                     final int prime = 31;
 581                     int result = 1;
 582                     «FOR property : genTO.hashCodeIdentifiers»
 583                         result = prime * result + «property.importedUtilClass».hashCode(«property.fieldName»);
 584                     «ENDFOR»
 585                     return result;
 586                 «ELSE»
 587                     return «CODEHELPERS.importedName».wrapperHashCode(«genTO.hashCodeIdentifiers.get(0).fieldName»);
 588                 «ENDIF»
 589             }
 590         '''
 591     }
 592
 593     /**
 594      * Template method which generates the method <code>equals()</code>.
 595      *
 596      * @return string with the <code>equals()</code> method definition in JAVA format
 597      */
 598     def private generateEquals() '''
 599         «IF !genTO.equalsIdentifiers.empty»
 600             @«OVERRIDE.importedName»
 601             public final boolean equals(java.lang.Object obj) {
 602                 if (this == obj) {
 603                     return true;
 604                 }
 605                 if (!(obj instanceof «type.name»)) {
 606                     return false;
 607                 }
 608                 final «type.name» other = («type.name») obj;
 609                 «FOR property : genTO.equalsIdentifiers»
 610                     «val fieldName = property.fieldName»
 611                     if (!«property.importedUtilClass».equals(«fieldName», other.«fieldName»)) {
 612                         return false;
 613                     }
 614                 «ENDFOR»
 615                 return true;
 616             }
 617         «ENDIF»
 618     '''
 619
 620     def private generateToString(Collection<? extends GeneratedProperty> properties) '''
 621         «IF !properties.empty»
 622             @«OVERRIDE.importedName»
 623             public «STRING.importedName» toString() {
 624                 final «MoreObjects.importedName».ToStringHelper helper = «MoreObjects.importedName».toStringHelper(«type.importedName».class);
 625                 «FOR property : properties»
 626                     «CODEHELPERS.importedName».appendValue(helper, "«property.fieldName»", «property.fieldName»);
 627                 «ENDFOR»
 628                 return helper.toString();
 629             }
 630         «ENDIF»
 631     '''
 632
 633     def GeneratedProperty getPropByName(String name) {
 634         for (GeneratedProperty prop : allProperties) {
 635             if (prop.name.equals(name)) {
 636                 return prop;
 637             }
 638         }
 639         return null
 640     }
 641
 642     def private hasUintProperties() {
 643         for (GeneratedProperty prop : allProperties) {
 644             if (prop.isUintType) {
 645                 return true
 646             }
 647         }
 648         return false
 649     }
 650
 651     def private static isUintType(GeneratedProperty prop) {
 652         UINT_TYPES.containsKey(prop.returnType)
 653     }
 654
 655     def private static legacyType(GeneratedProperty prop) {
 656         val type = prop.returnType
 657         val uint = UINT_TYPES.get(type)
 658         if (uint !== null) {
 659             return uint
 660         }
 661         return type
 662     }
 663 }