binding/mdsal-binding-java-api-generator/src/main/java/org/opendaylight/mdsal/binding/java/api/generator/InterfaceTemplate.xtend

   1 /*
   2  * Copyright (c) 2014 Cisco Systems, Inc. and others.  All rights reserved.
   3  *
   4  * This program and the accompanying materials are made available under the
   5  * terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6  * and is available at http://www.eclipse.org/legal/epl-v10.html
   7  */
   8 package org.opendaylight.mdsal.binding.java.api.generator
   9
  10 import static extension org.opendaylight.yangtools.yang.binding.contract.Naming.getGetterMethodForNonnull
  11 import static extension org.opendaylight.yangtools.yang.binding.contract.Naming.getGetterMethodForRequire
  12 import static extension org.opendaylight.yangtools.yang.binding.contract.Naming.isGetterMethodName
  13 import static extension org.opendaylight.yangtools.yang.binding.contract.Naming.isNonnullMethodName
  14 import static extension org.opendaylight.yangtools.yang.binding.contract.Naming.isRequireMethodName
  15 import static org.opendaylight.mdsal.binding.model.ri.Types.BOOLEAN
  16 import static org.opendaylight.mdsal.binding.model.ri.Types.STRING
  17 import static org.opendaylight.yangtools.yang.binding.contract.Naming.REQUIRE_PREFIX
  18 import static org.opendaylight.yangtools.yang.binding.contract.Naming.AUGMENTATION_FIELD
  19 import static org.opendaylight.yangtools.yang.binding.contract.Naming.BINDING_CONTRACT_IMPLEMENTED_INTERFACE_NAME
  20 import static org.opendaylight.yangtools.yang.binding.contract.Naming.BINDING_EQUALS_NAME
  21 import static org.opendaylight.yangtools.yang.binding.contract.Naming.BINDING_HASHCODE_NAME
  22 import static org.opendaylight.yangtools.yang.binding.contract.Naming.BINDING_TO_STRING_NAME
  23
  24 import com.google.common.annotations.VisibleForTesting;
  25 import java.util.List
  26 import java.util.Locale
  27 import java.util.Map.Entry
  28 import java.util.Set
  29 import org.gaul.modernizer_maven_annotations.SuppressModernizer
  30 import org.opendaylight.mdsal.binding.model.api.AnnotationType
  31 import org.opendaylight.mdsal.binding.model.api.Constant
  32 import org.opendaylight.mdsal.binding.model.api.Enumeration
  33 import org.opendaylight.mdsal.binding.model.api.GeneratedType
  34 import org.opendaylight.mdsal.binding.model.api.JavaTypeName
  35 import org.opendaylight.mdsal.binding.model.api.MethodSignature
  36 import org.opendaylight.mdsal.binding.model.api.ParameterizedType
  37 import org.opendaylight.mdsal.binding.model.api.Type
  38 import org.opendaylight.mdsal.binding.model.ri.Types
  39 import org.opendaylight.mdsal.binding.model.ri.TypeConstants
  40
  41 /**
  42  * Template for generating JAVA interfaces.
  43  */
  44 class InterfaceTemplate extends BaseTemplate {
  45     /**
  46      * List of constant instances which are generated as JAVA public static final attributes.
  47      */
  48     val List<Constant> consts
  49
  50     /**
  51      * List of method signatures which are generated as method declarations.
  52      */
  53     val List<MethodSignature> methods
  54
  55     /**
  56      * List of enumeration which are generated as JAVA enum type.
  57      */
  58     val List<Enumeration> enums
  59
  60     /**
  61      * List of generated types which are enclosed inside <code>genType</code>
  62      */
  63     val List<GeneratedType> enclosedGeneratedTypes
  64
  65     var Entry<Type, Set<BuilderGeneratedProperty>> typeAnalysis
  66
  67     /**
  68      * Creates the instance of this class which is used for generating the interface file source
  69      * code from <code>genType</code>.
  70      *
  71      * @throws NullPointerException if <code>genType</code> is <code>null</code>
  72      */
  73     new(GeneratedType genType) {
  74         super(genType)
  75         consts = genType.constantDefinitions
  76         methods = genType.methodDefinitions
  77         enums = genType.enumerations
  78         enclosedGeneratedTypes = genType.enclosedTypes
  79     }
  80
  81     /**
  82      * Template method which generate the whole body of the interface.
  83      *
  84      * @return string with code for interface body in JAVA format
  85      */
  86     override body() '''
  87         «type.formatDataForJavaDoc.wrapToDocumentation»
  88         «type.annotations.generateAnnotations»
  89         «generatedAnnotation»
  90         public interface «type.name»
  91             «superInterfaces»
  92         {
  93
  94             «generateInnerClasses»
  95
  96             «generateEnums»
  97
  98             «generateConstants»
  99
 100             «generateMethods»
 101
 102         }
 103
 104     '''
 105
 106     def private generateAnnotations(List<AnnotationType> annotations) '''
 107         «IF annotations !== null && !annotations.empty»
 108             «FOR annotation : annotations»
 109                 «annotation.generateAnnotation»
 110             «ENDFOR»
 111         «ENDIF»
 112     '''
 113
 114     def private generateAccessorAnnotations(MethodSignature method) '''
 115          «val annotations = method.annotations»
 116          «IF annotations !== null && !annotations.empty»
 117              «FOR annotation : annotations»
 118                   «IF !BOOLEAN.equals(method.returnType) || !OVERRIDE.equals(annotation.identifier)»
 119                       «annotation.generateAnnotation»
 120                   «ENDIF»
 121              «ENDFOR»
 122         «ENDIF»
 123     '''
 124
 125     /**
 126      * Template method which generates the interface name declaration.
 127      *
 128      * @return string with the code for the interface declaration in JAVA format
 129      */
 130     def private superInterfaces()
 131     '''
 132     «IF (!type.implements.empty)»
 133          extends
 134          «FOR type : type.implements SEPARATOR ","»
 135              «type.importedName»
 136          «ENDFOR»
 137      « ENDIF»
 138      '''
 139
 140     /**
 141      * Template method which generates inner classes inside this interface.
 142      *
 143      * @return string with the source code for inner classes in JAVA format
 144      */
 145     def private generateInnerClasses() '''
 146         «IF !enclosedGeneratedTypes.empty»
 147             «FOR innerClass : enclosedGeneratedTypes SEPARATOR "\n"»
 148                 «generateInnerClass(innerClass)»
 149             «ENDFOR»
 150         «ENDIF»
 151     '''
 152
 153     /**
 154      * Template method which generates JAVA enum type.
 155      *
 156      * @return string with inner enum source code in JAVA format
 157      */
 158     def private generateEnums() '''
 159         «IF !enums.empty»
 160             «FOR e : enums SEPARATOR "\n"»
 161                 «val enumTemplate = new EnumTemplate(javaType.getEnclosedType(e.identifier), e)»
 162                 «enumTemplate.generateAsInnerClass»
 163             «ENDFOR»
 164         «ENDIF»
 165     '''
 166
 167     /**
 168      * Template method which generates JAVA constants.
 169      *
 170      * @return string with constants in JAVA format
 171      */
 172     def private generateConstants() '''
 173         «IF !consts.empty»
 174             «FOR c : consts»
 175                 «IF !c.name.startsWith(TypeConstants.PATTERN_CONSTANT_NAME)»
 176                     «emitConstant(c)»
 177                 «ENDIF»
 178             «ENDFOR»
 179         «ENDIF»
 180     '''
 181
 182     /**
 183      * Template method which generates the declaration of the methods.
 184      *
 185      * @return string with the declaration of methods source code in JAVA format
 186      */
 187     def private generateMethods() '''
 188         «IF !methods.empty»
 189             «FOR m : methods SEPARATOR "\n"»
 190                 «IF m.isDefault»
 191                     «generateDefaultMethod(m)»
 192                 «ELSEIF m.isStatic»
 193                     «generateStaticMethod(m)»
 194                 «ELSEIF m.parameters.empty && m.name.isGetterMethodName»
 195                     «generateAccessorMethod(m)»
 196                 «ELSEIF m.parameters.empty && m.name.isNonnullMethodName»
 197                     «generateNonnullAccessorMethod(m)»
 198                 «ELSE»
 199                     «generateMethod(m)»
 200                 «ENDIF»
 201             «ENDFOR»
 202         «ENDIF»
 203     '''
 204
 205     @SuppressModernizer
 206     def private generateDefaultMethod(MethodSignature method) {
 207         if (method.name.isNonnullMethodName) {
 208             generateNonnullMethod(method)
 209         } else if (method.name.isRequireMethodName) {
 210             generateRequireMethod(method)
 211         } else {
 212             switch method.name {
 213                 case BINDING_CONTRACT_IMPLEMENTED_INTERFACE_NAME : generateDefaultImplementedInterface
 214                 default :
 215                     if (VOID.equals(method.returnType.identifier)) {
 216                         generateNoopVoidInterfaceMethod(method)
 217                     }
 218             }
 219         }
 220     }
 221
 222     @SuppressModernizer
 223     def private generateStaticMethod(MethodSignature method) {
 224         switch method.name {
 225             case BINDING_EQUALS_NAME : generateBindingEquals
 226             case BINDING_HASHCODE_NAME : generateBindingHashCode
 227             case BINDING_TO_STRING_NAME : generateBindingToString
 228             default : ""
 229         }
 230     }
 231
 232     def private generateMethod(MethodSignature method) '''
 233         «method.comment.asJavadoc»
 234         «method.annotations.generateAnnotations»
 235         «method.returnType.importedName» «method.name»(«method.parameters.generateParameters»);
 236     '''
 237
 238     def private generateNoopVoidInterfaceMethod(MethodSignature method) '''
 239         «method.comment.asJavadoc»
 240         «method.annotations.generateAnnotations»
 241         default «VOID.importedName» «method.name»(«method.parameters.generateParameters») {
 242             // No-op
 243         }
 244     '''
 245
 246     def private accessorJavadoc(MethodSignature method, String orString) {
 247         accessorJavadoc(method, orString, null)
 248     }
 249
 250     def private accessorJavadoc(MethodSignature method, String orString, JavaTypeName exception) {
 251         val propName = method.propertyNameFromGetter
 252         val propReturn = propName + orString
 253
 254         return wrapToDocumentation('''
 255             Return «propReturn»
 256
 257             «method.comment?.referenceDescription.formatReference»
 258             @return {@code «method.returnType.importedName»} «propReturn»
 259             «IF exception !== null»
 260                 @throws «exception.importedName» if «propName» is not present
 261             «ENDIF»
 262         ''')
 263     }
 264
 265     def private generateAccessorMethod(MethodSignature method) {
 266         return '''
 267             «accessorJavadoc(method, ", or {@code null} if it is not present.")»
 268             «method.generateAccessorAnnotations»
 269             «method.returnType.nullableType» «method.name»();
 270         '''
 271     }
 272
 273     def private generateNonnullAccessorMethod(MethodSignature method) {
 274         return '''
 275             «accessorJavadoc(method, ", or an empty instance if it is not present.")»
 276             «method.annotations.generateAnnotations»
 277             «method.returnType.importedNonNull» «method.name»();
 278         '''
 279     }
 280
 281     def private generateDefaultImplementedInterface() '''
 282         @«OVERRIDE.importedName»
 283         default «CLASS.importedName»<«type.fullyQualifiedName»> «BINDING_CONTRACT_IMPLEMENTED_INTERFACE_NAME»() {
 284             return «type.fullyQualifiedName».class;
 285         }
 286     '''
 287
 288     @VisibleForTesting
 289     def generateBindingHashCode() '''
 290         «val augmentable = analyzeType»
 291         «IF augmentable || !typeAnalysis.value.empty»
 292             /**
 293              * Default implementation of {@link «Object.importedName»#hashCode()} contract for this interface.
 294              * Implementations of this interface are encouraged to defer to this method to get consistent hashing
 295              * results across all implementations.
 296              *
 297              * @param obj Object for which to generate hashCode() result.
 298              * @return Hash code value of data modeled by this interface.
 299              * @throws «NPE.importedName» if {@code obj} is {@code null}
 300              */
 301             static int «BINDING_HASHCODE_NAME»(final «type.fullyQualifiedNonNull» obj) {
 302                 final int prime = 31;
 303                 int result = 1;
 304                 «FOR property : typeAnalysis.value»
 305                     result = prime * result + «property.importedUtilClass».hashCode(obj.«property.getterMethodName»());
 306                 «ENDFOR»
 307                 «IF augmentable»
 308                     for (var augmentation : obj.augmentations().values()) {
 309                         result += augmentation.hashCode();
 310                     }
 311                 «ENDIF»
 312                 return result;
 313             }
 314         «ENDIF»
 315     '''
 316
 317     def private generateBindingEquals() '''
 318         «val augmentable = analyzeType»
 319         «IF augmentable || !typeAnalysis.value.isEmpty»
 320             /**
 321              * Default implementation of {@link «Object.importedName»#equals(«Object.importedName»)} contract for this interface.
 322              * Implementations of this interface are encouraged to defer to this method to get consistent equality
 323              * results across all implementations.
 324              *
 325              * @param thisObj Object acting as the receiver of equals invocation
 326              * @param obj Object acting as argument to equals invocation
 327              * @return True if thisObj and obj are considered equal
 328              * @throws «NPE.importedName» if {@code thisObj} is {@code null}
 329              */
 330             static boolean «BINDING_EQUALS_NAME»(final «type.fullyQualifiedNonNull» thisObj, final «Types.objectType().importedName» obj) {
 331                 if (thisObj == obj) {
 332                     return true;
 333                 }
 334                 final var other = «CODEHELPERS.importedName».checkCast(«type.fullyQualifiedName».class, obj);
 335                 return other != null
 336                     «FOR property : ByTypeMemberComparator.sort(typeAnalysis.value)»
 337                         && «property.importedUtilClass».equals(thisObj.«property.getterName»(), other.«property.getterName»())
 338                     «ENDFOR»
 339                     «IF augmentable»&& thisObj.augmentations().equals(other.augmentations())«ENDIF»;
 340             }
 341         «ENDIF»
 342     '''
 343
 344     def generateBindingToString() '''
 345         «val augmentable = analyzeType»
 346         /**
 347          * Default implementation of {@link «Object.importedName»#toString()} contract for this interface.
 348          * Implementations of this interface are encouraged to defer to this method to get consistent string
 349          * representations across all implementations.
 350          *
 351          * @param obj Object for which to generate toString() result.
 352          * @return {@link «STRING.importedName»} value of data modeled by this interface.
 353          * @throws «NPE.importedName» if {@code obj} is {@code null}
 354          */
 355         static «STRING.importedName» «BINDING_TO_STRING_NAME»(final «type.fullyQualifiedNonNull» obj) {
 356             final var helper = «MOREOBJECTS.importedName».toStringHelper("«type.name»");
 357             «FOR property : typeAnalysis.value»
 358                 «CODEHELPERS.importedName».appendValue(helper, "«property.name»", obj.«property.getterName»());
 359             «ENDFOR»
 360             «IF augmentable»
 361                 «CODEHELPERS.importedName».appendAugmentations(helper, "«AUGMENTATION_FIELD»", obj);
 362             «ENDIF»
 363             return helper.toString();
 364         }
 365     '''
 366
 367     def private generateNonnullMethod(MethodSignature method) '''
 368         «val ret = method.returnType»
 369         «val name = method.name»
 370         «accessorJavadoc(method, ", or an empty list if it is not present.")»
 371         «method.annotations.generateAnnotations»
 372         default «ret.importedNonNull» «name»() {
 373             return «CODEHELPERS.importedName».nonnull(«name.getGetterMethodForNonnull»());
 374         }
 375     '''
 376
 377     def private generateRequireMethod(MethodSignature method) '''
 378         «val ret = method.returnType»
 379         «val name = method.name»
 380         «val fieldName = name.toLowerCase(Locale.ROOT).replace(REQUIRE_PREFIX, "")»
 381         «accessorJavadoc(method, ", guaranteed to be non-null.", NSEE)»
 382         default «ret.importedNonNull» «name»() {
 383             return «CODEHELPERS.importedName».require(«getGetterMethodForRequire(name)»(), "«fieldName»");
 384         }
 385     '''
 386
 387     def private String nullableType(Type type) {
 388         if (type.isObject && type instanceof ParameterizedType) {
 389             val param = type as ParameterizedType
 390             if (Types.isMapType(param) || Types.isListType(param) || Types.isSetType(param)) {
 391                 return type.importedNullable
 392             }
 393         }
 394         return type.importedName
 395     }
 396
 397     def private static boolean isObject(Type type) {
 398         // The return type has a package, so it's not a primitive type
 399         return !type.getPackageName().isEmpty()
 400     }
 401
 402     private def boolean analyzeType() {
 403         if (typeAnalysis === null) {
 404             typeAnalysis = analyzeTypeHierarchy(type)
 405         }
 406         typeAnalysis.key !== null
 407     }
 408 }