binding/mdsal-binding-java-api-generator/src/main/java/org/opendaylight/mdsal/binding/java/api/generator/InterfaceTemplate.xtend

   1 /*
   2  * Copyright (c) 2014 Cisco Systems, Inc. and others.  All rights reserved.
   3  *
   4  * This program and the accompanying materials are made available under the
   5  * terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6  * and is available at http://www.eclipse.org/legal/epl-v10.html
   7  */
   8 package org.opendaylight.mdsal.binding.java.api.generator
   9
  10 import static extension org.opendaylight.mdsal.binding.spec.naming.BindingMapping.getGetterMethodForNonnull
  11 import static extension org.opendaylight.mdsal.binding.spec.naming.BindingMapping.getGetterMethodForRequire
  12 import static extension org.opendaylight.mdsal.binding.spec.naming.BindingMapping.isGetterMethodName
  13 import static extension org.opendaylight.mdsal.binding.spec.naming.BindingMapping.isNonnullMethodName
  14 import static extension org.opendaylight.mdsal.binding.spec.naming.BindingMapping.isRequireMethodName
  15 import static org.opendaylight.mdsal.binding.model.ri.Types.BOOLEAN
  16 import static org.opendaylight.mdsal.binding.model.ri.Types.STRING
  17 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.REQUIRE_PREFIX
  18 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.AUGMENTATION_FIELD
  19 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.BINDING_CONTRACT_IMPLEMENTED_INTERFACE_NAME
  20 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.BINDING_EQUALS_NAME
  21 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.BINDING_HASHCODE_NAME
  22 import static org.opendaylight.mdsal.binding.spec.naming.BindingMapping.BINDING_TO_STRING_NAME
  23
  24 import com.google.common.annotations.VisibleForTesting;
  25 import java.util.List
  26 import java.util.Locale
  27 import java.util.Map.Entry
  28 import java.util.Set
  29 import org.gaul.modernizer_maven_annotations.SuppressModernizer
  30 import org.opendaylight.mdsal.binding.model.api.AnnotationType
  31 import org.opendaylight.mdsal.binding.model.api.Constant
  32 import org.opendaylight.mdsal.binding.model.api.Enumeration
  33 import org.opendaylight.mdsal.binding.model.api.GeneratedType
  34 import org.opendaylight.mdsal.binding.model.api.JavaTypeName
  35 import org.opendaylight.mdsal.binding.model.api.MethodSignature
  36 import org.opendaylight.mdsal.binding.model.api.ParameterizedType
  37 import org.opendaylight.mdsal.binding.model.api.Type
  38 import org.opendaylight.mdsal.binding.model.ri.Types
  39 import org.opendaylight.mdsal.binding.model.ri.TypeConstants
  40
  41 /**
  42  * Template for generating JAVA interfaces.
  43  */
  44 class InterfaceTemplate extends BaseTemplate {
  45     /**
  46      * List of constant instances which are generated as JAVA public static final attributes.
  47      */
  48     val List<Constant> consts
  49
  50     /**
  51      * List of method signatures which are generated as method declarations.
  52      */
  53     val List<MethodSignature> methods
  54
  55     /**
  56      * List of enumeration which are generated as JAVA enum type.
  57      */
  58     val List<Enumeration> enums
  59
  60     /**
  61      * List of generated types which are enclosed inside <code>genType</code>
  62      */
  63     val List<GeneratedType> enclosedGeneratedTypes
  64
  65     var Entry<Type, Set<BuilderGeneratedProperty>> typeAnalysis
  66
  67     /**
  68      * Creates the instance of this class which is used for generating the interface file source
  69      * code from <code>genType</code>.
  70      *
  71      * @throws NullPointerException if <code>genType</code> is <code>null</code>
  72      */
  73     new(GeneratedType genType) {
  74         super(genType)
  75         consts = genType.constantDefinitions
  76         methods = genType.methodDefinitions
  77         enums = genType.enumerations
  78         enclosedGeneratedTypes = genType.enclosedTypes
  79     }
  80
  81     /**
  82      * Template method which generate the whole body of the interface.
  83      *
  84      * @return string with code for interface body in JAVA format
  85      */
  86     override body() '''
  87         «type.formatDataForJavaDoc.wrapToDocumentation»
  88         «type.annotations.generateAnnotations»
  89         «generatedAnnotation»
  90         public interface «type.name»
  91             «superInterfaces»
  92         {
  93
  94             «generateInnerClasses»
  95
  96             «generateEnums»
  97
  98             «generateConstants»
  99
 100             «generateMethods»
 101
 102         }
 103
 104     '''
 105
 106     def private generateAnnotations(List<AnnotationType> annotations) '''
 107         «IF annotations !== null && !annotations.empty»
 108             «FOR annotation : annotations»
 109                 «annotation.generateAnnotation»
 110             «ENDFOR»
 111         «ENDIF»
 112     '''
 113
 114     def private generateAccessorAnnotations(MethodSignature method) '''
 115          «val annotations = method.annotations»
 116          «IF annotations !== null && !annotations.empty»
 117              «FOR annotation : annotations»
 118                   «IF !BOOLEAN.equals(method.returnType) || !OVERRIDE.equals(annotation.identifier)»
 119                       «annotation.generateAnnotation»
 120                   «ENDIF»
 121              «ENDFOR»
 122         «ENDIF»
 123     '''
 124
 125     /**
 126      * Template method which generates the interface name declaration.
 127      *
 128      * @return string with the code for the interface declaration in JAVA format
 129      */
 130     def private superInterfaces()
 131     '''
 132     «IF (!type.implements.empty)»
 133          extends
 134          «FOR type : type.implements SEPARATOR ","»
 135              «type.importedName»
 136          «ENDFOR»
 137      « ENDIF»
 138      '''
 139
 140     /**
 141      * Template method which generates inner classes inside this interface.
 142      *
 143      * @return string with the source code for inner classes in JAVA format
 144      */
 145     def private generateInnerClasses() '''
 146         «IF !enclosedGeneratedTypes.empty»
 147             «FOR innerClass : enclosedGeneratedTypes SEPARATOR "\n"»
 148                 «generateInnerClass(innerClass)»
 149             «ENDFOR»
 150         «ENDIF»
 151     '''
 152
 153     /**
 154      * Template method which generates JAVA enum type.
 155      *
 156      * @return string with inner enum source code in JAVA format
 157      */
 158     def private generateEnums() '''
 159         «IF !enums.empty»
 160             «FOR e : enums SEPARATOR "\n"»
 161                 «val enumTemplate = new EnumTemplate(javaType.getEnclosedType(e.identifier), e)»
 162                 «enumTemplate.generateAsInnerClass»
 163             «ENDFOR»
 164         «ENDIF»
 165     '''
 166
 167     /**
 168      * Template method which generates JAVA constants.
 169      *
 170      * @return string with constants in JAVA format
 171      */
 172     def private generateConstants() '''
 173         «IF !consts.empty»
 174             «FOR c : consts»
 175                 «IF !c.name.startsWith(TypeConstants.PATTERN_CONSTANT_NAME)»
 176                     «emitConstant(c)»
 177                 «ENDIF»
 178             «ENDFOR»
 179         «ENDIF»
 180     '''
 181
 182     /**
 183      * Template method which generates the declaration of the methods.
 184      *
 185      * @return string with the declaration of methods source code in JAVA format
 186      */
 187     def private generateMethods() '''
 188         «IF !methods.empty»
 189             «FOR m : methods SEPARATOR "\n"»
 190                 «IF m.isDefault»
 191                     «generateDefaultMethod(m)»
 192                 «ELSEIF m.isStatic»
 193                     «generateStaticMethod(m)»
 194                 «ELSEIF m.parameters.empty && m.name.isGetterMethodName»
 195                     «generateAccessorMethod(m)»
 196                 «ELSE»
 197                     «generateMethod(m)»
 198                 «ENDIF»
 199             «ENDFOR»
 200         «ENDIF»
 201     '''
 202
 203     @SuppressModernizer
 204     def private generateDefaultMethod(MethodSignature method) {
 205         if (method.name.isNonnullMethodName) {
 206             generateNonnullMethod(method)
 207         } else if (method.name.isRequireMethodName) {
 208             generateRequireMethod(method)
 209         } else {
 210             switch method.name {
 211                 case BINDING_CONTRACT_IMPLEMENTED_INTERFACE_NAME : generateDefaultImplementedInterface
 212                 default :
 213                     if (VOID.equals(method.returnType.identifier)) {
 214                         generateNoopVoidInterfaceMethod(method)
 215                     }
 216             }
 217         }
 218     }
 219
 220     @SuppressModernizer
 221     def private generateStaticMethod(MethodSignature method) {
 222         switch method.name {
 223             case BINDING_EQUALS_NAME : generateBindingEquals
 224             case BINDING_HASHCODE_NAME : generateBindingHashCode
 225             case BINDING_TO_STRING_NAME : generateBindingToString
 226             default : ""
 227         }
 228     }
 229
 230     def private generateMethod(MethodSignature method) '''
 231         «method.comment.asJavadoc»
 232         «method.annotations.generateAnnotations»
 233         «method.returnType.importedName» «method.name»(«method.parameters.generateParameters»);
 234     '''
 235
 236     def private generateNoopVoidInterfaceMethod(MethodSignature method) '''
 237         «method.comment.asJavadoc»
 238         «method.annotations.generateAnnotations»
 239         default «VOID.importedName» «method.name»(«method.parameters.generateParameters») {
 240             // No-op
 241         }
 242     '''
 243
 244     def private accessorJavadoc(MethodSignature method, String orString) {
 245         accessorJavadoc(method, orString, null)
 246     }
 247
 248     def private accessorJavadoc(MethodSignature method, String orString, JavaTypeName exception) {
 249         val propName = method.propertyNameFromGetter
 250         val propReturn = propName + orString
 251
 252         return wrapToDocumentation('''
 253             Return «propReturn»
 254
 255             «method.comment?.referenceDescription.formatReference»
 256             @return {@code «method.returnType.importedName»} «propReturn»
 257             «IF exception !== null»
 258                 @throws «exception.importedName» if «propName» is not present
 259             «ENDIF»
 260         ''')
 261     }
 262
 263     def private generateAccessorMethod(MethodSignature method) {
 264         return '''
 265             «accessorJavadoc(method, ", or {@code null} if it is not present.")»
 266             «method.generateAccessorAnnotations»
 267             «method.returnType.nullableType» «method.name»();
 268         '''
 269     }
 270
 271     def private generateDefaultImplementedInterface() '''
 272         @«OVERRIDE.importedName»
 273         default «CLASS.importedName»<«type.fullyQualifiedName»> «BINDING_CONTRACT_IMPLEMENTED_INTERFACE_NAME»() {
 274             return «type.fullyQualifiedName».class;
 275         }
 276     '''
 277
 278     @VisibleForTesting
 279     def generateBindingHashCode() '''
 280         «val augmentable = analyzeType»
 281         «IF augmentable || !typeAnalysis.value.empty»
 282             /**
 283              * Default implementation of {@link «Object.importedName»#hashCode()} contract for this interface.
 284              * Implementations of this interface are encouraged to defer to this method to get consistent hashing
 285              * results across all implementations.
 286              *
 287              * @param obj Object for which to generate hashCode() result.
 288              * @return Hash code value of data modeled by this interface.
 289              * @throws «NPE.importedName» if {@code obj} is null
 290              */
 291             static int «BINDING_HASHCODE_NAME»(final «type.fullyQualifiedNonNull» obj) {
 292                 final int prime = 31;
 293                 int result = 1;
 294                 «FOR property : typeAnalysis.value»
 295                     result = prime * result + «property.importedUtilClass».hashCode(obj.«property.getterMethodName»());
 296                 «ENDFOR»
 297                 «IF augmentable»
 298                     for (var augmentation : obj.augmentations().values()) {
 299                         result += augmentation.hashCode();
 300                     }
 301                 «ENDIF»
 302                 return result;
 303             }
 304         «ENDIF»
 305     '''
 306
 307     def private generateBindingEquals() '''
 308         «val augmentable = analyzeType»
 309         «IF augmentable || !typeAnalysis.value.isEmpty»
 310             /**
 311              * Default implementation of {@link «Object.importedName»#equals(«Object.importedName»)} contract for this interface.
 312              * Implementations of this interface are encouraged to defer to this method to get consistent equality
 313              * results across all implementations.
 314              *
 315              * @param thisObj Object acting as the receiver of equals invocation
 316              * @param obj Object acting as argument to equals invocation
 317              * @return True if thisObj and obj are considered equal
 318              * @throws «NPE.importedName» if {@code thisObj} is null
 319              */
 320             static boolean «BINDING_EQUALS_NAME»(final «type.fullyQualifiedNonNull» thisObj, final «Types.objectType().importedName» obj) {
 321                 if (thisObj == obj) {
 322                     return true;
 323                 }
 324                 final «type.fullyQualifiedName» other = «CODEHELPERS.importedName».checkCast(«type.fullyQualifiedName».class, obj);
 325                 if (other == null) {
 326                     return false;
 327                 }
 328                 «FOR property : ByTypeMemberComparator.sort(typeAnalysis.value)»
 329                     if (!«property.importedUtilClass».equals(thisObj.«property.getterName»(), other.«property.getterName»())) {
 330                         return false;
 331                     }
 332                 «ENDFOR»
 333                 return «IF augmentable»thisObj.augmentations().equals(other.augmentations())«ELSE»true«ENDIF»;
 334             }
 335         «ENDIF»
 336     '''
 337
 338     def generateBindingToString() '''
 339         «val augmentable = analyzeType»
 340         /**
 341          * Default implementation of {@link «Object.importedName»#toString()} contract for this interface.
 342          * Implementations of this interface are encouraged to defer to this method to get consistent string
 343          * representations across all implementations.
 344          *
 345          * @param obj Object for which to generate toString() result.
 346          * @return {@link «STRING.importedName»} value of data modeled by this interface.
 347          * @throws «NPE.importedName» if {@code obj} is null
 348          */
 349         static «STRING.importedName» «BINDING_TO_STRING_NAME»(final «type.fullyQualifiedNonNull» obj) {
 350             final var helper = «MOREOBJECTS.importedName».toStringHelper("«type.name»");
 351             «FOR property : typeAnalysis.value»
 352                 «CODEHELPERS.importedName».appendValue(helper, "«property.name»", obj.«property.getterName»());
 353             «ENDFOR»
 354             «IF augmentable»
 355                 «CODEHELPERS.importedName».appendAugmentations(helper, "«AUGMENTATION_FIELD»", obj);
 356             «ENDIF»
 357             return helper.toString();
 358         }
 359     '''
 360
 361     def private generateNonnullMethod(MethodSignature method) '''
 362         «val ret = method.returnType»
 363         «val name = method.name»
 364         «accessorJavadoc(method, ", or an empty list if it is not present.")»
 365         «method.annotations.generateAnnotations»
 366         default «ret.importedNonNull» «name»() {
 367             return «CODEHELPERS.importedName».nonnull(«name.getGetterMethodForNonnull»());
 368         }
 369     '''
 370
 371     def private generateRequireMethod(MethodSignature method) '''
 372         «val ret = method.returnType»
 373         «val name = method.name»
 374         «val fieldName = name.toLowerCase(Locale.ROOT).replace(REQUIRE_PREFIX, "")»
 375         «accessorJavadoc(method, ", guaranteed to be non-null.", NSEE)»
 376         default «ret.importedNonNull» «name»() {
 377             return «CODEHELPERS.importedName».require(«getGetterMethodForRequire(name)»(), "«fieldName»");
 378         }
 379     '''
 380
 381     def private String nullableType(Type type) {
 382         if (type.isObject && type instanceof ParameterizedType) {
 383             val param = type as ParameterizedType
 384             if (Types.isMapType(param) || Types.isListType(param) || Types.isSetType(param)) {
 385                 return type.importedNullable
 386             }
 387         }
 388         return type.importedName
 389     }
 390
 391     def private static boolean isObject(Type type) {
 392         // The return type has a package, so it's not a primitive type
 393         return !type.getPackageName().isEmpty()
 394     }
 395
 396     private def boolean analyzeType() {
 397         if (typeAnalysis === null) {
 398             typeAnalysis = analyzeTypeHierarchy(type)
 399         }
 400         typeAnalysis.key !== null
 401     }
 402 }