code-generator/binding-generator-impl/src/main/java/org/opendaylight/yangtools/sal/binding/generator/impl/BindingGeneratorImpl.xtend

   1 /*
   2  * Copyright (c) 2013 Cisco Systems, Inc. and others.  All rights reserved.
   3  *
   4  * This program and the accompanying materials are made available under the
   5  * terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6  * and is available at http://www.eclipse.org/legal/epl-v10.html
   7  */
   8 package org.opendaylight.yangtools.sal.binding.generator.impl;
   9
  10 import static com.google.common.base.Preconditions.*;
  11 import static extension org.opendaylight.yangtools.binding.generator.util.Types.*;
  12 import static org.opendaylight.yangtools.binding.generator.util.BindingGeneratorUtil.*;
  13 import static org.opendaylight.yangtools.binding.generator.util.BindingTypes.*;
  14 import static org.opendaylight.yangtools.yang.model.util.SchemaContextUtil.*;
  15
  16 import java.util.ArrayList;
  17 import java.util.Collections;
  18 import java.util.HashMap;
  19 import java.util.List;
  20 import java.util.Map;
  21 import java.util.Set;
  22 import java.util.Iterator
  23 import java.util.Collection
  24 import org.opendaylight.yangtools.binding.generator.util.BindingTypes;
  25 import org.opendaylight.yangtools.binding.generator.util.ReferencedTypeImpl;
  26 import org.opendaylight.yangtools.binding.generator.util.Types;
  27 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedTOBuilderImpl;
  28 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedTypeBuilderImpl;
  29 import org.opendaylight.yangtools.sal.binding.generator.api.BindingGenerator;
  30 import org.opendaylight.yangtools.sal.binding.generator.spi.TypeProvider;
  31 import org.opendaylight.yangtools.sal.binding.model.api.AccessModifier;
  32 import org.opendaylight.yangtools.sal.binding.model.api.Type;
  33 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.EnumBuilder;
  34 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTOBuilder;
  35 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTypeBuilder;
  36 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.MethodSignatureBuilder;
  37 import org.opendaylight.yangtools.sal.binding.yang.types.GroupingDefinitionDependencySort;
  38 import org.opendaylight.yangtools.sal.binding.yang.types.TypeProviderImpl;
  39 import org.opendaylight.yangtools.yang.binding.RpcService;
  40 import org.opendaylight.yangtools.yang.common.RpcResult;
  41 import org.opendaylight.yangtools.yang.model.api.AugmentationSchema;
  42 import org.opendaylight.yangtools.yang.model.api.ChoiceCaseNode;
  43 import org.opendaylight.yangtools.yang.model.api.ChoiceNode;
  44 import org.opendaylight.yangtools.yang.model.api.ContainerSchemaNode;
  45 import org.opendaylight.yangtools.yang.model.api.DataNodeContainer;
  46 import org.opendaylight.yangtools.yang.model.api.DataSchemaNode;
  47 import org.opendaylight.yangtools.yang.model.api.GroupingDefinition;
  48 import org.opendaylight.yangtools.yang.model.api.IdentitySchemaNode;
  49 import org.opendaylight.yangtools.yang.model.api.LeafListSchemaNode;
  50 import org.opendaylight.yangtools.yang.model.api.LeafSchemaNode;
  51 import org.opendaylight.yangtools.yang.model.api.ListSchemaNode;
  52 import org.opendaylight.yangtools.yang.model.api.Module;
  53 import org.opendaylight.yangtools.yang.model.api.RpcDefinition;
  54 import org.opendaylight.yangtools.yang.model.api.SchemaContext;
  55 import org.opendaylight.yangtools.yang.model.api.SchemaNode;
  56 import org.opendaylight.yangtools.yang.model.api.SchemaPath;
  57 import org.opendaylight.yangtools.yang.model.api.TypeDefinition;
  58 import org.opendaylight.yangtools.yang.model.api.UnknownSchemaNode;
  59 import org.opendaylight.yangtools.yang.model.api.type.BitsTypeDefinition;
  60 import org.opendaylight.yangtools.yang.model.api.type.EnumTypeDefinition;
  61 import org.opendaylight.yangtools.yang.model.api.type.UnionTypeDefinition;
  62 import org.opendaylight.yangtools.yang.model.util.DataNodeIterator;
  63 import org.opendaylight.yangtools.yang.model.util.SchemaContextUtil;
  64 import org.opendaylight.yangtools.yang.model.util.UnionType;
  65 import org.opendaylight.yangtools.yang.parser.util.ModuleDependencySort
  66 import org.opendaylight.yangtools.yang.model.util.ExtendedType;
  67 import org.opendaylight.yangtools.yang.model.api.UsesNode
  68 import org.opendaylight.yangtools.yang.binding.annotations.RoutingContext
  69 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.AnnotationTypeBuilder
  70 import org.opendaylight.yangtools.yang.model.api.ModuleImport
  71 import org.opendaylight.yangtools.yang.binding.DataContainer
  72 import org.opendaylight.yangtools.yang.model.api.NotificationDefinition
  73 import org.opendaylight.yangtools.binding.generator.util.BindingGeneratorUtil
  74 import org.opendaylight.yangtools.sal.binding.model.api.Restrictions
  75 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedPropertyBuilder
  76 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedPropertyBuilderImpl
  77 import org.opendaylight.yangtools.yang.common.QName
  78 import org.opendaylight.yangtools.yang.binding.BindingMapping
  79 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTypeBuilderBase
  80
  81 import com.google.common.collect.Sets
  82 import java.util.TreeSet
  83
  84 public class BindingGeneratorImpl implements BindingGenerator {
  85
  86     private final Map<Module, ModuleContext> genCtx = new HashMap()
  87
  88     /**
  89      * Outer key represents the package name. Outer value represents map of
  90      * all builders in the same package. Inner key represents the schema node
  91      * name (in JAVA class/interface name format). Inner value represents
  92      * instance of builder for schema node specified in key part.
  93      */
  94     private Map<String, Map<String, GeneratedTypeBuilder>> genTypeBuilders;
  95
  96     /**
  97      * Provide methods for converting YANG types to JAVA types.
  98      */
  99     private var TypeProvider typeProvider;
 100
 101     /**
 102      * Holds reference to schema context to resolve data of augmented element
 103      * when creating augmentation builder
 104      */
 105     private var SchemaContext schemaContext;
 106
 107     /**
 108      * Constant with the concrete name of namespace.
 109      */
 110     private val static String YANG_EXT_NAMESPACE = "urn:opendaylight:yang:extension:yang-ext";
 111
 112     /**
 113      * Constant with the concrete name of identifier.
 114      */
 115     private val static String AUGMENT_IDENTIFIER_NAME = "augment-identifier";
 116
 117     /**
 118      * Resolves generated types from <code>context</code> schema nodes of all
 119      * modules.
 120      *
 121      * Generated types are created for modules, groupings, types, containers,
 122      * lists, choices, augments, rpcs, notification, identities.
 123      *
 124      * @param context
 125      *            schema context which contains data about all schema nodes
 126      *            saved in modules
 127      * @return list of types (usually <code>GeneratedType</code>
 128      *         <code>GeneratedTransferObject</code>which are generated from
 129      *         <code>context</code> data.
 130      * @throws IllegalArgumentException
 131      *             if param <code>context</code> is null
 132      * @throws IllegalStateException
 133      *             if <code>context</code> contain no modules
 134      */
 135     override generateTypes(SchemaContext context) {
 136         checkArgument(context !== null, "Schema Context reference cannot be NULL.");
 137         checkState(context.modules !== null, "Schema Context does not contain defined modules.");
 138         schemaContext = context;
 139         typeProvider = new TypeProviderImpl(context);
 140         val Set<Module> modules = context.modules;
 141         return generateTypes(context, modules);
 142     }
 143
 144     /**
 145      * Resolves generated types from <code>context</code> schema nodes only for
 146      * modules specified in <code>modules</code>
 147      *
 148      * Generated types are created for modules, groupings, types, containers,
 149      * lists, choices, augments, rpcs, notification, identities.
 150      *
 151      * @param context
 152      *            schema context which contains data about all schema nodes
 153      *            saved in modules
 154      * @param modules
 155      *            set of modules for which schema nodes should be generated
 156      *            types
 157      * @return list of types (usually <code>GeneratedType</code> or
 158      *         <code>GeneratedTransferObject</code>) which:
 159      *         <ul>
 160      *         <li>are generated from <code>context</code> schema nodes and</li>
 161      *         <li>are also part of some of the module in <code>modules</code>
 162      *         set</li>.
 163      *         </ul>
 164      * @throws IllegalArgumentException
 165      *             <ul>
 166      *             <li>if param <code>context</code> is null or</li>
 167      *             <li>if param <code>modules</code> is null</li>
 168      *             </ul>
 169      * @throws IllegalStateException
 170      *             if <code>context</code> contain no modules
 171      */
 172     override generateTypes(SchemaContext context, Set<Module> modules) {
 173         checkArgument(context !== null, "Schema Context reference cannot be NULL.");
 174         checkState(context.modules !== null, "Schema Context does not contain defined modules.");
 175         checkArgument(modules !== null, "Set of Modules cannot be NULL.");
 176
 177         schemaContext = context;
 178         typeProvider = new TypeProviderImpl(context);
 179         val contextModules = ModuleDependencySort.sort(context.modules);
 180         genTypeBuilders = new HashMap();
 181
 182         for (contextModule : contextModules) {
 183             moduleToGenTypes(contextModule, context);
 184         }
 185         for (contextModule : contextModules) {
 186             allAugmentsToGenTypes(contextModule);
 187         }
 188
 189         val List<Type> filteredGenTypes = new ArrayList();
 190         for (Module m : modules) {
 191             val ctx = checkNotNull(genCtx.get(m), "Module context not found for module %s", m)
 192             filteredGenTypes.addAll(ctx.generatedTypes);
 193             val Set<Type> additionalTypes = (typeProvider as TypeProviderImpl).additionalTypes.get(m)
 194             if (additionalTypes != null) {
 195                 filteredGenTypes.addAll(additionalTypes)
 196             }
 197         }
 198
 199         return filteredGenTypes;
 200     }
 201
 202     private def void moduleToGenTypes(Module m, SchemaContext context) {
 203         genCtx.put(m, new ModuleContext)
 204         allTypeDefinitionsToGenTypes(m)
 205         groupingsToGenTypes(m, m.groupings)
 206         rpcMethodsToGenType(m)
 207         allIdentitiesToGenTypes(m, context)
 208         notificationsToGenType(m)
 209
 210         if (!m.childNodes.isEmpty()) {
 211             val moduleType = moduleToDataType(m)
 212             genCtx.get(m).addModuleNode(moduleType)
 213             val basePackageName = moduleNamespaceToPackageName(m);
 214             resolveDataSchemaNodes(m, basePackageName, moduleType, moduleType, m.childNodes)
 215         }
 216     }
 217
 218     /**
 219      * Converts all extended type definitions of module to the list of
 220      * <code>Type</code> objects.
 221      *
 222      * @param module
 223      *            module from which is obtained set of type definitions
 224      * @throws IllegalArgumentException
 225      *             <ul>
 226      *             <li>if module equals null</li>
 227      *             <li>if name of module equals null</li>
 228      *             <li>if type definitions of module equal null</li>
 229      *             </ul>
 230      *
 231      */
 232     private def void allTypeDefinitionsToGenTypes(Module module) {
 233         checkArgument(module !== null, "Module reference cannot be NULL.");
 234         checkArgument(module.name !== null, "Module name cannot be NULL.");
 235         val it = new DataNodeIterator(module);
 236         val List<TypeDefinition<?>> typeDefinitions = it.allTypedefs;
 237         checkState(typeDefinitions !== null, '''Type Definitions for module «module.name» cannot be NULL.''');
 238
 239         for (TypeDefinition<?> typedef : typeDefinitions) {
 240             if (typedef !== null) {
 241                 val type = (typeProvider as TypeProviderImpl).generatedTypeForExtendedDefinitionType(typedef, typedef);
 242                 if (type !== null) {
 243                     genCtx.get(module).addTypedefType(typedef.path, type)
 244                 }
 245             }
 246         }
 247     }
 248
 249     private def GeneratedTypeBuilder processDataSchemaNode(Module module, String basePackageName,
 250         GeneratedTypeBuilder parent, GeneratedTypeBuilder childOf, DataSchemaNode node) {
 251         if (node.augmenting || node.addedByUses) {
 252             return null
 253         }
 254         val packageName = packageNameForGeneratedType(basePackageName, node.path)
 255         val genType = addDefaultInterfaceDefinition(packageName, node, childOf)
 256         genType.addComment(node.getDescription());
 257         if (node instanceof DataNodeContainer) {
 258             genCtx.get(module).addChildNodeType(node.path, genType)
 259             groupingsToGenTypes(module, (node as DataNodeContainer).groupings)
 260             processUsesAugments(node as DataNodeContainer, module)
 261         }
 262         return genType
 263     }
 264
 265     private def void containerToGenType(Module module, String basePackageName, GeneratedTypeBuilder parent,
 266         GeneratedTypeBuilder childOf, ContainerSchemaNode node) {
 267         val genType = processDataSchemaNode(module, basePackageName, parent, childOf, node)
 268         if (genType != null) {
 269             constructGetter(parent, node.QName.localName, node.description, genType)
 270             resolveDataSchemaNodes(module, basePackageName, genType, genType, node.childNodes)
 271         }
 272     }
 273
 274     private def void listToGenType(Module module, String basePackageName, GeneratedTypeBuilder parent,
 275         GeneratedTypeBuilder childOf, ListSchemaNode node) {
 276         val genType = processDataSchemaNode(module, basePackageName, parent, childOf, node)
 277         if (genType != null) {
 278             constructGetter(parent, node.QName.localName, node.description, Types.listTypeFor(genType))
 279
 280             val List<String> listKeys = listKeys(node);
 281             val packageName = packageNameForGeneratedType(basePackageName, (node).path)
 282             val genTOBuilder = resolveListKeyTOBuilder(packageName, node);
 283             if (genTOBuilder !== null) {
 284                 val identifierMarker = IDENTIFIER.parameterizedTypeFor(genType);
 285                 val identifiableMarker = IDENTIFIABLE.parameterizedTypeFor(genTOBuilder);
 286                 genTOBuilder.addImplementsType(identifierMarker);
 287                 genType.addImplementsType(identifiableMarker);
 288             }
 289
 290             for (schemaNode : node.childNodes) {
 291                 if (!schemaNode.augmenting) {
 292                     addSchemaNodeToListBuilders(basePackageName, schemaNode, genType, genTOBuilder, listKeys, module);
 293                 }
 294             }
 295
 296             // serialVersionUID
 297             if (genTOBuilder !== null) {
 298                 val GeneratedPropertyBuilder prop = new GeneratedPropertyBuilderImpl("serialVersionUID");
 299                 prop.setValue(Long.toString(computeDefaultSUID(genTOBuilder as GeneratedTOBuilderImpl)));
 300                 genTOBuilder.setSUID(prop);
 301             }
 302
 303             typeBuildersToGenTypes(module, genType, genTOBuilder);
 304         }
 305     }
 306
 307     private def void processUsesAugments(DataNodeContainer node, Module module) {
 308         val basePackageName = moduleNamespaceToPackageName(module);
 309         for (usesNode : node.uses) {
 310             for (augment : usesNode.augmentations) {
 311                 usesAugmentationToGenTypes(basePackageName, augment, module, usesNode, node);
 312                 processUsesAugments(augment, module);
 313             }
 314         }
 315     }
 316
 317     /**
 318      * Converts all <b>augmentation</b> of the module to the list
 319      * <code>Type</code> objects.
 320      *
 321      * @param module
 322      *            module from which is obtained list of all augmentation objects
 323      *            to iterate over them
 324      * @throws IllegalArgumentException
 325      *             <ul>
 326      *             <li>if the module equals null</li>
 327      *             <li>if the name of module equals null</li>
 328      *             <li>if the set of child nodes equals null</li>
 329      *             </ul>
 330      *
 331      */
 332     private def void allAugmentsToGenTypes(Module module) {
 333         checkArgument(module !== null, "Module reference cannot be NULL.");
 334         checkArgument(module.name !== null, "Module name cannot be NULL.");
 335         if (module.childNodes === null) {
 336             throw new IllegalArgumentException(
 337                 "Reference to Set of Augmentation Definitions in module " + module.name + " cannot be NULL.");
 338         }
 339
 340         val basePackageName = moduleNamespaceToPackageName(module);
 341         val List<AugmentationSchema> augmentations = resolveAugmentations(module);
 342         for (augment : augmentations) {
 343             augmentationToGenTypes(basePackageName, augment, module);
 344         }
 345     }
 346
 347     /**
 348      * Returns list of <code>AugmentationSchema</code> objects. The objects are
 349      * sorted according to the length of their target path from the shortest to
 350      * the longest.
 351      *
 352      * @param module
 353      *            module from which is obtained list of all augmentation objects
 354      * @return list of sorted <code>AugmentationSchema</code> objects obtained
 355      *         from <code>module</code>
 356      * @throws IllegalArgumentException
 357      *             <ul>
 358      *             <li>if the module equals null</li>
 359      *             <li>if the set of augmentation equals null</li>
 360      *             </ul>
 361      *
 362      */
 363     private def List<AugmentationSchema> resolveAugmentations(Module module) {
 364         checkArgument(module !== null, "Module reference cannot be NULL.");
 365         checkState(module.augmentations !== null, "Augmentations Set cannot be NULL.");
 366
 367         val Set<AugmentationSchema> augmentations = module.augmentations;
 368         var List<AugmentationSchema> sortedAugmentations = getSortedOrNull(augmentations)
 369         if (sortedAugmentations != null) {
 370             return sortedAugmentations
 371         }
 372         sortedAugmentations = new ArrayList(augmentations);
 373         Collections.sort(sortedAugmentations,
 374             [ augSchema1, augSchema2 |
 375                 val Iterator<QName> thisIt = augSchema1.targetPath.getPath().iterator();
 376                 val Iterator<QName> otherIt = augSchema2.getTargetPath().getPath().iterator();
 377                 while (thisIt.hasNext()) {
 378                     if (otherIt.hasNext()) {
 379                         val int comp = thisIt.next().compareTo(otherIt.next());
 380                         if (comp != 0) {
 381                             return comp
 382                         }
 383                     } else {
 384                         return 1
 385                     }
 386                 }
 387                 if (otherIt.hasNext()) {
 388                     return -1
 389                 }
 390                 return 0
 391             ]);
 392         return sortedAugmentations;
 393     }
 394
 395     private def List<AugmentationSchema> getSortedOrNull(Collection<AugmentationSchema> collection) {
 396         val TreeSet<AugmentationSchema> set = new TreeSet()
 397         for (e : collection) {
 398             if (e instanceof Comparable<?>) {
 399                 set.add(e)
 400             } else {
 401                 return null
 402             }
 403         }
 404         return new ArrayList(set.toArray)
 405     }
 406
 407     /**
 408      * Converts whole <b>module</b> to <code>GeneratedType</code> object.
 409      * Firstly is created the module builder object from which is vally
 410      * obtained reference to <code>GeneratedType</code> object.
 411      *
 412      * @param module
 413      *            module from which are obtained the module name, child nodes,
 414      *            uses and is derived package name
 415      * @return <code>GeneratedType</code> which is internal representation of
 416      *         the module
 417      * @throws IllegalArgumentException
 418      *             if the module equals null
 419      *
 420      */
 421     private def GeneratedTypeBuilder moduleToDataType(Module module) {
 422         checkArgument(module !== null, "Module reference cannot be NULL.");
 423
 424         val moduleDataTypeBuilder = moduleTypeBuilder(module, "Data");
 425         addImplementedInterfaceFromUses(module, moduleDataTypeBuilder);
 426         moduleDataTypeBuilder.addImplementsType(DATA_ROOT);
 427         moduleDataTypeBuilder.addComment(module.getDescription());
 428         return moduleDataTypeBuilder;
 429     }
 430
 431     /**
 432      * Converts all <b>rpcs</b> inputs and outputs substatements of the module
 433      * to the list of <code>Type</code> objects. In addition are to containers
 434      * and lists which belong to input or output also part of returning list.
 435      *
 436      * @param module
 437      *            module from which is obtained set of all rpc objects to
 438      *            iterate over them
 439      * @throws IllegalArgumentException
 440      *             <ul>
 441      *             <li>if the module equals null</li>
 442      *             <li>if the name of module equals null</li>
 443      *             <li>if the set of child nodes equals null</li>
 444      *             </ul>
 445      *
 446      */
 447     private def void rpcMethodsToGenType(Module module) {
 448         checkArgument(module !== null, "Module reference cannot be NULL.");
 449         checkArgument(module.name !== null, "Module name cannot be NULL.");
 450         checkArgument(module.childNodes !== null,
 451             "Reference to Set of RPC Method Definitions in module " + module.name + " cannot be NULL.");
 452
 453         val basePackageName = moduleNamespaceToPackageName(module);
 454         val Set<RpcDefinition> rpcDefinitions = module.rpcs;
 455         if (rpcDefinitions.isEmpty()) {
 456             return;
 457         }
 458
 459         val interfaceBuilder = moduleTypeBuilder(module, "Service");
 460         interfaceBuilder.addImplementsType(Types.typeForClass(RpcService));
 461         for (rpc : rpcDefinitions) {
 462             if (rpc !== null) {
 463                 val rpcName = BindingMapping.getClassName(rpc.QName);
 464                 val rpcMethodName = parseToValidParamName(rpcName);
 465                 val rpcComment = rpc.getDescription();
 466                 val method = interfaceBuilder.addMethod(rpcMethodName);
 467
 468                 val input = rpc.input;
 469                 val output = rpc.output;
 470
 471                 if (input !== null) {
 472                     val inType = addRawInterfaceDefinition(basePackageName, input, rpcName);
 473                     addImplementedInterfaceFromUses(input, inType);
 474                     inType.addImplementsType(DATA_OBJECT);
 475                     inType.addImplementsType(augmentable(inType));
 476                     resolveDataSchemaNodes(module, basePackageName, inType, inType, input.childNodes);
 477                     genCtx.get(module).addChildNodeType(input.path, inType)
 478                     val inTypeInstance = inType.toInstance();
 479                     method.addParameter(inTypeInstance, "input");
 480                 }
 481
 482                 var Type outTypeInstance = VOID;
 483                 if (output !== null) {
 484                     val outType = addRawInterfaceDefinition(basePackageName, output, rpcName);
 485                     addImplementedInterfaceFromUses(output, outType);
 486                     outType.addImplementsType(DATA_OBJECT);
 487                     outType.addImplementsType(augmentable(outType));
 488                     resolveDataSchemaNodes(module, basePackageName, outType, outType, output.childNodes);
 489                     genCtx.get(module).addChildNodeType(output.path, outType)
 490                     outTypeInstance = outType.toInstance();
 491                 }
 492
 493                 val rpcRes = Types.parameterizedTypeFor(Types.typeForClass(RpcResult), outTypeInstance);
 494                 method.setComment(rpcComment);
 495                 method.setReturnType(Types.parameterizedTypeFor(FUTURE, rpcRes));
 496
 497             }
 498         }
 499
 500         genCtx.get(module).addTopLevelNodeType(interfaceBuilder)
 501     }
 502
 503     /**
 504      * Converts all <b>notifications</b> of the module to the list of
 505      * <code>Type</code> objects. In addition are to this list added containers
 506      * and lists which are part of this notification.
 507      *
 508      * @param module
 509      *            module from which is obtained set of all notification objects
 510      *            to iterate over them
 511      * @throws IllegalArgumentException
 512      *             <ul>
 513      *             <li>if the module equals null</li>
 514      *             <li>if the name of module equals null</li>
 515      *             <li>if the set of child nodes equals null</li>
 516      *             </ul>
 517      *
 518      */
 519     private def void notificationsToGenType(Module module) {
 520         checkArgument(module !== null, "Module reference cannot be NULL.");
 521         checkArgument(module.name !== null, "Module name cannot be NULL.");
 522
 523         if (module.childNodes === null) {
 524             throw new IllegalArgumentException(
 525                 "Reference to Set of Notification Definitions in module " + module.name + " cannot be NULL.");
 526         }
 527         val notifications = module.notifications;
 528         if(notifications.empty) return;
 529
 530         val listenerInterface = moduleTypeBuilder(module, "Listener");
 531         listenerInterface.addImplementsType(BindingTypes.NOTIFICATION_LISTENER);
 532         val basePackageName = moduleNamespaceToPackageName(module);
 533
 534         for (notification : notifications) {
 535             if (notification !== null) {
 536                 processUsesAugments(notification, module);
 537
 538                 val notificationInterface = addDefaultInterfaceDefinition(basePackageName, notification,
 539                     BindingTypes.DATA_OBJECT);
 540                 notificationInterface.addImplementsType(NOTIFICATION);
 541                 genCtx.get(module).addChildNodeType(notification.path, notificationInterface)
 542
 543                 // Notification object
 544                 resolveDataSchemaNodes(module, basePackageName, notificationInterface, notificationInterface,
 545                     notification.childNodes);
 546
 547                 listenerInterface.addMethod("on" + notificationInterface.name) //
 548                 .setAccessModifier(AccessModifier.PUBLIC).addParameter(notificationInterface, "notification").
 549                     setComment(notification.getDescription()).setReturnType(Types.VOID);
 550             }
 551         }
 552
 553         genCtx.get(module).addTopLevelNodeType(listenerInterface)
 554     }
 555
 556     /**
 557      * Converts all <b>identities</b> of the module to the list of
 558      * <code>Type</code> objects.
 559      *
 560      * @param module
 561      *            module from which is obtained set of all identity objects to
 562      *            iterate over them
 563      * @param context
 564      *            schema context only used as input parameter for method
 565      *            {@link identityToGenType}
 566      *
 567      */
 568     private def void allIdentitiesToGenTypes(Module module, SchemaContext context) {
 569         val Set<IdentitySchemaNode> schemaIdentities = module.identities;
 570         val basePackageName = moduleNamespaceToPackageName(module);
 571
 572         if (schemaIdentities !== null && !schemaIdentities.isEmpty()) {
 573             for (identity : schemaIdentities) {
 574                 identityToGenType(module, basePackageName, identity, context);
 575             }
 576         }
 577     }
 578
 579     /**
 580      * Converts the <b>identity</b> object to GeneratedType. Firstly it is
 581      * created transport object builder. If identity contains base identity then
 582      * reference to base identity is added to superior identity as its extend.
 583      * If identity doesn't contain base identity then only reference to abstract
 584      * class {@link org.opendaylight.yangtools.yang.model.api.BaseIdentity
 585      * BaseIdentity} is added
 586      *
 587      * @param module current module
 588      * @param basePackageName
 589      *            string contains the module package name
 590      * @param identity
 591      *            IdentitySchemaNode which contains data about identity
 592      * @param context
 593      *            SchemaContext which is used to get package and name
 594      *            information about base of identity
 595      *
 596      */
 597     private def void identityToGenType(Module module, String basePackageName, IdentitySchemaNode identity,
 598         SchemaContext context) {
 599         if (identity === null) {
 600             return;
 601         }
 602         val packageName = packageNameForGeneratedType(basePackageName, identity.path);
 603         val genTypeName = BindingMapping.getClassName(identity.QName);
 604         val newType = new GeneratedTOBuilderImpl(packageName, genTypeName);
 605         val baseIdentity = identity.baseIdentity;
 606         if (baseIdentity === null) {
 607             newType.setExtendsType(Types.baseIdentityTO);
 608         } else {
 609             val baseIdentityParentModule = SchemaContextUtil.findParentModule(context, baseIdentity);
 610             val returnTypePkgName = moduleNamespaceToPackageName(baseIdentityParentModule);
 611             val returnTypeName = BindingMapping.getClassName(baseIdentity.QName);
 612             val gto = new GeneratedTOBuilderImpl(returnTypePkgName, returnTypeName).toInstance();
 613             newType.setExtendsType(gto);
 614         }
 615         newType.setAbstract(true);
 616         newType.addComment(identity.getDescription());
 617         val qname = identity.QName;
 618
 619         newType.qnameConstant(BindingMapping.QNAME_STATIC_FIELD_NAME,qname);
 620
 621         genCtx.get(module).addIdentityType(identity.QName,newType)
 622     }
 623
 624     private static def qnameConstant(GeneratedTypeBuilderBase<?> toBuilder, String constantName, QName name) {
 625         toBuilder.addConstant(QName.typeForClass,constantName,'''
 626             org.opendaylight.yangtools.yang.common.QName.create("«name.namespace»","«name.formattedRevision»","«name.localName»")
 627         ''');
 628     }
 629
 630     /**
 631      * Converts all <b>groupings</b> of the module to the list of
 632      * <code>Type</code> objects. Firstly are groupings sorted according mutual
 633      * dependencies. At least dependent (independent) groupings are in the list
 634      * saved at first positions. For every grouping the record is added to map
 635      * {@link BindingGeneratorImpl#allGroupings allGroupings}
 636      *
 637      * @param module
 638      *            current module
 639      * @param collection of groupings from which types will be generated
 640      *
 641      */
 642     private def void groupingsToGenTypes(Module module, Collection<GroupingDefinition> groupings) {
 643         val basePackageName = moduleNamespaceToPackageName(module);
 644         val List<GroupingDefinition> groupingsSortedByDependencies = new GroupingDefinitionDependencySort().sort(
 645             groupings);
 646         for (grouping : groupingsSortedByDependencies) {
 647             groupingToGenType(basePackageName, grouping, module);
 648         }
 649     }
 650
 651     /**
 652      * Converts individual grouping to GeneratedType. Firstly generated type
 653      * builder is created and every child node of grouping is resolved to the
 654      * method.
 655      *
 656      * @param basePackageName
 657      *            string contains the module package name
 658      * @param grouping
 659      *            GroupingDefinition which contains data about grouping
 660      * @param module current module
 661      * @return GeneratedType which is generated from grouping (object of type
 662      *         <code>GroupingDefinition</code>)
 663      */
 664     private def void groupingToGenType(String basePackageName, GroupingDefinition grouping, Module module) {
 665         val packageName = packageNameForGeneratedType(basePackageName, grouping.path);
 666         val genType = addDefaultInterfaceDefinition(packageName, grouping);
 667         genCtx.get(module).addGroupingType(grouping.path, genType)
 668         resolveDataSchemaNodes(module, basePackageName, genType, genType, grouping.childNodes);
 669         groupingsToGenTypes(module, grouping.groupings);
 670         processUsesAugments(grouping, module);
 671     }
 672
 673     /**
 674      * Tries to find EnumTypeDefinition in <code>typeDefinition</code>. If base
 675      * type of <code>typeDefinition</code> is of the type ExtendedType then this
 676      * method is recursively called with this base type.
 677      *
 678      * @param typeDefinition
 679      *            TypeDefinition in which should be EnumTypeDefinition found as
 680      *            base type
 681      * @return EnumTypeDefinition if it is found inside
 682      *         <code>typeDefinition</code> or <code>null</code> in other case
 683      */
 684     private def EnumTypeDefinition enumTypeDefFromExtendedType(TypeDefinition<?> typeDefinition) {
 685         if (typeDefinition !== null) {
 686             if (typeDefinition.baseType instanceof EnumTypeDefinition) {
 687                 return typeDefinition.baseType as EnumTypeDefinition;
 688             } else if (typeDefinition.baseType instanceof ExtendedType) {
 689                 return enumTypeDefFromExtendedType(typeDefinition.baseType);
 690             }
 691         }
 692         return null;
 693     }
 694
 695     /**
 696      * Adds enumeration builder created from <code>enumTypeDef</code> to
 697      * <code>typeBuilder</code>.
 698      *
 699      * Each <code>enumTypeDef</code> item is added to builder with its name and
 700      * value.
 701      *
 702      * @param enumTypeDef
 703      *            EnumTypeDefinition contains enum data
 704      * @param enumName
 705      *            string contains name which will be assigned to enumeration
 706      *            builder
 707      * @param typeBuilder
 708      *            GeneratedTypeBuilder to which will be enum builder assigned
 709      * @return enumeration builder which contains data from
 710      *         <code>enumTypeDef</code>
 711      */
 712     private def EnumBuilder resolveInnerEnumFromTypeDefinition(EnumTypeDefinition enumTypeDef, QName enumName,
 713         GeneratedTypeBuilder typeBuilder) {
 714         if ((enumTypeDef !== null) && (typeBuilder !== null) && (enumTypeDef.QName !== null) &&
 715             (enumTypeDef.QName.localName !== null)) {
 716             val enumerationName = BindingMapping.getClassName(enumName);
 717             val enumBuilder = typeBuilder.addEnumeration(enumerationName);
 718             enumBuilder.updateEnumPairsFromEnumTypeDef(enumTypeDef);
 719             return enumBuilder;
 720         }
 721         return null;
 722     }
 723
 724     /**
 725      * Generates type builder for <code>module</code>.
 726      *
 727      * @param module
 728      *            Module which is source of package name for generated type
 729      *            builder
 730      * @param postfix
 731      *            string which is added to the module class name representation
 732      *            as suffix
 733      * @return instance of GeneratedTypeBuilder which represents
 734      *         <code>module</code>.
 735      * @throws IllegalArgumentException
 736      *             if <code>module</code> equals null
 737      */
 738     private def GeneratedTypeBuilder moduleTypeBuilder(Module module, String postfix) {
 739         checkArgument(module !== null, "Module reference cannot be NULL.");
 740         val packageName = moduleNamespaceToPackageName(module);
 741         val moduleName = BindingMapping.getClassName(module.name) + postfix;
 742         return new GeneratedTypeBuilderImpl(packageName, moduleName);
 743     }
 744
 745     /**
 746      * Converts <code>augSchema</code> to list of <code>Type</code> which
 747      * contains generated type for augmentation. In addition there are also
 748      * generated types for all containers, list and choices which are child of
 749      * <code>augSchema</code> node or a generated types for cases are added if
 750      * augmented node is choice.
 751      *
 752      * @param augmentPackageName
 753      *            string with the name of the package to which the augmentation
 754      *            belongs
 755      * @param augSchema
 756      *            AugmentationSchema which is contains data about augmentation
 757      *            (target path, childs...)
 758      * @param module current module
 759      * @param parentUsesNode parent uses node of this augment (can be null if this augment is not defined under uses statement)
 760      * @throws IllegalArgumentException
 761      *             <ul>
 762      *             <li>if <code>augmentPackageName</code> equals null</li>
 763      *             <li>if <code>augSchema</code> equals null</li>
 764      *             <li>if target path of <code>augSchema</code> equals null</li>
 765      *             </ul>
 766      */
 767     private def void augmentationToGenTypes(String augmentPackageName, AugmentationSchema augSchema, Module module) {
 768         checkArgument(augmentPackageName !== null, "Package Name cannot be NULL.");
 769         checkArgument(augSchema !== null, "Augmentation Schema cannot be NULL.");
 770         checkState(augSchema.targetPath !== null,
 771             "Augmentation Schema does not contain Target Path (Target Path is NULL).");
 772
 773         processUsesAugments(augSchema, module);
 774         val targetPath = augSchema.targetPath;
 775         var SchemaNode targetSchemaNode = null
 776
 777         targetSchemaNode = findDataSchemaNode(schemaContext, targetPath);
 778         if (targetSchemaNode instanceof DataSchemaNode && (targetSchemaNode as DataSchemaNode).isAddedByUses()) {
 779             targetSchemaNode = findOriginal(targetSchemaNode as DataSchemaNode, schemaContext);
 780             if (targetSchemaNode == null) {
 781                 throw new NullPointerException(
 782                     "Failed to find target node from grouping in augmentation " + augSchema + " in module " +
 783                         module.name);
 784             }
 785         }
 786         if (targetSchemaNode == null) {
 787             throw new IllegalArgumentException("augment target not found: " + targetPath)
 788         }
 789
 790         var targetTypeBuilder = findChildNodeByPath(targetSchemaNode.path)
 791         if (targetTypeBuilder === null) {
 792             targetTypeBuilder = findCaseByPath(targetSchemaNode.path)
 793         }
 794         if (targetTypeBuilder === null) {
 795             throw new NullPointerException("Target type not yet generated: " + targetSchemaNode);
 796         }
 797
 798         if (!(targetSchemaNode instanceof ChoiceNode)) {
 799             var packageName = augmentPackageName;
 800             val targetType = new ReferencedTypeImpl(targetTypeBuilder.packageName,targetTypeBuilder.name);
 801             addRawAugmentGenTypeDefinition(module, packageName, augmentPackageName,targetType, augSchema);
 802
 803         } else {
 804             generateTypesFromAugmentedChoiceCases(module, augmentPackageName, targetTypeBuilder.toInstance,
 805                 targetSchemaNode as ChoiceNode, augSchema.childNodes);
 806         }
 807     }
 808
 809     private def void usesAugmentationToGenTypes(String augmentPackageName, AugmentationSchema augSchema, Module module,
 810         UsesNode usesNode, DataNodeContainer usesNodeParent) {
 811         checkArgument(augmentPackageName !== null, "Package Name cannot be NULL.");
 812         checkArgument(augSchema !== null, "Augmentation Schema cannot be NULL.");
 813         checkState(augSchema.targetPath !== null,
 814             "Augmentation Schema does not contain Target Path (Target Path is NULL).");
 815
 816         processUsesAugments(augSchema, module);
 817         val targetPath = augSchema.targetPath;
 818         var SchemaNode targetSchemaNode = null
 819         targetSchemaNode = findOriginalTargetFromGrouping(targetPath, usesNode);
 820         if (targetSchemaNode == null) {
 821             throw new IllegalArgumentException("augment target not found: " + targetPath)
 822         }
 823
 824         var targetTypeBuilder = findChildNodeByPath(targetSchemaNode.path)
 825         if (targetTypeBuilder === null) {
 826             targetTypeBuilder = findCaseByPath(targetSchemaNode.path)
 827         }
 828         if (targetTypeBuilder === null) {
 829             throw new NullPointerException("Target type not yet generated: " + targetSchemaNode);
 830         }
 831
 832         if (!(targetSchemaNode instanceof ChoiceNode)) {
 833             var packageName = augmentPackageName;
 834             if (usesNodeParent instanceof SchemaNode) {
 835                 packageName = packageNameForGeneratedType(augmentPackageName, (usesNodeParent as SchemaNode).path, true)
 836             }
 837             addRawAugmentGenTypeDefinition(module, packageName, augmentPackageName,
 838                 targetTypeBuilder.toInstance, augSchema);
 839         } else {
 840             generateTypesFromAugmentedChoiceCases(module, augmentPackageName, targetTypeBuilder.toInstance,
 841                 targetSchemaNode as ChoiceNode, augSchema.childNodes);
 842         }
 843     }
 844
 845     /**
 846      * Convenient method to find node added by uses statement.
 847      */
 848     private def DataSchemaNode findOriginalTargetFromGrouping(SchemaPath targetPath, UsesNode parentUsesNode) {
 849         var SchemaNode targetGrouping = findNodeInSchemaContext(schemaContext, parentUsesNode.groupingPath.path);
 850         if (!(targetGrouping instanceof GroupingDefinition)) {
 851             throw new IllegalArgumentException("Failed to generate code for augment in " + parentUsesNode);
 852         }
 853
 854         var grouping = targetGrouping as GroupingDefinition;
 855         var SchemaNode result = grouping;
 856         val List<QName> path = targetPath.path
 857         for (node : path) {
 858             // finding by local name is valid, grouping cannot contain nodes with same name and different namespace
 859             if (result instanceof DataNodeContainer) {
 860                 result = (result as DataNodeContainer).getDataChildByName(node.localName)
 861             } else if (result instanceof ChoiceNode) {
 862                 result = (result as ChoiceNode).getCaseNodeByName(node.localName)
 863             }
 864         }
 865         if (result == null) {
 866             return null;
 867         }
 868
 869         var boolean fromUses = (result as DataSchemaNode).addedByUses
 870         var Iterator<UsesNode> groupingUses = grouping.uses.iterator;
 871         while (groupingUses.hasNext && fromUses) {
 872             result = findOriginalTargetFromGrouping(targetPath, groupingUses.next);
 873             if (result != null) {
 874                 fromUses = (result as DataSchemaNode).addedByUses
 875             }
 876         }
 877         if (fromUses) {
 878             throw new NullPointerException("Failed to generate code for augment in " + parentUsesNode);
 879         }
 880
 881         return result as DataSchemaNode
 882     }
 883
 884     /**
 885      * Returns a generated type builder for an augmentation.
 886      *
 887      * The name of the type builder is equal to the name of augmented node with
 888      * serial number as suffix.
 889      *
 890      * @param module current module
 891      * @param augmentPackageName
 892      *            string with contains the package name to which the augment
 893      *            belongs
 894      * @param basePackageName
 895      *            string with the package name to which the augmented node
 896      *            belongs
 897      * @param targetTypeRef
 898      *            target type
 899      * @param augSchema
 900      *            augmentation schema which contains data about the child nodes
 901      *            and uses of augment
 902      * @return generated type builder for augment
 903      */
 904     private def GeneratedTypeBuilder addRawAugmentGenTypeDefinition(Module module, String augmentPackageName,
 905         String basePackageName, Type targetTypeRef, AugmentationSchema augSchema) {
 906         var Map<String, GeneratedTypeBuilder> augmentBuilders = genTypeBuilders.get(augmentPackageName);
 907         if (augmentBuilders === null) {
 908             augmentBuilders = new HashMap();
 909             genTypeBuilders.put(augmentPackageName, augmentBuilders);
 910         }
 911         val augIdentifier = getAugmentIdentifier(augSchema.unknownSchemaNodes);
 912
 913         val augTypeName = if (augIdentifier !== null) {
 914                 BindingMapping.getClassName(augIdentifier)
 915             } else {
 916                 augGenTypeName(augmentBuilders, targetTypeRef.name);
 917             }
 918
 919         val augTypeBuilder = new GeneratedTypeBuilderImpl(augmentPackageName, augTypeName);
 920
 921         augTypeBuilder.addImplementsType(DATA_OBJECT);
 922         augTypeBuilder.addImplementsType(Types.augmentationTypeFor(targetTypeRef));
 923         addImplementedInterfaceFromUses(augSchema, augTypeBuilder);
 924
 925         augSchemaNodeToMethods(module, basePackageName, augTypeBuilder, augTypeBuilder, augSchema.childNodes);
 926         augmentBuilders.put(augTypeName, augTypeBuilder);
 927
 928         genCtx.get(module).addTargetToAugmentation(targetTypeRef,augTypeBuilder);
 929         genCtx.get(module).addAugmentType(augTypeBuilder);
 930         genCtx.get(module).addTypeToAugmentation(augTypeBuilder, augSchema);
 931         return augTypeBuilder;
 932     }
 933
 934     /**
 935      *
 936      * @param unknownSchemaNodes
 937      * @return nodeParameter of UnknownSchemaNode
 938      */
 939     private def String getAugmentIdentifier(List<UnknownSchemaNode> unknownSchemaNodes) {
 940         for (unknownSchemaNode : unknownSchemaNodes) {
 941             val nodeType = unknownSchemaNode.nodeType;
 942             if (AUGMENT_IDENTIFIER_NAME.equals(nodeType.localName) &&
 943                 YANG_EXT_NAMESPACE.equals(nodeType.namespace.toString())) {
 944                 return unknownSchemaNode.nodeParameter;
 945             }
 946         }
 947         return null;
 948     }
 949
 950     /**
 951      * Returns first unique name for the augment generated type builder. The
 952      * generated type builder name for augment consists from name of augmented
 953      * node and serial number of its augmentation.
 954      *
 955      * @param builders
 956      *            map of builders which were created in the package to which the
 957      *            augmentation belongs
 958      * @param genTypeName
 959      *            string with name of augmented node
 960      * @return string with unique name for augmentation builder
 961      */
 962     private def String augGenTypeName(Map<String, GeneratedTypeBuilder> builders, String genTypeName) {
 963         var index = 1;
 964         while ((builders !== null) && builders.containsKey(genTypeName + index)) {
 965             index = index + 1;
 966         }
 967         return genTypeName + index;
 968     }
 969
 970     /**
 971      * Adds the methods to <code>typeBuilder</code> which represent subnodes of
 972      * node for which <code>typeBuilder</code> was created.
 973      *
 974      * The subnodes aren't mapped to the methods if they are part of grouping or
 975      * augment (in this case are already part of them).
 976      *
 977      * @param module current module
 978      * @param basePackageName
 979      *            string contains the module package name
 980      * @param parent
 981      *            generated type builder which represents any node. The subnodes
 982      *            of this node are added to the <code>typeBuilder</code> as
 983      *            methods. The subnode can be of type leaf, leaf-list, list,
 984      *            container, choice.
 985      * @param childOf parent type
 986      * @param schemaNodes
 987      *            set of data schema nodes which are the children of the node
 988      *            for which <code>typeBuilder</code> was created
 989      * @return generated type builder which is the same builder as input
 990      *         parameter. The getter methods (representing child nodes) could be
 991      *         added to it.
 992      */
 993     private def GeneratedTypeBuilder resolveDataSchemaNodes(Module module, String basePackageName,
 994         GeneratedTypeBuilder parent, GeneratedTypeBuilder childOf, Set<DataSchemaNode> schemaNodes) {
 995         if ((schemaNodes !== null) && (parent !== null)) {
 996             for (schemaNode : schemaNodes) {
 997                 if (!schemaNode.augmenting && !schemaNode.addedByUses) {
 998                     addSchemaNodeToBuilderAsMethod(basePackageName, schemaNode, parent, childOf, module);
 999                 }
1000             }
1001         }
1002         return parent;
1003     }
1004
1005     /**
1006      * Adds the methods to <code>typeBuilder</code> what represents subnodes of
1007      * node for which <code>typeBuilder</code> was created.
1008      *
1009      * @param module current module
1010      * @param basePackageName
1011      *            string contains the module package name
1012      * @param typeBuilder
1013      *            generated type builder which represents any node. The subnodes
1014      *            of this node are added to the <code>typeBuilder</code> as
1015      *            methods. The subnode can be of type leaf, leaf-list, list,
1016      *            container, choice.
1017      * @param childOf parent type
1018      * @param schemaNodes
1019      *            set of data schema nodes which are the children of the node
1020      *            for which <code>typeBuilder</code> was created
1021      * @return generated type builder which is the same object as the input
1022      *         parameter <code>typeBuilder</code>. The getter method could be
1023      *         added to it.
1024      */
1025     private def GeneratedTypeBuilder augSchemaNodeToMethods(Module module, String basePackageName,
1026         GeneratedTypeBuilder typeBuilder, GeneratedTypeBuilder childOf, Set<DataSchemaNode> schemaNodes) {
1027         if ((schemaNodes !== null) && (typeBuilder !== null)) {
1028             for (schemaNode : schemaNodes) {
1029                 if (!schemaNode.isAugmenting()) {
1030                     addSchemaNodeToBuilderAsMethod(basePackageName, schemaNode, typeBuilder, childOf, module);
1031                 }
1032             }
1033         }
1034         return typeBuilder;
1035     }
1036
1037     /**
1038      * Adds to <code>typeBuilder</code> a method which is derived from
1039      * <code>schemaNode</code>.
1040      *
1041      * @param basePackageName
1042      *            string with the module package name
1043      * @param node
1044      *            data schema node which is added to <code>typeBuilder</code> as
1045      *            a method
1046      * @param typeBuilder
1047      *            generated type builder to which is <code>schemaNode</code>
1048      *            added as a method.
1049      * @param childOf parent type
1050      * @param module current module
1051      */
1052     private def void addSchemaNodeToBuilderAsMethod(String basePackageName, DataSchemaNode node,
1053         GeneratedTypeBuilder typeBuilder, GeneratedTypeBuilder childOf, Module module) {
1054         if (node !== null && typeBuilder !== null) {
1055             switch (node) {
1056                 case node instanceof LeafSchemaNode:
1057                     resolveLeafSchemaNodeAsMethod(typeBuilder, node as LeafSchemaNode)
1058                 case node instanceof LeafListSchemaNode:
1059                     resolveLeafListSchemaNode(typeBuilder, node as LeafListSchemaNode)
1060                 case node instanceof ContainerSchemaNode:
1061                     containerToGenType(module, basePackageName, typeBuilder, childOf, node as ContainerSchemaNode)
1062                 case node instanceof ListSchemaNode:
1063                     listToGenType(module, basePackageName, typeBuilder, childOf, node as ListSchemaNode)
1064                 case node instanceof ChoiceNode:
1065                     choiceToGeneratedType(module, basePackageName, typeBuilder, node as ChoiceNode)
1066             }
1067         }
1068     }
1069
1070     /**
1071      * Converts <code>choiceNode</code> to the list of generated types for
1072      * choice and its cases.
1073      *
1074      * The package names for choice and for its cases are created as
1075      * concatenation of the module package (<code>basePackageName</code>) and
1076      * names of all parents node.
1077      *
1078      * @param module current module
1079      * @param basePackageName
1080      *            string with the module package name
1081      * @param parent parent type
1082      * @param childOf concrete parent for case child nodes
1083      * @param choiceNode
1084      *            choice node which is mapped to generated type. Also child
1085      *            nodes - cases are mapped to generated types.
1086      * @throws IllegalArgumentException
1087      *             <ul>
1088      *             <li>if <code>basePackageName</code> equals null</li>
1089      *             <li>if <code>choiceNode</code> equals null</li>
1090      *             </ul>
1091      *
1092      */
1093     private def void choiceToGeneratedType(Module module, String basePackageName, GeneratedTypeBuilder parent,
1094         ChoiceNode choiceNode) {
1095         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1096         checkArgument(choiceNode !== null, "Choice Schema Node cannot be NULL.");
1097
1098         if (!choiceNode.addedByUses) {
1099             val packageName = packageNameForGeneratedType(basePackageName, choiceNode.path);
1100             val choiceTypeBuilder = addRawInterfaceDefinition(packageName, choiceNode);
1101             constructGetter(parent, choiceNode.QName.localName, choiceNode.description, choiceTypeBuilder);
1102             choiceTypeBuilder.addImplementsType(DataContainer.typeForClass);
1103             genCtx.get(module).addChildNodeType(choiceNode.path, choiceTypeBuilder)
1104             generateTypesFromChoiceCases(module, basePackageName, parent, choiceTypeBuilder.toInstance, choiceNode);
1105         }
1106     }
1107
1108     /**
1109      * Converts <code>caseNodes</code> set to list of corresponding generated
1110      * types.
1111      *
1112      * For every <i>case</i> which isn't added through augment or <i>uses</i> is
1113      * created generated type builder. The package names for the builder is
1114      * created as concatenation of the module package (
1115      * <code>basePackageName</code>) and names of all parents nodes of the
1116      * concrete <i>case</i>. There is also relation "<i>implements type</i>"
1117      * between every case builder and <i>choice</i> type
1118      *
1119      * @param basePackageName
1120      *            string with the module package name
1121      * @param refChoiceType
1122      *            type which represents superior <i>case</i>
1123      * @param caseNodes
1124      *            set of choice case nodes which are mapped to generated types
1125      * @return list of generated types for <code>caseNodes</code>.
1126      * @throws IllegalArgumentException
1127      *             <ul>
1128      *             <li>if <code>basePackageName</code> equals null</li>
1129      *             <li>if <code>refChoiceType</code> equals null</li>
1130      *             <li>if <code>caseNodes</code> equals null</li>
1131      *             </ul>
1132      *             *
1133      */
1134     private def void generateTypesFromChoiceCases(Module module, String basePackageName,
1135         GeneratedTypeBuilder choiceParent, Type refChoiceType, ChoiceNode choiceNode) {
1136         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1137         checkArgument(refChoiceType !== null, "Referenced Choice Type cannot be NULL.");
1138         checkArgument(choiceNode !== null, "ChoiceNode cannot be NULL.");
1139
1140         val Set<ChoiceCaseNode> caseNodes = choiceNode.cases;
1141         if (caseNodes == null) {
1142             return
1143         }
1144
1145         for (caseNode : caseNodes) {
1146             if (caseNode !== null && !caseNode.isAddedByUses() && !caseNode.isAugmenting()) {
1147                 val packageName = packageNameForGeneratedType(basePackageName, caseNode.path)
1148                 val caseTypeBuilder = addDefaultInterfaceDefinition(packageName, caseNode)
1149                 caseTypeBuilder.addImplementsType(refChoiceType)
1150                 genCtx.get(module).addCaseType(caseNode.path, caseTypeBuilder)
1151                 val Set<DataSchemaNode> caseChildNodes = caseNode.childNodes
1152                 if (caseChildNodes !== null) {
1153                     var Object parentNode = null
1154                     val SchemaPath nodeSp = choiceNode.path
1155                     val List<QName> nodeNames = nodeSp.path
1156                     val List<QName> nodeNewNames = new ArrayList(nodeNames)
1157                     nodeNewNames.remove(nodeNewNames.size - 1)
1158                     val SchemaPath nodeNewSp = SchemaPath.create(nodeNewNames, nodeSp.absolute)
1159                     parentNode = findDataSchemaNode(schemaContext, nodeNewSp)
1160
1161                     var SchemaNode parent
1162                     if (parentNode instanceof AugmentationSchema) {
1163                         val augSchema = parentNode as AugmentationSchema;
1164                         val targetPath = augSchema.targetPath;
1165                         var targetSchemaNode = findDataSchemaNode(schemaContext, targetPath)
1166                         if (targetSchemaNode instanceof DataSchemaNode &&
1167                             (targetSchemaNode as DataSchemaNode).isAddedByUses()) {
1168                             targetSchemaNode = findOriginal(targetSchemaNode as DataSchemaNode, schemaContext);
1169                             if (targetSchemaNode == null) {
1170                                 throw new NullPointerException(
1171                                     "Failed to find target node from grouping for augmentation " + augSchema +
1172                                         " in module " + module.name);
1173                             }
1174                         }
1175                         parent = targetSchemaNode
1176                     } else {
1177                         val SchemaPath sp = choiceNode.path
1178                         val List<QName> names = sp.path
1179                         val List<QName> newNames = new ArrayList(names)
1180                         newNames.remove(newNames.size - 1)
1181                         val SchemaPath newSp = SchemaPath.create(newNames, sp.absolute)
1182                         parent = findDataSchemaNode(schemaContext, newSp)
1183                     }
1184                     var GeneratedTypeBuilder childOfType = findChildNodeByPath(parent.path)
1185                     resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, caseChildNodes)
1186                 }
1187             }
1188
1189             processUsesAugments(caseNode, module);
1190         }
1191     }
1192
1193     /**
1194      * Generates list of generated types for all the cases of a choice which are
1195      * added to the choice through the augment.
1196      *
1197      *
1198      * @param basePackageName
1199      *            string contains name of package to which augment belongs. If
1200      *            an augmented choice is from an other package (pcg1) than an
1201      *            augmenting choice (pcg2) then case's of the augmenting choice
1202      *            will belong to pcg2.
1203      * @param refChoiceType
1204      *            Type which represents the choice to which case belongs. Every
1205      *            case has to contain its choice in extend part.
1206      * @param caseNodes
1207      *            set of choice case nodes for which is checked if are/aren't
1208      *            added to choice through augmentation
1209      * @return list of generated types which represents augmented cases of
1210      *         choice <code>refChoiceType</code>
1211      * @throws IllegalArgumentException
1212      *             <ul>
1213      *             <li>if <code>basePackageName</code> equals null</li>
1214      *             <li>if <code>refChoiceType</code> equals null</li>
1215      *             <li>if <code>caseNodes</code> equals null</li>
1216      *             </ul>
1217      */
1218     private def void generateTypesFromAugmentedChoiceCases(Module module, String basePackageName, Type targetType,
1219         ChoiceNode targetNode, Set<DataSchemaNode> augmentedNodes) {
1220         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1221         checkArgument(targetType !== null, "Referenced Choice Type cannot be NULL.");
1222         checkArgument(augmentedNodes !== null, "Set of Choice Case Nodes cannot be NULL.");
1223
1224         for (caseNode : augmentedNodes) {
1225             if (caseNode !== null) {
1226                 val packageName = packageNameForGeneratedType(basePackageName, caseNode.path);
1227                 val caseTypeBuilder = addDefaultInterfaceDefinition(packageName, caseNode);
1228                 caseTypeBuilder.addImplementsType(targetType);
1229
1230                 var SchemaNode parent = null
1231                 val SchemaPath nodeSp = targetNode.path
1232                 val List<QName> nodeNames = nodeSp.path
1233                 val List<QName> nodeNewNames = new ArrayList(nodeNames)
1234                 nodeNewNames.remove(nodeNewNames.size - 1)
1235                 val SchemaPath nodeNewSp = SchemaPath.create(nodeNewNames, nodeSp.absolute)
1236                 parent = findDataSchemaNode(schemaContext, nodeNewSp)
1237
1238                 var GeneratedTypeBuilder childOfType = null;
1239                 if (parent instanceof Module) {
1240                     childOfType = genCtx.get(parent as Module).moduleNode
1241                 } else if (parent instanceof ChoiceCaseNode) {
1242                     childOfType = findCaseByPath(parent.path)
1243                 } else if (parent instanceof DataSchemaNode || parent instanceof NotificationDefinition) {
1244                     childOfType = findChildNodeByPath(parent.path)
1245                 } else if (parent instanceof GroupingDefinition) {
1246                     childOfType = findGroupingByPath(parent.path);
1247                 }
1248
1249                 if (childOfType == null) {
1250                     throw new IllegalArgumentException("Failed to find parent type of choice " + targetNode);
1251                 }
1252
1253                 if (caseNode instanceof DataNodeContainer) {
1254                     val DataNodeContainer dataNodeCase = caseNode as DataNodeContainer;
1255                     val Set<DataSchemaNode> childNodes = dataNodeCase.childNodes;
1256                     if (childNodes !== null) {
1257                         resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, childNodes);
1258                     }
1259                 } else {
1260                     val ChoiceCaseNode node = targetNode.getCaseNodeByName(caseNode.getQName().getLocalName());
1261                     val Set<DataSchemaNode> childNodes = node.childNodes;
1262                     if (childNodes !== null) {
1263                         resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, childNodes);
1264                     }
1265                 }
1266
1267                 genCtx.get(module).addCaseType(caseNode.path, caseTypeBuilder)
1268             }
1269         }
1270
1271     }
1272
1273     /**
1274      * Converts <code>leaf</code> to the getter method which is added to
1275      * <code>typeBuilder</code>.
1276      *
1277      * @param typeBuilder
1278      *            generated type builder to which is added getter method as
1279      *            <code>leaf</code> mapping
1280      * @param leaf
1281      *            leaf schema node which is mapped as getter method which is
1282      *            added to <code>typeBuilder</code>
1283      * @return boolean value
1284      *         <ul>
1285      *         <li>false - if <code>leaf</code> or <code>typeBuilder</code> are
1286      *         null</li>
1287      *         <li>true - in other cases</li>
1288      *         </ul>
1289      */
1290     private def Type resolveLeafSchemaNodeAsMethod(GeneratedTypeBuilder typeBuilder, LeafSchemaNode leaf) {
1291         var Type returnType = null;
1292         if ((leaf !== null) && (typeBuilder !== null)) {
1293             val leafName = leaf.QName.localName;
1294             var String leafDesc = leaf.description;
1295             if (leafDesc === null) {
1296                 leafDesc = "";
1297             }
1298
1299             val parentModule = findParentModule(schemaContext, leaf);
1300             if (leafName !== null && !leaf.isAddedByUses()) {
1301                 val TypeDefinition<?> typeDef = leaf.type;
1302
1303                 var GeneratedTOBuilder genTOBuilder;
1304                 if (typeDef instanceof EnumTypeDefinition) {
1305                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf);
1306                     val enumTypeDef = typeDef as EnumTypeDefinition;
1307                     val enumBuilder = resolveInnerEnumFromTypeDefinition(enumTypeDef, leaf.QName, typeBuilder);
1308
1309                     if (enumBuilder !== null) {
1310                         returnType = enumBuilder.toInstance(typeBuilder)
1311                     }
1312                     (typeProvider as TypeProviderImpl).putReferencedType(leaf.path, returnType);
1313                 } else if (typeDef instanceof UnionType) {
1314                     genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, leaf, parentModule);
1315                     if (genTOBuilder !== null) {
1316                         returnType = createReturnTypeForUnion(genTOBuilder, typeDef, typeBuilder, parentModule)
1317                     }
1318                 } else if (typeDef instanceof BitsTypeDefinition) {
1319                     genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, leaf, parentModule);
1320                     if (genTOBuilder !== null) {
1321                         returnType = new ReferencedTypeImpl(genTOBuilder.packageName, genTOBuilder.name);
1322                     }
1323                 } else {
1324                     val Restrictions restrictions = BindingGeneratorUtil.getRestrictions(typeDef);
1325                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf, restrictions);
1326                 }
1327                 if (returnType !== null) {
1328                     val MethodSignatureBuilder getter = constructGetter(typeBuilder, leafName, leafDesc, returnType);
1329                     processContextRefExtension(leaf, getter, parentModule);
1330                 }
1331             }
1332         }
1333         return returnType;
1334     }
1335
1336     private def void processContextRefExtension(LeafSchemaNode leaf, MethodSignatureBuilder getter, Module module) {
1337         for (node : leaf.unknownSchemaNodes) {
1338             val nodeType = node.nodeType;
1339             if ("context-reference".equals(nodeType.localName)) {
1340                 val nodeParam = node.nodeParameter;
1341                 var IdentitySchemaNode identity = null;
1342                 var String basePackageName = null;
1343                 val String[] splittedElement = nodeParam.split(":");
1344                 if (splittedElement.length == 1) {
1345                     identity = findIdentityByName(module.identities, splittedElement.get(0));
1346                     basePackageName = moduleNamespaceToPackageName(module);
1347                 } else if (splittedElement.length == 2) {
1348                     var prefix = splittedElement.get(0);
1349                     val Module dependentModule = findModuleFromImports(module.imports, prefix)
1350                     if (dependentModule == null) {
1351                         throw new IllegalArgumentException(
1352                             "Failed to process context-reference: unknown prefix " + prefix);
1353                     }
1354                     identity = findIdentityByName(dependentModule.identities, splittedElement.get(1));
1355                     basePackageName = moduleNamespaceToPackageName(dependentModule);
1356                 } else {
1357                     throw new IllegalArgumentException(
1358                         "Failed to process context-reference: unknown identity " + nodeParam);
1359                 }
1360                 if (identity == null) {
1361                     throw new IllegalArgumentException(
1362                         "Failed to process context-reference: unknown identity " + nodeParam);
1363                 }
1364
1365                 val Class<RoutingContext> clazz = typeof(RoutingContext);
1366                 val AnnotationTypeBuilder rc = getter.addAnnotation(clazz.package.name, clazz.simpleName);
1367                 val packageName = packageNameForGeneratedType(basePackageName, identity.path);
1368                 val genTypeName = BindingMapping.getClassName(identity.QName.localName);
1369                 rc.addParameter("value", packageName + "." + genTypeName + ".class");
1370             }
1371         }
1372     }
1373
1374     private def IdentitySchemaNode findIdentityByName(Set<IdentitySchemaNode> identities, String name) {
1375         for (id : identities) {
1376             if (id.QName.localName.equals(name)) {
1377                 return id;
1378             }
1379         }
1380         return null;
1381     }
1382
1383     private def Module findModuleFromImports(Set<ModuleImport> imports, String prefix) {
1384         for (imp : imports) {
1385             if (imp.prefix.equals(prefix)) {
1386                 return schemaContext.findModuleByName(imp.moduleName, imp.revision);
1387             }
1388         }
1389         return null;
1390     }
1391
1392     private def boolean resolveLeafSchemaNodeAsProperty(GeneratedTOBuilder toBuilder, LeafSchemaNode leaf,
1393         boolean isReadOnly, Module module) {
1394         if ((leaf !== null) && (toBuilder !== null)) {
1395             val leafName = leaf.QName.localName;
1396             var String leafDesc = leaf.description;
1397             if (leafDesc === null) {
1398                 leafDesc = "";
1399             }
1400
1401             if (leafName !== null) {
1402                 var Type returnType = null;
1403                 val TypeDefinition<?> typeDef = leaf.type;
1404                 if (typeDef instanceof UnionTypeDefinition) {
1405                     // GeneratedType for this type definition should be already created
1406                     var qname = typeDef.QName
1407                     var Module unionModule = null
1408                     if (qname.prefix == null || qname.prefix.empty) {
1409                         unionModule = module
1410                     } else {
1411                         unionModule = findModuleFromImports(module.imports, qname.prefix)
1412                     }
1413                     val ModuleContext mc = genCtx.get(unionModule)
1414                     returnType = mc.typedefs.get(typeDef.path)
1415                 } else {
1416                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf);
1417                 }
1418                 return resolveLeafSchemaNodeAsProperty(toBuilder, leaf, returnType, isReadOnly)
1419             }
1420         }
1421         return false;
1422     }
1423
1424     /**
1425      * Converts <code>leaf</code> schema node to property of generated TO
1426      * builder.
1427      *
1428      * @param toBuilder
1429      *            generated TO builder to which is <code>leaf</code> added as
1430      *            property
1431      * @param leaf
1432      *            leaf schema node which is added to <code>toBuilder</code> as
1433      *            property
1434      * @param returnType property type
1435      * @param isReadOnly
1436      *            boolean value which says if leaf property is|isn't read only
1437      * @return boolean value
1438      *         <ul>
1439      *         <li>false - if <code>leaf</code>, <code>toBuilder</code> or leaf
1440      *         name equals null or if leaf is added by <i>uses</i>.</li>
1441      *         <li>true - other cases</li>
1442      *         </ul>
1443      */
1444     private def resolveLeafSchemaNodeAsProperty(GeneratedTOBuilder toBuilder, LeafSchemaNode leaf, Type returnType,
1445         boolean isReadOnly) {
1446         if (returnType == null) {
1447             return false;
1448         }
1449         val leafName = leaf.QName.localName
1450         val leafDesc = leaf.description
1451         val propBuilder = toBuilder.addProperty(parseToValidParamName(leafName));
1452         propBuilder.setReadOnly(isReadOnly);
1453         propBuilder.setReturnType(returnType);
1454         propBuilder.setComment(leafDesc);
1455         toBuilder.addEqualsIdentity(propBuilder);
1456         toBuilder.addHashIdentity(propBuilder);
1457         toBuilder.addToStringProperty(propBuilder);
1458         return true;
1459     }
1460
1461     /**
1462      * Converts <code>node</code> leaf list schema node to getter method of
1463      * <code>typeBuilder</code>.
1464      *
1465      * @param typeBuilder
1466      *            generated type builder to which is <code>node</code> added as
1467      *            getter method
1468      * @param node
1469      *            leaf list schema node which is added to
1470      *            <code>typeBuilder</code> as getter method
1471      * @return boolean value
1472      *         <ul>
1473      *         <li>true - if <code>node</code>, <code>typeBuilder</code>,
1474      *         nodeName equal null or <code>node</code> is added by <i>uses</i></li>
1475      *         <li>false - other cases</li>
1476      *         </ul>
1477      */
1478     private def boolean resolveLeafListSchemaNode(GeneratedTypeBuilder typeBuilder, LeafListSchemaNode node) {
1479         if ((node !== null) && (typeBuilder !== null)) {
1480             val nodeName = node.QName;
1481             var String nodeDesc = node.description;
1482             if (nodeDesc === null) {
1483                 nodeDesc = "";
1484             }
1485             if (nodeName !== null && !node.isAddedByUses()) {
1486                 val TypeDefinition<?> typeDef = node.type;
1487                 val parentModule = findParentModule(schemaContext, node);
1488
1489                 var Type returnType = null;
1490                 if (typeDef instanceof EnumTypeDefinition) {
1491                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, node);
1492                     val enumTypeDef = typeDef as EnumTypeDefinition;
1493                     val enumBuilder = resolveInnerEnumFromTypeDefinition(enumTypeDef, nodeName, typeBuilder);
1494                     returnType = new ReferencedTypeImpl(enumBuilder.packageName, enumBuilder.name);
1495                     (typeProvider as TypeProviderImpl).putReferencedType(node.path, returnType);
1496                 } else if (typeDef instanceof UnionType) {
1497                     val genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, node, parentModule);
1498                     if (genTOBuilder !== null) {
1499                         returnType = createReturnTypeForUnion(genTOBuilder, typeDef, typeBuilder, parentModule)
1500                     }
1501                 } else if (typeDef instanceof BitsTypeDefinition) {
1502                     val genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, node, parentModule);
1503                     returnType = new ReferencedTypeImpl(genTOBuilder.packageName, genTOBuilder.name);
1504                 } else {
1505                     val Restrictions restrictions = BindingGeneratorUtil.getRestrictions(typeDef);
1506                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, node, restrictions);
1507                 }
1508
1509                 val listType = Types.listTypeFor(returnType);
1510                 constructGetter(typeBuilder, nodeName.localName, nodeDesc, listType);
1511                 return true;
1512             }
1513         }
1514         return false;
1515     }
1516
1517     private def Type createReturnTypeForUnion(GeneratedTOBuilder genTOBuilder, TypeDefinition<?> typeDef,
1518         GeneratedTypeBuilder typeBuilder, Module parentModule) {
1519         val GeneratedTOBuilderImpl returnType = new GeneratedTOBuilderImpl(genTOBuilder.packageName, genTOBuilder.name)
1520         genTOBuilder.setTypedef(true);
1521         genTOBuilder.setIsUnion(true);
1522         (typeProvider as TypeProviderImpl).addUnitsToGenTO(genTOBuilder, typeDef.getUnits());
1523
1524         // union builder
1525         val GeneratedTOBuilder unionBuilder = new GeneratedTOBuilderImpl(typeBuilder.getPackageName(),
1526             genTOBuilder.getName() + "Builder");
1527         unionBuilder.setIsUnionBuilder(true);
1528         val MethodSignatureBuilder method = unionBuilder.addMethod("getDefaultInstance");
1529         method.setReturnType(returnType);
1530         method.addParameter(Types.STRING, "defaultValue");
1531         method.setAccessModifier(AccessModifier.PUBLIC);
1532         method.setStatic(true);
1533
1534         val Set<Type> types = (typeProvider as TypeProviderImpl).additionalTypes.get(parentModule);
1535         if (types == null) {
1536             (typeProvider as TypeProviderImpl).additionalTypes.put(parentModule,
1537                 Sets.newHashSet(unionBuilder.toInstance))
1538         } else {
1539             types.add(unionBuilder.toInstance)
1540         }
1541         return returnType.toInstance
1542     }
1543
1544     private def GeneratedTypeBuilder addDefaultInterfaceDefinition(String packageName, SchemaNode schemaNode) {
1545         return addDefaultInterfaceDefinition(packageName, schemaNode, null);
1546     }
1547
1548     /**
1549      * Instantiates generated type builder with <code>packageName</code> and
1550      * <code>schemaNode</code>.
1551      *
1552      * The new builder always implements
1553      * {@link org.opendaylight.yangtools.yang.binding.DataObject DataObject}.<br />
1554      * If <code>schemaNode</code> is instance of GroupingDefinition it also
1555      * implements {@link org.opendaylight.yangtools.yang.binding.Augmentable
1556      * Augmentable}.<br />
1557      * If <code>schemaNode</code> is instance of
1558      * {@link org.opendaylight.yangtools.yang.model.api.DataNodeContainer
1559      * DataNodeContainer} it can also implement nodes which are specified in
1560      * <i>uses</i>.
1561      *
1562      * @param packageName
1563      *            string with the name of the package to which
1564      *            <code>schemaNode</code> belongs.
1565      * @param schemaNode
1566      *            schema node for which is created generated type builder
1567      * @param parent parent type (can be null)
1568      * @return generated type builder <code>schemaNode</code>
1569      */
1570     private def GeneratedTypeBuilder addDefaultInterfaceDefinition(String packageName, SchemaNode schemaNode,
1571         Type parent) {
1572         val it = addRawInterfaceDefinition(packageName, schemaNode, "");
1573         if (parent === null) {
1574             addImplementsType(DATA_OBJECT);
1575         } else {
1576             addImplementsType(BindingTypes.childOf(parent));
1577         }
1578         if (!(schemaNode instanceof GroupingDefinition)) {
1579             addImplementsType(augmentable(it));
1580         }
1581
1582         if (schemaNode instanceof DataNodeContainer) {
1583             addImplementedInterfaceFromUses(schemaNode as DataNodeContainer, it);
1584         }
1585
1586         return it;
1587     }
1588
1589     /**
1590      * Wraps the calling of the same overloaded method.
1591      *
1592      * @param packageName
1593      *            string with the package name to which returning generated type
1594      *            builder belongs
1595      * @param schemaNode
1596      *            schema node which provide data about the schema node name
1597      * @return generated type builder for <code>schemaNode</code>
1598      */
1599     private def GeneratedTypeBuilder addRawInterfaceDefinition(String packageName, SchemaNode schemaNode) {
1600         return addRawInterfaceDefinition(packageName, schemaNode, "");
1601     }
1602
1603     /**
1604      * Returns reference to generated type builder for specified
1605      * <code>schemaNode</code> with <code>packageName</code>.
1606      *
1607      * Firstly the generated type builder is searched in
1608      * {@link BindingGeneratorImpl#genTypeBuilders genTypeBuilders}. If it isn't
1609      * found it is created and added to <code>genTypeBuilders</code>.
1610      *
1611      * @param packageName
1612      *            string with the package name to which returning generated type
1613      *            builder belongs
1614      * @param schemaNode
1615      *            schema node which provide data about the schema node name
1616      * @param prefix return type name prefix
1617      * @return generated type builder for <code>schemaNode</code>
1618      * @throws IllegalArgumentException
1619      *             <ul>
1620      *             <li>if <code>schemaNode</code> equals null</li>
1621      *             <li>if <code>packageName</code> equals null</li>
1622      *             <li>if Q name of schema node is null</li>
1623      *             <li>if schema node name is null</li>
1624      *             </ul>
1625      *
1626      */
1627     private def GeneratedTypeBuilder addRawInterfaceDefinition(String packageName, SchemaNode schemaNode,
1628         String prefix) {
1629         checkArgument(schemaNode !== null, "Data Schema Node cannot be NULL.");
1630         checkArgument(packageName !== null, "Package Name for Generated Type cannot be NULL.");
1631         checkArgument(schemaNode.QName !== null, "QName for Data Schema Node cannot be NULL.");
1632         val schemaNodeName = schemaNode.QName.localName;
1633         checkArgument(schemaNodeName !== null, "Local Name of QName for Data Schema Node cannot be NULL.");
1634
1635         var String genTypeName;
1636         if (prefix === null) {
1637             genTypeName = BindingMapping.getClassName(schemaNodeName);
1638         } else {
1639             genTypeName = prefix + BindingMapping.getClassName(schemaNodeName);
1640         }
1641
1642         //FIXME: Validation of name conflict
1643         val newType = new GeneratedTypeBuilderImpl(packageName, genTypeName);
1644         qnameConstant(newType,BindingMapping.QNAME_STATIC_FIELD_NAME,schemaNode.QName);
1645         newType.addComment(schemaNode.getDescription());
1646         if (!genTypeBuilders.containsKey(packageName)) {
1647             val Map<String, GeneratedTypeBuilder> builders = new HashMap();
1648             builders.put(genTypeName, newType);
1649             genTypeBuilders.put(packageName, builders);
1650         } else {
1651             val Map<String, GeneratedTypeBuilder> builders = genTypeBuilders.get(packageName);
1652             if (!builders.containsKey(genTypeName)) {
1653                 builders.put(genTypeName, newType);
1654             }
1655         }
1656         return newType;
1657     }
1658
1659     /**
1660      * Creates the name of the getter method name from <code>localName</code>.
1661      *
1662      * @param localName
1663      *            string with the name of the getter method
1664      * @param returnType return type
1665      * @return string with the name of the getter method for
1666      *         <code>methodName</code> in JAVA method format
1667      */
1668     public static def String getterMethodName(String localName, Type returnType) {
1669         val method = new StringBuilder();
1670         if (BOOLEAN.equals(returnType)) {
1671             method.append("is");
1672         } else {
1673             method.append("get");
1674         }
1675         method.append(BindingMapping.getPropertyName(localName).toFirstUpper);
1676         return method.toString();
1677     }
1678
1679     /**
1680      * Created a method signature builder as part of
1681      * <code>interfaceBuilder</code>.
1682      *
1683      * The method signature builder is created for the getter method of
1684      * <code>schemaNodeName</code>. Also <code>comment</code> and
1685      * <code>returnType</code> information are added to the builder.
1686      *
1687      * @param interfaceBuilder
1688      *            generated type builder for which the getter method should be
1689      *            created
1690      * @param schemaNodeName
1691      *            string with schema node name. The name will be the part of the
1692      *            getter method name.
1693      * @param comment
1694      *            string with comment for the getter method
1695      * @param returnType
1696      *            type which represents the return type of the getter method
1697      * @return method signature builder which represents the getter method of
1698      *         <code>interfaceBuilder</code>
1699      */
1700     private def MethodSignatureBuilder constructGetter(GeneratedTypeBuilder interfaceBuilder, String schemaNodeName,
1701         String comment, Type returnType) {
1702         val getMethod = interfaceBuilder.addMethod(getterMethodName(schemaNodeName, returnType));
1703         getMethod.setComment(comment);
1704         getMethod.setReturnType(returnType);
1705         return getMethod;
1706     }
1707
1708     /**
1709      * Adds <code>schemaNode</code> to <code>typeBuilder</code> as getter method
1710      * or to <code>genTOBuilder</code> as property.
1711      *
1712      * @param basePackageName
1713      *            string contains the module package name
1714      * @param schemaNode
1715      *            data schema node which should be added as getter method to
1716      *            <code>typeBuilder</code> or as a property to
1717      *            <code>genTOBuilder</code> if is part of the list key
1718      * @param typeBuilder
1719      *            generated type builder for the list schema node
1720      * @param genTOBuilder
1721      *            generated TO builder for the list keys
1722      * @param listKeys
1723      *            list of string which contains names of the list keys
1724      * @param module current module
1725      * @throws IllegalArgumentException
1726      *             <ul>
1727      *             <li>if <code>schemaNode</code> equals null</li>
1728      *             <li>if <code>typeBuilder</code> equals null</li>
1729      *             </ul>
1730      */
1731     private def void addSchemaNodeToListBuilders(String basePackageName, DataSchemaNode schemaNode,
1732         GeneratedTypeBuilder typeBuilder, GeneratedTOBuilder genTOBuilder, List<String> listKeys, Module module) {
1733         checkArgument(schemaNode !== null, "Data Schema Node cannot be NULL.");
1734         checkArgument(typeBuilder !== null, "Generated Type Builder cannot be NULL.");
1735
1736         if (schemaNode instanceof LeafSchemaNode) {
1737             val leaf = schemaNode as LeafSchemaNode;
1738             val leafName = leaf.QName.localName;
1739             val Type type = resolveLeafSchemaNodeAsMethod(typeBuilder, leaf);
1740             if (listKeys.contains(leafName)) {
1741                 if (type == null) {
1742                     resolveLeafSchemaNodeAsProperty(genTOBuilder, leaf, true, module)
1743                 } else {
1744                     resolveLeafSchemaNodeAsProperty(genTOBuilder, leaf, type, true)
1745                 }
1746             }
1747         } else if (!schemaNode.addedByUses) {
1748             if (schemaNode instanceof LeafListSchemaNode) {
1749                 resolveLeafListSchemaNode(typeBuilder, schemaNode as LeafListSchemaNode);
1750             } else if (schemaNode instanceof ContainerSchemaNode) {
1751                 containerToGenType(module, basePackageName, typeBuilder, typeBuilder, schemaNode as ContainerSchemaNode);
1752             } else if (schemaNode instanceof ChoiceNode) {
1753                 choiceToGeneratedType(module, basePackageName, typeBuilder, schemaNode as ChoiceNode);
1754             } else if (schemaNode instanceof ListSchemaNode) {
1755                 listToGenType(module, basePackageName, typeBuilder, typeBuilder, schemaNode as ListSchemaNode);
1756             }
1757         }
1758     }
1759
1760     private def typeBuildersToGenTypes(Module module, GeneratedTypeBuilder typeBuilder, GeneratedTOBuilder genTOBuilder) {
1761         checkArgument(typeBuilder !== null, "Generated Type Builder cannot be NULL.");
1762
1763         if (genTOBuilder !== null) {
1764             val genTO = genTOBuilder.toInstance();
1765             constructGetter(typeBuilder, "key", "Returns Primary Key of Yang List Type", genTO);
1766             genCtx.get(module).addGeneratedTOBuilder(genTOBuilder)
1767         }
1768     }
1769
1770     /**
1771      * Selects the names of the list keys from <code>list</code> and returns
1772      * them as the list of the strings
1773      *
1774      * @param list
1775      *            of string with names of the list keys
1776      * @return list of string which represents names of the list keys. If the
1777      *         <code>list</code> contains no keys then the empty list is
1778      *         returned.
1779      */
1780     private def listKeys(ListSchemaNode list) {
1781         val List<String> listKeys = new ArrayList();
1782
1783         if (list.keyDefinition !== null) {
1784             val keyDefinitions = list.keyDefinition;
1785             for (keyDefinition : keyDefinitions) {
1786                 listKeys.add(keyDefinition.localName);
1787             }
1788         }
1789         return listKeys;
1790     }
1791
1792     /**
1793      * Generates for the <code>list</code> which contains any list keys special
1794      * generated TO builder.
1795      *
1796      * @param packageName
1797      *            string with package name to which the list belongs
1798      * @param list
1799      *            list schema node which is source of data about the list name
1800      * @return generated TO builder which represents the keys of the
1801      *         <code>list</code> or null if <code>list</code> is null or list of
1802      *         key definitions is null or empty.
1803      */
1804     private def GeneratedTOBuilder resolveListKeyTOBuilder(String packageName, ListSchemaNode list) {
1805         var GeneratedTOBuilder genTOBuilder = null;
1806         if ((list.keyDefinition !== null) && (!list.keyDefinition.isEmpty())) {
1807             val listName = list.QName.localName + "Key";
1808             val String genTOName = BindingMapping.getClassName(listName);
1809             genTOBuilder = new GeneratedTOBuilderImpl(packageName, genTOName);
1810         }
1811         return genTOBuilder;
1812     }
1813
1814     /**
1815      * Builds generated TO builders for <code>typeDef</code> of type
1816      * {@link org.opendaylight.yangtools.yang.model.util.UnionType UnionType} or
1817      * {@link org.opendaylight.yangtools.yang.model.api.type.BitsTypeDefinition
1818      * BitsTypeDefinition} which are also added to <code>typeBuilder</code> as
1819      * enclosing transfer object.
1820      *
1821      * If more then one generated TO builder is created for enclosing then all
1822      * of the generated TO builders are added to <code>typeBuilder</code> as
1823      * enclosing transfer objects.
1824      *
1825      * @param typeDef
1826      *            type definition which can be of type <code>UnionType</code> or
1827      *            <code>BitsTypeDefinition</code>
1828      * @param typeBuilder
1829      *            generated type builder to which is added generated TO created
1830      *            from <code>typeDef</code>
1831      * @param leafName
1832      *            string with name for generated TO builder
1833      * @param leaf
1834      * @param parentModule
1835      * @return generated TO builder for <code>typeDef</code>
1836      */
1837     private def GeneratedTOBuilder addTOToTypeBuilder(TypeDefinition<?> typeDef, GeneratedTypeBuilder typeBuilder,
1838         DataSchemaNode leaf, Module parentModule) {
1839         val classNameFromLeaf = BindingMapping.getClassName(leaf.QName);
1840         val List<GeneratedTOBuilder> genTOBuilders = new ArrayList();
1841         val packageName = typeBuilder.fullyQualifiedName;
1842         if (typeDef instanceof UnionTypeDefinition) {
1843             val List<GeneratedTOBuilder> types = (typeProvider as TypeProviderImpl).
1844                     provideGeneratedTOBuildersForUnionTypeDef(packageName, (typeDef as UnionTypeDefinition),
1845                         classNameFromLeaf, leaf);
1846             genTOBuilders.addAll(types);
1847
1848
1849         var GeneratedTOBuilder resultTOBuilder = null;
1850         if (!types.isEmpty()) {
1851             resultTOBuilder = types.remove(0);
1852             for (GeneratedTOBuilder genTOBuilder : types) {
1853                 resultTOBuilder.addEnclosingTransferObject(genTOBuilder);
1854             }
1855         }
1856
1857         val GeneratedPropertyBuilder genPropBuilder = resultTOBuilder.addProperty("value");
1858         genPropBuilder.setReturnType(Types.primitiveType("char[]", null));
1859         resultTOBuilder.addEqualsIdentity(genPropBuilder);
1860         resultTOBuilder.addHashIdentity(genPropBuilder);
1861         resultTOBuilder.addToStringProperty(genPropBuilder);
1862
1863         } else if (typeDef instanceof BitsTypeDefinition) {
1864             genTOBuilders.add(
1865                 ((typeProvider as TypeProviderImpl) ).
1866                     provideGeneratedTOBuilderForBitsTypeDefinition(packageName, typeDef, classNameFromLeaf));
1867         }
1868         if (genTOBuilders !== null && !genTOBuilders.isEmpty()) {
1869             for (genTOBuilder : genTOBuilders) {
1870                 typeBuilder.addEnclosingTransferObject(genTOBuilder);
1871             }
1872             return genTOBuilders.get(0);
1873         }
1874         return null;
1875
1876     }
1877
1878     /**
1879      * Adds the implemented types to type builder.
1880      *
1881      * The method passes through the list of <i>uses</i> in
1882      * {@code dataNodeContainer}. For every <i>use</i> is obtained corresponding
1883      * generated type from {@link BindingGeneratorImpl#allGroupings
1884      * allGroupings} which is added as <i>implements type</i> to
1885      * <code>builder</code>
1886      *
1887      * @param dataNodeContainer
1888      *            element which contains the list of used YANG groupings
1889      * @param builder
1890      *            builder to which are added implemented types according to
1891      *            <code>dataNodeContainer</code>
1892      * @return generated type builder with all implemented types
1893      */
1894     private def addImplementedInterfaceFromUses(DataNodeContainer dataNodeContainer, GeneratedTypeBuilder builder) {
1895         for (usesNode : dataNodeContainer.uses) {
1896             if (usesNode.groupingPath !== null) {
1897                 val genType = findGroupingByPath(usesNode.groupingPath).toInstance
1898                 if (genType === null) {
1899                     throw new IllegalStateException(
1900                         "Grouping " + usesNode.groupingPath + "is not resolved for " + builder.name);
1901                 }
1902                 builder.addImplementsType(genType);
1903                 builder.addComment(genType.getComment());
1904             }
1905         }
1906         return builder;
1907     }
1908
1909     private def GeneratedTypeBuilder findChildNodeByPath(SchemaPath path) {
1910         for (ctx : genCtx.values) {
1911             var result = ctx.getChildNode(path)
1912             if (result !== null) {
1913                 return result
1914             }
1915         }
1916         return null
1917     }
1918
1919     private def GeneratedTypeBuilder findGroupingByPath(SchemaPath path) {
1920         for (ctx : genCtx.values) {
1921             var result = ctx.getGrouping(path)
1922             if (result !== null) {
1923                 return result
1924             }
1925         }
1926         return null
1927     }
1928
1929     private def GeneratedTypeBuilder findCaseByPath(SchemaPath path) {
1930         for (ctx : genCtx.values) {
1931             var result = ctx.getCase(path)
1932             if (result !== null) {
1933                 return result
1934             }
1935         }
1936         return null
1937     }
1938
1939     public def getModuleContexts() {
1940         genCtx;
1941     }
1942
1943 }