code-generator/binding-generator-impl/src/main/java/org/opendaylight/yangtools/sal/binding/generator/impl/BindingGeneratorImpl.xtend

   1 /*
   2  * Copyright (c) 2013 Cisco Systems, Inc. and others.  All rights reserved.
   3  *
   4  * This program and the accompanying materials are made available under the
   5  * terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6  * and is available at http://www.eclipse.org/legal/epl-v10.html
   7  */
   8 package org.opendaylight.yangtools.sal.binding.generator.impl;
   9
  10 import static com.google.common.base.Preconditions.*;
  11 import static extension org.opendaylight.yangtools.binding.generator.util.Types.*;
  12 import static org.opendaylight.yangtools.binding.generator.util.BindingGeneratorUtil.*;
  13 import static org.opendaylight.yangtools.binding.generator.util.BindingTypes.*;
  14 import static org.opendaylight.yangtools.yang.model.util.SchemaContextUtil.*;
  15
  16 import java.util.ArrayList;
  17 import java.util.Collections;
  18 import java.util.HashMap;
  19 import java.util.List;
  20 import java.util.Map;
  21 import java.util.Set;
  22 import java.util.Iterator
  23 import java.util.Collection
  24 import org.opendaylight.yangtools.binding.generator.util.BindingTypes;
  25 import org.opendaylight.yangtools.binding.generator.util.ReferencedTypeImpl;
  26 import org.opendaylight.yangtools.binding.generator.util.Types;
  27 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedTOBuilderImpl;
  28 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedTypeBuilderImpl;
  29 import org.opendaylight.yangtools.sal.binding.generator.api.BindingGenerator;
  30 import org.opendaylight.yangtools.sal.binding.generator.spi.TypeProvider;
  31 import org.opendaylight.yangtools.sal.binding.model.api.AccessModifier;
  32 import org.opendaylight.yangtools.sal.binding.model.api.Type;
  33 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.EnumBuilder;
  34 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTOBuilder;
  35 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTypeBuilder;
  36 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.MethodSignatureBuilder;
  37 import org.opendaylight.yangtools.sal.binding.yang.types.GroupingDefinitionDependencySort;
  38 import org.opendaylight.yangtools.sal.binding.yang.types.TypeProviderImpl;
  39 import org.opendaylight.yangtools.yang.binding.RpcService;
  40 import org.opendaylight.yangtools.yang.common.RpcResult;
  41 import org.opendaylight.yangtools.yang.model.api.AugmentationSchema;
  42 import org.opendaylight.yangtools.yang.model.api.ChoiceCaseNode;
  43 import org.opendaylight.yangtools.yang.model.api.ChoiceNode;
  44 import org.opendaylight.yangtools.yang.model.api.ContainerSchemaNode;
  45 import org.opendaylight.yangtools.yang.model.api.DataNodeContainer;
  46 import org.opendaylight.yangtools.yang.model.api.DataSchemaNode;
  47 import org.opendaylight.yangtools.yang.model.api.GroupingDefinition;
  48 import org.opendaylight.yangtools.yang.model.api.IdentitySchemaNode;
  49 import org.opendaylight.yangtools.yang.model.api.LeafListSchemaNode;
  50 import org.opendaylight.yangtools.yang.model.api.LeafSchemaNode;
  51 import org.opendaylight.yangtools.yang.model.api.ListSchemaNode;
  52 import org.opendaylight.yangtools.yang.model.api.Module;
  53 import org.opendaylight.yangtools.yang.model.api.RpcDefinition;
  54 import org.opendaylight.yangtools.yang.model.api.SchemaContext;
  55 import org.opendaylight.yangtools.yang.model.api.SchemaNode;
  56 import org.opendaylight.yangtools.yang.model.api.SchemaPath;
  57 import org.opendaylight.yangtools.yang.model.api.TypeDefinition;
  58 import org.opendaylight.yangtools.yang.model.api.UnknownSchemaNode;
  59 import org.opendaylight.yangtools.yang.model.api.type.BitsTypeDefinition;
  60 import org.opendaylight.yangtools.yang.model.api.type.EnumTypeDefinition;
  61 import org.opendaylight.yangtools.yang.model.api.type.UnionTypeDefinition;
  62 import org.opendaylight.yangtools.yang.model.util.DataNodeIterator;
  63 import org.opendaylight.yangtools.yang.model.util.SchemaContextUtil;
  64 import org.opendaylight.yangtools.yang.model.util.UnionType;
  65 import org.opendaylight.yangtools.yang.parser.util.ModuleDependencySort
  66 import org.opendaylight.yangtools.yang.model.util.ExtendedType;
  67 import org.opendaylight.yangtools.yang.model.api.UsesNode
  68 import org.opendaylight.yangtools.yang.binding.annotations.RoutingContext
  69 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.AnnotationTypeBuilder
  70 import org.opendaylight.yangtools.yang.model.api.ModuleImport
  71 import org.opendaylight.yangtools.yang.binding.DataContainer
  72 import org.opendaylight.yangtools.yang.model.api.NotificationDefinition
  73 import org.opendaylight.yangtools.binding.generator.util.BindingGeneratorUtil
  74 import org.opendaylight.yangtools.sal.binding.model.api.Restrictions
  75 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedPropertyBuilder
  76 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedPropertyBuilderImpl
  77 import org.opendaylight.yangtools.yang.common.QName
  78 import org.opendaylight.yangtools.yang.binding.BindingMapping
  79 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTypeBuilderBase
  80
  81 import com.google.common.collect.Sets
  82 import java.util.TreeSet
  83
  84 public class BindingGeneratorImpl implements BindingGenerator {
  85
  86     private final Map<Module, ModuleContext> genCtx = new HashMap()
  87
  88     /**
  89      * Outer key represents the package name. Outer value represents map of
  90      * all builders in the same package. Inner key represents the schema node
  91      * name (in JAVA class/interface name format). Inner value represents
  92      * instance of builder for schema node specified in key part.
  93      */
  94     private Map<String, Map<String, GeneratedTypeBuilder>> genTypeBuilders;
  95
  96     /**
  97      * Provide methods for converting YANG types to JAVA types.
  98      */
  99     private var TypeProvider typeProvider;
 100
 101     /**
 102      * Holds reference to schema context to resolve data of augmented element
 103      * when creating augmentation builder
 104      */
 105     private var SchemaContext schemaContext;
 106
 107     /**
 108      * Constant with the concrete name of namespace.
 109      */
 110     private val static String YANG_EXT_NAMESPACE = "urn:opendaylight:yang:extension:yang-ext";
 111
 112     /**
 113      * Constant with the concrete name of identifier.
 114      */
 115     private val static String AUGMENT_IDENTIFIER_NAME = "augment-identifier";
 116
 117     /**
 118      * Resolves generated types from <code>context</code> schema nodes of all
 119      * modules.
 120      *
 121      * Generated types are created for modules, groupings, types, containers,
 122      * lists, choices, augments, rpcs, notification, identities.
 123      *
 124      * @param context
 125      *            schema context which contains data about all schema nodes
 126      *            saved in modules
 127      * @return list of types (usually <code>GeneratedType</code>
 128      *         <code>GeneratedTransferObject</code>which are generated from
 129      *         <code>context</code> data.
 130      * @throws IllegalArgumentException
 131      *             if param <code>context</code> is null
 132      * @throws IllegalStateException
 133      *             if <code>context</code> contain no modules
 134      */
 135     override generateTypes(SchemaContext context) {
 136         checkArgument(context !== null, "Schema Context reference cannot be NULL.");
 137         checkState(context.modules !== null, "Schema Context does not contain defined modules.");
 138         schemaContext = context;
 139         typeProvider = new TypeProviderImpl(context);
 140         val Set<Module> modules = context.modules;
 141         return generateTypes(context, modules);
 142     }
 143
 144     /**
 145      * Resolves generated types from <code>context</code> schema nodes only for
 146      * modules specified in <code>modules</code>
 147      *
 148      * Generated types are created for modules, groupings, types, containers,
 149      * lists, choices, augments, rpcs, notification, identities.
 150      *
 151      * @param context
 152      *            schema context which contains data about all schema nodes
 153      *            saved in modules
 154      * @param modules
 155      *            set of modules for which schema nodes should be generated
 156      *            types
 157      * @return list of types (usually <code>GeneratedType</code> or
 158      *         <code>GeneratedTransferObject</code>) which:
 159      *         <ul>
 160      *         <li>are generated from <code>context</code> schema nodes and</li>
 161      *         <li>are also part of some of the module in <code>modules</code>
 162      *         set</li>.
 163      *         </ul>
 164      * @throws IllegalArgumentException
 165      *             <ul>
 166      *             <li>if param <code>context</code> is null or</li>
 167      *             <li>if param <code>modules</code> is null</li>
 168      *             </ul>
 169      * @throws IllegalStateException
 170      *             if <code>context</code> contain no modules
 171      */
 172     override generateTypes(SchemaContext context, Set<Module> modules) {
 173         checkArgument(context !== null, "Schema Context reference cannot be NULL.");
 174         checkState(context.modules !== null, "Schema Context does not contain defined modules.");
 175         checkArgument(modules !== null, "Set of Modules cannot be NULL.");
 176
 177         schemaContext = context;
 178         typeProvider = new TypeProviderImpl(context);
 179         val contextModules = ModuleDependencySort.sort(context.modules);
 180         genTypeBuilders = new HashMap();
 181
 182         for (contextModule : contextModules) {
 183             moduleToGenTypes(contextModule, context);
 184         }
 185         for (contextModule : contextModules) {
 186             allAugmentsToGenTypes(contextModule);
 187         }
 188
 189         val List<Type> filteredGenTypes = new ArrayList();
 190         for (Module m : modules) {
 191             val ctx = checkNotNull(genCtx.get(m), "Module context not found for module %s", m)
 192             filteredGenTypes.addAll(ctx.generatedTypes);
 193             val Set<Type> additionalTypes = (typeProvider as TypeProviderImpl).additionalTypes.get(m)
 194             if (additionalTypes != null) {
 195                 filteredGenTypes.addAll(additionalTypes)
 196             }
 197         }
 198
 199         return filteredGenTypes;
 200     }
 201
 202     private def void moduleToGenTypes(Module m, SchemaContext context) {
 203         genCtx.put(m, new ModuleContext)
 204         allTypeDefinitionsToGenTypes(m)
 205         groupingsToGenTypes(m, m.groupings)
 206         rpcMethodsToGenType(m)
 207         allIdentitiesToGenTypes(m, context)
 208         notificationsToGenType(m)
 209
 210         if (!m.childNodes.isEmpty()) {
 211             val moduleType = moduleToDataType(m)
 212             genCtx.get(m).addModuleNode(moduleType)
 213             val basePackageName = moduleNamespaceToPackageName(m);
 214             resolveDataSchemaNodes(m, basePackageName, moduleType, moduleType, m.childNodes)
 215         }
 216     }
 217
 218     /**
 219      * Converts all extended type definitions of module to the list of
 220      * <code>Type</code> objects.
 221      *
 222      * @param module
 223      *            module from which is obtained set of type definitions
 224      * @throws IllegalArgumentException
 225      *             <ul>
 226      *             <li>if module equals null</li>
 227      *             <li>if name of module equals null</li>
 228      *             <li>if type definitions of module equal null</li>
 229      *             </ul>
 230      *
 231      */
 232     private def void allTypeDefinitionsToGenTypes(Module module) {
 233         checkArgument(module !== null, "Module reference cannot be NULL.");
 234         checkArgument(module.name !== null, "Module name cannot be NULL.");
 235         val it = new DataNodeIterator(module);
 236         val List<TypeDefinition<?>> typeDefinitions = it.allTypedefs;
 237         checkState(typeDefinitions !== null, '''Type Definitions for module «module.name» cannot be NULL.''');
 238
 239         for (TypeDefinition<?> typedef : typeDefinitions) {
 240             if (typedef !== null) {
 241                 val type = (typeProvider as TypeProviderImpl).generatedTypeForExtendedDefinitionType(typedef, typedef);
 242                 if (type !== null) {
 243                     genCtx.get(module).addTypedefType(typedef.path, type)
 244                 }
 245             }
 246         }
 247     }
 248
 249     private def GeneratedTypeBuilder processDataSchemaNode(Module module, String basePackageName,
 250         GeneratedTypeBuilder parent, GeneratedTypeBuilder childOf, DataSchemaNode node) {
 251         if (node.augmenting || node.addedByUses) {
 252             return null
 253         }
 254         val packageName = packageNameForGeneratedType(basePackageName, node.path)
 255         val genType = addDefaultInterfaceDefinition(packageName, node, childOf)
 256         genType.addComment(node.getDescription());
 257         if (node instanceof DataNodeContainer) {
 258             genCtx.get(module).addChildNodeType(node.path, genType)
 259             groupingsToGenTypes(module, (node as DataNodeContainer).groupings)
 260             processUsesAugments(node as DataNodeContainer, module)
 261         }
 262         return genType
 263     }
 264
 265     private def void containerToGenType(Module module, String basePackageName, GeneratedTypeBuilder parent,
 266         GeneratedTypeBuilder childOf, ContainerSchemaNode node) {
 267         val genType = processDataSchemaNode(module, basePackageName, parent, childOf, node)
 268         if (genType != null) {
 269             constructGetter(parent, node.QName.localName, node.description, genType)
 270             resolveDataSchemaNodes(module, basePackageName, genType, genType, node.childNodes)
 271         }
 272     }
 273
 274     private def void listToGenType(Module module, String basePackageName, GeneratedTypeBuilder parent,
 275         GeneratedTypeBuilder childOf, ListSchemaNode node) {
 276         val genType = processDataSchemaNode(module, basePackageName, parent, childOf, node)
 277         if (genType != null) {
 278             constructGetter(parent, node.QName.localName, node.description, Types.listTypeFor(genType))
 279
 280             val List<String> listKeys = listKeys(node);
 281             val packageName = packageNameForGeneratedType(basePackageName, (node).path)
 282             val genTOBuilder = resolveListKeyTOBuilder(packageName, node);
 283             if (genTOBuilder !== null) {
 284                 val identifierMarker = IDENTIFIER.parameterizedTypeFor(genType);
 285                 val identifiableMarker = IDENTIFIABLE.parameterizedTypeFor(genTOBuilder);
 286                 genTOBuilder.addImplementsType(identifierMarker);
 287                 genType.addImplementsType(identifiableMarker);
 288             }
 289
 290             for (schemaNode : node.childNodes) {
 291                 if (!schemaNode.augmenting) {
 292                     addSchemaNodeToListBuilders(basePackageName, schemaNode, genType, genTOBuilder, listKeys, module);
 293                 }
 294             }
 295
 296             // serialVersionUID
 297             if (genTOBuilder !== null) {
 298                 val GeneratedPropertyBuilder prop = new GeneratedPropertyBuilderImpl("serialVersionUID");
 299                 prop.setValue(Long.toString(computeDefaultSUID(genTOBuilder as GeneratedTOBuilderImpl)));
 300                 genTOBuilder.setSUID(prop);
 301             }
 302
 303             typeBuildersToGenTypes(module, genType, genTOBuilder);
 304         }
 305     }
 306
 307     private def void processUsesAugments(DataNodeContainer node, Module module) {
 308         val basePackageName = moduleNamespaceToPackageName(module);
 309         for (usesNode : node.uses) {
 310             for (augment : usesNode.augmentations) {
 311                 usesAugmentationToGenTypes(basePackageName, augment, module, usesNode, node);
 312                 processUsesAugments(augment, module);
 313             }
 314         }
 315     }
 316
 317     /**
 318      * Converts all <b>augmentation</b> of the module to the list
 319      * <code>Type</code> objects.
 320      *
 321      * @param module
 322      *            module from which is obtained list of all augmentation objects
 323      *            to iterate over them
 324      * @throws IllegalArgumentException
 325      *             <ul>
 326      *             <li>if the module equals null</li>
 327      *             <li>if the name of module equals null</li>
 328      *             <li>if the set of child nodes equals null</li>
 329      *             </ul>
 330      *
 331      */
 332     private def void allAugmentsToGenTypes(Module module) {
 333         checkArgument(module !== null, "Module reference cannot be NULL.");
 334         checkArgument(module.name !== null, "Module name cannot be NULL.");
 335         if (module.childNodes === null) {
 336             throw new IllegalArgumentException(
 337                 "Reference to Set of Augmentation Definitions in module " + module.name + " cannot be NULL.");
 338         }
 339
 340         val basePackageName = moduleNamespaceToPackageName(module);
 341         val List<AugmentationSchema> augmentations = resolveAugmentations(module);
 342         for (augment : augmentations) {
 343             augmentationToGenTypes(basePackageName, augment, module);
 344         }
 345     }
 346
 347     /**
 348      * Returns list of <code>AugmentationSchema</code> objects. The objects are
 349      * sorted according to the length of their target path from the shortest to
 350      * the longest.
 351      *
 352      * @param module
 353      *            module from which is obtained list of all augmentation objects
 354      * @return list of sorted <code>AugmentationSchema</code> objects obtained
 355      *         from <code>module</code>
 356      * @throws IllegalArgumentException
 357      *             <ul>
 358      *             <li>if the module equals null</li>
 359      *             <li>if the set of augmentation equals null</li>
 360      *             </ul>
 361      *
 362      */
 363     private def List<AugmentationSchema> resolveAugmentations(Module module) {
 364         checkArgument(module !== null, "Module reference cannot be NULL.");
 365         checkState(module.augmentations !== null, "Augmentations Set cannot be NULL.");
 366
 367         val Set<AugmentationSchema> augmentations = module.augmentations;
 368         var List<AugmentationSchema> sortedAugmentations = getSortedOrNull(augmentations)
 369         if (sortedAugmentations != null) {
 370             return sortedAugmentations
 371         }
 372         sortedAugmentations = new ArrayList(augmentations);
 373         Collections.sort(sortedAugmentations,
 374             [ augSchema1, augSchema2 |
 375                 val Iterator<QName> thisIt = augSchema1.targetPath.getPath().iterator();
 376                 val Iterator<QName> otherIt = augSchema2.getTargetPath().getPath().iterator();
 377                 while (thisIt.hasNext()) {
 378                     if (otherIt.hasNext()) {
 379                         val int comp = thisIt.next().compareTo(otherIt.next());
 380                         if (comp != 0) {
 381                             return comp
 382                         }
 383                     } else {
 384                         return 1
 385                     }
 386                 }
 387                 if (otherIt.hasNext()) {
 388                     return -1
 389                 }
 390                 return 0
 391             ]);
 392         return sortedAugmentations;
 393     }
 394
 395     private def List<AugmentationSchema> getSortedOrNull(Collection<AugmentationSchema> collection) {
 396         val TreeSet<AugmentationSchema> set = new TreeSet()
 397         for (e : collection) {
 398             if (e instanceof Comparable<?>) {
 399                 set.add(e)
 400             } else {
 401                 return null
 402             }
 403         }
 404         return new ArrayList(set.toArray)
 405     }
 406
 407     /**
 408      * Converts whole <b>module</b> to <code>GeneratedType</code> object.
 409      * Firstly is created the module builder object from which is vally
 410      * obtained reference to <code>GeneratedType</code> object.
 411      *
 412      * @param module
 413      *            module from which are obtained the module name, child nodes,
 414      *            uses and is derived package name
 415      * @return <code>GeneratedType</code> which is internal representation of
 416      *         the module
 417      * @throws IllegalArgumentException
 418      *             if the module equals null
 419      *
 420      */
 421     private def GeneratedTypeBuilder moduleToDataType(Module module) {
 422         checkArgument(module !== null, "Module reference cannot be NULL.");
 423
 424         val moduleDataTypeBuilder = moduleTypeBuilder(module, "Data");
 425         addImplementedInterfaceFromUses(module, moduleDataTypeBuilder);
 426         moduleDataTypeBuilder.addImplementsType(DATA_ROOT);
 427         moduleDataTypeBuilder.addComment(module.getDescription());
 428         return moduleDataTypeBuilder;
 429     }
 430
 431     /**
 432      * Converts all <b>rpcs</b> inputs and outputs substatements of the module
 433      * to the list of <code>Type</code> objects. In addition are to containers
 434      * and lists which belong to input or output also part of returning list.
 435      *
 436      * @param module
 437      *            module from which is obtained set of all rpc objects to
 438      *            iterate over them
 439      * @throws IllegalArgumentException
 440      *             <ul>
 441      *             <li>if the module equals null</li>
 442      *             <li>if the name of module equals null</li>
 443      *             <li>if the set of child nodes equals null</li>
 444      *             </ul>
 445      *
 446      */
 447     private def void rpcMethodsToGenType(Module module) {
 448         checkArgument(module !== null, "Module reference cannot be NULL.");
 449         checkArgument(module.name !== null, "Module name cannot be NULL.");
 450         checkArgument(module.childNodes !== null,
 451             "Reference to Set of RPC Method Definitions in module " + module.name + " cannot be NULL.");
 452
 453         val basePackageName = moduleNamespaceToPackageName(module);
 454         val Set<RpcDefinition> rpcDefinitions = module.rpcs;
 455         if (rpcDefinitions.isEmpty()) {
 456             return;
 457         }
 458
 459         val interfaceBuilder = moduleTypeBuilder(module, "Service");
 460         interfaceBuilder.addImplementsType(Types.typeForClass(RpcService));
 461         for (rpc : rpcDefinitions) {
 462             if (rpc !== null) {
 463                 val rpcName = BindingMapping.getClassName(rpc.QName);
 464                 val rpcMethodName = parseToValidParamName(rpcName);
 465                 val rpcComment = rpc.getDescription();
 466                 val method = interfaceBuilder.addMethod(rpcMethodName);
 467
 468                 val input = rpc.input;
 469                 val output = rpc.output;
 470
 471                 if (input !== null) {
 472                     val inType = addRawInterfaceDefinition(basePackageName, input, rpcName);
 473                     addImplementedInterfaceFromUses(input, inType);
 474                     inType.addImplementsType(DATA_OBJECT);
 475                     inType.addImplementsType(augmentable(inType));
 476                     resolveDataSchemaNodes(module, basePackageName, inType, inType, input.childNodes);
 477                     genCtx.get(module).addChildNodeType(input.path, inType)
 478                     val inTypeInstance = inType.toInstance();
 479                     method.addParameter(inTypeInstance, "input");
 480                 }
 481
 482                 var Type outTypeInstance = VOID;
 483                 if (output !== null) {
 484                     val outType = addRawInterfaceDefinition(basePackageName, output, rpcName);
 485                     addImplementedInterfaceFromUses(output, outType);
 486                     outType.addImplementsType(DATA_OBJECT);
 487                     outType.addImplementsType(augmentable(outType));
 488                     resolveDataSchemaNodes(module, basePackageName, outType, outType, output.childNodes);
 489                     genCtx.get(module).addChildNodeType(output.path, outType)
 490                     outTypeInstance = outType.toInstance();
 491                 }
 492
 493                 val rpcRes = Types.parameterizedTypeFor(Types.typeForClass(RpcResult), outTypeInstance);
 494                 method.setComment(rpcComment);
 495                 method.setReturnType(Types.parameterizedTypeFor(FUTURE, rpcRes));
 496
 497             }
 498         }
 499
 500         genCtx.get(module).addTopLevelNodeType(interfaceBuilder)
 501     }
 502
 503     /**
 504      * Converts all <b>notifications</b> of the module to the list of
 505      * <code>Type</code> objects. In addition are to this list added containers
 506      * and lists which are part of this notification.
 507      *
 508      * @param module
 509      *            module from which is obtained set of all notification objects
 510      *            to iterate over them
 511      * @throws IllegalArgumentException
 512      *             <ul>
 513      *             <li>if the module equals null</li>
 514      *             <li>if the name of module equals null</li>
 515      *             <li>if the set of child nodes equals null</li>
 516      *             </ul>
 517      *
 518      */
 519     private def void notificationsToGenType(Module module) {
 520         checkArgument(module !== null, "Module reference cannot be NULL.");
 521         checkArgument(module.name !== null, "Module name cannot be NULL.");
 522
 523         if (module.childNodes === null) {
 524             throw new IllegalArgumentException(
 525                 "Reference to Set of Notification Definitions in module " + module.name + " cannot be NULL.");
 526         }
 527         val notifications = module.notifications;
 528         if(notifications.empty) return;
 529
 530         val listenerInterface = moduleTypeBuilder(module, "Listener");
 531         listenerInterface.addImplementsType(BindingTypes.NOTIFICATION_LISTENER);
 532         val basePackageName = moduleNamespaceToPackageName(module);
 533
 534         for (notification : notifications) {
 535             if (notification !== null) {
 536                 processUsesAugments(notification, module);
 537
 538                 val notificationInterface = addDefaultInterfaceDefinition(basePackageName, notification,
 539                     BindingTypes.DATA_OBJECT);
 540                 notificationInterface.addImplementsType(NOTIFICATION);
 541                 genCtx.get(module).addChildNodeType(notification.path, notificationInterface)
 542
 543                 // Notification object
 544                 resolveDataSchemaNodes(module, basePackageName, notificationInterface, notificationInterface,
 545                     notification.childNodes);
 546
 547                 listenerInterface.addMethod("on" + notificationInterface.name) //
 548                 .setAccessModifier(AccessModifier.PUBLIC).addParameter(notificationInterface, "notification").
 549                     setComment(notification.getDescription()).setReturnType(Types.VOID);
 550             }
 551         }
 552
 553         genCtx.get(module).addTopLevelNodeType(listenerInterface)
 554     }
 555
 556     /**
 557      * Converts all <b>identities</b> of the module to the list of
 558      * <code>Type</code> objects.
 559      *
 560      * @param module
 561      *            module from which is obtained set of all identity objects to
 562      *            iterate over them
 563      * @param context
 564      *            schema context only used as input parameter for method
 565      *            {@link identityToGenType}
 566      *
 567      */
 568     private def void allIdentitiesToGenTypes(Module module, SchemaContext context) {
 569         val Set<IdentitySchemaNode> schemaIdentities = module.identities;
 570         val basePackageName = moduleNamespaceToPackageName(module);
 571
 572         if (schemaIdentities !== null && !schemaIdentities.isEmpty()) {
 573             for (identity : schemaIdentities) {
 574                 identityToGenType(module, basePackageName, identity, context);
 575             }
 576         }
 577     }
 578
 579     /**
 580      * Converts the <b>identity</b> object to GeneratedType. Firstly it is
 581      * created transport object builder. If identity contains base identity then
 582      * reference to base identity is added to superior identity as its extend.
 583      * If identity doesn't contain base identity then only reference to abstract
 584      * class {@link org.opendaylight.yangtools.yang.model.api.BaseIdentity
 585      * BaseIdentity} is added
 586      *
 587      * @param module current module
 588      * @param basePackageName
 589      *            string contains the module package name
 590      * @param identity
 591      *            IdentitySchemaNode which contains data about identity
 592      * @param context
 593      *            SchemaContext which is used to get package and name
 594      *            information about base of identity
 595      *
 596      */
 597     private def void identityToGenType(Module module, String basePackageName, IdentitySchemaNode identity,
 598         SchemaContext context) {
 599         if (identity === null) {
 600             return;
 601         }
 602         val packageName = packageNameForGeneratedType(basePackageName, identity.path);
 603         val genTypeName = BindingMapping.getClassName(identity.QName);
 604         val newType = new GeneratedTOBuilderImpl(packageName, genTypeName);
 605         val baseIdentity = identity.baseIdentity;
 606         if (baseIdentity === null) {
 607             newType.setExtendsType(Types.baseIdentityTO);
 608         } else {
 609             val baseIdentityParentModule = SchemaContextUtil.findParentModule(context, baseIdentity);
 610             val returnTypePkgName = moduleNamespaceToPackageName(baseIdentityParentModule);
 611             val returnTypeName = BindingMapping.getClassName(baseIdentity.QName);
 612             val gto = new GeneratedTOBuilderImpl(returnTypePkgName, returnTypeName).toInstance();
 613             newType.setExtendsType(gto);
 614         }
 615         newType.setAbstract(true);
 616         newType.addComment(identity.getDescription());
 617         val qname = identity.QName;
 618
 619         newType.qnameConstant(BindingMapping.QNAME_STATIC_FIELD_NAME,qname);
 620
 621         genCtx.get(module).addIdentityType(identity.QName,newType)
 622     }
 623
 624     private static def qnameConstant(GeneratedTypeBuilderBase<?> toBuilder, String constantName, QName name) {
 625         toBuilder.addConstant(QName.typeForClass,constantName,'''
 626             org.opendaylight.yangtools.yang.common.QName.create("«name.namespace»","«name.formattedRevision»","«name.localName»")
 627         ''');
 628     }
 629
 630     /**
 631      * Converts all <b>groupings</b> of the module to the list of
 632      * <code>Type</code> objects. Firstly are groupings sorted according mutual
 633      * dependencies. At least dependent (independent) groupings are in the list
 634      * saved at first positions. For every grouping the record is added to map
 635      * {@link BindingGeneratorImpl#allGroupings allGroupings}
 636      *
 637      * @param module
 638      *            current module
 639      * @param collection of groupings from which types will be generated
 640      *
 641      */
 642     private def void groupingsToGenTypes(Module module, Collection<GroupingDefinition> groupings) {
 643         val basePackageName = moduleNamespaceToPackageName(module);
 644         val List<GroupingDefinition> groupingsSortedByDependencies = new GroupingDefinitionDependencySort().sort(
 645             groupings);
 646         for (grouping : groupingsSortedByDependencies) {
 647             groupingToGenType(basePackageName, grouping, module);
 648         }
 649     }
 650
 651     /**
 652      * Converts individual grouping to GeneratedType. Firstly generated type
 653      * builder is created and every child node of grouping is resolved to the
 654      * method.
 655      *
 656      * @param basePackageName
 657      *            string contains the module package name
 658      * @param grouping
 659      *            GroupingDefinition which contains data about grouping
 660      * @param module current module
 661      * @return GeneratedType which is generated from grouping (object of type
 662      *         <code>GroupingDefinition</code>)
 663      */
 664     private def void groupingToGenType(String basePackageName, GroupingDefinition grouping, Module module) {
 665         val packageName = packageNameForGeneratedType(basePackageName, grouping.path);
 666         val genType = addDefaultInterfaceDefinition(packageName, grouping);
 667         genCtx.get(module).addGroupingType(grouping.path, genType)
 668         resolveDataSchemaNodes(module, basePackageName, genType, genType, grouping.childNodes);
 669         groupingsToGenTypes(module, grouping.groupings);
 670         processUsesAugments(grouping, module);
 671     }
 672
 673     /**
 674      * Tries to find EnumTypeDefinition in <code>typeDefinition</code>. If base
 675      * type of <code>typeDefinition</code> is of the type ExtendedType then this
 676      * method is recursively called with this base type.
 677      *
 678      * @param typeDefinition
 679      *            TypeDefinition in which should be EnumTypeDefinition found as
 680      *            base type
 681      * @return EnumTypeDefinition if it is found inside
 682      *         <code>typeDefinition</code> or <code>null</code> in other case
 683      */
 684     private def EnumTypeDefinition enumTypeDefFromExtendedType(TypeDefinition<?> typeDefinition) {
 685         if (typeDefinition !== null) {
 686             if (typeDefinition.baseType instanceof EnumTypeDefinition) {
 687                 return typeDefinition.baseType as EnumTypeDefinition;
 688             } else if (typeDefinition.baseType instanceof ExtendedType) {
 689                 return enumTypeDefFromExtendedType(typeDefinition.baseType);
 690             }
 691         }
 692         return null;
 693     }
 694
 695     /**
 696      * Adds enumeration builder created from <code>enumTypeDef</code> to
 697      * <code>typeBuilder</code>.
 698      *
 699      * Each <code>enumTypeDef</code> item is added to builder with its name and
 700      * value.
 701      *
 702      * @param enumTypeDef
 703      *            EnumTypeDefinition contains enum data
 704      * @param enumName
 705      *            string contains name which will be assigned to enumeration
 706      *            builder
 707      * @param typeBuilder
 708      *            GeneratedTypeBuilder to which will be enum builder assigned
 709      * @return enumeration builder which contains data from
 710      *         <code>enumTypeDef</code>
 711      */
 712     private def EnumBuilder resolveInnerEnumFromTypeDefinition(EnumTypeDefinition enumTypeDef, QName enumName,
 713         GeneratedTypeBuilder typeBuilder) {
 714         if ((enumTypeDef !== null) && (typeBuilder !== null) && (enumTypeDef.QName !== null) &&
 715             (enumTypeDef.QName.localName !== null)) {
 716             val enumerationName = BindingMapping.getClassName(enumName);
 717             val enumBuilder = typeBuilder.addEnumeration(enumerationName);
 718             enumBuilder.updateEnumPairsFromEnumTypeDef(enumTypeDef);
 719             return enumBuilder;
 720         }
 721         return null;
 722     }
 723
 724     /**
 725      * Generates type builder for <code>module</code>.
 726      *
 727      * @param module
 728      *            Module which is source of package name for generated type
 729      *            builder
 730      * @param postfix
 731      *            string which is added to the module class name representation
 732      *            as suffix
 733      * @return instance of GeneratedTypeBuilder which represents
 734      *         <code>module</code>.
 735      * @throws IllegalArgumentException
 736      *             if <code>module</code> equals null
 737      */
 738     private def GeneratedTypeBuilder moduleTypeBuilder(Module module, String postfix) {
 739         checkArgument(module !== null, "Module reference cannot be NULL.");
 740         val packageName = moduleNamespaceToPackageName(module);
 741         val moduleName = BindingMapping.getClassName(module.name) + postfix;
 742         return new GeneratedTypeBuilderImpl(packageName, moduleName);
 743     }
 744
 745     /**
 746      * Converts <code>augSchema</code> to list of <code>Type</code> which
 747      * contains generated type for augmentation. In addition there are also
 748      * generated types for all containers, list and choices which are child of
 749      * <code>augSchema</code> node or a generated types for cases are added if
 750      * augmented node is choice.
 751      *
 752      * @param augmentPackageName
 753      *            string with the name of the package to which the augmentation
 754      *            belongs
 755      * @param augSchema
 756      *            AugmentationSchema which is contains data about augmentation
 757      *            (target path, childs...)
 758      * @param module current module
 759      * @param parentUsesNode parent uses node of this augment (can be null if this augment is not defined under uses statement)
 760      * @throws IllegalArgumentException
 761      *             <ul>
 762      *             <li>if <code>augmentPackageName</code> equals null</li>
 763      *             <li>if <code>augSchema</code> equals null</li>
 764      *             <li>if target path of <code>augSchema</code> equals null</li>
 765      *             </ul>
 766      */
 767     private def void augmentationToGenTypes(String augmentPackageName, AugmentationSchema augSchema, Module module) {
 768         checkArgument(augmentPackageName !== null, "Package Name cannot be NULL.");
 769         checkArgument(augSchema !== null, "Augmentation Schema cannot be NULL.");
 770         checkState(augSchema.targetPath !== null,
 771             "Augmentation Schema does not contain Target Path (Target Path is NULL).");
 772
 773         processUsesAugments(augSchema, module);
 774         val targetPath = augSchema.targetPath;
 775         var SchemaNode targetSchemaNode = null
 776
 777         targetSchemaNode = findDataSchemaNode(schemaContext, targetPath);
 778         if (targetSchemaNode instanceof DataSchemaNode && (targetSchemaNode as DataSchemaNode).isAddedByUses()) {
 779             targetSchemaNode = findOriginal(targetSchemaNode as DataSchemaNode, schemaContext);
 780             if (targetSchemaNode == null) {
 781                 throw new NullPointerException(
 782                     "Failed to find target node from grouping in augmentation " + augSchema + " in module " +
 783                         module.name);
 784             }
 785         }
 786         if (targetSchemaNode == null) {
 787             throw new IllegalArgumentException("augment target not found: " + targetPath)
 788         }
 789
 790         var targetTypeBuilder = findChildNodeByPath(targetSchemaNode.path)
 791         if (targetTypeBuilder === null) {
 792             targetTypeBuilder = findCaseByPath(targetSchemaNode.path)
 793         }
 794         if (targetTypeBuilder === null) {
 795             throw new NullPointerException("Target type not yet generated: " + targetSchemaNode);
 796         }
 797
 798         if (!(targetSchemaNode instanceof ChoiceNode)) {
 799             var packageName = augmentPackageName;
 800             val targetType = new ReferencedTypeImpl(targetTypeBuilder.packageName,targetTypeBuilder.name);
 801             addRawAugmentGenTypeDefinition(module, packageName, augmentPackageName,targetType, augSchema);
 802
 803         } else {
 804             generateTypesFromAugmentedChoiceCases(module, augmentPackageName, targetTypeBuilder.toInstance,
 805                 targetSchemaNode as ChoiceNode, augSchema.childNodes);
 806         }
 807     }
 808
 809     private def void usesAugmentationToGenTypes(String augmentPackageName, AugmentationSchema augSchema, Module module,
 810         UsesNode usesNode, DataNodeContainer usesNodeParent) {
 811         checkArgument(augmentPackageName !== null, "Package Name cannot be NULL.");
 812         checkArgument(augSchema !== null, "Augmentation Schema cannot be NULL.");
 813         checkState(augSchema.targetPath !== null,
 814             "Augmentation Schema does not contain Target Path (Target Path is NULL).");
 815
 816         processUsesAugments(augSchema, module);
 817         val targetPath = augSchema.targetPath;
 818         var SchemaNode targetSchemaNode = null
 819         targetSchemaNode = findOriginalTargetFromGrouping(targetPath, usesNode);
 820         if (targetSchemaNode == null) {
 821             throw new IllegalArgumentException("augment target not found: " + targetPath)
 822         }
 823
 824         var targetTypeBuilder = findChildNodeByPath(targetSchemaNode.path)
 825         if (targetTypeBuilder === null) {
 826             targetTypeBuilder = findCaseByPath(targetSchemaNode.path)
 827         }
 828         if (targetTypeBuilder === null) {
 829             throw new NullPointerException("Target type not yet generated: " + targetSchemaNode);
 830         }
 831
 832         if (!(targetSchemaNode instanceof ChoiceNode)) {
 833             var packageName = augmentPackageName;
 834             if (usesNodeParent instanceof SchemaNode) {
 835                 packageName = packageNameForGeneratedType(augmentPackageName, (usesNodeParent as SchemaNode).path, true)
 836             }
 837             addRawAugmentGenTypeDefinition(module, packageName, augmentPackageName,
 838                 targetTypeBuilder.toInstance, augSchema);
 839         } else {
 840             generateTypesFromAugmentedChoiceCases(module, augmentPackageName, targetTypeBuilder.toInstance,
 841                 targetSchemaNode as ChoiceNode, augSchema.childNodes);
 842         }
 843     }
 844
 845     /**
 846      * Convenient method to find node added by uses statement.
 847      */
 848     private def DataSchemaNode findOriginalTargetFromGrouping(SchemaPath targetPath, UsesNode parentUsesNode) {
 849         var SchemaNode targetGrouping = findNodeInSchemaContext(schemaContext, parentUsesNode.groupingPath.path);
 850         if (!(targetGrouping instanceof GroupingDefinition)) {
 851             throw new IllegalArgumentException("Failed to generate code for augment in " + parentUsesNode);
 852         }
 853
 854         var grouping = targetGrouping as GroupingDefinition;
 855         var SchemaNode result = grouping;
 856         val List<QName> path = targetPath.path
 857         for (node : path) {
 858             // finding by local name is valid, grouping cannot contain nodes with same name and different namespace
 859             if (result instanceof DataNodeContainer) {
 860                 result = (result as DataNodeContainer).getDataChildByName(node.localName)
 861             } else if (result instanceof ChoiceNode) {
 862                 result = (result as ChoiceNode).getCaseNodeByName(node.localName)
 863             }
 864         }
 865         if (result == null) {
 866             return null;
 867         }
 868
 869         var boolean fromUses = (result as DataSchemaNode).addedByUses
 870         var Iterator<UsesNode> groupingUses = grouping.uses.iterator;
 871         while (groupingUses.hasNext && fromUses) {
 872             result = findOriginalTargetFromGrouping(targetPath, groupingUses.next);
 873             if (result != null) {
 874                 fromUses = (result as DataSchemaNode).addedByUses
 875             }
 876         }
 877         if (fromUses) {
 878             throw new NullPointerException("Failed to generate code for augment in " + parentUsesNode);
 879         }
 880
 881         return result as DataSchemaNode
 882     }
 883
 884     /**
 885      * Returns a generated type builder for an augmentation.
 886      *
 887      * The name of the type builder is equal to the name of augmented node with
 888      * serial number as suffix.
 889      *
 890      * @param module current module
 891      * @param augmentPackageName
 892      *            string with contains the package name to which the augment
 893      *            belongs
 894      * @param basePackageName
 895      *            string with the package name to which the augmented node
 896      *            belongs
 897      * @param targetTypeRef
 898      *            target type
 899      * @param augSchema
 900      *            augmentation schema which contains data about the child nodes
 901      *            and uses of augment
 902      * @return generated type builder for augment
 903      */
 904     private def GeneratedTypeBuilder addRawAugmentGenTypeDefinition(Module module, String augmentPackageName,
 905         String basePackageName, Type targetTypeRef, AugmentationSchema augSchema) {
 906         var Map<String, GeneratedTypeBuilder> augmentBuilders = genTypeBuilders.get(augmentPackageName);
 907         if (augmentBuilders === null) {
 908             augmentBuilders = new HashMap();
 909             genTypeBuilders.put(augmentPackageName, augmentBuilders);
 910         }
 911         val augIdentifier = getAugmentIdentifier(augSchema.unknownSchemaNodes);
 912
 913         val augTypeName = if (augIdentifier !== null) {
 914                 BindingMapping.getClassName(augIdentifier)
 915             } else {
 916                 augGenTypeName(augmentBuilders, targetTypeRef.name);
 917             }
 918
 919         val augTypeBuilder = new GeneratedTypeBuilderImpl(augmentPackageName, augTypeName);
 920
 921         augTypeBuilder.addImplementsType(DATA_OBJECT);
 922         augTypeBuilder.addImplementsType(Types.augmentationTypeFor(targetTypeRef));
 923         addImplementedInterfaceFromUses(augSchema, augTypeBuilder);
 924
 925         augSchemaNodeToMethods(module, basePackageName, augTypeBuilder, augTypeBuilder, augSchema.childNodes);
 926         augmentBuilders.put(augTypeName, augTypeBuilder);
 927
 928         genCtx.get(module).addTargetToAugmentation(targetTypeRef,augTypeBuilder);
 929         genCtx.get(module).addAugmentType(augTypeBuilder);
 930         genCtx.get(module).addTypeToAugmentation(augTypeBuilder, augSchema);
 931         return augTypeBuilder;
 932     }
 933
 934     /**
 935      *
 936      * @param unknownSchemaNodes
 937      * @return nodeParameter of UnknownSchemaNode
 938      */
 939     private def String getAugmentIdentifier(List<UnknownSchemaNode> unknownSchemaNodes) {
 940         for (unknownSchemaNode : unknownSchemaNodes) {
 941             val nodeType = unknownSchemaNode.nodeType;
 942             if (AUGMENT_IDENTIFIER_NAME.equals(nodeType.localName) &&
 943                 YANG_EXT_NAMESPACE.equals(nodeType.namespace.toString())) {
 944                 return unknownSchemaNode.nodeParameter;
 945             }
 946         }
 947         return null;
 948     }
 949
 950     /**
 951      * Returns first unique name for the augment generated type builder. The
 952      * generated type builder name for augment consists from name of augmented
 953      * node and serial number of its augmentation.
 954      *
 955      * @param builders
 956      *            map of builders which were created in the package to which the
 957      *            augmentation belongs
 958      * @param genTypeName
 959      *            string with name of augmented node
 960      * @return string with unique name for augmentation builder
 961      */
 962     private def String augGenTypeName(Map<String, GeneratedTypeBuilder> builders, String genTypeName) {
 963         var index = 1;
 964         while ((builders !== null) && builders.containsKey(genTypeName + index)) {
 965             index = index + 1;
 966         }
 967         return genTypeName + index;
 968     }
 969
 970     /**
 971      * Adds the methods to <code>typeBuilder</code> which represent subnodes of
 972      * node for which <code>typeBuilder</code> was created.
 973      *
 974      * The subnodes aren't mapped to the methods if they are part of grouping or
 975      * augment (in this case are already part of them).
 976      *
 977      * @param module current module
 978      * @param basePackageName
 979      *            string contains the module package name
 980      * @param parent
 981      *            generated type builder which represents any node. The subnodes
 982      *            of this node are added to the <code>typeBuilder</code> as
 983      *            methods. The subnode can be of type leaf, leaf-list, list,
 984      *            container, choice.
 985      * @param childOf parent type
 986      * @param schemaNodes
 987      *            set of data schema nodes which are the children of the node
 988      *            for which <code>typeBuilder</code> was created
 989      * @return generated type builder which is the same builder as input
 990      *         parameter. The getter methods (representing child nodes) could be
 991      *         added to it.
 992      */
 993     private def GeneratedTypeBuilder resolveDataSchemaNodes(Module module, String basePackageName,
 994         GeneratedTypeBuilder parent, GeneratedTypeBuilder childOf, Set<DataSchemaNode> schemaNodes) {
 995         if ((schemaNodes !== null) && (parent !== null)) {
 996             for (schemaNode : schemaNodes) {
 997                 if (!schemaNode.augmenting && !schemaNode.addedByUses) {
 998                     addSchemaNodeToBuilderAsMethod(basePackageName, schemaNode, parent, childOf, module);
 999                 }
1000             }
1001         }
1002         return parent;
1003     }
1004
1005     /**
1006      * Adds the methods to <code>typeBuilder</code> what represents subnodes of
1007      * node for which <code>typeBuilder</code> was created.
1008      *
1009      * @param module current module
1010      * @param basePackageName
1011      *            string contains the module package name
1012      * @param typeBuilder
1013      *            generated type builder which represents any node. The subnodes
1014      *            of this node are added to the <code>typeBuilder</code> as
1015      *            methods. The subnode can be of type leaf, leaf-list, list,
1016      *            container, choice.
1017      * @param childOf parent type
1018      * @param schemaNodes
1019      *            set of data schema nodes which are the children of the node
1020      *            for which <code>typeBuilder</code> was created
1021      * @return generated type builder which is the same object as the input
1022      *         parameter <code>typeBuilder</code>. The getter method could be
1023      *         added to it.
1024      */
1025     private def GeneratedTypeBuilder augSchemaNodeToMethods(Module module, String basePackageName,
1026         GeneratedTypeBuilder typeBuilder, GeneratedTypeBuilder childOf, Set<DataSchemaNode> schemaNodes) {
1027         if ((schemaNodes !== null) && (typeBuilder !== null)) {
1028             for (schemaNode : schemaNodes) {
1029                 if (!schemaNode.isAugmenting()) {
1030                     addSchemaNodeToBuilderAsMethod(basePackageName, schemaNode, typeBuilder, childOf, module);
1031                 }
1032             }
1033         }
1034         return typeBuilder;
1035     }
1036
1037     /**
1038      * Adds to <code>typeBuilder</code> a method which is derived from
1039      * <code>schemaNode</code>.
1040      *
1041      * @param basePackageName
1042      *            string with the module package name
1043      * @param node
1044      *            data schema node which is added to <code>typeBuilder</code> as
1045      *            a method
1046      * @param typeBuilder
1047      *            generated type builder to which is <code>schemaNode</code>
1048      *            added as a method.
1049      * @param childOf parent type
1050      * @param module current module
1051      */
1052     private def void addSchemaNodeToBuilderAsMethod(String basePackageName, DataSchemaNode node,
1053         GeneratedTypeBuilder typeBuilder, GeneratedTypeBuilder childOf, Module module) {
1054         if (node !== null && typeBuilder !== null) {
1055             switch (node) {
1056                 case node instanceof LeafSchemaNode:
1057                     resolveLeafSchemaNodeAsMethod(typeBuilder, node as LeafSchemaNode)
1058                 case node instanceof LeafListSchemaNode:
1059                     resolveLeafListSchemaNode(typeBuilder, node as LeafListSchemaNode)
1060                 case node instanceof ContainerSchemaNode:
1061                     containerToGenType(module, basePackageName, typeBuilder, childOf, node as ContainerSchemaNode)
1062                 case node instanceof ListSchemaNode:
1063                     listToGenType(module, basePackageName, typeBuilder, childOf, node as ListSchemaNode)
1064                 case node instanceof ChoiceNode:
1065                     choiceToGeneratedType(module, basePackageName, typeBuilder, node as ChoiceNode)
1066             }
1067         }
1068     }
1069
1070     /**
1071      * Converts <code>choiceNode</code> to the list of generated types for
1072      * choice and its cases.
1073      *
1074      * The package names for choice and for its cases are created as
1075      * concatenation of the module package (<code>basePackageName</code>) and
1076      * names of all parents node.
1077      *
1078      * @param module current module
1079      * @param basePackageName
1080      *            string with the module package name
1081      * @param parent parent type
1082      * @param childOf concrete parent for case child nodes
1083      * @param choiceNode
1084      *            choice node which is mapped to generated type. Also child
1085      *            nodes - cases are mapped to generated types.
1086      * @throws IllegalArgumentException
1087      *             <ul>
1088      *             <li>if <code>basePackageName</code> equals null</li>
1089      *             <li>if <code>choiceNode</code> equals null</li>
1090      *             </ul>
1091      *
1092      */
1093     private def void choiceToGeneratedType(Module module, String basePackageName, GeneratedTypeBuilder parent,
1094         ChoiceNode choiceNode) {
1095         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1096         checkArgument(choiceNode !== null, "Choice Schema Node cannot be NULL.");
1097
1098         if (!choiceNode.addedByUses) {
1099             val packageName = packageNameForGeneratedType(basePackageName, choiceNode.path);
1100             val choiceTypeBuilder = addRawInterfaceDefinition(packageName, choiceNode);
1101             constructGetter(parent, choiceNode.QName.localName, choiceNode.description, choiceTypeBuilder);
1102             choiceTypeBuilder.addImplementsType(DataContainer.typeForClass);
1103             genCtx.get(module).addChildNodeType(choiceNode.path, choiceTypeBuilder)
1104             generateTypesFromChoiceCases(module, basePackageName, parent, choiceTypeBuilder.toInstance, choiceNode);
1105         }
1106     }
1107
1108     /**
1109      * Converts <code>caseNodes</code> set to list of corresponding generated
1110      * types.
1111      *
1112      * For every <i>case</i> which isn't added through augment or <i>uses</i> is
1113      * created generated type builder. The package names for the builder is
1114      * created as concatenation of the module package (
1115      * <code>basePackageName</code>) and names of all parents nodes of the
1116      * concrete <i>case</i>. There is also relation "<i>implements type</i>"
1117      * between every case builder and <i>choice</i> type
1118      *
1119      * @param basePackageName
1120      *            string with the module package name
1121      * @param refChoiceType
1122      *            type which represents superior <i>case</i>
1123      * @param caseNodes
1124      *            set of choice case nodes which are mapped to generated types
1125      * @return list of generated types for <code>caseNodes</code>.
1126      * @throws IllegalArgumentException
1127      *             <ul>
1128      *             <li>if <code>basePackageName</code> equals null</li>
1129      *             <li>if <code>refChoiceType</code> equals null</li>
1130      *             <li>if <code>caseNodes</code> equals null</li>
1131      *             </ul>
1132      *             *
1133      */
1134     private def void generateTypesFromChoiceCases(Module module, String basePackageName,
1135         GeneratedTypeBuilder choiceParent, Type refChoiceType, ChoiceNode choiceNode) {
1136         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1137         checkArgument(refChoiceType !== null, "Referenced Choice Type cannot be NULL.");
1138         checkArgument(choiceNode !== null, "ChoiceNode cannot be NULL.");
1139
1140         val Set<ChoiceCaseNode> caseNodes = choiceNode.cases;
1141         if (caseNodes == null) {
1142             return
1143         }
1144
1145         for (caseNode : caseNodes) {
1146             if (caseNode !== null && !caseNode.isAddedByUses() && !caseNode.isAugmenting()) {
1147                 val packageName = packageNameForGeneratedType(basePackageName, caseNode.path)
1148                 val caseTypeBuilder = addDefaultInterfaceDefinition(packageName, caseNode)
1149                 caseTypeBuilder.addImplementsType(refChoiceType)
1150                 genCtx.get(module).addCaseType(caseNode.path, caseTypeBuilder)
1151                 genCtx.get(module).addChoiceToCaseMapping(refChoiceType, caseTypeBuilder,caseNode)
1152                 val Set<DataSchemaNode> caseChildNodes = caseNode.childNodes
1153                 if (caseChildNodes !== null) {
1154                     var Object parentNode = null
1155                     val SchemaPath nodeSp = choiceNode.path
1156                     val List<QName> nodeNames = nodeSp.path
1157                     val List<QName> nodeNewNames = new ArrayList(nodeNames)
1158                     nodeNewNames.remove(nodeNewNames.size - 1)
1159                     val SchemaPath nodeNewSp = SchemaPath.create(nodeNewNames, nodeSp.absolute)
1160                     parentNode = findDataSchemaNode(schemaContext, nodeNewSp)
1161
1162                     var SchemaNode parent
1163                     if (parentNode instanceof AugmentationSchema) {
1164                         val augSchema = parentNode as AugmentationSchema;
1165                         val targetPath = augSchema.targetPath;
1166                         var targetSchemaNode = findDataSchemaNode(schemaContext, targetPath)
1167                         if (targetSchemaNode instanceof DataSchemaNode &&
1168                             (targetSchemaNode as DataSchemaNode).isAddedByUses()) {
1169                             targetSchemaNode = findOriginal(targetSchemaNode as DataSchemaNode, schemaContext);
1170                             if (targetSchemaNode == null) {
1171                                 throw new NullPointerException(
1172                                     "Failed to find target node from grouping for augmentation " + augSchema +
1173                                         " in module " + module.name);
1174                             }
1175                         }
1176                         parent = targetSchemaNode
1177                     } else {
1178                         val SchemaPath sp = choiceNode.path
1179                         val List<QName> names = sp.path
1180                         val List<QName> newNames = new ArrayList(names)
1181                         newNames.remove(newNames.size - 1)
1182                         val SchemaPath newSp = SchemaPath.create(newNames, sp.absolute)
1183                         parent = findDataSchemaNode(schemaContext, newSp)
1184                     }
1185                     var GeneratedTypeBuilder childOfType = findChildNodeByPath(parent.path)
1186                     resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, caseChildNodes)
1187                 }
1188             }
1189
1190             processUsesAugments(caseNode, module);
1191         }
1192     }
1193
1194     /**
1195      * Generates list of generated types for all the cases of a choice which are
1196      * added to the choice through the augment.
1197      *
1198      *
1199      * @param basePackageName
1200      *            string contains name of package to which augment belongs. If
1201      *            an augmented choice is from an other package (pcg1) than an
1202      *            augmenting choice (pcg2) then case's of the augmenting choice
1203      *            will belong to pcg2.
1204      * @param refChoiceType
1205      *            Type which represents the choice to which case belongs. Every
1206      *            case has to contain its choice in extend part.
1207      * @param caseNodes
1208      *            set of choice case nodes for which is checked if are/aren't
1209      *            added to choice through augmentation
1210      * @return list of generated types which represents augmented cases of
1211      *         choice <code>refChoiceType</code>
1212      * @throws IllegalArgumentException
1213      *             <ul>
1214      *             <li>if <code>basePackageName</code> equals null</li>
1215      *             <li>if <code>refChoiceType</code> equals null</li>
1216      *             <li>if <code>caseNodes</code> equals null</li>
1217      *             </ul>
1218      */
1219     private def void generateTypesFromAugmentedChoiceCases(Module module, String basePackageName, Type targetType,
1220         ChoiceNode targetNode, Set<DataSchemaNode> augmentedNodes) {
1221         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1222         checkArgument(targetType !== null, "Referenced Choice Type cannot be NULL.");
1223         checkArgument(augmentedNodes !== null, "Set of Choice Case Nodes cannot be NULL.");
1224
1225         for (caseNode : augmentedNodes) {
1226             if (caseNode !== null) {
1227                 val packageName = packageNameForGeneratedType(basePackageName, caseNode.path);
1228                 val caseTypeBuilder = addDefaultInterfaceDefinition(packageName, caseNode);
1229                 caseTypeBuilder.addImplementsType(targetType);
1230
1231                 var SchemaNode parent = null
1232                 val SchemaPath nodeSp = targetNode.path
1233                 val List<QName> nodeNames = nodeSp.path
1234                 val List<QName> nodeNewNames = new ArrayList(nodeNames)
1235                 nodeNewNames.remove(nodeNewNames.size - 1)
1236                 val SchemaPath nodeNewSp = SchemaPath.create(nodeNewNames, nodeSp.absolute)
1237                 parent = findDataSchemaNode(schemaContext, nodeNewSp)
1238
1239                 var GeneratedTypeBuilder childOfType = null;
1240                 if (parent instanceof Module) {
1241                     childOfType = genCtx.get(parent as Module).moduleNode
1242                 } else if (parent instanceof ChoiceCaseNode) {
1243                     childOfType = findCaseByPath(parent.path)
1244                 } else if (parent instanceof DataSchemaNode || parent instanceof NotificationDefinition) {
1245                     childOfType = findChildNodeByPath(parent.path)
1246                 } else if (parent instanceof GroupingDefinition) {
1247                     childOfType = findGroupingByPath(parent.path);
1248                 }
1249
1250                 if (childOfType == null) {
1251                     throw new IllegalArgumentException("Failed to find parent type of choice " + targetNode);
1252                 }
1253
1254                 var ChoiceCaseNode node = null;
1255                 if (caseNode instanceof ChoiceCaseNode) {
1256                     node = caseNode as ChoiceCaseNode;
1257                 }  else {
1258                     node = targetNode.getCaseNodeByName(caseNode.getQName().getLocalName());
1259                 }
1260                 val Set<DataSchemaNode> childNodes = node.childNodes;
1261                 if (childNodes !== null) {
1262                     resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, childNodes);
1263                 }
1264                 genCtx.get(module).addCaseType(caseNode.path, caseTypeBuilder)
1265                 genCtx.get(module).addChoiceToCaseMapping(targetType, caseTypeBuilder,node);
1266             }
1267         }
1268
1269     }
1270
1271     /**
1272      * Converts <code>leaf</code> to the getter method which is added to
1273      * <code>typeBuilder</code>.
1274      *
1275      * @param typeBuilder
1276      *            generated type builder to which is added getter method as
1277      *            <code>leaf</code> mapping
1278      * @param leaf
1279      *            leaf schema node which is mapped as getter method which is
1280      *            added to <code>typeBuilder</code>
1281      * @return boolean value
1282      *         <ul>
1283      *         <li>false - if <code>leaf</code> or <code>typeBuilder</code> are
1284      *         null</li>
1285      *         <li>true - in other cases</li>
1286      *         </ul>
1287      */
1288     private def Type resolveLeafSchemaNodeAsMethod(GeneratedTypeBuilder typeBuilder, LeafSchemaNode leaf) {
1289         var Type returnType = null;
1290         if ((leaf !== null) && (typeBuilder !== null)) {
1291             val leafName = leaf.QName.localName;
1292             var String leafDesc = leaf.description;
1293             if (leafDesc === null) {
1294                 leafDesc = "";
1295             }
1296
1297             val parentModule = findParentModule(schemaContext, leaf);
1298             if (leafName !== null && !leaf.isAddedByUses()) {
1299                 val TypeDefinition<?> typeDef = leaf.type;
1300
1301                 var GeneratedTOBuilder genTOBuilder;
1302                 if (typeDef instanceof EnumTypeDefinition) {
1303                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf);
1304                     val enumTypeDef = typeDef as EnumTypeDefinition;
1305                     val enumBuilder = resolveInnerEnumFromTypeDefinition(enumTypeDef, leaf.QName, typeBuilder);
1306
1307                     if (enumBuilder !== null) {
1308                         returnType = enumBuilder.toInstance(typeBuilder)
1309                     }
1310                     (typeProvider as TypeProviderImpl).putReferencedType(leaf.path, returnType);
1311                 } else if (typeDef instanceof UnionType) {
1312                     genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, leaf, parentModule);
1313                     if (genTOBuilder !== null) {
1314                         returnType = createReturnTypeForUnion(genTOBuilder, typeDef, typeBuilder, parentModule)
1315                     }
1316                 } else if (typeDef instanceof BitsTypeDefinition) {
1317                     genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, leaf, parentModule);
1318                     if (genTOBuilder !== null) {
1319                         returnType = new ReferencedTypeImpl(genTOBuilder.packageName, genTOBuilder.name);
1320                     }
1321                 } else {
1322                     val Restrictions restrictions = BindingGeneratorUtil.getRestrictions(typeDef);
1323                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf, restrictions);
1324                 }
1325                 if (returnType !== null) {
1326                     val MethodSignatureBuilder getter = constructGetter(typeBuilder, leafName, leafDesc, returnType);
1327                     processContextRefExtension(leaf, getter, parentModule);
1328                 }
1329             }
1330         }
1331         return returnType;
1332     }
1333
1334     private def void processContextRefExtension(LeafSchemaNode leaf, MethodSignatureBuilder getter, Module module) {
1335         for (node : leaf.unknownSchemaNodes) {
1336             val nodeType = node.nodeType;
1337             if ("context-reference".equals(nodeType.localName)) {
1338                 val nodeParam = node.nodeParameter;
1339                 var IdentitySchemaNode identity = null;
1340                 var String basePackageName = null;
1341                 val String[] splittedElement = nodeParam.split(":");
1342                 if (splittedElement.length == 1) {
1343                     identity = findIdentityByName(module.identities, splittedElement.get(0));
1344                     basePackageName = moduleNamespaceToPackageName(module);
1345                 } else if (splittedElement.length == 2) {
1346                     var prefix = splittedElement.get(0);
1347                     val Module dependentModule = findModuleFromImports(module.imports, prefix)
1348                     if (dependentModule == null) {
1349                         throw new IllegalArgumentException(
1350                             "Failed to process context-reference: unknown prefix " + prefix);
1351                     }
1352                     identity = findIdentityByName(dependentModule.identities, splittedElement.get(1));
1353                     basePackageName = moduleNamespaceToPackageName(dependentModule);
1354                 } else {
1355                     throw new IllegalArgumentException(
1356                         "Failed to process context-reference: unknown identity " + nodeParam);
1357                 }
1358                 if (identity == null) {
1359                     throw new IllegalArgumentException(
1360                         "Failed to process context-reference: unknown identity " + nodeParam);
1361                 }
1362
1363                 val Class<RoutingContext> clazz = typeof(RoutingContext);
1364                 val AnnotationTypeBuilder rc = getter.addAnnotation(clazz.package.name, clazz.simpleName);
1365                 val packageName = packageNameForGeneratedType(basePackageName, identity.path);
1366                 val genTypeName = BindingMapping.getClassName(identity.QName.localName);
1367                 rc.addParameter("value", packageName + "." + genTypeName + ".class");
1368             }
1369         }
1370     }
1371
1372     private def IdentitySchemaNode findIdentityByName(Set<IdentitySchemaNode> identities, String name) {
1373         for (id : identities) {
1374             if (id.QName.localName.equals(name)) {
1375                 return id;
1376             }
1377         }
1378         return null;
1379     }
1380
1381     private def Module findModuleFromImports(Set<ModuleImport> imports, String prefix) {
1382         for (imp : imports) {
1383             if (imp.prefix.equals(prefix)) {
1384                 return schemaContext.findModuleByName(imp.moduleName, imp.revision);
1385             }
1386         }
1387         return null;
1388     }
1389
1390     private def boolean resolveLeafSchemaNodeAsProperty(GeneratedTOBuilder toBuilder, LeafSchemaNode leaf,
1391         boolean isReadOnly, Module module) {
1392         if ((leaf !== null) && (toBuilder !== null)) {
1393             val leafName = leaf.QName.localName;
1394             var String leafDesc = leaf.description;
1395             if (leafDesc === null) {
1396                 leafDesc = "";
1397             }
1398
1399             if (leafName !== null) {
1400                 var Type returnType = null;
1401                 val TypeDefinition<?> typeDef = leaf.type;
1402                 if (typeDef instanceof UnionTypeDefinition) {
1403                     // GeneratedType for this type definition should be already created
1404                     var qname = typeDef.QName
1405                     var Module unionModule = null
1406                     if (qname.prefix == null || qname.prefix.empty) {
1407                         unionModule = module
1408                     } else {
1409                         unionModule = findModuleFromImports(module.imports, qname.prefix)
1410                     }
1411                     val ModuleContext mc = genCtx.get(unionModule)
1412                     returnType = mc.typedefs.get(typeDef.path)
1413                 } else {
1414                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf);
1415                 }
1416                 return resolveLeafSchemaNodeAsProperty(toBuilder, leaf, returnType, isReadOnly)
1417             }
1418         }
1419         return false;
1420     }
1421
1422     /**
1423      * Converts <code>leaf</code> schema node to property of generated TO
1424      * builder.
1425      *
1426      * @param toBuilder
1427      *            generated TO builder to which is <code>leaf</code> added as
1428      *            property
1429      * @param leaf
1430      *            leaf schema node which is added to <code>toBuilder</code> as
1431      *            property
1432      * @param returnType property type
1433      * @param isReadOnly
1434      *            boolean value which says if leaf property is|isn't read only
1435      * @return boolean value
1436      *         <ul>
1437      *         <li>false - if <code>leaf</code>, <code>toBuilder</code> or leaf
1438      *         name equals null or if leaf is added by <i>uses</i>.</li>
1439      *         <li>true - other cases</li>
1440      *         </ul>
1441      */
1442     private def resolveLeafSchemaNodeAsProperty(GeneratedTOBuilder toBuilder, LeafSchemaNode leaf, Type returnType,
1443         boolean isReadOnly) {
1444         if (returnType == null) {
1445             return false;
1446         }
1447         val leafName = leaf.QName.localName
1448         val leafDesc = leaf.description
1449         val propBuilder = toBuilder.addProperty(parseToValidParamName(leafName));
1450         propBuilder.setReadOnly(isReadOnly);
1451         propBuilder.setReturnType(returnType);
1452         propBuilder.setComment(leafDesc);
1453         toBuilder.addEqualsIdentity(propBuilder);
1454         toBuilder.addHashIdentity(propBuilder);
1455         toBuilder.addToStringProperty(propBuilder);
1456         return true;
1457     }
1458
1459     /**
1460      * Converts <code>node</code> leaf list schema node to getter method of
1461      * <code>typeBuilder</code>.
1462      *
1463      * @param typeBuilder
1464      *            generated type builder to which is <code>node</code> added as
1465      *            getter method
1466      * @param node
1467      *            leaf list schema node which is added to
1468      *            <code>typeBuilder</code> as getter method
1469      * @return boolean value
1470      *         <ul>
1471      *         <li>true - if <code>node</code>, <code>typeBuilder</code>,
1472      *         nodeName equal null or <code>node</code> is added by <i>uses</i></li>
1473      *         <li>false - other cases</li>
1474      *         </ul>
1475      */
1476     private def boolean resolveLeafListSchemaNode(GeneratedTypeBuilder typeBuilder, LeafListSchemaNode node) {
1477         if ((node !== null) && (typeBuilder !== null)) {
1478             val nodeName = node.QName;
1479             var String nodeDesc = node.description;
1480             if (nodeDesc === null) {
1481                 nodeDesc = "";
1482             }
1483             if (nodeName !== null && !node.isAddedByUses()) {
1484                 val TypeDefinition<?> typeDef = node.type;
1485                 val parentModule = findParentModule(schemaContext, node);
1486
1487                 var Type returnType = null;
1488                 if (typeDef instanceof EnumTypeDefinition) {
1489                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, node);
1490                     val enumTypeDef = typeDef as EnumTypeDefinition;
1491                     val enumBuilder = resolveInnerEnumFromTypeDefinition(enumTypeDef, nodeName, typeBuilder);
1492                     returnType = new ReferencedTypeImpl(enumBuilder.packageName, enumBuilder.name);
1493                     (typeProvider as TypeProviderImpl).putReferencedType(node.path, returnType);
1494                 } else if (typeDef instanceof UnionType) {
1495                     val genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, node, parentModule);
1496                     if (genTOBuilder !== null) {
1497                         returnType = createReturnTypeForUnion(genTOBuilder, typeDef, typeBuilder, parentModule)
1498                     }
1499                 } else if (typeDef instanceof BitsTypeDefinition) {
1500                     val genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, node, parentModule);
1501                     returnType = new ReferencedTypeImpl(genTOBuilder.packageName, genTOBuilder.name);
1502                 } else {
1503                     val Restrictions restrictions = BindingGeneratorUtil.getRestrictions(typeDef);
1504                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, node, restrictions);
1505                 }
1506
1507                 val listType = Types.listTypeFor(returnType);
1508                 constructGetter(typeBuilder, nodeName.localName, nodeDesc, listType);
1509                 return true;
1510             }
1511         }
1512         return false;
1513     }
1514
1515     private def Type createReturnTypeForUnion(GeneratedTOBuilder genTOBuilder, TypeDefinition<?> typeDef,
1516         GeneratedTypeBuilder typeBuilder, Module parentModule) {
1517         val GeneratedTOBuilderImpl returnType = new GeneratedTOBuilderImpl(genTOBuilder.packageName, genTOBuilder.name)
1518         genTOBuilder.setTypedef(true);
1519         genTOBuilder.setIsUnion(true);
1520         (typeProvider as TypeProviderImpl).addUnitsToGenTO(genTOBuilder, typeDef.getUnits());
1521
1522         // union builder
1523         val GeneratedTOBuilder unionBuilder = new GeneratedTOBuilderImpl(typeBuilder.getPackageName(),
1524             genTOBuilder.getName() + "Builder");
1525         unionBuilder.setIsUnionBuilder(true);
1526         val MethodSignatureBuilder method = unionBuilder.addMethod("getDefaultInstance");
1527         method.setReturnType(returnType);
1528         method.addParameter(Types.STRING, "defaultValue");
1529         method.setAccessModifier(AccessModifier.PUBLIC);
1530         method.setStatic(true);
1531
1532         val Set<Type> types = (typeProvider as TypeProviderImpl).additionalTypes.get(parentModule);
1533         if (types == null) {
1534             (typeProvider as TypeProviderImpl).additionalTypes.put(parentModule,
1535                 Sets.newHashSet(unionBuilder.toInstance))
1536         } else {
1537             types.add(unionBuilder.toInstance)
1538         }
1539         return returnType.toInstance
1540     }
1541
1542     private def GeneratedTypeBuilder addDefaultInterfaceDefinition(String packageName, SchemaNode schemaNode) {
1543         return addDefaultInterfaceDefinition(packageName, schemaNode, null);
1544     }
1545
1546     /**
1547      * Instantiates generated type builder with <code>packageName</code> and
1548      * <code>schemaNode</code>.
1549      *
1550      * The new builder always implements
1551      * {@link org.opendaylight.yangtools.yang.binding.DataObject DataObject}.<br />
1552      * If <code>schemaNode</code> is instance of GroupingDefinition it also
1553      * implements {@link org.opendaylight.yangtools.yang.binding.Augmentable
1554      * Augmentable}.<br />
1555      * If <code>schemaNode</code> is instance of
1556      * {@link org.opendaylight.yangtools.yang.model.api.DataNodeContainer
1557      * DataNodeContainer} it can also implement nodes which are specified in
1558      * <i>uses</i>.
1559      *
1560      * @param packageName
1561      *            string with the name of the package to which
1562      *            <code>schemaNode</code> belongs.
1563      * @param schemaNode
1564      *            schema node for which is created generated type builder
1565      * @param parent parent type (can be null)
1566      * @return generated type builder <code>schemaNode</code>
1567      */
1568     private def GeneratedTypeBuilder addDefaultInterfaceDefinition(String packageName, SchemaNode schemaNode,
1569         Type parent) {
1570         val it = addRawInterfaceDefinition(packageName, schemaNode, "");
1571         if (parent === null) {
1572             addImplementsType(DATA_OBJECT);
1573         } else {
1574             addImplementsType(BindingTypes.childOf(parent));
1575         }
1576         if (!(schemaNode instanceof GroupingDefinition)) {
1577             addImplementsType(augmentable(it));
1578         }
1579
1580         if (schemaNode instanceof DataNodeContainer) {
1581             addImplementedInterfaceFromUses(schemaNode as DataNodeContainer, it);
1582         }
1583
1584         return it;
1585     }
1586
1587     /**
1588      * Wraps the calling of the same overloaded method.
1589      *
1590      * @param packageName
1591      *            string with the package name to which returning generated type
1592      *            builder belongs
1593      * @param schemaNode
1594      *            schema node which provide data about the schema node name
1595      * @return generated type builder for <code>schemaNode</code>
1596      */
1597     private def GeneratedTypeBuilder addRawInterfaceDefinition(String packageName, SchemaNode schemaNode) {
1598         return addRawInterfaceDefinition(packageName, schemaNode, "");
1599     }
1600
1601     /**
1602      * Returns reference to generated type builder for specified
1603      * <code>schemaNode</code> with <code>packageName</code>.
1604      *
1605      * Firstly the generated type builder is searched in
1606      * {@link BindingGeneratorImpl#genTypeBuilders genTypeBuilders}. If it isn't
1607      * found it is created and added to <code>genTypeBuilders</code>.
1608      *
1609      * @param packageName
1610      *            string with the package name to which returning generated type
1611      *            builder belongs
1612      * @param schemaNode
1613      *            schema node which provide data about the schema node name
1614      * @param prefix return type name prefix
1615      * @return generated type builder for <code>schemaNode</code>
1616      * @throws IllegalArgumentException
1617      *             <ul>
1618      *             <li>if <code>schemaNode</code> equals null</li>
1619      *             <li>if <code>packageName</code> equals null</li>
1620      *             <li>if Q name of schema node is null</li>
1621      *             <li>if schema node name is null</li>
1622      *             </ul>
1623      *
1624      */
1625     private def GeneratedTypeBuilder addRawInterfaceDefinition(String packageName, SchemaNode schemaNode,
1626         String prefix) {
1627         checkArgument(schemaNode !== null, "Data Schema Node cannot be NULL.");
1628         checkArgument(packageName !== null, "Package Name for Generated Type cannot be NULL.");
1629         checkArgument(schemaNode.QName !== null, "QName for Data Schema Node cannot be NULL.");
1630         val schemaNodeName = schemaNode.QName.localName;
1631         checkArgument(schemaNodeName !== null, "Local Name of QName for Data Schema Node cannot be NULL.");
1632
1633         var String genTypeName;
1634         if (prefix === null) {
1635             genTypeName = BindingMapping.getClassName(schemaNodeName);
1636         } else {
1637             genTypeName = prefix + BindingMapping.getClassName(schemaNodeName);
1638         }
1639
1640         //FIXME: Validation of name conflict
1641         val newType = new GeneratedTypeBuilderImpl(packageName, genTypeName);
1642         qnameConstant(newType,BindingMapping.QNAME_STATIC_FIELD_NAME,schemaNode.QName);
1643         newType.addComment(schemaNode.getDescription());
1644         if (!genTypeBuilders.containsKey(packageName)) {
1645             val Map<String, GeneratedTypeBuilder> builders = new HashMap();
1646             builders.put(genTypeName, newType);
1647             genTypeBuilders.put(packageName, builders);
1648         } else {
1649             val Map<String, GeneratedTypeBuilder> builders = genTypeBuilders.get(packageName);
1650             if (!builders.containsKey(genTypeName)) {
1651                 builders.put(genTypeName, newType);
1652             }
1653         }
1654         return newType;
1655     }
1656
1657     /**
1658      * Creates the name of the getter method name from <code>localName</code>.
1659      *
1660      * @param localName
1661      *            string with the name of the getter method
1662      * @param returnType return type
1663      * @return string with the name of the getter method for
1664      *         <code>methodName</code> in JAVA method format
1665      */
1666     public static def String getterMethodName(String localName, Type returnType) {
1667         val method = new StringBuilder();
1668         if (BOOLEAN.equals(returnType)) {
1669             method.append("is");
1670         } else {
1671             method.append("get");
1672         }
1673         method.append(BindingMapping.getPropertyName(localName).toFirstUpper);
1674         return method.toString();
1675     }
1676
1677     /**
1678      * Created a method signature builder as part of
1679      * <code>interfaceBuilder</code>.
1680      *
1681      * The method signature builder is created for the getter method of
1682      * <code>schemaNodeName</code>. Also <code>comment</code> and
1683      * <code>returnType</code> information are added to the builder.
1684      *
1685      * @param interfaceBuilder
1686      *            generated type builder for which the getter method should be
1687      *            created
1688      * @param schemaNodeName
1689      *            string with schema node name. The name will be the part of the
1690      *            getter method name.
1691      * @param comment
1692      *            string with comment for the getter method
1693      * @param returnType
1694      *            type which represents the return type of the getter method
1695      * @return method signature builder which represents the getter method of
1696      *         <code>interfaceBuilder</code>
1697      */
1698     private def MethodSignatureBuilder constructGetter(GeneratedTypeBuilder interfaceBuilder, String schemaNodeName,
1699         String comment, Type returnType) {
1700         val getMethod = interfaceBuilder.addMethod(getterMethodName(schemaNodeName, returnType));
1701         getMethod.setComment(comment);
1702         getMethod.setReturnType(returnType);
1703         return getMethod;
1704     }
1705
1706     /**
1707      * Adds <code>schemaNode</code> to <code>typeBuilder</code> as getter method
1708      * or to <code>genTOBuilder</code> as property.
1709      *
1710      * @param basePackageName
1711      *            string contains the module package name
1712      * @param schemaNode
1713      *            data schema node which should be added as getter method to
1714      *            <code>typeBuilder</code> or as a property to
1715      *            <code>genTOBuilder</code> if is part of the list key
1716      * @param typeBuilder
1717      *            generated type builder for the list schema node
1718      * @param genTOBuilder
1719      *            generated TO builder for the list keys
1720      * @param listKeys
1721      *            list of string which contains names of the list keys
1722      * @param module current module
1723      * @throws IllegalArgumentException
1724      *             <ul>
1725      *             <li>if <code>schemaNode</code> equals null</li>
1726      *             <li>if <code>typeBuilder</code> equals null</li>
1727      *             </ul>
1728      */
1729     private def void addSchemaNodeToListBuilders(String basePackageName, DataSchemaNode schemaNode,
1730         GeneratedTypeBuilder typeBuilder, GeneratedTOBuilder genTOBuilder, List<String> listKeys, Module module) {
1731         checkArgument(schemaNode !== null, "Data Schema Node cannot be NULL.");
1732         checkArgument(typeBuilder !== null, "Generated Type Builder cannot be NULL.");
1733
1734         if (schemaNode instanceof LeafSchemaNode) {
1735             val leaf = schemaNode as LeafSchemaNode;
1736             val leafName = leaf.QName.localName;
1737             val Type type = resolveLeafSchemaNodeAsMethod(typeBuilder, leaf);
1738             if (listKeys.contains(leafName)) {
1739                 if (type == null) {
1740                     resolveLeafSchemaNodeAsProperty(genTOBuilder, leaf, true, module)
1741                 } else {
1742                     resolveLeafSchemaNodeAsProperty(genTOBuilder, leaf, type, true)
1743                 }
1744             }
1745         } else if (!schemaNode.addedByUses) {
1746             if (schemaNode instanceof LeafListSchemaNode) {
1747                 resolveLeafListSchemaNode(typeBuilder, schemaNode as LeafListSchemaNode);
1748             } else if (schemaNode instanceof ContainerSchemaNode) {
1749                 containerToGenType(module, basePackageName, typeBuilder, typeBuilder, schemaNode as ContainerSchemaNode);
1750             } else if (schemaNode instanceof ChoiceNode) {
1751                 choiceToGeneratedType(module, basePackageName, typeBuilder, schemaNode as ChoiceNode);
1752             } else if (schemaNode instanceof ListSchemaNode) {
1753                 listToGenType(module, basePackageName, typeBuilder, typeBuilder, schemaNode as ListSchemaNode);
1754             }
1755         }
1756     }
1757
1758     private def typeBuildersToGenTypes(Module module, GeneratedTypeBuilder typeBuilder, GeneratedTOBuilder genTOBuilder) {
1759         checkArgument(typeBuilder !== null, "Generated Type Builder cannot be NULL.");
1760
1761         if (genTOBuilder !== null) {
1762             val genTO = genTOBuilder.toInstance();
1763             constructGetter(typeBuilder, "key", "Returns Primary Key of Yang List Type", genTO);
1764             genCtx.get(module).addGeneratedTOBuilder(genTOBuilder)
1765         }
1766     }
1767
1768     /**
1769      * Selects the names of the list keys from <code>list</code> and returns
1770      * them as the list of the strings
1771      *
1772      * @param list
1773      *            of string with names of the list keys
1774      * @return list of string which represents names of the list keys. If the
1775      *         <code>list</code> contains no keys then the empty list is
1776      *         returned.
1777      */
1778     private def listKeys(ListSchemaNode list) {
1779         val List<String> listKeys = new ArrayList();
1780
1781         if (list.keyDefinition !== null) {
1782             val keyDefinitions = list.keyDefinition;
1783             for (keyDefinition : keyDefinitions) {
1784                 listKeys.add(keyDefinition.localName);
1785             }
1786         }
1787         return listKeys;
1788     }
1789
1790     /**
1791      * Generates for the <code>list</code> which contains any list keys special
1792      * generated TO builder.
1793      *
1794      * @param packageName
1795      *            string with package name to which the list belongs
1796      * @param list
1797      *            list schema node which is source of data about the list name
1798      * @return generated TO builder which represents the keys of the
1799      *         <code>list</code> or null if <code>list</code> is null or list of
1800      *         key definitions is null or empty.
1801      */
1802     private def GeneratedTOBuilder resolveListKeyTOBuilder(String packageName, ListSchemaNode list) {
1803         var GeneratedTOBuilder genTOBuilder = null;
1804         if ((list.keyDefinition !== null) && (!list.keyDefinition.isEmpty())) {
1805             val listName = list.QName.localName + "Key";
1806             val String genTOName = BindingMapping.getClassName(listName);
1807             genTOBuilder = new GeneratedTOBuilderImpl(packageName, genTOName);
1808         }
1809         return genTOBuilder;
1810     }
1811
1812     /**
1813      * Builds generated TO builders for <code>typeDef</code> of type
1814      * {@link org.opendaylight.yangtools.yang.model.util.UnionType UnionType} or
1815      * {@link org.opendaylight.yangtools.yang.model.api.type.BitsTypeDefinition
1816      * BitsTypeDefinition} which are also added to <code>typeBuilder</code> as
1817      * enclosing transfer object.
1818      *
1819      * If more then one generated TO builder is created for enclosing then all
1820      * of the generated TO builders are added to <code>typeBuilder</code> as
1821      * enclosing transfer objects.
1822      *
1823      * @param typeDef
1824      *            type definition which can be of type <code>UnionType</code> or
1825      *            <code>BitsTypeDefinition</code>
1826      * @param typeBuilder
1827      *            generated type builder to which is added generated TO created
1828      *            from <code>typeDef</code>
1829      * @param leafName
1830      *            string with name for generated TO builder
1831      * @param leaf
1832      * @param parentModule
1833      * @return generated TO builder for <code>typeDef</code>
1834      */
1835     private def GeneratedTOBuilder addTOToTypeBuilder(TypeDefinition<?> typeDef, GeneratedTypeBuilder typeBuilder,
1836         DataSchemaNode leaf, Module parentModule) {
1837         val classNameFromLeaf = BindingMapping.getClassName(leaf.QName);
1838         val List<GeneratedTOBuilder> genTOBuilders = new ArrayList();
1839         val packageName = typeBuilder.fullyQualifiedName;
1840         if (typeDef instanceof UnionTypeDefinition) {
1841             val List<GeneratedTOBuilder> types = (typeProvider as TypeProviderImpl).
1842                     provideGeneratedTOBuildersForUnionTypeDef(packageName, (typeDef as UnionTypeDefinition),
1843                         classNameFromLeaf, leaf);
1844             genTOBuilders.addAll(types);
1845
1846
1847         var GeneratedTOBuilder resultTOBuilder = null;
1848         if (!types.isEmpty()) {
1849             resultTOBuilder = types.remove(0);
1850             for (GeneratedTOBuilder genTOBuilder : types) {
1851                 resultTOBuilder.addEnclosingTransferObject(genTOBuilder);
1852             }
1853         }
1854
1855         val GeneratedPropertyBuilder genPropBuilder = resultTOBuilder.addProperty("value");
1856         genPropBuilder.setReturnType(Types.primitiveType("char[]", null));
1857         resultTOBuilder.addEqualsIdentity(genPropBuilder);
1858         resultTOBuilder.addHashIdentity(genPropBuilder);
1859         resultTOBuilder.addToStringProperty(genPropBuilder);
1860
1861         } else if (typeDef instanceof BitsTypeDefinition) {
1862             genTOBuilders.add(
1863                 ((typeProvider as TypeProviderImpl) ).
1864                     provideGeneratedTOBuilderForBitsTypeDefinition(packageName, typeDef, classNameFromLeaf));
1865         }
1866         if (genTOBuilders !== null && !genTOBuilders.isEmpty()) {
1867             for (genTOBuilder : genTOBuilders) {
1868                 typeBuilder.addEnclosingTransferObject(genTOBuilder);
1869             }
1870             return genTOBuilders.get(0);
1871         }
1872         return null;
1873
1874     }
1875
1876     /**
1877      * Adds the implemented types to type builder.
1878      *
1879      * The method passes through the list of <i>uses</i> in
1880      * {@code dataNodeContainer}. For every <i>use</i> is obtained corresponding
1881      * generated type from {@link BindingGeneratorImpl#allGroupings
1882      * allGroupings} which is added as <i>implements type</i> to
1883      * <code>builder</code>
1884      *
1885      * @param dataNodeContainer
1886      *            element which contains the list of used YANG groupings
1887      * @param builder
1888      *            builder to which are added implemented types according to
1889      *            <code>dataNodeContainer</code>
1890      * @return generated type builder with all implemented types
1891      */
1892     private def addImplementedInterfaceFromUses(DataNodeContainer dataNodeContainer, GeneratedTypeBuilder builder) {
1893         for (usesNode : dataNodeContainer.uses) {
1894             if (usesNode.groupingPath !== null) {
1895                 val genType = findGroupingByPath(usesNode.groupingPath).toInstance
1896                 if (genType === null) {
1897                     throw new IllegalStateException(
1898                         "Grouping " + usesNode.groupingPath + "is not resolved for " + builder.name);
1899                 }
1900                 builder.addImplementsType(genType);
1901                 builder.addComment(genType.getComment());
1902             }
1903         }
1904         return builder;
1905     }
1906
1907     private def GeneratedTypeBuilder findChildNodeByPath(SchemaPath path) {
1908         for (ctx : genCtx.values) {
1909             var result = ctx.getChildNode(path)
1910             if (result !== null) {
1911                 return result
1912             }
1913         }
1914         return null
1915     }
1916
1917     private def GeneratedTypeBuilder findGroupingByPath(SchemaPath path) {
1918         for (ctx : genCtx.values) {
1919             var result = ctx.getGrouping(path)
1920             if (result !== null) {
1921                 return result
1922             }
1923         }
1924         return null
1925     }
1926
1927     private def GeneratedTypeBuilder findCaseByPath(SchemaPath path) {
1928         for (ctx : genCtx.values) {
1929             var result = ctx.getCase(path)
1930             if (result !== null) {
1931                 return result
1932             }
1933         }
1934         return null
1935     }
1936
1937     public def getModuleContexts() {
1938         genCtx;
1939     }
1940
1941 }