code-generator/binding-generator-impl/src/main/java/org/opendaylight/yangtools/sal/binding/generator/impl/BindingGeneratorImpl.xtend

   1 /*
   2  * Copyright (c) 2013 Cisco Systems, Inc. and others.  All rights reserved.
   3  *
   4  * This program and the accompanying materials are made available under the
   5  * terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6  * and is available at http://www.eclipse.org/legal/epl-v10.html
   7  */
   8 package org.opendaylight.yangtools.sal.binding.generator.impl;
   9
  10 import static com.google.common.base.Preconditions.*;
  11 import static extension org.opendaylight.yangtools.binding.generator.util.Types.*;
  12 import static org.opendaylight.yangtools.binding.generator.util.BindingGeneratorUtil.*;
  13 import static org.opendaylight.yangtools.binding.generator.util.BindingTypes.*;
  14 import static org.opendaylight.yangtools.yang.model.util.SchemaContextUtil.*;
  15
  16 import java.util.ArrayList;
  17 import java.util.Collections;
  18 import java.util.HashMap;
  19 import java.util.List;
  20 import java.util.Map;
  21 import java.util.Set;
  22 import java.util.Iterator
  23 import java.util.Collection
  24 import org.opendaylight.yangtools.binding.generator.util.BindingTypes;
  25 import org.opendaylight.yangtools.binding.generator.util.ReferencedTypeImpl;
  26 import org.opendaylight.yangtools.binding.generator.util.Types;
  27 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedTOBuilderImpl;
  28 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedTypeBuilderImpl;
  29 import org.opendaylight.yangtools.sal.binding.generator.api.BindingGenerator;
  30 import org.opendaylight.yangtools.sal.binding.generator.spi.TypeProvider;
  31 import org.opendaylight.yangtools.sal.binding.model.api.AccessModifier;
  32 import org.opendaylight.yangtools.sal.binding.model.api.Type;
  33 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.EnumBuilder;
  34 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTOBuilder;
  35 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTypeBuilder;
  36 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.MethodSignatureBuilder;
  37 import org.opendaylight.yangtools.sal.binding.yang.types.GroupingDefinitionDependencySort;
  38 import org.opendaylight.yangtools.sal.binding.yang.types.TypeProviderImpl;
  39 import org.opendaylight.yangtools.yang.binding.RpcService;
  40 import org.opendaylight.yangtools.yang.common.RpcResult;
  41 import org.opendaylight.yangtools.yang.model.api.AugmentationSchema;
  42 import org.opendaylight.yangtools.yang.model.api.ChoiceCaseNode;
  43 import org.opendaylight.yangtools.yang.model.api.ChoiceNode;
  44 import org.opendaylight.yangtools.yang.model.api.ContainerSchemaNode;
  45 import org.opendaylight.yangtools.yang.model.api.DataNodeContainer;
  46 import org.opendaylight.yangtools.yang.model.api.DataSchemaNode;
  47 import org.opendaylight.yangtools.yang.model.api.GroupingDefinition;
  48 import org.opendaylight.yangtools.yang.model.api.IdentitySchemaNode;
  49 import org.opendaylight.yangtools.yang.model.api.LeafListSchemaNode;
  50 import org.opendaylight.yangtools.yang.model.api.LeafSchemaNode;
  51 import org.opendaylight.yangtools.yang.model.api.ListSchemaNode;
  52 import org.opendaylight.yangtools.yang.model.api.Module;
  53 import org.opendaylight.yangtools.yang.model.api.RpcDefinition;
  54 import org.opendaylight.yangtools.yang.model.api.SchemaContext;
  55 import org.opendaylight.yangtools.yang.model.api.SchemaNode;
  56 import org.opendaylight.yangtools.yang.model.api.SchemaPath;
  57 import org.opendaylight.yangtools.yang.model.api.TypeDefinition;
  58 import org.opendaylight.yangtools.yang.model.api.UnknownSchemaNode;
  59 import org.opendaylight.yangtools.yang.model.api.type.BitsTypeDefinition;
  60 import org.opendaylight.yangtools.yang.model.api.type.EnumTypeDefinition;
  61 import org.opendaylight.yangtools.yang.model.api.type.UnionTypeDefinition;
  62 import org.opendaylight.yangtools.yang.model.util.DataNodeIterator;
  63 import org.opendaylight.yangtools.yang.model.util.SchemaContextUtil;
  64 import org.opendaylight.yangtools.yang.model.util.UnionType;
  65 import org.opendaylight.yangtools.yang.parser.util.ModuleDependencySort
  66 import org.opendaylight.yangtools.yang.model.util.ExtendedType;
  67 import org.opendaylight.yangtools.yang.model.api.UsesNode
  68 import org.opendaylight.yangtools.yang.binding.annotations.RoutingContext
  69 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.AnnotationTypeBuilder
  70 import org.opendaylight.yangtools.yang.model.api.ModuleImport
  71 import org.opendaylight.yangtools.yang.binding.DataContainer
  72 import org.opendaylight.yangtools.yang.model.api.NotificationDefinition
  73 import org.opendaylight.yangtools.binding.generator.util.BindingGeneratorUtil
  74 import org.opendaylight.yangtools.sal.binding.model.api.Restrictions
  75 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedPropertyBuilder
  76 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedPropertyBuilderImpl
  77 import org.opendaylight.yangtools.yang.common.QName
  78 import org.opendaylight.yangtools.yang.binding.BindingMapping
  79 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTypeBuilderBase
  80
  81 import com.google.common.collect.Sets
  82
  83 public class BindingGeneratorImpl implements BindingGenerator {
  84
  85     private final Map<Module, ModuleContext> genCtx = new HashMap()
  86
  87     /**
  88      * Outer key represents the package name. Outer value represents map of
  89      * all builders in the same package. Inner key represents the schema node
  90      * name (in JAVA class/interface name format). Inner value represents
  91      * instance of builder for schema node specified in key part.
  92      */
  93     private Map<String, Map<String, GeneratedTypeBuilder>> genTypeBuilders;
  94
  95     /**
  96      * Provide methods for converting YANG types to JAVA types.
  97      */
  98     private var TypeProvider typeProvider;
  99
 100     /**
 101      * Holds reference to schema context to resolve data of augmented element
 102      * when creating augmentation builder
 103      */
 104     private var SchemaContext schemaContext;
 105
 106     /**
 107      * Constant with the concrete name of namespace.
 108      */
 109     private val static String YANG_EXT_NAMESPACE = "urn:opendaylight:yang:extension:yang-ext";
 110
 111     /**
 112      * Constant with the concrete name of identifier.
 113      */
 114     private val static String AUGMENT_IDENTIFIER_NAME = "augment-identifier";
 115
 116     /**
 117      * Resolves generated types from <code>context</code> schema nodes of all
 118      * modules.
 119      *
 120      * Generated types are created for modules, groupings, types, containers,
 121      * lists, choices, augments, rpcs, notification, identities.
 122      *
 123      * @param context
 124      *            schema context which contains data about all schema nodes
 125      *            saved in modules
 126      * @return list of types (usually <code>GeneratedType</code>
 127      *         <code>GeneratedTransferObject</code>which are generated from
 128      *         <code>context</code> data.
 129      * @throws IllegalArgumentException
 130      *             if param <code>context</code> is null
 131      * @throws IllegalStateException
 132      *             if <code>context</code> contain no modules
 133      */
 134     override generateTypes(SchemaContext context) {
 135         checkArgument(context !== null, "Schema Context reference cannot be NULL.");
 136         checkState(context.modules !== null, "Schema Context does not contain defined modules.");
 137         schemaContext = context;
 138         typeProvider = new TypeProviderImpl(context);
 139         val Set<Module> modules = context.modules;
 140         return generateTypes(context, modules);
 141     }
 142
 143     /**
 144      * Resolves generated types from <code>context</code> schema nodes only for
 145      * modules specified in <code>modules</code>
 146      *
 147      * Generated types are created for modules, groupings, types, containers,
 148      * lists, choices, augments, rpcs, notification, identities.
 149      *
 150      * @param context
 151      *            schema context which contains data about all schema nodes
 152      *            saved in modules
 153      * @param modules
 154      *            set of modules for which schema nodes should be generated
 155      *            types
 156      * @return list of types (usually <code>GeneratedType</code> or
 157      *         <code>GeneratedTransferObject</code>) which:
 158      *         <ul>
 159      *         <li>are generated from <code>context</code> schema nodes and</li>
 160      *         <li>are also part of some of the module in <code>modules</code>
 161      *         set</li>.
 162      *         </ul>
 163      * @throws IllegalArgumentException
 164      *             <ul>
 165      *             <li>if param <code>context</code> is null or</li>
 166      *             <li>if param <code>modules</code> is null</li>
 167      *             </ul>
 168      * @throws IllegalStateException
 169      *             if <code>context</code> contain no modules
 170      */
 171     override generateTypes(SchemaContext context, Set<Module> modules) {
 172         checkArgument(context !== null, "Schema Context reference cannot be NULL.");
 173         checkState(context.modules !== null, "Schema Context does not contain defined modules.");
 174         checkArgument(modules !== null, "Set of Modules cannot be NULL.");
 175
 176         schemaContext = context;
 177         typeProvider = new TypeProviderImpl(context);
 178         val contextModules = ModuleDependencySort.sort(context.modules);
 179         genTypeBuilders = new HashMap();
 180
 181         for (contextModule : contextModules) {
 182             moduleToGenTypes(contextModule, context);
 183         }
 184         for (contextModule : contextModules) {
 185             allAugmentsToGenTypes(contextModule);
 186         }
 187
 188         val List<Type> filteredGenTypes = new ArrayList();
 189         for (Module m : modules) {
 190             val ctx = checkNotNull(genCtx.get(m), "Module context not found for module %s", m)
 191             filteredGenTypes.addAll(ctx.generatedTypes);
 192             val Set<Type> additionalTypes = (typeProvider as TypeProviderImpl).additionalTypes.get(m)
 193             if (additionalTypes != null) {
 194                 filteredGenTypes.addAll(additionalTypes)
 195             }
 196         }
 197
 198         return filteredGenTypes;
 199     }
 200
 201     private def void moduleToGenTypes(Module m, SchemaContext context) {
 202         genCtx.put(m, new ModuleContext)
 203         allTypeDefinitionsToGenTypes(m)
 204         groupingsToGenTypes(m, m.groupings)
 205         rpcMethodsToGenType(m)
 206         allIdentitiesToGenTypes(m, context)
 207         notificationsToGenType(m)
 208
 209         if (!m.childNodes.isEmpty()) {
 210             val moduleType = moduleToDataType(m)
 211             genCtx.get(m).addModuleNode(moduleType)
 212             val basePackageName = moduleNamespaceToPackageName(m);
 213             resolveDataSchemaNodes(m, basePackageName, moduleType, moduleType, m.childNodes)
 214         }
 215     }
 216
 217     /**
 218      * Converts all extended type definitions of module to the list of
 219      * <code>Type</code> objects.
 220      *
 221      * @param module
 222      *            module from which is obtained set of type definitions
 223      * @throws IllegalArgumentException
 224      *             <ul>
 225      *             <li>if module equals null</li>
 226      *             <li>if name of module equals null</li>
 227      *             <li>if type definitions of module equal null</li>
 228      *             </ul>
 229      *
 230      */
 231     private def void allTypeDefinitionsToGenTypes(Module module) {
 232         checkArgument(module !== null, "Module reference cannot be NULL.");
 233         checkArgument(module.name !== null, "Module name cannot be NULL.");
 234         val it = new DataNodeIterator(module);
 235         val List<TypeDefinition<?>> typeDefinitions = it.allTypedefs;
 236         checkState(typeDefinitions !== null, '''Type Definitions for module «module.name» cannot be NULL.''');
 237
 238         for (TypeDefinition<?> typedef : typeDefinitions) {
 239             if (typedef !== null) {
 240                 val type = (typeProvider as TypeProviderImpl).generatedTypeForExtendedDefinitionType(typedef, typedef);
 241                 if (type !== null) {
 242                     genCtx.get(module).addTypedefType(typedef.path, type)
 243                 }
 244             }
 245         }
 246     }
 247
 248     private def GeneratedTypeBuilder processDataSchemaNode(Module module, String basePackageName,
 249         GeneratedTypeBuilder parent, GeneratedTypeBuilder childOf, DataSchemaNode node) {
 250         if (node.augmenting || node.addedByUses) {
 251             return null
 252         }
 253         val packageName = packageNameForGeneratedType(basePackageName, node.path)
 254         val genType = addDefaultInterfaceDefinition(packageName, node, childOf)
 255         genType.addComment(node.getDescription());
 256         if (node instanceof DataNodeContainer) {
 257             genCtx.get(module).addChildNodeType(node.path, genType)
 258             groupingsToGenTypes(module, (node as DataNodeContainer).groupings)
 259             processUsesAugments(node as DataNodeContainer, module)
 260         }
 261         return genType
 262     }
 263
 264     private def void containerToGenType(Module module, String basePackageName, GeneratedTypeBuilder parent,
 265         GeneratedTypeBuilder childOf, ContainerSchemaNode node) {
 266         val genType = processDataSchemaNode(module, basePackageName, parent, childOf, node)
 267         if (genType != null) {
 268             constructGetter(parent, node.QName.localName, node.description, genType)
 269             resolveDataSchemaNodes(module, basePackageName, genType, genType, node.childNodes)
 270         }
 271     }
 272
 273     private def void listToGenType(Module module, String basePackageName, GeneratedTypeBuilder parent,
 274         GeneratedTypeBuilder childOf, ListSchemaNode node) {
 275         val genType = processDataSchemaNode(module, basePackageName, parent, childOf, node)
 276         if (genType != null) {
 277             constructGetter(parent, node.QName.localName, node.description, Types.listTypeFor(genType))
 278
 279             val List<String> listKeys = listKeys(node);
 280             val packageName = packageNameForGeneratedType(basePackageName, (node).path)
 281             val genTOBuilder = resolveListKeyTOBuilder(packageName, node);
 282             if (genTOBuilder !== null) {
 283                 val identifierMarker = IDENTIFIER.parameterizedTypeFor(genType);
 284                 val identifiableMarker = IDENTIFIABLE.parameterizedTypeFor(genTOBuilder);
 285                 genTOBuilder.addImplementsType(identifierMarker);
 286                 genType.addImplementsType(identifiableMarker);
 287             }
 288
 289             for (schemaNode : node.childNodes) {
 290                 if (!schemaNode.augmenting) {
 291                     addSchemaNodeToListBuilders(basePackageName, schemaNode, genType, genTOBuilder, listKeys, module);
 292                 }
 293             }
 294
 295             // serialVersionUID
 296             if (genTOBuilder !== null) {
 297                 val GeneratedPropertyBuilder prop = new GeneratedPropertyBuilderImpl("serialVersionUID");
 298                 prop.setValue(Long.toString(computeDefaultSUID(genTOBuilder as GeneratedTOBuilderImpl)));
 299                 genTOBuilder.setSUID(prop);
 300             }
 301
 302             typeBuildersToGenTypes(module, genType, genTOBuilder);
 303         }
 304     }
 305
 306     private def void processUsesAugments(DataNodeContainer node, Module module) {
 307         val basePackageName = moduleNamespaceToPackageName(module);
 308         for (usesNode : node.uses) {
 309             for (augment : usesNode.augmentations) {
 310                 usesAugmentationToGenTypes(basePackageName, augment, module, usesNode, node);
 311                 processUsesAugments(augment, module);
 312             }
 313         }
 314     }
 315
 316     /**
 317      * Converts all <b>augmentation</b> of the module to the list
 318      * <code>Type</code> objects.
 319      *
 320      * @param module
 321      *            module from which is obtained list of all augmentation objects
 322      *            to iterate over them
 323      * @throws IllegalArgumentException
 324      *             <ul>
 325      *             <li>if the module equals null</li>
 326      *             <li>if the name of module equals null</li>
 327      *             <li>if the set of child nodes equals null</li>
 328      *             </ul>
 329      *
 330      */
 331     private def void allAugmentsToGenTypes(Module module) {
 332         checkArgument(module !== null, "Module reference cannot be NULL.");
 333         checkArgument(module.name !== null, "Module name cannot be NULL.");
 334         if (module.childNodes === null) {
 335             throw new IllegalArgumentException(
 336                 "Reference to Set of Augmentation Definitions in module " + module.name + " cannot be NULL.");
 337         }
 338
 339         val basePackageName = moduleNamespaceToPackageName(module);
 340         val List<AugmentationSchema> augmentations = resolveAugmentations(module);
 341         for (augment : augmentations) {
 342             augmentationToGenTypes(basePackageName, augment, module);
 343         }
 344     }
 345
 346     /**
 347      * Returns list of <code>AugmentationSchema</code> objects. The objects are
 348      * sorted according to the length of their target path from the shortest to
 349      * the longest.
 350      *
 351      * @param module
 352      *            module from which is obtained list of all augmentation objects
 353      * @return list of sorted <code>AugmentationSchema</code> objects obtained
 354      *         from <code>module</code>
 355      * @throws IllegalArgumentException
 356      *             <ul>
 357      *             <li>if the module equals null</li>
 358      *             <li>if the set of augmentation equals null</li>
 359      *             </ul>
 360      *
 361      */
 362     private def List<AugmentationSchema> resolveAugmentations(Module module) {
 363         checkArgument(module !== null, "Module reference cannot be NULL.");
 364         checkState(module.augmentations !== null, "Augmentations Set cannot be NULL.");
 365
 366         val Set<AugmentationSchema> augmentations = module.augmentations;
 367         val List<AugmentationSchema> sortedAugmentations = new ArrayList(augmentations);
 368         Collections.sort(sortedAugmentations,
 369             [ augSchema1, augSchema2 |
 370                 if (augSchema1.targetPath.path.size() > augSchema2.targetPath.path.size()) {
 371                     return 1;
 372                 } else if (augSchema1.targetPath.path.size() < augSchema2.targetPath.path.size()) {
 373                     return -1;
 374                 }
 375                 return 0;
 376             ]);
 377         return sortedAugmentations;
 378     }
 379
 380     /**
 381      * Converts whole <b>module</b> to <code>GeneratedType</code> object.
 382      * Firstly is created the module builder object from which is vally
 383      * obtained reference to <code>GeneratedType</code> object.
 384      *
 385      * @param module
 386      *            module from which are obtained the module name, child nodes,
 387      *            uses and is derived package name
 388      * @return <code>GeneratedType</code> which is internal representation of
 389      *         the module
 390      * @throws IllegalArgumentException
 391      *             if the module equals null
 392      *
 393      */
 394     private def GeneratedTypeBuilder moduleToDataType(Module module) {
 395         checkArgument(module !== null, "Module reference cannot be NULL.");
 396
 397         val moduleDataTypeBuilder = moduleTypeBuilder(module, "Data");
 398         addImplementedInterfaceFromUses(module, moduleDataTypeBuilder);
 399         moduleDataTypeBuilder.addImplementsType(DATA_ROOT);
 400         moduleDataTypeBuilder.addComment(module.getDescription());
 401         return moduleDataTypeBuilder;
 402     }
 403
 404     /**
 405      * Converts all <b>rpcs</b> inputs and outputs substatements of the module
 406      * to the list of <code>Type</code> objects. In addition are to containers
 407      * and lists which belong to input or output also part of returning list.
 408      *
 409      * @param module
 410      *            module from which is obtained set of all rpc objects to
 411      *            iterate over them
 412      * @throws IllegalArgumentException
 413      *             <ul>
 414      *             <li>if the module equals null</li>
 415      *             <li>if the name of module equals null</li>
 416      *             <li>if the set of child nodes equals null</li>
 417      *             </ul>
 418      *
 419      */
 420     private def void rpcMethodsToGenType(Module module) {
 421         checkArgument(module !== null, "Module reference cannot be NULL.");
 422         checkArgument(module.name !== null, "Module name cannot be NULL.");
 423         checkArgument(module.childNodes !== null,
 424             "Reference to Set of RPC Method Definitions in module " + module.name + " cannot be NULL.");
 425
 426         val basePackageName = moduleNamespaceToPackageName(module);
 427         val Set<RpcDefinition> rpcDefinitions = module.rpcs;
 428         if (rpcDefinitions.isEmpty()) {
 429             return;
 430         }
 431
 432         val interfaceBuilder = moduleTypeBuilder(module, "Service");
 433         interfaceBuilder.addImplementsType(Types.typeForClass(RpcService));
 434         for (rpc : rpcDefinitions) {
 435             if (rpc !== null) {
 436                 val rpcName = BindingMapping.getClassName(rpc.QName);
 437                 val rpcMethodName = parseToValidParamName(rpcName);
 438                 val rpcComment = rpc.getDescription();
 439                 val method = interfaceBuilder.addMethod(rpcMethodName);
 440
 441                 val input = rpc.input;
 442                 val output = rpc.output;
 443
 444                 if (input !== null) {
 445                     val inType = addRawInterfaceDefinition(basePackageName, input, rpcName);
 446                     addImplementedInterfaceFromUses(input, inType);
 447                     inType.addImplementsType(DATA_OBJECT);
 448                     inType.addImplementsType(augmentable(inType));
 449                     resolveDataSchemaNodes(module, basePackageName, inType, inType, input.childNodes);
 450                     genCtx.get(module).addChildNodeType(input.path, inType)
 451                     val inTypeInstance = inType.toInstance();
 452                     method.addParameter(inTypeInstance, "input");
 453                 }
 454
 455                 var Type outTypeInstance = VOID;
 456                 if (output !== null) {
 457                     val outType = addRawInterfaceDefinition(basePackageName, output, rpcName);
 458                     addImplementedInterfaceFromUses(output, outType);
 459                     outType.addImplementsType(DATA_OBJECT);
 460                     outType.addImplementsType(augmentable(outType));
 461                     resolveDataSchemaNodes(module, basePackageName, outType, outType, output.childNodes);
 462                     genCtx.get(module).addChildNodeType(output.path, outType)
 463                     outTypeInstance = outType.toInstance();
 464                 }
 465
 466                 val rpcRes = Types.parameterizedTypeFor(Types.typeForClass(RpcResult), outTypeInstance);
 467                 method.setComment(rpcComment);
 468                 method.setReturnType(Types.parameterizedTypeFor(FUTURE, rpcRes));
 469
 470             }
 471         }
 472
 473         genCtx.get(module).addTopLevelNodeType(interfaceBuilder)
 474     }
 475
 476     /**
 477      * Converts all <b>notifications</b> of the module to the list of
 478      * <code>Type</code> objects. In addition are to this list added containers
 479      * and lists which are part of this notification.
 480      *
 481      * @param module
 482      *            module from which is obtained set of all notification objects
 483      *            to iterate over them
 484      * @throws IllegalArgumentException
 485      *             <ul>
 486      *             <li>if the module equals null</li>
 487      *             <li>if the name of module equals null</li>
 488      *             <li>if the set of child nodes equals null</li>
 489      *             </ul>
 490      *
 491      */
 492     private def void notificationsToGenType(Module module) {
 493         checkArgument(module !== null, "Module reference cannot be NULL.");
 494         checkArgument(module.name !== null, "Module name cannot be NULL.");
 495
 496         if (module.childNodes === null) {
 497             throw new IllegalArgumentException(
 498                 "Reference to Set of Notification Definitions in module " + module.name + " cannot be NULL.");
 499         }
 500         val notifications = module.notifications;
 501         if(notifications.empty) return;
 502
 503         val listenerInterface = moduleTypeBuilder(module, "Listener");
 504         listenerInterface.addImplementsType(BindingTypes.NOTIFICATION_LISTENER);
 505         val basePackageName = moduleNamespaceToPackageName(module);
 506
 507         for (notification : notifications) {
 508             if (notification !== null) {
 509                 processUsesAugments(notification, module);
 510
 511                 val notificationInterface = addDefaultInterfaceDefinition(basePackageName, notification,
 512                     BindingTypes.DATA_OBJECT);
 513                 notificationInterface.addImplementsType(NOTIFICATION);
 514                 genCtx.get(module).addChildNodeType(notification.path, notificationInterface)
 515
 516                 // Notification object
 517                 resolveDataSchemaNodes(module, basePackageName, notificationInterface, notificationInterface,
 518                     notification.childNodes);
 519
 520                 listenerInterface.addMethod("on" + notificationInterface.name) //
 521                 .setAccessModifier(AccessModifier.PUBLIC).addParameter(notificationInterface, "notification").
 522                     setComment(notification.getDescription()).setReturnType(Types.VOID);
 523             }
 524         }
 525
 526         genCtx.get(module).addTopLevelNodeType(listenerInterface)
 527     }
 528
 529     /**
 530      * Converts all <b>identities</b> of the module to the list of
 531      * <code>Type</code> objects.
 532      *
 533      * @param module
 534      *            module from which is obtained set of all identity objects to
 535      *            iterate over them
 536      * @param context
 537      *            schema context only used as input parameter for method
 538      *            {@link identityToGenType}
 539      *
 540      */
 541     private def void allIdentitiesToGenTypes(Module module, SchemaContext context) {
 542         val Set<IdentitySchemaNode> schemaIdentities = module.identities;
 543         val basePackageName = moduleNamespaceToPackageName(module);
 544
 545         if (schemaIdentities !== null && !schemaIdentities.isEmpty()) {
 546             for (identity : schemaIdentities) {
 547                 identityToGenType(module, basePackageName, identity, context);
 548             }
 549         }
 550     }
 551
 552     /**
 553      * Converts the <b>identity</b> object to GeneratedType. Firstly it is
 554      * created transport object builder. If identity contains base identity then
 555      * reference to base identity is added to superior identity as its extend.
 556      * If identity doesn't contain base identity then only reference to abstract
 557      * class {@link org.opendaylight.yangtools.yang.model.api.BaseIdentity
 558      * BaseIdentity} is added
 559      *
 560      * @param module current module
 561      * @param basePackageName
 562      *            string contains the module package name
 563      * @param identity
 564      *            IdentitySchemaNode which contains data about identity
 565      * @param context
 566      *            SchemaContext which is used to get package and name
 567      *            information about base of identity
 568      *
 569      */
 570     private def void identityToGenType(Module module, String basePackageName, IdentitySchemaNode identity,
 571         SchemaContext context) {
 572         if (identity === null) {
 573             return;
 574         }
 575         val packageName = packageNameForGeneratedType(basePackageName, identity.path);
 576         val genTypeName = BindingMapping.getClassName(identity.QName);
 577         val newType = new GeneratedTOBuilderImpl(packageName, genTypeName);
 578         val baseIdentity = identity.baseIdentity;
 579         if (baseIdentity === null) {
 580             newType.setExtendsType(Types.baseIdentityTO);
 581         } else {
 582             val baseIdentityParentModule = SchemaContextUtil.findParentModule(context, baseIdentity);
 583             val returnTypePkgName = moduleNamespaceToPackageName(baseIdentityParentModule);
 584             val returnTypeName = BindingMapping.getClassName(baseIdentity.QName);
 585             val gto = new GeneratedTOBuilderImpl(returnTypePkgName, returnTypeName).toInstance();
 586             newType.setExtendsType(gto);
 587         }
 588         newType.setAbstract(true);
 589         newType.addComment(identity.getDescription());
 590         val qname = identity.QName;
 591
 592         newType.qnameConstant(BindingMapping.QNAME_STATIC_FIELD_NAME,qname);
 593
 594         genCtx.get(module).addIdentityType(identity.QName,newType)
 595     }
 596
 597     private static def qnameConstant(GeneratedTypeBuilderBase<?> toBuilder, String constantName, QName name) {
 598         toBuilder.addConstant(QName.typeForClass,constantName,'''
 599             org.opendaylight.yangtools.yang.common.QName.create("«name.namespace»","«name.formattedRevision»","«name.localName»")
 600         ''');
 601     }
 602
 603     /**
 604      * Converts all <b>groupings</b> of the module to the list of
 605      * <code>Type</code> objects. Firstly are groupings sorted according mutual
 606      * dependencies. At least dependent (independent) groupings are in the list
 607      * saved at first positions. For every grouping the record is added to map
 608      * {@link BindingGeneratorImpl#allGroupings allGroupings}
 609      *
 610      * @param module
 611      *            current module
 612      * @param collection of groupings from which types will be generated
 613      *
 614      */
 615     private def void groupingsToGenTypes(Module module, Collection<GroupingDefinition> groupings) {
 616         val basePackageName = moduleNamespaceToPackageName(module);
 617         val List<GroupingDefinition> groupingsSortedByDependencies = new GroupingDefinitionDependencySort().sort(
 618             groupings);
 619         for (grouping : groupingsSortedByDependencies) {
 620             groupingToGenType(basePackageName, grouping, module);
 621         }
 622     }
 623
 624     /**
 625      * Converts individual grouping to GeneratedType. Firstly generated type
 626      * builder is created and every child node of grouping is resolved to the
 627      * method.
 628      *
 629      * @param basePackageName
 630      *            string contains the module package name
 631      * @param grouping
 632      *            GroupingDefinition which contains data about grouping
 633      * @param module current module
 634      * @return GeneratedType which is generated from grouping (object of type
 635      *         <code>GroupingDefinition</code>)
 636      */
 637     private def void groupingToGenType(String basePackageName, GroupingDefinition grouping, Module module) {
 638         val packageName = packageNameForGeneratedType(basePackageName, grouping.path);
 639         val genType = addDefaultInterfaceDefinition(packageName, grouping);
 640         genCtx.get(module).addGroupingType(grouping.path, genType)
 641         resolveDataSchemaNodes(module, basePackageName, genType, genType, grouping.childNodes);
 642         groupingsToGenTypes(module, grouping.groupings);
 643         processUsesAugments(grouping, module);
 644     }
 645
 646     /**
 647      * Tries to find EnumTypeDefinition in <code>typeDefinition</code>. If base
 648      * type of <code>typeDefinition</code> is of the type ExtendedType then this
 649      * method is recursively called with this base type.
 650      *
 651      * @param typeDefinition
 652      *            TypeDefinition in which should be EnumTypeDefinition found as
 653      *            base type
 654      * @return EnumTypeDefinition if it is found inside
 655      *         <code>typeDefinition</code> or <code>null</code> in other case
 656      */
 657     private def EnumTypeDefinition enumTypeDefFromExtendedType(TypeDefinition<?> typeDefinition) {
 658         if (typeDefinition !== null) {
 659             if (typeDefinition.baseType instanceof EnumTypeDefinition) {
 660                 return typeDefinition.baseType as EnumTypeDefinition;
 661             } else if (typeDefinition.baseType instanceof ExtendedType) {
 662                 return enumTypeDefFromExtendedType(typeDefinition.baseType);
 663             }
 664         }
 665         return null;
 666     }
 667
 668     /**
 669      * Adds enumeration builder created from <code>enumTypeDef</code> to
 670      * <code>typeBuilder</code>.
 671      *
 672      * Each <code>enumTypeDef</code> item is added to builder with its name and
 673      * value.
 674      *
 675      * @param enumTypeDef
 676      *            EnumTypeDefinition contains enum data
 677      * @param enumName
 678      *            string contains name which will be assigned to enumeration
 679      *            builder
 680      * @param typeBuilder
 681      *            GeneratedTypeBuilder to which will be enum builder assigned
 682      * @return enumeration builder which contains data from
 683      *         <code>enumTypeDef</code>
 684      */
 685     private def EnumBuilder resolveInnerEnumFromTypeDefinition(EnumTypeDefinition enumTypeDef, QName enumName,
 686         GeneratedTypeBuilder typeBuilder) {
 687         if ((enumTypeDef !== null) && (typeBuilder !== null) && (enumTypeDef.QName !== null) &&
 688             (enumTypeDef.QName.localName !== null)) {
 689             val enumerationName = BindingMapping.getClassName(enumName);
 690             val enumBuilder = typeBuilder.addEnumeration(enumerationName);
 691             enumBuilder.updateEnumPairsFromEnumTypeDef(enumTypeDef);
 692             return enumBuilder;
 693         }
 694         return null;
 695     }
 696
 697     /**
 698      * Generates type builder for <code>module</code>.
 699      *
 700      * @param module
 701      *            Module which is source of package name for generated type
 702      *            builder
 703      * @param postfix
 704      *            string which is added to the module class name representation
 705      *            as suffix
 706      * @return instance of GeneratedTypeBuilder which represents
 707      *         <code>module</code>.
 708      * @throws IllegalArgumentException
 709      *             if <code>module</code> equals null
 710      */
 711     private def GeneratedTypeBuilder moduleTypeBuilder(Module module, String postfix) {
 712         checkArgument(module !== null, "Module reference cannot be NULL.");
 713         val packageName = moduleNamespaceToPackageName(module);
 714         val moduleName = BindingMapping.getClassName(module.name) + postfix;
 715         return new GeneratedTypeBuilderImpl(packageName, moduleName);
 716     }
 717
 718     /**
 719      * Converts <code>augSchema</code> to list of <code>Type</code> which
 720      * contains generated type for augmentation. In addition there are also
 721      * generated types for all containers, list and choices which are child of
 722      * <code>augSchema</code> node or a generated types for cases are added if
 723      * augmented node is choice.
 724      *
 725      * @param augmentPackageName
 726      *            string with the name of the package to which the augmentation
 727      *            belongs
 728      * @param augSchema
 729      *            AugmentationSchema which is contains data about augmentation
 730      *            (target path, childs...)
 731      * @param module current module
 732      * @param parentUsesNode parent uses node of this augment (can be null if this augment is not defined under uses statement)
 733      * @throws IllegalArgumentException
 734      *             <ul>
 735      *             <li>if <code>augmentPackageName</code> equals null</li>
 736      *             <li>if <code>augSchema</code> equals null</li>
 737      *             <li>if target path of <code>augSchema</code> equals null</li>
 738      *             </ul>
 739      */
 740     private def void augmentationToGenTypes(String augmentPackageName, AugmentationSchema augSchema, Module module) {
 741         checkArgument(augmentPackageName !== null, "Package Name cannot be NULL.");
 742         checkArgument(augSchema !== null, "Augmentation Schema cannot be NULL.");
 743         checkState(augSchema.targetPath !== null,
 744             "Augmentation Schema does not contain Target Path (Target Path is NULL).");
 745
 746         processUsesAugments(augSchema, module);
 747         val targetPath = augSchema.targetPath;
 748         var SchemaNode targetSchemaNode = null
 749
 750         targetSchemaNode = findDataSchemaNode(schemaContext, targetPath);
 751         if (targetSchemaNode instanceof DataSchemaNode && (targetSchemaNode as DataSchemaNode).isAddedByUses()) {
 752             targetSchemaNode = findOriginal(targetSchemaNode as DataSchemaNode, schemaContext);
 753             if (targetSchemaNode == null) {
 754                 throw new NullPointerException(
 755                     "Failed to find target node from grouping in augmentation " + augSchema + " in module " +
 756                         module.name);
 757             }
 758         }
 759         if (targetSchemaNode == null) {
 760             throw new IllegalArgumentException("augment target not found: " + targetPath)
 761         }
 762
 763         var targetTypeBuilder = findChildNodeByPath(targetSchemaNode.path)
 764         if (targetTypeBuilder === null) {
 765             targetTypeBuilder = findCaseByPath(targetSchemaNode.path)
 766         }
 767         if (targetTypeBuilder === null) {
 768             throw new NullPointerException("Target type not yet generated: " + targetSchemaNode);
 769         }
 770
 771         if (!(targetSchemaNode instanceof ChoiceNode)) {
 772             var packageName = augmentPackageName;
 773             val targetType = new ReferencedTypeImpl(targetTypeBuilder.packageName,targetTypeBuilder.name);
 774             addRawAugmentGenTypeDefinition(module, packageName, augmentPackageName,targetType, augSchema);
 775
 776         } else {
 777             generateTypesFromAugmentedChoiceCases(module, augmentPackageName, targetTypeBuilder.toInstance,
 778                 targetSchemaNode as ChoiceNode, augSchema.childNodes);
 779         }
 780     }
 781
 782     private def void usesAugmentationToGenTypes(String augmentPackageName, AugmentationSchema augSchema, Module module,
 783         UsesNode usesNode, DataNodeContainer usesNodeParent) {
 784         checkArgument(augmentPackageName !== null, "Package Name cannot be NULL.");
 785         checkArgument(augSchema !== null, "Augmentation Schema cannot be NULL.");
 786         checkState(augSchema.targetPath !== null,
 787             "Augmentation Schema does not contain Target Path (Target Path is NULL).");
 788
 789         processUsesAugments(augSchema, module);
 790         val targetPath = augSchema.targetPath;
 791         var SchemaNode targetSchemaNode = null
 792         targetSchemaNode = findOriginalTargetFromGrouping(targetPath, usesNode);
 793         if (targetSchemaNode == null) {
 794             throw new IllegalArgumentException("augment target not found: " + targetPath)
 795         }
 796
 797         var targetTypeBuilder = findChildNodeByPath(targetSchemaNode.path)
 798         if (targetTypeBuilder === null) {
 799             targetTypeBuilder = findCaseByPath(targetSchemaNode.path)
 800         }
 801         if (targetTypeBuilder === null) {
 802             throw new NullPointerException("Target type not yet generated: " + targetSchemaNode);
 803         }
 804
 805         if (!(targetSchemaNode instanceof ChoiceNode)) {
 806             var packageName = augmentPackageName;
 807             if (usesNodeParent instanceof SchemaNode) {
 808                 packageName = packageNameForGeneratedType(augmentPackageName, (usesNodeParent as SchemaNode).path, true)
 809             }
 810             addRawAugmentGenTypeDefinition(module, packageName, augmentPackageName,
 811                 targetTypeBuilder.toInstance, augSchema);
 812         } else {
 813             generateTypesFromAugmentedChoiceCases(module, augmentPackageName, targetTypeBuilder.toInstance,
 814                 targetSchemaNode as ChoiceNode, augSchema.childNodes);
 815         }
 816     }
 817
 818     /**
 819      * Convenient method to find node added by uses statement.
 820      */
 821     private def DataSchemaNode findOriginalTargetFromGrouping(SchemaPath targetPath, UsesNode parentUsesNode) {
 822         var SchemaNode targetGrouping = findNodeInSchemaContext(schemaContext, parentUsesNode.groupingPath.path);
 823         if (!(targetGrouping instanceof GroupingDefinition)) {
 824             throw new IllegalArgumentException("Failed to generate code for augment in " + parentUsesNode);
 825         }
 826
 827         var grouping = targetGrouping as GroupingDefinition;
 828         var SchemaNode result = grouping;
 829         val List<QName> path = targetPath.path
 830         for (node : path) {
 831             // finding by local name is valid, grouping cannot contain nodes with same name and different namespace
 832             if (result instanceof DataNodeContainer) {
 833                 result = (result as DataNodeContainer).getDataChildByName(node.localName)
 834             } else if (result instanceof ChoiceNode) {
 835                 result = (result as ChoiceNode).getCaseNodeByName(node.localName)
 836             }
 837         }
 838         if (result == null) {
 839             return null;
 840         }
 841
 842         val String targetSchemaNodeName = result.QName.localName;
 843         var boolean fromUses = (result as DataSchemaNode).addedByUses
 844         var Iterator<UsesNode> groupingUses = grouping.uses.iterator;
 845         while (fromUses) {
 846             if (groupingUses.hasNext()) {
 847                 grouping = findNodeInSchemaContext(schemaContext, groupingUses.next().groupingPath.path) as GroupingDefinition;
 848                 result = grouping.getDataChildByName(targetSchemaNodeName);
 849                 fromUses = (result as DataSchemaNode).addedByUses;
 850             } else {
 851                 throw new NullPointerException("Failed to generate code for augment in " + parentUsesNode);
 852             }
 853         }
 854
 855         return result as DataSchemaNode
 856     }
 857
 858     /**
 859      * Returns a generated type builder for an augmentation.
 860      *
 861      * The name of the type builder is equal to the name of augmented node with
 862      * serial number as suffix.
 863      *
 864      * @param module current module
 865      * @param augmentPackageName
 866      *            string with contains the package name to which the augment
 867      *            belongs
 868      * @param basePackageName
 869      *            string with the package name to which the augmented node
 870      *            belongs
 871      * @param targetTypeRef
 872      *            target type
 873      * @param augSchema
 874      *            augmentation schema which contains data about the child nodes
 875      *            and uses of augment
 876      * @return generated type builder for augment
 877      */
 878     private def GeneratedTypeBuilder addRawAugmentGenTypeDefinition(Module module, String augmentPackageName,
 879         String basePackageName, Type targetTypeRef, AugmentationSchema augSchema) {
 880         var Map<String, GeneratedTypeBuilder> augmentBuilders = genTypeBuilders.get(augmentPackageName);
 881         if (augmentBuilders === null) {
 882             augmentBuilders = new HashMap();
 883             genTypeBuilders.put(augmentPackageName, augmentBuilders);
 884         }
 885         val augIdentifier = getAugmentIdentifier(augSchema.unknownSchemaNodes);
 886
 887         val augTypeName = if (augIdentifier !== null) {
 888                 BindingMapping.getClassName(augIdentifier)
 889             } else {
 890                 augGenTypeName(augmentBuilders, targetTypeRef.name);
 891             }
 892
 893         val augTypeBuilder = new GeneratedTypeBuilderImpl(augmentPackageName, augTypeName);
 894
 895         augTypeBuilder.addImplementsType(DATA_OBJECT);
 896         augTypeBuilder.addImplementsType(Types.augmentationTypeFor(targetTypeRef));
 897         addImplementedInterfaceFromUses(augSchema, augTypeBuilder);
 898
 899         augSchemaNodeToMethods(module, basePackageName, augTypeBuilder, augTypeBuilder, augSchema.childNodes);
 900         augmentBuilders.put(augTypeName, augTypeBuilder);
 901
 902         genCtx.get(module).addTargetToAugmentation(targetTypeRef,augTypeBuilder);
 903         genCtx.get(module).addAugmentType(augTypeBuilder);
 904         genCtx.get(module).addTypeToAugmentation(augTypeBuilder, augSchema);
 905         return augTypeBuilder;
 906     }
 907
 908     /**
 909      *
 910      * @param unknownSchemaNodes
 911      * @return nodeParameter of UnknownSchemaNode
 912      */
 913     private def String getAugmentIdentifier(List<UnknownSchemaNode> unknownSchemaNodes) {
 914         for (unknownSchemaNode : unknownSchemaNodes) {
 915             val nodeType = unknownSchemaNode.nodeType;
 916             if (AUGMENT_IDENTIFIER_NAME.equals(nodeType.localName) &&
 917                 YANG_EXT_NAMESPACE.equals(nodeType.namespace.toString())) {
 918                 return unknownSchemaNode.nodeParameter;
 919             }
 920         }
 921         return null;
 922     }
 923
 924     /**
 925      * Returns first unique name for the augment generated type builder. The
 926      * generated type builder name for augment consists from name of augmented
 927      * node and serial number of its augmentation.
 928      *
 929      * @param builders
 930      *            map of builders which were created in the package to which the
 931      *            augmentation belongs
 932      * @param genTypeName
 933      *            string with name of augmented node
 934      * @return string with unique name for augmentation builder
 935      */
 936     private def String augGenTypeName(Map<String, GeneratedTypeBuilder> builders, String genTypeName) {
 937         var index = 1;
 938         while ((builders !== null) && builders.containsKey(genTypeName + index)) {
 939             index = index + 1;
 940         }
 941         return genTypeName + index;
 942     }
 943
 944     /**
 945      * Adds the methods to <code>typeBuilder</code> which represent subnodes of
 946      * node for which <code>typeBuilder</code> was created.
 947      *
 948      * The subnodes aren't mapped to the methods if they are part of grouping or
 949      * augment (in this case are already part of them).
 950      *
 951      * @param module current module
 952      * @param basePackageName
 953      *            string contains the module package name
 954      * @param parent
 955      *            generated type builder which represents any node. The subnodes
 956      *            of this node are added to the <code>typeBuilder</code> as
 957      *            methods. The subnode can be of type leaf, leaf-list, list,
 958      *            container, choice.
 959      * @param childOf parent type
 960      * @param schemaNodes
 961      *            set of data schema nodes which are the children of the node
 962      *            for which <code>typeBuilder</code> was created
 963      * @return generated type builder which is the same builder as input
 964      *         parameter. The getter methods (representing child nodes) could be
 965      *         added to it.
 966      */
 967     private def GeneratedTypeBuilder resolveDataSchemaNodes(Module module, String basePackageName,
 968         GeneratedTypeBuilder parent, GeneratedTypeBuilder childOf, Set<DataSchemaNode> schemaNodes) {
 969         if ((schemaNodes !== null) && (parent !== null)) {
 970             for (schemaNode : schemaNodes) {
 971                 if (!schemaNode.augmenting && !schemaNode.addedByUses) {
 972                     addSchemaNodeToBuilderAsMethod(basePackageName, schemaNode, parent, childOf, module);
 973                 }
 974             }
 975         }
 976         return parent;
 977     }
 978
 979     /**
 980      * Adds the methods to <code>typeBuilder</code> what represents subnodes of
 981      * node for which <code>typeBuilder</code> was created.
 982      *
 983      * @param module current module
 984      * @param basePackageName
 985      *            string contains the module package name
 986      * @param typeBuilder
 987      *            generated type builder which represents any node. The subnodes
 988      *            of this node are added to the <code>typeBuilder</code> as
 989      *            methods. The subnode can be of type leaf, leaf-list, list,
 990      *            container, choice.
 991      * @param childOf parent type
 992      * @param schemaNodes
 993      *            set of data schema nodes which are the children of the node
 994      *            for which <code>typeBuilder</code> was created
 995      * @return generated type builder which is the same object as the input
 996      *         parameter <code>typeBuilder</code>. The getter method could be
 997      *         added to it.
 998      */
 999     private def GeneratedTypeBuilder augSchemaNodeToMethods(Module module, String basePackageName,
1000         GeneratedTypeBuilder typeBuilder, GeneratedTypeBuilder childOf, Set<DataSchemaNode> schemaNodes) {
1001         if ((schemaNodes !== null) && (typeBuilder !== null)) {
1002             for (schemaNode : schemaNodes) {
1003                 if (!schemaNode.isAugmenting()) {
1004                     addSchemaNodeToBuilderAsMethod(basePackageName, schemaNode, typeBuilder, childOf, module);
1005                 }
1006             }
1007         }
1008         return typeBuilder;
1009     }
1010
1011     /**
1012      * Adds to <code>typeBuilder</code> a method which is derived from
1013      * <code>schemaNode</code>.
1014      *
1015      * @param basePackageName
1016      *            string with the module package name
1017      * @param node
1018      *            data schema node which is added to <code>typeBuilder</code> as
1019      *            a method
1020      * @param typeBuilder
1021      *            generated type builder to which is <code>schemaNode</code>
1022      *            added as a method.
1023      * @param childOf parent type
1024      * @param module current module
1025      */
1026     private def void addSchemaNodeToBuilderAsMethod(String basePackageName, DataSchemaNode node,
1027         GeneratedTypeBuilder typeBuilder, GeneratedTypeBuilder childOf, Module module) {
1028         if (node !== null && typeBuilder !== null) {
1029             switch (node) {
1030                 case node instanceof LeafSchemaNode:
1031                     resolveLeafSchemaNodeAsMethod(typeBuilder, node as LeafSchemaNode)
1032                 case node instanceof LeafListSchemaNode:
1033                     resolveLeafListSchemaNode(typeBuilder, node as LeafListSchemaNode)
1034                 case node instanceof ContainerSchemaNode:
1035                     containerToGenType(module, basePackageName, typeBuilder, childOf, node as ContainerSchemaNode)
1036                 case node instanceof ListSchemaNode:
1037                     listToGenType(module, basePackageName, typeBuilder, childOf, node as ListSchemaNode)
1038                 case node instanceof ChoiceNode:
1039                     choiceToGeneratedType(module, basePackageName, typeBuilder, node as ChoiceNode)
1040             }
1041         }
1042     }
1043
1044     /**
1045      * Converts <code>choiceNode</code> to the list of generated types for
1046      * choice and its cases.
1047      *
1048      * The package names for choice and for its cases are created as
1049      * concatenation of the module package (<code>basePackageName</code>) and
1050      * names of all parents node.
1051      *
1052      * @param module current module
1053      * @param basePackageName
1054      *            string with the module package name
1055      * @param parent parent type
1056      * @param childOf concrete parent for case child nodes
1057      * @param choiceNode
1058      *            choice node which is mapped to generated type. Also child
1059      *            nodes - cases are mapped to generated types.
1060      * @throws IllegalArgumentException
1061      *             <ul>
1062      *             <li>if <code>basePackageName</code> equals null</li>
1063      *             <li>if <code>choiceNode</code> equals null</li>
1064      *             </ul>
1065      *
1066      */
1067     private def void choiceToGeneratedType(Module module, String basePackageName, GeneratedTypeBuilder parent,
1068         ChoiceNode choiceNode) {
1069         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1070         checkArgument(choiceNode !== null, "Choice Schema Node cannot be NULL.");
1071
1072         if (!choiceNode.addedByUses) {
1073             val packageName = packageNameForGeneratedType(basePackageName, choiceNode.path);
1074             val choiceTypeBuilder = addRawInterfaceDefinition(packageName, choiceNode);
1075             constructGetter(parent, choiceNode.QName.localName, choiceNode.description, choiceTypeBuilder);
1076             choiceTypeBuilder.addImplementsType(DataContainer.typeForClass);
1077             genCtx.get(module).addChildNodeType(choiceNode.path, choiceTypeBuilder)
1078             generateTypesFromChoiceCases(module, basePackageName, parent, choiceTypeBuilder.toInstance, choiceNode);
1079         }
1080     }
1081
1082     /**
1083      * Converts <code>caseNodes</code> set to list of corresponding generated
1084      * types.
1085      *
1086      * For every <i>case</i> which isn't added through augment or <i>uses</i> is
1087      * created generated type builder. The package names for the builder is
1088      * created as concatenation of the module package (
1089      * <code>basePackageName</code>) and names of all parents nodes of the
1090      * concrete <i>case</i>. There is also relation "<i>implements type</i>"
1091      * between every case builder and <i>choice</i> type
1092      *
1093      * @param basePackageName
1094      *            string with the module package name
1095      * @param refChoiceType
1096      *            type which represents superior <i>case</i>
1097      * @param caseNodes
1098      *            set of choice case nodes which are mapped to generated types
1099      * @return list of generated types for <code>caseNodes</code>.
1100      * @throws IllegalArgumentException
1101      *             <ul>
1102      *             <li>if <code>basePackageName</code> equals null</li>
1103      *             <li>if <code>refChoiceType</code> equals null</li>
1104      *             <li>if <code>caseNodes</code> equals null</li>
1105      *             </ul>
1106      *             *
1107      */
1108     private def void generateTypesFromChoiceCases(Module module, String basePackageName,
1109         GeneratedTypeBuilder choiceParent, Type refChoiceType, ChoiceNode choiceNode) {
1110         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1111         checkArgument(refChoiceType !== null, "Referenced Choice Type cannot be NULL.");
1112         checkArgument(choiceNode !== null, "ChoiceNode cannot be NULL.");
1113
1114         val Set<ChoiceCaseNode> caseNodes = choiceNode.cases;
1115         if (caseNodes == null) {
1116             return
1117         }
1118
1119         for (caseNode : caseNodes) {
1120             if (caseNode !== null && !caseNode.isAddedByUses() && !caseNode.isAugmenting()) {
1121                 val packageName = packageNameForGeneratedType(basePackageName, caseNode.path)
1122                 val caseTypeBuilder = addDefaultInterfaceDefinition(packageName, caseNode)
1123                 caseTypeBuilder.addImplementsType(refChoiceType)
1124                 genCtx.get(module).addCaseType(caseNode.path, caseTypeBuilder)
1125                 val Set<DataSchemaNode> caseChildNodes = caseNode.childNodes
1126                 if (caseChildNodes !== null) {
1127                     var Object parentNode = null
1128                     val SchemaPath nodeSp = choiceNode.path
1129                     val List<QName> nodeNames = nodeSp.path
1130                     val List<QName> nodeNewNames = new ArrayList(nodeNames)
1131                     nodeNewNames.remove(nodeNewNames.size - 1)
1132                     val SchemaPath nodeNewSp = new SchemaPath(nodeNewNames, nodeSp.absolute)
1133                     parentNode = findDataSchemaNode(schemaContext, nodeNewSp)
1134
1135                     var SchemaNode parent
1136                     if (parentNode instanceof AugmentationSchema) {
1137                         val augSchema = parentNode as AugmentationSchema;
1138                         val targetPath = augSchema.targetPath;
1139                         var targetSchemaNode = findDataSchemaNode(schemaContext, targetPath)
1140                         if (targetSchemaNode instanceof DataSchemaNode &&
1141                             (targetSchemaNode as DataSchemaNode).isAddedByUses()) {
1142                             targetSchemaNode = findOriginal(targetSchemaNode as DataSchemaNode, schemaContext);
1143                             if (targetSchemaNode == null) {
1144                                 throw new NullPointerException(
1145                                     "Failed to find target node from grouping for augmentation " + augSchema +
1146                                         " in module " + module.name);
1147                             }
1148                         }
1149                         parent = targetSchemaNode
1150                     } else {
1151                         val SchemaPath sp = choiceNode.path
1152                         val List<QName> names = sp.path
1153                         val List<QName> newNames = new ArrayList(names)
1154                         newNames.remove(newNames.size - 1)
1155                         val SchemaPath newSp = new SchemaPath(newNames, sp.absolute)
1156                         parent = findDataSchemaNode(schemaContext, newSp)
1157                     }
1158                     var GeneratedTypeBuilder childOfType = findChildNodeByPath(parent.path)
1159                     resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, caseChildNodes)
1160                 }
1161             }
1162
1163             processUsesAugments(caseNode, module);
1164         }
1165     }
1166
1167     /**
1168      * Generates list of generated types for all the cases of a choice which are
1169      * added to the choice through the augment.
1170      *
1171      *
1172      * @param basePackageName
1173      *            string contains name of package to which augment belongs. If
1174      *            an augmented choice is from an other package (pcg1) than an
1175      *            augmenting choice (pcg2) then case's of the augmenting choice
1176      *            will belong to pcg2.
1177      * @param refChoiceType
1178      *            Type which represents the choice to which case belongs. Every
1179      *            case has to contain its choice in extend part.
1180      * @param caseNodes
1181      *            set of choice case nodes for which is checked if are/aren't
1182      *            added to choice through augmentation
1183      * @return list of generated types which represents augmented cases of
1184      *         choice <code>refChoiceType</code>
1185      * @throws IllegalArgumentException
1186      *             <ul>
1187      *             <li>if <code>basePackageName</code> equals null</li>
1188      *             <li>if <code>refChoiceType</code> equals null</li>
1189      *             <li>if <code>caseNodes</code> equals null</li>
1190      *             </ul>
1191      */
1192     private def void generateTypesFromAugmentedChoiceCases(Module module, String basePackageName, Type targetType,
1193         ChoiceNode targetNode, Set<DataSchemaNode> augmentedNodes) {
1194         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1195         checkArgument(targetType !== null, "Referenced Choice Type cannot be NULL.");
1196         checkArgument(augmentedNodes !== null, "Set of Choice Case Nodes cannot be NULL.");
1197
1198         for (caseNode : augmentedNodes) {
1199             if (caseNode !== null) {
1200                 val packageName = packageNameForGeneratedType(basePackageName, caseNode.path);
1201                 val caseTypeBuilder = addDefaultInterfaceDefinition(packageName, caseNode);
1202                 caseTypeBuilder.addImplementsType(targetType);
1203
1204                 var SchemaNode parent = null
1205                 val SchemaPath nodeSp = targetNode.path
1206                 val List<QName> nodeNames = nodeSp.path
1207                 val List<QName> nodeNewNames = new ArrayList(nodeNames)
1208                 nodeNewNames.remove(nodeNewNames.size - 1)
1209                 val SchemaPath nodeNewSp = new SchemaPath(nodeNewNames, nodeSp.absolute)
1210                 parent = findDataSchemaNode(schemaContext, nodeNewSp)
1211
1212                 var GeneratedTypeBuilder childOfType = null;
1213                 if (parent instanceof Module) {
1214                     childOfType = genCtx.get(parent as Module).moduleNode
1215                 } else if (parent instanceof ChoiceCaseNode) {
1216                     childOfType = findCaseByPath(parent.path)
1217                 } else if (parent instanceof DataSchemaNode || parent instanceof NotificationDefinition) {
1218                     childOfType = findChildNodeByPath(parent.path)
1219                 } else if (parent instanceof GroupingDefinition) {
1220                     childOfType = findGroupingByPath(parent.path);
1221                 }
1222
1223                 if (childOfType == null) {
1224                     throw new IllegalArgumentException("Failed to find parent type of choice " + targetNode);
1225                 }
1226
1227                 if (caseNode instanceof DataNodeContainer) {
1228                     val DataNodeContainer dataNodeCase = caseNode as DataNodeContainer;
1229                     val Set<DataSchemaNode> childNodes = dataNodeCase.childNodes;
1230                     if (childNodes !== null) {
1231                         resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, childNodes);
1232                     }
1233                 } else {
1234                     val ChoiceCaseNode node = targetNode.getCaseNodeByName(caseNode.getQName().getLocalName());
1235                     val Set<DataSchemaNode> childNodes = node.childNodes;
1236                     if (childNodes !== null) {
1237                         resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, childNodes);
1238                     }
1239                 }
1240
1241                 genCtx.get(module).addCaseType(caseNode.path, caseTypeBuilder)
1242             }
1243         }
1244
1245     }
1246
1247     /**
1248      * Converts <code>leaf</code> to the getter method which is added to
1249      * <code>typeBuilder</code>.
1250      *
1251      * @param typeBuilder
1252      *            generated type builder to which is added getter method as
1253      *            <code>leaf</code> mapping
1254      * @param leaf
1255      *            leaf schema node which is mapped as getter method which is
1256      *            added to <code>typeBuilder</code>
1257      * @return boolean value
1258      *         <ul>
1259      *         <li>false - if <code>leaf</code> or <code>typeBuilder</code> are
1260      *         null</li>
1261      *         <li>true - in other cases</li>
1262      *         </ul>
1263      */
1264     private def Type resolveLeafSchemaNodeAsMethod(GeneratedTypeBuilder typeBuilder, LeafSchemaNode leaf) {
1265         var Type returnType = null;
1266         if ((leaf !== null) && (typeBuilder !== null)) {
1267             val leafName = leaf.QName.localName;
1268             var String leafDesc = leaf.description;
1269             if (leafDesc === null) {
1270                 leafDesc = "";
1271             }
1272
1273             val parentModule = findParentModule(schemaContext, leaf);
1274             if (leafName !== null && !leaf.isAddedByUses()) {
1275                 val TypeDefinition<?> typeDef = leaf.type;
1276
1277                 var GeneratedTOBuilder genTOBuilder;
1278                 if (typeDef instanceof EnumTypeDefinition) {
1279                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf);
1280                     val enumTypeDef = typeDef as EnumTypeDefinition;
1281                     val enumBuilder = resolveInnerEnumFromTypeDefinition(enumTypeDef, leaf.QName, typeBuilder);
1282
1283                     if (enumBuilder !== null) {
1284                         returnType = enumBuilder.toInstance(typeBuilder)
1285                     }
1286                     (typeProvider as TypeProviderImpl).putReferencedType(leaf.path, returnType);
1287                 } else if (typeDef instanceof UnionType) {
1288                     genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, leaf, parentModule);
1289                     if (genTOBuilder !== null) {
1290                         returnType = createReturnTypeForUnion(genTOBuilder, typeDef, typeBuilder, parentModule)
1291                     }
1292                 } else if (typeDef instanceof BitsTypeDefinition) {
1293                     genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, leaf, parentModule);
1294                     if (genTOBuilder !== null) {
1295                         returnType = new ReferencedTypeImpl(genTOBuilder.packageName, genTOBuilder.name);
1296                     }
1297                 } else {
1298                     val Restrictions restrictions = BindingGeneratorUtil.getRestrictions(typeDef);
1299                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf, restrictions);
1300                 }
1301                 if (returnType !== null) {
1302                     val MethodSignatureBuilder getter = constructGetter(typeBuilder, leafName, leafDesc, returnType);
1303                     processContextRefExtension(leaf, getter, parentModule);
1304                 }
1305             }
1306         }
1307         return returnType;
1308     }
1309
1310     private def void processContextRefExtension(LeafSchemaNode leaf, MethodSignatureBuilder getter, Module module) {
1311         for (node : leaf.unknownSchemaNodes) {
1312             val nodeType = node.nodeType;
1313             if ("context-reference".equals(nodeType.localName)) {
1314                 val nodeParam = node.nodeParameter;
1315                 var IdentitySchemaNode identity = null;
1316                 var String basePackageName = null;
1317                 val String[] splittedElement = nodeParam.split(":");
1318                 if (splittedElement.length == 1) {
1319                     identity = findIdentityByName(module.identities, splittedElement.get(0));
1320                     basePackageName = moduleNamespaceToPackageName(module);
1321                 } else if (splittedElement.length == 2) {
1322                     var prefix = splittedElement.get(0);
1323                     val Module dependentModule = findModuleFromImports(module.imports, prefix)
1324                     if (dependentModule == null) {
1325                         throw new IllegalArgumentException(
1326                             "Failed to process context-reference: unknown prefix " + prefix);
1327                     }
1328                     identity = findIdentityByName(dependentModule.identities, splittedElement.get(1));
1329                     basePackageName = moduleNamespaceToPackageName(dependentModule);
1330                 } else {
1331                     throw new IllegalArgumentException(
1332                         "Failed to process context-reference: unknown identity " + nodeParam);
1333                 }
1334                 if (identity == null) {
1335                     throw new IllegalArgumentException(
1336                         "Failed to process context-reference: unknown identity " + nodeParam);
1337                 }
1338
1339                 val Class<RoutingContext> clazz = typeof(RoutingContext);
1340                 val AnnotationTypeBuilder rc = getter.addAnnotation(clazz.package.name, clazz.simpleName);
1341                 val packageName = packageNameForGeneratedType(basePackageName, identity.path);
1342                 val genTypeName = BindingMapping.getClassName(identity.QName.localName);
1343                 rc.addParameter("value", packageName + "." + genTypeName + ".class");
1344             }
1345         }
1346     }
1347
1348     private def IdentitySchemaNode findIdentityByName(Set<IdentitySchemaNode> identities, String name) {
1349         for (id : identities) {
1350             if (id.QName.localName.equals(name)) {
1351                 return id;
1352             }
1353         }
1354         return null;
1355     }
1356
1357     private def Module findModuleFromImports(Set<ModuleImport> imports, String prefix) {
1358         for (imp : imports) {
1359             if (imp.prefix.equals(prefix)) {
1360                 return schemaContext.findModuleByName(imp.moduleName, imp.revision);
1361             }
1362         }
1363         return null;
1364     }
1365
1366     private def boolean resolveLeafSchemaNodeAsProperty(GeneratedTOBuilder toBuilder, LeafSchemaNode leaf,
1367         boolean isReadOnly, Module module) {
1368         if ((leaf !== null) && (toBuilder !== null)) {
1369             val leafName = leaf.QName.localName;
1370             var String leafDesc = leaf.description;
1371             if (leafDesc === null) {
1372                 leafDesc = "";
1373             }
1374
1375             if (leafName !== null) {
1376                 var Type returnType = null;
1377                 val TypeDefinition<?> typeDef = leaf.type;
1378                 if (typeDef instanceof UnionTypeDefinition) {
1379                     // GeneratedType for this type definition should be already created
1380                     var qname = typeDef.QName
1381                     var Module unionModule = null
1382                     if (qname.prefix == null || qname.prefix.empty) {
1383                         unionModule = module
1384                     } else {
1385                         unionModule = findModuleFromImports(module.imports, qname.prefix)
1386                     }
1387                     val ModuleContext mc = genCtx.get(unionModule)
1388                     returnType = mc.typedefs.get(typeDef.path)
1389                 } else {
1390                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf);
1391                 }
1392                 return resolveLeafSchemaNodeAsProperty(toBuilder, leaf, returnType, isReadOnly)
1393             }
1394         }
1395         return false;
1396     }
1397
1398     /**
1399      * Converts <code>leaf</code> schema node to property of generated TO
1400      * builder.
1401      *
1402      * @param toBuilder
1403      *            generated TO builder to which is <code>leaf</code> added as
1404      *            property
1405      * @param leaf
1406      *            leaf schema node which is added to <code>toBuilder</code> as
1407      *            property
1408      * @param returnType property type
1409      * @param isReadOnly
1410      *            boolean value which says if leaf property is|isn't read only
1411      * @return boolean value
1412      *         <ul>
1413      *         <li>false - if <code>leaf</code>, <code>toBuilder</code> or leaf
1414      *         name equals null or if leaf is added by <i>uses</i>.</li>
1415      *         <li>true - other cases</li>
1416      *         </ul>
1417      */
1418     private def resolveLeafSchemaNodeAsProperty(GeneratedTOBuilder toBuilder, LeafSchemaNode leaf, Type returnType,
1419         boolean isReadOnly) {
1420         if (returnType == null) {
1421             return false;
1422         }
1423         val leafName = leaf.QName.localName
1424         val leafDesc = leaf.description
1425         val propBuilder = toBuilder.addProperty(parseToValidParamName(leafName));
1426         propBuilder.setReadOnly(isReadOnly);
1427         propBuilder.setReturnType(returnType);
1428         propBuilder.setComment(leafDesc);
1429         toBuilder.addEqualsIdentity(propBuilder);
1430         toBuilder.addHashIdentity(propBuilder);
1431         toBuilder.addToStringProperty(propBuilder);
1432         return true;
1433     }
1434
1435     /**
1436      * Converts <code>node</code> leaf list schema node to getter method of
1437      * <code>typeBuilder</code>.
1438      *
1439      * @param typeBuilder
1440      *            generated type builder to which is <code>node</code> added as
1441      *            getter method
1442      * @param node
1443      *            leaf list schema node which is added to
1444      *            <code>typeBuilder</code> as getter method
1445      * @return boolean value
1446      *         <ul>
1447      *         <li>true - if <code>node</code>, <code>typeBuilder</code>,
1448      *         nodeName equal null or <code>node</code> is added by <i>uses</i></li>
1449      *         <li>false - other cases</li>
1450      *         </ul>
1451      */
1452     private def boolean resolveLeafListSchemaNode(GeneratedTypeBuilder typeBuilder, LeafListSchemaNode node) {
1453         if ((node !== null) && (typeBuilder !== null)) {
1454             val nodeName = node.QName;
1455             var String nodeDesc = node.description;
1456             if (nodeDesc === null) {
1457                 nodeDesc = "";
1458             }
1459             if (nodeName !== null && !node.isAddedByUses()) {
1460                 val TypeDefinition<?> typeDef = node.type;
1461                 val parentModule = findParentModule(schemaContext, node);
1462
1463                 var Type returnType = null;
1464                 if (typeDef instanceof EnumTypeDefinition) {
1465                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, node);
1466                     val enumTypeDef = typeDef as EnumTypeDefinition;
1467                     val enumBuilder = resolveInnerEnumFromTypeDefinition(enumTypeDef, nodeName, typeBuilder);
1468                     returnType = new ReferencedTypeImpl(enumBuilder.packageName, enumBuilder.name);
1469                     (typeProvider as TypeProviderImpl).putReferencedType(node.path, returnType);
1470                 } else if (typeDef instanceof UnionType) {
1471                     val genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, node, parentModule);
1472                     if (genTOBuilder !== null) {
1473                         returnType = createReturnTypeForUnion(genTOBuilder, typeDef, typeBuilder, parentModule)
1474                     }
1475                 } else if (typeDef instanceof BitsTypeDefinition) {
1476                     val genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, node, parentModule);
1477                     returnType = new ReferencedTypeImpl(genTOBuilder.packageName, genTOBuilder.name);
1478                 } else {
1479                     val Restrictions restrictions = BindingGeneratorUtil.getRestrictions(typeDef);
1480                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, node, restrictions);
1481                 }
1482
1483                 val listType = Types.listTypeFor(returnType);
1484                 constructGetter(typeBuilder, nodeName.localName, nodeDesc, listType);
1485                 return true;
1486             }
1487         }
1488         return false;
1489     }
1490
1491     private def Type createReturnTypeForUnion(GeneratedTOBuilder genTOBuilder, TypeDefinition<?> typeDef,
1492         GeneratedTypeBuilder typeBuilder, Module parentModule) {
1493         val GeneratedTOBuilderImpl returnType = new GeneratedTOBuilderImpl(genTOBuilder.packageName, genTOBuilder.name)
1494         genTOBuilder.setTypedef(true);
1495         genTOBuilder.setIsUnion(true);
1496         (typeProvider as TypeProviderImpl).addUnitsToGenTO(genTOBuilder, typeDef.getUnits());
1497
1498         // union builder
1499         val GeneratedTOBuilder unionBuilder = new GeneratedTOBuilderImpl(typeBuilder.getPackageName(),
1500             genTOBuilder.getName() + "Builder");
1501         unionBuilder.setIsUnionBuilder(true);
1502         val MethodSignatureBuilder method = unionBuilder.addMethod("getDefaultInstance");
1503         method.setReturnType(returnType);
1504         method.addParameter(Types.STRING, "defaultValue");
1505         method.setAccessModifier(AccessModifier.PUBLIC);
1506         method.setStatic(true);
1507
1508         val Set<Type> types = (typeProvider as TypeProviderImpl).additionalTypes.get(parentModule);
1509         if (types == null) {
1510             (typeProvider as TypeProviderImpl).additionalTypes.put(parentModule,
1511                 Sets.newHashSet(unionBuilder.toInstance))
1512         } else {
1513             types.add(unionBuilder.toInstance)
1514         }
1515         return returnType.toInstance
1516     }
1517
1518     private def GeneratedTypeBuilder addDefaultInterfaceDefinition(String packageName, SchemaNode schemaNode) {
1519         return addDefaultInterfaceDefinition(packageName, schemaNode, null);
1520     }
1521
1522     /**
1523      * Instantiates generated type builder with <code>packageName</code> and
1524      * <code>schemaNode</code>.
1525      *
1526      * The new builder always implements
1527      * {@link org.opendaylight.yangtools.yang.binding.DataObject DataObject}.<br />
1528      * If <code>schemaNode</code> is instance of GroupingDefinition it also
1529      * implements {@link org.opendaylight.yangtools.yang.binding.Augmentable
1530      * Augmentable}.<br />
1531      * If <code>schemaNode</code> is instance of
1532      * {@link org.opendaylight.yangtools.yang.model.api.DataNodeContainer
1533      * DataNodeContainer} it can also implement nodes which are specified in
1534      * <i>uses</i>.
1535      *
1536      * @param packageName
1537      *            string with the name of the package to which
1538      *            <code>schemaNode</code> belongs.
1539      * @param schemaNode
1540      *            schema node for which is created generated type builder
1541      * @param parent parent type (can be null)
1542      * @return generated type builder <code>schemaNode</code>
1543      */
1544     private def GeneratedTypeBuilder addDefaultInterfaceDefinition(String packageName, SchemaNode schemaNode,
1545         Type parent) {
1546         val it = addRawInterfaceDefinition(packageName, schemaNode, "");
1547         qnameConstant(BindingMapping.QNAME_STATIC_FIELD_NAME,schemaNode.QName);
1548         if (parent === null) {
1549             addImplementsType(DATA_OBJECT);
1550         } else {
1551             addImplementsType(BindingTypes.childOf(parent));
1552         }
1553         if (!(schemaNode instanceof GroupingDefinition)) {
1554             addImplementsType(augmentable(it));
1555         }
1556
1557         if (schemaNode instanceof DataNodeContainer) {
1558             addImplementedInterfaceFromUses(schemaNode as DataNodeContainer, it);
1559         }
1560
1561         return it;
1562     }
1563
1564     /**
1565      * Wraps the calling of the same overloaded method.
1566      *
1567      * @param packageName
1568      *            string with the package name to which returning generated type
1569      *            builder belongs
1570      * @param schemaNode
1571      *            schema node which provide data about the schema node name
1572      * @return generated type builder for <code>schemaNode</code>
1573      */
1574     private def GeneratedTypeBuilder addRawInterfaceDefinition(String packageName, SchemaNode schemaNode) {
1575         return addRawInterfaceDefinition(packageName, schemaNode, "");
1576     }
1577
1578     /**
1579      * Returns reference to generated type builder for specified
1580      * <code>schemaNode</code> with <code>packageName</code>.
1581      *
1582      * Firstly the generated type builder is searched in
1583      * {@link BindingGeneratorImpl#genTypeBuilders genTypeBuilders}. If it isn't
1584      * found it is created and added to <code>genTypeBuilders</code>.
1585      *
1586      * @param packageName
1587      *            string with the package name to which returning generated type
1588      *            builder belongs
1589      * @param schemaNode
1590      *            schema node which provide data about the schema node name
1591      * @param prefix return type name prefix
1592      * @return generated type builder for <code>schemaNode</code>
1593      * @throws IllegalArgumentException
1594      *             <ul>
1595      *             <li>if <code>schemaNode</code> equals null</li>
1596      *             <li>if <code>packageName</code> equals null</li>
1597      *             <li>if Q name of schema node is null</li>
1598      *             <li>if schema node name is null</li>
1599      *             </ul>
1600      *
1601      */
1602     private def GeneratedTypeBuilder addRawInterfaceDefinition(String packageName, SchemaNode schemaNode,
1603         String prefix) {
1604         checkArgument(schemaNode !== null, "Data Schema Node cannot be NULL.");
1605         checkArgument(packageName !== null, "Package Name for Generated Type cannot be NULL.");
1606         checkArgument(schemaNode.QName !== null, "QName for Data Schema Node cannot be NULL.");
1607         val schemaNodeName = schemaNode.QName.localName;
1608         checkArgument(schemaNodeName !== null, "Local Name of QName for Data Schema Node cannot be NULL.");
1609
1610         var String genTypeName;
1611         if (prefix === null) {
1612             genTypeName = BindingMapping.getClassName(schemaNodeName);
1613         } else {
1614             genTypeName = prefix + BindingMapping.getClassName(schemaNodeName);
1615         }
1616
1617         //FIXME: Validation of name conflict
1618         val newType = new GeneratedTypeBuilderImpl(packageName, genTypeName);
1619         newType.addComment(schemaNode.getDescription());
1620         if (!genTypeBuilders.containsKey(packageName)) {
1621             val Map<String, GeneratedTypeBuilder> builders = new HashMap();
1622             builders.put(genTypeName, newType);
1623             genTypeBuilders.put(packageName, builders);
1624         } else {
1625             val Map<String, GeneratedTypeBuilder> builders = genTypeBuilders.get(packageName);
1626             if (!builders.containsKey(genTypeName)) {
1627                 builders.put(genTypeName, newType);
1628             }
1629         }
1630         return newType;
1631     }
1632
1633     /**
1634      * Creates the name of the getter method name from <code>localName</code>.
1635      *
1636      * @param localName
1637      *            string with the name of the getter method
1638      * @param returnType return type
1639      * @return string with the name of the getter method for
1640      *         <code>methodName</code> in JAVA method format
1641      */
1642     public static def String getterMethodName(String localName, Type returnType) {
1643         val method = new StringBuilder();
1644         if (BOOLEAN.equals(returnType)) {
1645             method.append("is");
1646         } else {
1647             method.append("get");
1648         }
1649         method.append(BindingMapping.getPropertyName(localName).toFirstUpper);
1650         return method.toString();
1651     }
1652
1653     /**
1654      * Created a method signature builder as part of
1655      * <code>interfaceBuilder</code>.
1656      *
1657      * The method signature builder is created for the getter method of
1658      * <code>schemaNodeName</code>. Also <code>comment</code> and
1659      * <code>returnType</code> information are added to the builder.
1660      *
1661      * @param interfaceBuilder
1662      *            generated type builder for which the getter method should be
1663      *            created
1664      * @param schemaNodeName
1665      *            string with schema node name. The name will be the part of the
1666      *            getter method name.
1667      * @param comment
1668      *            string with comment for the getter method
1669      * @param returnType
1670      *            type which represents the return type of the getter method
1671      * @return method signature builder which represents the getter method of
1672      *         <code>interfaceBuilder</code>
1673      */
1674     private def MethodSignatureBuilder constructGetter(GeneratedTypeBuilder interfaceBuilder, String schemaNodeName,
1675         String comment, Type returnType) {
1676         val getMethod = interfaceBuilder.addMethod(getterMethodName(schemaNodeName, returnType));
1677         getMethod.setComment(comment);
1678         getMethod.setReturnType(returnType);
1679         return getMethod;
1680     }
1681
1682     /**
1683      * Adds <code>schemaNode</code> to <code>typeBuilder</code> as getter method
1684      * or to <code>genTOBuilder</code> as property.
1685      *
1686      * @param basePackageName
1687      *            string contains the module package name
1688      * @param schemaNode
1689      *            data schema node which should be added as getter method to
1690      *            <code>typeBuilder</code> or as a property to
1691      *            <code>genTOBuilder</code> if is part of the list key
1692      * @param typeBuilder
1693      *            generated type builder for the list schema node
1694      * @param genTOBuilder
1695      *            generated TO builder for the list keys
1696      * @param listKeys
1697      *            list of string which contains names of the list keys
1698      * @param module current module
1699      * @throws IllegalArgumentException
1700      *             <ul>
1701      *             <li>if <code>schemaNode</code> equals null</li>
1702      *             <li>if <code>typeBuilder</code> equals null</li>
1703      *             </ul>
1704      */
1705     private def void addSchemaNodeToListBuilders(String basePackageName, DataSchemaNode schemaNode,
1706         GeneratedTypeBuilder typeBuilder, GeneratedTOBuilder genTOBuilder, List<String> listKeys, Module module) {
1707         checkArgument(schemaNode !== null, "Data Schema Node cannot be NULL.");
1708         checkArgument(typeBuilder !== null, "Generated Type Builder cannot be NULL.");
1709
1710         if (schemaNode instanceof LeafSchemaNode) {
1711             val leaf = schemaNode as LeafSchemaNode;
1712             val leafName = leaf.QName.localName;
1713             val Type type = resolveLeafSchemaNodeAsMethod(typeBuilder, leaf);
1714             if (listKeys.contains(leafName)) {
1715                 if (type == null) {
1716                     resolveLeafSchemaNodeAsProperty(genTOBuilder, leaf, true, module)
1717                 } else {
1718                     resolveLeafSchemaNodeAsProperty(genTOBuilder, leaf, type, true)
1719                 }
1720             }
1721         } else if (!schemaNode.addedByUses) {
1722             if (schemaNode instanceof LeafListSchemaNode) {
1723                 resolveLeafListSchemaNode(typeBuilder, schemaNode as LeafListSchemaNode);
1724             } else if (schemaNode instanceof ContainerSchemaNode) {
1725                 containerToGenType(module, basePackageName, typeBuilder, typeBuilder, schemaNode as ContainerSchemaNode);
1726             } else if (schemaNode instanceof ChoiceNode) {
1727                 choiceToGeneratedType(module, basePackageName, typeBuilder, schemaNode as ChoiceNode);
1728             } else if (schemaNode instanceof ListSchemaNode) {
1729                 listToGenType(module, basePackageName, typeBuilder, typeBuilder, schemaNode as ListSchemaNode);
1730             }
1731         }
1732     }
1733
1734     private def typeBuildersToGenTypes(Module module, GeneratedTypeBuilder typeBuilder, GeneratedTOBuilder genTOBuilder) {
1735         checkArgument(typeBuilder !== null, "Generated Type Builder cannot be NULL.");
1736
1737         if (genTOBuilder !== null) {
1738             val genTO = genTOBuilder.toInstance();
1739             constructGetter(typeBuilder, "key", "Returns Primary Key of Yang List Type", genTO);
1740             genCtx.get(module).addGeneratedTOBuilder(genTOBuilder)
1741         }
1742     }
1743
1744     /**
1745      * Selects the names of the list keys from <code>list</code> and returns
1746      * them as the list of the strings
1747      *
1748      * @param list
1749      *            of string with names of the list keys
1750      * @return list of string which represents names of the list keys. If the
1751      *         <code>list</code> contains no keys then the empty list is
1752      *         returned.
1753      */
1754     private def listKeys(ListSchemaNode list) {
1755         val List<String> listKeys = new ArrayList();
1756
1757         if (list.keyDefinition !== null) {
1758             val keyDefinitions = list.keyDefinition;
1759             for (keyDefinition : keyDefinitions) {
1760                 listKeys.add(keyDefinition.localName);
1761             }
1762         }
1763         return listKeys;
1764     }
1765
1766     /**
1767      * Generates for the <code>list</code> which contains any list keys special
1768      * generated TO builder.
1769      *
1770      * @param packageName
1771      *            string with package name to which the list belongs
1772      * @param list
1773      *            list schema node which is source of data about the list name
1774      * @return generated TO builder which represents the keys of the
1775      *         <code>list</code> or null if <code>list</code> is null or list of
1776      *         key definitions is null or empty.
1777      */
1778     private def GeneratedTOBuilder resolveListKeyTOBuilder(String packageName, ListSchemaNode list) {
1779         var GeneratedTOBuilder genTOBuilder = null;
1780         if ((list.keyDefinition !== null) && (!list.keyDefinition.isEmpty())) {
1781             val listName = list.QName.localName + "Key";
1782             val String genTOName = BindingMapping.getClassName(listName);
1783             genTOBuilder = new GeneratedTOBuilderImpl(packageName, genTOName);
1784         }
1785         return genTOBuilder;
1786     }
1787
1788     /**
1789      * Builds generated TO builders for <code>typeDef</code> of type
1790      * {@link org.opendaylight.yangtools.yang.model.util.UnionType UnionType} or
1791      * {@link org.opendaylight.yangtools.yang.model.api.type.BitsTypeDefinition
1792      * BitsTypeDefinition} which are also added to <code>typeBuilder</code> as
1793      * enclosing transfer object.
1794      *
1795      * If more then one generated TO builder is created for enclosing then all
1796      * of the generated TO builders are added to <code>typeBuilder</code> as
1797      * enclosing transfer objects.
1798      *
1799      * @param typeDef
1800      *            type definition which can be of type <code>UnionType</code> or
1801      *            <code>BitsTypeDefinition</code>
1802      * @param typeBuilder
1803      *            generated type builder to which is added generated TO created
1804      *            from <code>typeDef</code>
1805      * @param leafName
1806      *            string with name for generated TO builder
1807      * @param leaf
1808      * @param parentModule
1809      * @return generated TO builder for <code>typeDef</code>
1810      */
1811     private def GeneratedTOBuilder addTOToTypeBuilder(TypeDefinition<?> typeDef, GeneratedTypeBuilder typeBuilder,
1812         DataSchemaNode leaf, Module parentModule) {
1813         val classNameFromLeaf = BindingMapping.getClassName(leaf.QName);
1814         val List<GeneratedTOBuilder> genTOBuilders = new ArrayList();
1815         val packageName = typeBuilder.fullyQualifiedName;
1816         if (typeDef instanceof UnionTypeDefinition) {
1817             val List<GeneratedTOBuilder> types = (typeProvider as TypeProviderImpl).
1818                     provideGeneratedTOBuildersForUnionTypeDef(packageName, (typeDef as UnionTypeDefinition),
1819                         classNameFromLeaf, leaf);
1820             genTOBuilders.addAll(types);
1821
1822
1823         var GeneratedTOBuilder resultTOBuilder = null;
1824         if (!types.isEmpty()) {
1825             resultTOBuilder = types.remove(0);
1826             for (GeneratedTOBuilder genTOBuilder : types) {
1827                 resultTOBuilder.addEnclosingTransferObject(genTOBuilder);
1828             }
1829         }
1830
1831         val GeneratedPropertyBuilder genPropBuilder = resultTOBuilder.addProperty("value");
1832         genPropBuilder.setReturnType(Types.primitiveType("char[]", null));
1833         resultTOBuilder.addEqualsIdentity(genPropBuilder);
1834         resultTOBuilder.addHashIdentity(genPropBuilder);
1835         resultTOBuilder.addToStringProperty(genPropBuilder);
1836
1837         } else if (typeDef instanceof BitsTypeDefinition) {
1838             genTOBuilders.add(
1839                 ((typeProvider as TypeProviderImpl) ).
1840                     provideGeneratedTOBuilderForBitsTypeDefinition(packageName, typeDef, classNameFromLeaf));
1841         }
1842         if (genTOBuilders !== null && !genTOBuilders.isEmpty()) {
1843             for (genTOBuilder : genTOBuilders) {
1844                 typeBuilder.addEnclosingTransferObject(genTOBuilder);
1845             }
1846             return genTOBuilders.get(0);
1847         }
1848         return null;
1849
1850     }
1851
1852     /**
1853      * Adds the implemented types to type builder.
1854      *
1855      * The method passes through the list of <i>uses</i> in
1856      * {@code dataNodeContainer}. For every <i>use</i> is obtained corresponding
1857      * generated type from {@link BindingGeneratorImpl#allGroupings
1858      * allGroupings} which is added as <i>implements type</i> to
1859      * <code>builder</code>
1860      *
1861      * @param dataNodeContainer
1862      *            element which contains the list of used YANG groupings
1863      * @param builder
1864      *            builder to which are added implemented types according to
1865      *            <code>dataNodeContainer</code>
1866      * @return generated type builder with all implemented types
1867      */
1868     private def addImplementedInterfaceFromUses(DataNodeContainer dataNodeContainer, GeneratedTypeBuilder builder) {
1869         for (usesNode : dataNodeContainer.uses) {
1870             if (usesNode.groupingPath !== null) {
1871                 val genType = findGroupingByPath(usesNode.groupingPath).toInstance
1872                 if (genType === null) {
1873                     throw new IllegalStateException(
1874                         "Grouping " + usesNode.groupingPath + "is not resolved for " + builder.name);
1875                 }
1876                 builder.addImplementsType(genType);
1877                 builder.addComment(genType.getComment());
1878             }
1879         }
1880         return builder;
1881     }
1882
1883     private def GeneratedTypeBuilder findChildNodeByPath(SchemaPath path) {
1884         for (ctx : genCtx.values) {
1885             var result = ctx.getChildNode(path)
1886             if (result !== null) {
1887                 return result
1888             }
1889         }
1890         return null
1891     }
1892
1893     private def GeneratedTypeBuilder findGroupingByPath(SchemaPath path) {
1894         for (ctx : genCtx.values) {
1895             var result = ctx.getGrouping(path)
1896             if (result !== null) {
1897                 return result
1898             }
1899         }
1900         return null
1901     }
1902
1903     private def GeneratedTypeBuilder findCaseByPath(SchemaPath path) {
1904         for (ctx : genCtx.values) {
1905             var result = ctx.getCase(path)
1906             if (result !== null) {
1907                 return result
1908             }
1909         }
1910         return null
1911     }
1912
1913     public def getModuleContexts() {
1914         genCtx;
1915     }
1916
1917 }