code-generator/binding-generator-impl/src/main/java/org/opendaylight/yangtools/sal/binding/generator/impl/BindingGeneratorImpl.xtend

   1 /*
   2  * Copyright (c) 2013 Cisco Systems, Inc. and others.  All rights reserved.
   3  *
   4  * This program and the accompanying materials are made available under the
   5  * terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6  * and is available at http://www.eclipse.org/legal/epl-v10.html
   7  */
   8 package org.opendaylight.yangtools.sal.binding.generator.impl;
   9
  10 import static com.google.common.base.Preconditions.*;
  11 import static extension org.opendaylight.yangtools.binding.generator.util.Types.*;
  12 import static org.opendaylight.yangtools.binding.generator.util.BindingGeneratorUtil.*;
  13 import static org.opendaylight.yangtools.binding.generator.util.BindingTypes.*;
  14 import static org.opendaylight.yangtools.yang.model.util.SchemaContextUtil.*;
  15
  16 import java.util.ArrayList;
  17 import java.util.Collections;
  18 import java.util.HashMap;
  19 import java.util.List;
  20 import java.util.Map;
  21 import java.util.Set;
  22 import java.util.Iterator
  23 import java.util.Collection
  24 import org.opendaylight.yangtools.binding.generator.util.BindingTypes;
  25 import org.opendaylight.yangtools.binding.generator.util.ReferencedTypeImpl;
  26 import org.opendaylight.yangtools.binding.generator.util.Types;
  27 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedTOBuilderImpl;
  28 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedTypeBuilderImpl;
  29 import org.opendaylight.yangtools.sal.binding.generator.api.BindingGenerator;
  30 import org.opendaylight.yangtools.sal.binding.generator.spi.TypeProvider;
  31 import org.opendaylight.yangtools.sal.binding.model.api.AccessModifier;
  32 import org.opendaylight.yangtools.sal.binding.model.api.Type;
  33 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.EnumBuilder;
  34 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTOBuilder;
  35 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTypeBuilder;
  36 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.MethodSignatureBuilder;
  37 import org.opendaylight.yangtools.sal.binding.yang.types.GroupingDefinitionDependencySort;
  38 import org.opendaylight.yangtools.sal.binding.yang.types.TypeProviderImpl;
  39 import org.opendaylight.yangtools.yang.binding.RpcService;
  40 import org.opendaylight.yangtools.yang.common.RpcResult;
  41 import org.opendaylight.yangtools.yang.model.api.AugmentationSchema;
  42 import org.opendaylight.yangtools.yang.model.api.ChoiceCaseNode;
  43 import org.opendaylight.yangtools.yang.model.api.ChoiceNode;
  44 import org.opendaylight.yangtools.yang.model.api.ContainerSchemaNode;
  45 import org.opendaylight.yangtools.yang.model.api.DataNodeContainer;
  46 import org.opendaylight.yangtools.yang.model.api.DataSchemaNode;
  47 import org.opendaylight.yangtools.yang.model.api.GroupingDefinition;
  48 import org.opendaylight.yangtools.yang.model.api.IdentitySchemaNode;
  49 import org.opendaylight.yangtools.yang.model.api.LeafListSchemaNode;
  50 import org.opendaylight.yangtools.yang.model.api.LeafSchemaNode;
  51 import org.opendaylight.yangtools.yang.model.api.ListSchemaNode;
  52 import org.opendaylight.yangtools.yang.model.api.Module;
  53 import org.opendaylight.yangtools.yang.model.api.RpcDefinition;
  54 import org.opendaylight.yangtools.yang.model.api.SchemaContext;
  55 import org.opendaylight.yangtools.yang.model.api.SchemaNode;
  56 import org.opendaylight.yangtools.yang.model.api.SchemaPath;
  57 import org.opendaylight.yangtools.yang.model.api.TypeDefinition;
  58 import org.opendaylight.yangtools.yang.model.api.UnknownSchemaNode;
  59 import org.opendaylight.yangtools.yang.model.api.type.BitsTypeDefinition;
  60 import org.opendaylight.yangtools.yang.model.api.type.EnumTypeDefinition;
  61 import org.opendaylight.yangtools.yang.model.api.type.UnionTypeDefinition;
  62 import org.opendaylight.yangtools.yang.model.util.DataNodeIterator;
  63 import org.opendaylight.yangtools.yang.model.util.SchemaContextUtil;
  64 import org.opendaylight.yangtools.yang.model.util.UnionType;
  65 import org.opendaylight.yangtools.yang.parser.util.ModuleDependencySort
  66 import org.opendaylight.yangtools.yang.model.util.ExtendedType;
  67 import org.opendaylight.yangtools.yang.model.api.UsesNode
  68 import org.opendaylight.yangtools.yang.binding.annotations.RoutingContext
  69 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.AnnotationTypeBuilder
  70 import org.opendaylight.yangtools.yang.model.api.ModuleImport
  71 import org.opendaylight.yangtools.yang.binding.DataContainer
  72 import org.opendaylight.yangtools.yang.model.api.NotificationDefinition
  73 import org.opendaylight.yangtools.binding.generator.util.BindingGeneratorUtil
  74 import org.opendaylight.yangtools.sal.binding.model.api.Restrictions
  75 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedPropertyBuilder
  76 import org.opendaylight.yangtools.binding.generator.util.generated.type.builder.GeneratedPropertyBuilderImpl
  77 import org.opendaylight.yangtools.yang.common.QName
  78 import org.opendaylight.yangtools.yang.binding.BindingMapping
  79 import org.opendaylight.yangtools.sal.binding.model.api.type.builder.GeneratedTypeBuilderBase
  80
  81 import com.google.common.collect.Sets
  82
  83 public class BindingGeneratorImpl implements BindingGenerator {
  84
  85     private final Map<Module, ModuleContext> genCtx = new HashMap()
  86
  87     /**
  88      * Outer key represents the package name. Outer value represents map of
  89      * all builders in the same package. Inner key represents the schema node
  90      * name (in JAVA class/interface name format). Inner value represents
  91      * instance of builder for schema node specified in key part.
  92      */
  93     private Map<String, Map<String, GeneratedTypeBuilder>> genTypeBuilders;
  94
  95     /**
  96      * Provide methods for converting YANG types to JAVA types.
  97      */
  98     private var TypeProvider typeProvider;
  99
 100     /**
 101      * Holds reference to schema context to resolve data of augmented element
 102      * when creating augmentation builder
 103      */
 104     private var SchemaContext schemaContext;
 105
 106     /**
 107      * Constant with the concrete name of namespace.
 108      */
 109     private val static String YANG_EXT_NAMESPACE = "urn:opendaylight:yang:extension:yang-ext";
 110
 111     /**
 112      * Constant with the concrete name of identifier.
 113      */
 114     private val static String AUGMENT_IDENTIFIER_NAME = "augment-identifier";
 115
 116     /**
 117      * Resolves generated types from <code>context</code> schema nodes of all
 118      * modules.
 119      *
 120      * Generated types are created for modules, groupings, types, containers,
 121      * lists, choices, augments, rpcs, notification, identities.
 122      *
 123      * @param context
 124      *            schema context which contains data about all schema nodes
 125      *            saved in modules
 126      * @return list of types (usually <code>GeneratedType</code>
 127      *         <code>GeneratedTransferObject</code>which are generated from
 128      *         <code>context</code> data.
 129      * @throws IllegalArgumentException
 130      *             if param <code>context</code> is null
 131      * @throws IllegalStateException
 132      *             if <code>context</code> contain no modules
 133      */
 134     override generateTypes(SchemaContext context) {
 135         checkArgument(context !== null, "Schema Context reference cannot be NULL.");
 136         checkState(context.modules !== null, "Schema Context does not contain defined modules.");
 137         schemaContext = context;
 138         typeProvider = new TypeProviderImpl(context);
 139         val Set<Module> modules = context.modules;
 140         return generateTypes(context, modules);
 141     }
 142
 143     /**
 144      * Resolves generated types from <code>context</code> schema nodes only for
 145      * modules specified in <code>modules</code>
 146      *
 147      * Generated types are created for modules, groupings, types, containers,
 148      * lists, choices, augments, rpcs, notification, identities.
 149      *
 150      * @param context
 151      *            schema context which contains data about all schema nodes
 152      *            saved in modules
 153      * @param modules
 154      *            set of modules for which schema nodes should be generated
 155      *            types
 156      * @return list of types (usually <code>GeneratedType</code> or
 157      *         <code>GeneratedTransferObject</code>) which:
 158      *         <ul>
 159      *         <li>are generated from <code>context</code> schema nodes and</li>
 160      *         <li>are also part of some of the module in <code>modules</code>
 161      *         set</li>.
 162      *         </ul>
 163      * @throws IllegalArgumentException
 164      *             <ul>
 165      *             <li>if param <code>context</code> is null or</li>
 166      *             <li>if param <code>modules</code> is null</li>
 167      *             </ul>
 168      * @throws IllegalStateException
 169      *             if <code>context</code> contain no modules
 170      */
 171     override generateTypes(SchemaContext context, Set<Module> modules) {
 172         checkArgument(context !== null, "Schema Context reference cannot be NULL.");
 173         checkState(context.modules !== null, "Schema Context does not contain defined modules.");
 174         checkArgument(modules !== null, "Set of Modules cannot be NULL.");
 175
 176         schemaContext = context;
 177         typeProvider = new TypeProviderImpl(context);
 178         val contextModules = ModuleDependencySort.sort(context.modules);
 179         genTypeBuilders = new HashMap();
 180
 181         for (contextModule : contextModules) {
 182             moduleToGenTypes(contextModule, context);
 183         }
 184         for (contextModule : contextModules) {
 185             allAugmentsToGenTypes(contextModule);
 186         }
 187
 188         val List<Type> filteredGenTypes = new ArrayList();
 189         for (Module m : modules) {
 190             val ctx = checkNotNull(genCtx.get(m), "Module context not found for module %s", m)
 191             filteredGenTypes.addAll(ctx.generatedTypes);
 192             val Set<Type> additionalTypes = (typeProvider as TypeProviderImpl).additionalTypes.get(m)
 193             if (additionalTypes != null) {
 194                 filteredGenTypes.addAll(additionalTypes)
 195             }
 196         }
 197
 198         return filteredGenTypes;
 199     }
 200
 201     private def void moduleToGenTypes(Module m, SchemaContext context) {
 202         genCtx.put(m, new ModuleContext)
 203         allTypeDefinitionsToGenTypes(m)
 204         groupingsToGenTypes(m, m.groupings)
 205         rpcMethodsToGenType(m)
 206         allIdentitiesToGenTypes(m, context)
 207         notificationsToGenType(m)
 208
 209         if (!m.childNodes.isEmpty()) {
 210             val moduleType = moduleToDataType(m)
 211             genCtx.get(m).addModuleNode(moduleType)
 212             val basePackageName = moduleNamespaceToPackageName(m);
 213             resolveDataSchemaNodes(m, basePackageName, moduleType, moduleType, m.childNodes)
 214         }
 215     }
 216
 217     /**
 218      * Converts all extended type definitions of module to the list of
 219      * <code>Type</code> objects.
 220      *
 221      * @param module
 222      *            module from which is obtained set of type definitions
 223      * @throws IllegalArgumentException
 224      *             <ul>
 225      *             <li>if module equals null</li>
 226      *             <li>if name of module equals null</li>
 227      *             <li>if type definitions of module equal null</li>
 228      *             </ul>
 229      *
 230      */
 231     private def void allTypeDefinitionsToGenTypes(Module module) {
 232         checkArgument(module !== null, "Module reference cannot be NULL.");
 233         checkArgument(module.name !== null, "Module name cannot be NULL.");
 234         val it = new DataNodeIterator(module);
 235         val List<TypeDefinition<?>> typeDefinitions = it.allTypedefs;
 236         checkState(typeDefinitions !== null, '''Type Definitions for module «module.name» cannot be NULL.''');
 237
 238         for (TypeDefinition<?> typedef : typeDefinitions) {
 239             if (typedef !== null) {
 240                 val type = (typeProvider as TypeProviderImpl).generatedTypeForExtendedDefinitionType(typedef, typedef);
 241                 if (type !== null) {
 242                     genCtx.get(module).addTypedefType(typedef.path, type)
 243                 }
 244             }
 245         }
 246     }
 247
 248     private def GeneratedTypeBuilder processDataSchemaNode(Module module, String basePackageName,
 249         GeneratedTypeBuilder parent, GeneratedTypeBuilder childOf, DataSchemaNode node) {
 250         if (node.augmenting || node.addedByUses) {
 251             return null
 252         }
 253         val packageName = packageNameForGeneratedType(basePackageName, node.path)
 254         val genType = addDefaultInterfaceDefinition(packageName, node, childOf)
 255         if (node instanceof DataNodeContainer) {
 256             genCtx.get(module).addChildNodeType(node.path, genType)
 257             groupingsToGenTypes(module, (node as DataNodeContainer).groupings)
 258             processUsesAugments(node as DataNodeContainer, module)
 259         }
 260         return genType
 261     }
 262
 263     private def void containerToGenType(Module module, String basePackageName, GeneratedTypeBuilder parent,
 264         GeneratedTypeBuilder childOf, ContainerSchemaNode node) {
 265         val genType = processDataSchemaNode(module, basePackageName, parent, childOf, node)
 266         if (genType != null) {
 267             constructGetter(parent, node.QName.localName, node.description, genType)
 268             resolveDataSchemaNodes(module, basePackageName, genType, genType, node.childNodes)
 269         }
 270     }
 271
 272     private def void listToGenType(Module module, String basePackageName, GeneratedTypeBuilder parent,
 273         GeneratedTypeBuilder childOf, ListSchemaNode node) {
 274         val genType = processDataSchemaNode(module, basePackageName, parent, childOf, node)
 275         if (genType != null) {
 276             constructGetter(parent, node.QName.localName, node.description, Types.listTypeFor(genType))
 277
 278             val List<String> listKeys = listKeys(node);
 279             val packageName = packageNameForGeneratedType(basePackageName, (node).path)
 280             val genTOBuilder = resolveListKeyTOBuilder(packageName, node);
 281             if (genTOBuilder !== null) {
 282                 val identifierMarker = IDENTIFIER.parameterizedTypeFor(genType);
 283                 val identifiableMarker = IDENTIFIABLE.parameterizedTypeFor(genTOBuilder);
 284                 genTOBuilder.addImplementsType(identifierMarker);
 285                 genType.addImplementsType(identifiableMarker);
 286             }
 287
 288             for (schemaNode : node.childNodes) {
 289                 if (!schemaNode.augmenting) {
 290                     addSchemaNodeToListBuilders(basePackageName, schemaNode, genType, genTOBuilder, listKeys, module);
 291                 }
 292             }
 293
 294             // serialVersionUID
 295             if (genTOBuilder !== null) {
 296                 val GeneratedPropertyBuilder prop = new GeneratedPropertyBuilderImpl("serialVersionUID");
 297                 prop.setValue(Long.toString(computeDefaultSUID(genTOBuilder as GeneratedTOBuilderImpl)));
 298                 genTOBuilder.setSUID(prop);
 299             }
 300
 301             typeBuildersToGenTypes(module, genType, genTOBuilder);
 302         }
 303     }
 304
 305     private def void processUsesAugments(DataNodeContainer node, Module module) {
 306         val basePackageName = moduleNamespaceToPackageName(module);
 307         for (usesNode : node.uses) {
 308             for (augment : usesNode.augmentations) {
 309                 usesAugmentationToGenTypes(basePackageName, augment, module, usesNode, node);
 310                 processUsesAugments(augment, module);
 311             }
 312         }
 313     }
 314
 315     /**
 316      * Converts all <b>augmentation</b> of the module to the list
 317      * <code>Type</code> objects.
 318      *
 319      * @param module
 320      *            module from which is obtained list of all augmentation objects
 321      *            to iterate over them
 322      * @throws IllegalArgumentException
 323      *             <ul>
 324      *             <li>if the module equals null</li>
 325      *             <li>if the name of module equals null</li>
 326      *             <li>if the set of child nodes equals null</li>
 327      *             </ul>
 328      *
 329      */
 330     private def void allAugmentsToGenTypes(Module module) {
 331         checkArgument(module !== null, "Module reference cannot be NULL.");
 332         checkArgument(module.name !== null, "Module name cannot be NULL.");
 333         if (module.childNodes === null) {
 334             throw new IllegalArgumentException(
 335                 "Reference to Set of Augmentation Definitions in module " + module.name + " cannot be NULL.");
 336         }
 337
 338         val basePackageName = moduleNamespaceToPackageName(module);
 339         val List<AugmentationSchema> augmentations = resolveAugmentations(module);
 340         for (augment : augmentations) {
 341             augmentationToGenTypes(basePackageName, augment, module);
 342         }
 343     }
 344
 345     /**
 346      * Returns list of <code>AugmentationSchema</code> objects. The objects are
 347      * sorted according to the length of their target path from the shortest to
 348      * the longest.
 349      *
 350      * @param module
 351      *            module from which is obtained list of all augmentation objects
 352      * @return list of sorted <code>AugmentationSchema</code> objects obtained
 353      *         from <code>module</code>
 354      * @throws IllegalArgumentException
 355      *             <ul>
 356      *             <li>if the module equals null</li>
 357      *             <li>if the set of augmentation equals null</li>
 358      *             </ul>
 359      *
 360      */
 361     private def List<AugmentationSchema> resolveAugmentations(Module module) {
 362         checkArgument(module !== null, "Module reference cannot be NULL.");
 363         checkState(module.augmentations !== null, "Augmentations Set cannot be NULL.");
 364
 365         val Set<AugmentationSchema> augmentations = module.augmentations;
 366         val List<AugmentationSchema> sortedAugmentations = new ArrayList(augmentations);
 367         Collections.sort(sortedAugmentations,
 368             [ augSchema1, augSchema2 |
 369                 if (augSchema1.targetPath.path.size() > augSchema2.targetPath.path.size()) {
 370                     return 1;
 371                 } else if (augSchema1.targetPath.path.size() < augSchema2.targetPath.path.size()) {
 372                     return -1;
 373                 }
 374                 return 0;
 375             ]);
 376         return sortedAugmentations;
 377     }
 378
 379     /**
 380      * Converts whole <b>module</b> to <code>GeneratedType</code> object.
 381      * Firstly is created the module builder object from which is vally
 382      * obtained reference to <code>GeneratedType</code> object.
 383      *
 384      * @param module
 385      *            module from which are obtained the module name, child nodes,
 386      *            uses and is derived package name
 387      * @return <code>GeneratedType</code> which is internal representation of
 388      *         the module
 389      * @throws IllegalArgumentException
 390      *             if the module equals null
 391      *
 392      */
 393     private def GeneratedTypeBuilder moduleToDataType(Module module) {
 394         checkArgument(module !== null, "Module reference cannot be NULL.");
 395
 396         val moduleDataTypeBuilder = moduleTypeBuilder(module, "Data");
 397         addImplementedInterfaceFromUses(module, moduleDataTypeBuilder);
 398         moduleDataTypeBuilder.addImplementsType(DATA_ROOT);
 399         return moduleDataTypeBuilder;
 400     }
 401
 402     /**
 403      * Converts all <b>rpcs</b> inputs and outputs substatements of the module
 404      * to the list of <code>Type</code> objects. In addition are to containers
 405      * and lists which belong to input or output also part of returning list.
 406      *
 407      * @param module
 408      *            module from which is obtained set of all rpc objects to
 409      *            iterate over them
 410      * @throws IllegalArgumentException
 411      *             <ul>
 412      *             <li>if the module equals null</li>
 413      *             <li>if the name of module equals null</li>
 414      *             <li>if the set of child nodes equals null</li>
 415      *             </ul>
 416      *
 417      */
 418     private def void rpcMethodsToGenType(Module module) {
 419         checkArgument(module !== null, "Module reference cannot be NULL.");
 420         checkArgument(module.name !== null, "Module name cannot be NULL.");
 421         checkArgument(module.childNodes !== null,
 422             "Reference to Set of RPC Method Definitions in module " + module.name + " cannot be NULL.");
 423
 424         val basePackageName = moduleNamespaceToPackageName(module);
 425         val Set<RpcDefinition> rpcDefinitions = module.rpcs;
 426         if (rpcDefinitions.isEmpty()) {
 427             return;
 428         }
 429
 430         val interfaceBuilder = moduleTypeBuilder(module, "Service");
 431         interfaceBuilder.addImplementsType(Types.typeForClass(RpcService));
 432         for (rpc : rpcDefinitions) {
 433             if (rpc !== null) {
 434                 val rpcName = BindingMapping.getClassName(rpc.QName);
 435                 val rpcMethodName = parseToValidParamName(rpcName);
 436                 val method = interfaceBuilder.addMethod(rpcMethodName);
 437                 val input = rpc.input;
 438                 val output = rpc.output;
 439
 440                 if (input !== null) {
 441                     val inType = addRawInterfaceDefinition(basePackageName, input, rpcName);
 442                     addImplementedInterfaceFromUses(input, inType);
 443                     inType.addImplementsType(DATA_OBJECT);
 444                     inType.addImplementsType(augmentable(inType));
 445                     resolveDataSchemaNodes(module, basePackageName, inType, inType, input.childNodes);
 446                     genCtx.get(module).addChildNodeType(input.path, inType)
 447                     val inTypeInstance = inType.toInstance();
 448                     method.addParameter(inTypeInstance, "input");
 449                 }
 450
 451                 var Type outTypeInstance = VOID;
 452                 if (output !== null) {
 453                     val outType = addRawInterfaceDefinition(basePackageName, output, rpcName);
 454                     addImplementedInterfaceFromUses(output, outType);
 455                     outType.addImplementsType(DATA_OBJECT);
 456                     outType.addImplementsType(augmentable(outType));
 457                     resolveDataSchemaNodes(module, basePackageName, outType, outType, output.childNodes);
 458                     genCtx.get(module).addChildNodeType(output.path, outType)
 459                     outTypeInstance = outType.toInstance();
 460                 }
 461
 462                 val rpcRes = Types.parameterizedTypeFor(Types.typeForClass(RpcResult), outTypeInstance);
 463                 method.setReturnType(Types.parameterizedTypeFor(FUTURE, rpcRes));
 464             }
 465         }
 466
 467         genCtx.get(module).addTopLevelNodeType(interfaceBuilder)
 468     }
 469
 470     /**
 471      * Converts all <b>notifications</b> of the module to the list of
 472      * <code>Type</code> objects. In addition are to this list added containers
 473      * and lists which are part of this notification.
 474      *
 475      * @param module
 476      *            module from which is obtained set of all notification objects
 477      *            to iterate over them
 478      * @throws IllegalArgumentException
 479      *             <ul>
 480      *             <li>if the module equals null</li>
 481      *             <li>if the name of module equals null</li>
 482      *             <li>if the set of child nodes equals null</li>
 483      *             </ul>
 484      *
 485      */
 486     private def void notificationsToGenType(Module module) {
 487         checkArgument(module !== null, "Module reference cannot be NULL.");
 488         checkArgument(module.name !== null, "Module name cannot be NULL.");
 489
 490         if (module.childNodes === null) {
 491             throw new IllegalArgumentException(
 492                 "Reference to Set of Notification Definitions in module " + module.name + " cannot be NULL.");
 493         }
 494         val notifications = module.notifications;
 495         if(notifications.empty) return;
 496
 497         val listenerInterface = moduleTypeBuilder(module, "Listener");
 498         listenerInterface.addImplementsType(BindingTypes.NOTIFICATION_LISTENER);
 499         val basePackageName = moduleNamespaceToPackageName(module);
 500
 501         for (notification : notifications) {
 502             if (notification !== null) {
 503                 processUsesAugments(notification, module);
 504
 505                 val notificationInterface = addDefaultInterfaceDefinition(basePackageName, notification,
 506                     BindingTypes.DATA_OBJECT);
 507                 notificationInterface.addImplementsType(NOTIFICATION);
 508                 genCtx.get(module).addChildNodeType(notification.path, notificationInterface)
 509
 510                 // Notification object
 511                 resolveDataSchemaNodes(module, basePackageName, notificationInterface, notificationInterface,
 512                     notification.childNodes);
 513
 514                 listenerInterface.addMethod("on" + notificationInterface.name) //
 515                 .setAccessModifier(AccessModifier.PUBLIC).addParameter(notificationInterface, "notification").
 516                     setReturnType(Types.VOID);
 517             }
 518         }
 519
 520         genCtx.get(module).addTopLevelNodeType(listenerInterface)
 521     }
 522
 523     /**
 524      * Converts all <b>identities</b> of the module to the list of
 525      * <code>Type</code> objects.
 526      *
 527      * @param module
 528      *            module from which is obtained set of all identity objects to
 529      *            iterate over them
 530      * @param context
 531      *            schema context only used as input parameter for method
 532      *            {@link identityToGenType}
 533      *
 534      */
 535     private def void allIdentitiesToGenTypes(Module module, SchemaContext context) {
 536         val Set<IdentitySchemaNode> schemaIdentities = module.identities;
 537         val basePackageName = moduleNamespaceToPackageName(module);
 538
 539         if (schemaIdentities !== null && !schemaIdentities.isEmpty()) {
 540             for (identity : schemaIdentities) {
 541                 identityToGenType(module, basePackageName, identity, context);
 542             }
 543         }
 544     }
 545
 546     /**
 547      * Converts the <b>identity</b> object to GeneratedType. Firstly it is
 548      * created transport object builder. If identity contains base identity then
 549      * reference to base identity is added to superior identity as its extend.
 550      * If identity doesn't contain base identity then only reference to abstract
 551      * class {@link org.opendaylight.yangtools.yang.model.api.BaseIdentity
 552      * BaseIdentity} is added
 553      *
 554      * @param module current module
 555      * @param basePackageName
 556      *            string contains the module package name
 557      * @param identity
 558      *            IdentitySchemaNode which contains data about identity
 559      * @param context
 560      *            SchemaContext which is used to get package and name
 561      *            information about base of identity
 562      *
 563      */
 564     private def void identityToGenType(Module module, String basePackageName, IdentitySchemaNode identity,
 565         SchemaContext context) {
 566         if (identity === null) {
 567             return;
 568         }
 569         val packageName = packageNameForGeneratedType(basePackageName, identity.path);
 570         val genTypeName = BindingMapping.getClassName(identity.QName);
 571         val newType = new GeneratedTOBuilderImpl(packageName, genTypeName);
 572         val baseIdentity = identity.baseIdentity;
 573         if (baseIdentity === null) {
 574             newType.setExtendsType(Types.baseIdentityTO);
 575         } else {
 576             val baseIdentityParentModule = SchemaContextUtil.findParentModule(context, baseIdentity);
 577             val returnTypePkgName = moduleNamespaceToPackageName(baseIdentityParentModule);
 578             val returnTypeName = BindingMapping.getClassName(baseIdentity.QName);
 579             val gto = new GeneratedTOBuilderImpl(returnTypePkgName, returnTypeName).toInstance();
 580             newType.setExtendsType(gto);
 581         }
 582         newType.setAbstract(true);
 583         val qname = identity.QName;
 584
 585         newType.qnameConstant(BindingMapping.QNAME_STATIC_FIELD_NAME,qname);
 586
 587         genCtx.get(module).addIdentityType(identity.QName,newType)
 588     }
 589
 590     private static def qnameConstant(GeneratedTypeBuilderBase<?> toBuilder, String constantName, QName name) {
 591         toBuilder.addConstant(QName.typeForClass,constantName,'''
 592             org.opendaylight.yangtools.yang.common.QName.create("«name.namespace»","«name.formattedRevision»","«name.localName»")
 593         ''');
 594     }
 595
 596     /**
 597      * Converts all <b>groupings</b> of the module to the list of
 598      * <code>Type</code> objects. Firstly are groupings sorted according mutual
 599      * dependencies. At least dependent (independent) groupings are in the list
 600      * saved at first positions. For every grouping the record is added to map
 601      * {@link BindingGeneratorImpl#allGroupings allGroupings}
 602      *
 603      * @param module
 604      *            current module
 605      * @param collection of groupings from which types will be generated
 606      *
 607      */
 608     private def void groupingsToGenTypes(Module module, Collection<GroupingDefinition> groupings) {
 609         val basePackageName = moduleNamespaceToPackageName(module);
 610         val List<GroupingDefinition> groupingsSortedByDependencies = new GroupingDefinitionDependencySort().sort(
 611             groupings);
 612         for (grouping : groupingsSortedByDependencies) {
 613             groupingToGenType(basePackageName, grouping, module);
 614         }
 615     }
 616
 617     /**
 618      * Converts individual grouping to GeneratedType. Firstly generated type
 619      * builder is created and every child node of grouping is resolved to the
 620      * method.
 621      *
 622      * @param basePackageName
 623      *            string contains the module package name
 624      * @param grouping
 625      *            GroupingDefinition which contains data about grouping
 626      * @param module current module
 627      * @return GeneratedType which is generated from grouping (object of type
 628      *         <code>GroupingDefinition</code>)
 629      */
 630     private def void groupingToGenType(String basePackageName, GroupingDefinition grouping, Module module) {
 631         val packageName = packageNameForGeneratedType(basePackageName, grouping.path);
 632         val genType = addDefaultInterfaceDefinition(packageName, grouping);
 633         genCtx.get(module).addGroupingType(grouping.path, genType)
 634         resolveDataSchemaNodes(module, basePackageName, genType, genType, grouping.childNodes);
 635         groupingsToGenTypes(module, grouping.groupings);
 636         processUsesAugments(grouping, module);
 637     }
 638
 639     /**
 640      * Tries to find EnumTypeDefinition in <code>typeDefinition</code>. If base
 641      * type of <code>typeDefinition</code> is of the type ExtendedType then this
 642      * method is recursively called with this base type.
 643      *
 644      * @param typeDefinition
 645      *            TypeDefinition in which should be EnumTypeDefinition found as
 646      *            base type
 647      * @return EnumTypeDefinition if it is found inside
 648      *         <code>typeDefinition</code> or <code>null</code> in other case
 649      */
 650     private def EnumTypeDefinition enumTypeDefFromExtendedType(TypeDefinition<?> typeDefinition) {
 651         if (typeDefinition !== null) {
 652             if (typeDefinition.baseType instanceof EnumTypeDefinition) {
 653                 return typeDefinition.baseType as EnumTypeDefinition;
 654             } else if (typeDefinition.baseType instanceof ExtendedType) {
 655                 return enumTypeDefFromExtendedType(typeDefinition.baseType);
 656             }
 657         }
 658         return null;
 659     }
 660
 661     /**
 662      * Adds enumeration builder created from <code>enumTypeDef</code> to
 663      * <code>typeBuilder</code>.
 664      *
 665      * Each <code>enumTypeDef</code> item is added to builder with its name and
 666      * value.
 667      *
 668      * @param enumTypeDef
 669      *            EnumTypeDefinition contains enum data
 670      * @param enumName
 671      *            string contains name which will be assigned to enumeration
 672      *            builder
 673      * @param typeBuilder
 674      *            GeneratedTypeBuilder to which will be enum builder assigned
 675      * @return enumeration builder which contains data from
 676      *         <code>enumTypeDef</code>
 677      */
 678     private def EnumBuilder resolveInnerEnumFromTypeDefinition(EnumTypeDefinition enumTypeDef, QName enumName,
 679         GeneratedTypeBuilder typeBuilder) {
 680         if ((enumTypeDef !== null) && (typeBuilder !== null) && (enumTypeDef.QName !== null) &&
 681             (enumTypeDef.QName.localName !== null)) {
 682             val enumerationName = BindingMapping.getClassName(enumName);
 683             val enumBuilder = typeBuilder.addEnumeration(enumerationName);
 684             enumBuilder.updateEnumPairsFromEnumTypeDef(enumTypeDef);
 685             return enumBuilder;
 686         }
 687         return null;
 688     }
 689
 690     /**
 691      * Generates type builder for <code>module</code>.
 692      *
 693      * @param module
 694      *            Module which is source of package name for generated type
 695      *            builder
 696      * @param postfix
 697      *            string which is added to the module class name representation
 698      *            as suffix
 699      * @return instance of GeneratedTypeBuilder which represents
 700      *         <code>module</code>.
 701      * @throws IllegalArgumentException
 702      *             if <code>module</code> equals null
 703      */
 704     private def GeneratedTypeBuilder moduleTypeBuilder(Module module, String postfix) {
 705         checkArgument(module !== null, "Module reference cannot be NULL.");
 706         val packageName = moduleNamespaceToPackageName(module);
 707         val moduleName = BindingMapping.getClassName(module.name) + postfix;
 708         return new GeneratedTypeBuilderImpl(packageName, moduleName);
 709     }
 710
 711     /**
 712      * Converts <code>augSchema</code> to list of <code>Type</code> which
 713      * contains generated type for augmentation. In addition there are also
 714      * generated types for all containers, list and choices which are child of
 715      * <code>augSchema</code> node or a generated types for cases are added if
 716      * augmented node is choice.
 717      *
 718      * @param augmentPackageName
 719      *            string with the name of the package to which the augmentation
 720      *            belongs
 721      * @param augSchema
 722      *            AugmentationSchema which is contains data about augmentation
 723      *            (target path, childs...)
 724      * @param module current module
 725      * @param parentUsesNode parent uses node of this augment (can be null if this augment is not defined under uses statement)
 726      * @throws IllegalArgumentException
 727      *             <ul>
 728      *             <li>if <code>augmentPackageName</code> equals null</li>
 729      *             <li>if <code>augSchema</code> equals null</li>
 730      *             <li>if target path of <code>augSchema</code> equals null</li>
 731      *             </ul>
 732      */
 733     private def void augmentationToGenTypes(String augmentPackageName, AugmentationSchema augSchema, Module module) {
 734         checkArgument(augmentPackageName !== null, "Package Name cannot be NULL.");
 735         checkArgument(augSchema !== null, "Augmentation Schema cannot be NULL.");
 736         checkState(augSchema.targetPath !== null,
 737             "Augmentation Schema does not contain Target Path (Target Path is NULL).");
 738
 739         processUsesAugments(augSchema, module);
 740         val targetPath = augSchema.targetPath;
 741         var SchemaNode targetSchemaNode = null
 742
 743         targetSchemaNode = findDataSchemaNode(schemaContext, targetPath);
 744         if (targetSchemaNode instanceof DataSchemaNode && (targetSchemaNode as DataSchemaNode).isAddedByUses()) {
 745             targetSchemaNode = findOriginal(targetSchemaNode as DataSchemaNode, schemaContext);
 746             if (targetSchemaNode == null) {
 747                 throw new NullPointerException(
 748                     "Failed to find target node from grouping in augmentation " + augSchema + " in module " +
 749                         module.name);
 750             }
 751         }
 752         if (targetSchemaNode == null) {
 753             throw new IllegalArgumentException("augment target not found: " + targetPath)
 754         }
 755
 756         var targetTypeBuilder = findChildNodeByPath(targetSchemaNode.path)
 757         if (targetTypeBuilder === null) {
 758             targetTypeBuilder = findCaseByPath(targetSchemaNode.path)
 759         }
 760         if (targetTypeBuilder === null) {
 761             throw new NullPointerException("Target type not yet generated: " + targetSchemaNode);
 762         }
 763
 764         if (!(targetSchemaNode instanceof ChoiceNode)) {
 765             var packageName = augmentPackageName;
 766             val augTypeBuilder = addRawAugmentGenTypeDefinition(module, packageName, augmentPackageName,
 767                 targetTypeBuilder.toInstance, augSchema);
 768             genCtx.get(module).addAugmentType(augTypeBuilder)
 769             genCtx.get(module).addTypeToAugmentation(augTypeBuilder, augSchema);
 770         } else {
 771             generateTypesFromAugmentedChoiceCases(module, augmentPackageName, targetTypeBuilder.toInstance,
 772                 targetSchemaNode as ChoiceNode, augSchema.childNodes);
 773         }
 774     }
 775
 776     private def void usesAugmentationToGenTypes(String augmentPackageName, AugmentationSchema augSchema, Module module,
 777         UsesNode usesNode, DataNodeContainer usesNodeParent) {
 778         checkArgument(augmentPackageName !== null, "Package Name cannot be NULL.");
 779         checkArgument(augSchema !== null, "Augmentation Schema cannot be NULL.");
 780         checkState(augSchema.targetPath !== null,
 781             "Augmentation Schema does not contain Target Path (Target Path is NULL).");
 782
 783         processUsesAugments(augSchema, module);
 784         val targetPath = augSchema.targetPath;
 785         var SchemaNode targetSchemaNode = null
 786         targetSchemaNode = findOriginalTargetFromGrouping(targetPath, usesNode);
 787         if (targetSchemaNode == null) {
 788             throw new IllegalArgumentException("augment target not found: " + targetPath)
 789         }
 790
 791         var targetTypeBuilder = findChildNodeByPath(targetSchemaNode.path)
 792         if (targetTypeBuilder === null) {
 793             targetTypeBuilder = findCaseByPath(targetSchemaNode.path)
 794         }
 795         if (targetTypeBuilder === null) {
 796             throw new NullPointerException("Target type not yet generated: " + targetSchemaNode);
 797         }
 798
 799         if (!(targetSchemaNode instanceof ChoiceNode)) {
 800             var packageName = augmentPackageName;
 801             if (usesNodeParent instanceof SchemaNode) {
 802                 packageName = packageNameForGeneratedType(augmentPackageName, (usesNodeParent as SchemaNode).path, true)
 803             }
 804             val augTypeBuilder = addRawAugmentGenTypeDefinition(module, packageName, augmentPackageName,
 805                 targetTypeBuilder.toInstance, augSchema);
 806             genCtx.get(module).addAugmentType(augTypeBuilder)
 807             genCtx.get(module).addTypeToAugmentation(augTypeBuilder, augSchema);
 808         } else {
 809             generateTypesFromAugmentedChoiceCases(module, augmentPackageName, targetTypeBuilder.toInstance,
 810                 targetSchemaNode as ChoiceNode, augSchema.childNodes);
 811         }
 812     }
 813
 814     /**
 815      * Convenient method to find node added by uses statement.
 816      */
 817     private def DataSchemaNode findOriginalTargetFromGrouping(SchemaPath targetPath, UsesNode parentUsesNode) {
 818         var SchemaNode targetGrouping = findNodeInSchemaContext(schemaContext, parentUsesNode.groupingPath.path);
 819         if (!(targetGrouping instanceof GroupingDefinition)) {
 820             throw new IllegalArgumentException("Failed to generate code for augment in " + parentUsesNode);
 821         }
 822
 823         var grouping = targetGrouping as GroupingDefinition;
 824         var SchemaNode result = grouping;
 825         val List<QName> path = targetPath.path
 826         for (node : path) {
 827             // finding by local name is valid, grouping cannot contain nodes with same name and different namespace
 828             if (result instanceof DataNodeContainer) {
 829                 result = (result as DataNodeContainer).getDataChildByName(node.localName)
 830             } else if (result instanceof ChoiceNode) {
 831                 result = (result as ChoiceNode).getCaseNodeByName(node.localName)
 832             }
 833         }
 834         if (result == null) {
 835             return null;
 836         }
 837
 838         val String targetSchemaNodeName = result.QName.localName;
 839         var boolean fromUses = (result as DataSchemaNode).addedByUses
 840         var Iterator<UsesNode> groupingUses = grouping.uses.iterator;
 841         while (fromUses) {
 842             if (groupingUses.hasNext()) {
 843                 grouping = findNodeInSchemaContext(schemaContext, groupingUses.next().groupingPath.path) as GroupingDefinition;
 844                 result = grouping.getDataChildByName(targetSchemaNodeName);
 845                 fromUses = (result as DataSchemaNode).addedByUses;
 846             } else {
 847                 throw new NullPointerException("Failed to generate code for augment in " + parentUsesNode);
 848             }
 849         }
 850
 851         return result as DataSchemaNode
 852     }
 853
 854     /**
 855      * Returns a generated type builder for an augmentation.
 856      *
 857      * The name of the type builder is equal to the name of augmented node with
 858      * serial number as suffix.
 859      *
 860      * @param module current module
 861      * @param augmentPackageName
 862      *            string with contains the package name to which the augment
 863      *            belongs
 864      * @param basePackageName
 865      *            string with the package name to which the augmented node
 866      *            belongs
 867      * @param targetTypeRef
 868      *            target type
 869      * @param augSchema
 870      *            augmentation schema which contains data about the child nodes
 871      *            and uses of augment
 872      * @return generated type builder for augment
 873      */
 874     private def GeneratedTypeBuilder addRawAugmentGenTypeDefinition(Module module, String augmentPackageName,
 875         String basePackageName, Type targetTypeRef, AugmentationSchema augSchema) {
 876         var Map<String, GeneratedTypeBuilder> augmentBuilders = genTypeBuilders.get(augmentPackageName);
 877         if (augmentBuilders === null) {
 878             augmentBuilders = new HashMap();
 879             genTypeBuilders.put(augmentPackageName, augmentBuilders);
 880         }
 881         val augIdentifier = getAugmentIdentifier(augSchema.unknownSchemaNodes);
 882
 883         val augTypeName = if (augIdentifier !== null) {
 884                 BindingMapping.getClassName(augIdentifier)
 885             } else {
 886                 augGenTypeName(augmentBuilders, targetTypeRef.name);
 887             }
 888
 889         val augTypeBuilder = new GeneratedTypeBuilderImpl(augmentPackageName, augTypeName);
 890
 891         augTypeBuilder.addImplementsType(DATA_OBJECT);
 892         augTypeBuilder.addImplementsType(Types.augmentationTypeFor(targetTypeRef));
 893         addImplementedInterfaceFromUses(augSchema, augTypeBuilder);
 894
 895         augSchemaNodeToMethods(module, basePackageName, augTypeBuilder, augTypeBuilder, augSchema.childNodes);
 896         augmentBuilders.put(augTypeName, augTypeBuilder);
 897         return augTypeBuilder;
 898     }
 899
 900     /**
 901      *
 902      * @param unknownSchemaNodes
 903      * @return nodeParameter of UnknownSchemaNode
 904      */
 905     private def String getAugmentIdentifier(List<UnknownSchemaNode> unknownSchemaNodes) {
 906         for (unknownSchemaNode : unknownSchemaNodes) {
 907             val nodeType = unknownSchemaNode.nodeType;
 908             if (AUGMENT_IDENTIFIER_NAME.equals(nodeType.localName) &&
 909                 YANG_EXT_NAMESPACE.equals(nodeType.namespace.toString())) {
 910                 return unknownSchemaNode.nodeParameter;
 911             }
 912         }
 913         return null;
 914     }
 915
 916     /**
 917      * Returns first unique name for the augment generated type builder. The
 918      * generated type builder name for augment consists from name of augmented
 919      * node and serial number of its augmentation.
 920      *
 921      * @param builders
 922      *            map of builders which were created in the package to which the
 923      *            augmentation belongs
 924      * @param genTypeName
 925      *            string with name of augmented node
 926      * @return string with unique name for augmentation builder
 927      */
 928     private def String augGenTypeName(Map<String, GeneratedTypeBuilder> builders, String genTypeName) {
 929         var index = 1;
 930         while ((builders !== null) && builders.containsKey(genTypeName + index)) {
 931             index = index + 1;
 932         }
 933         return genTypeName + index;
 934     }
 935
 936     /**
 937      * Adds the methods to <code>typeBuilder</code> which represent subnodes of
 938      * node for which <code>typeBuilder</code> was created.
 939      *
 940      * The subnodes aren't mapped to the methods if they are part of grouping or
 941      * augment (in this case are already part of them).
 942      *
 943      * @param module current module
 944      * @param basePackageName
 945      *            string contains the module package name
 946      * @param parent
 947      *            generated type builder which represents any node. The subnodes
 948      *            of this node are added to the <code>typeBuilder</code> as
 949      *            methods. The subnode can be of type leaf, leaf-list, list,
 950      *            container, choice.
 951      * @param childOf parent type
 952      * @param schemaNodes
 953      *            set of data schema nodes which are the children of the node
 954      *            for which <code>typeBuilder</code> was created
 955      * @return generated type builder which is the same builder as input
 956      *         parameter. The getter methods (representing child nodes) could be
 957      *         added to it.
 958      */
 959     private def GeneratedTypeBuilder resolveDataSchemaNodes(Module module, String basePackageName,
 960         GeneratedTypeBuilder parent, GeneratedTypeBuilder childOf, Set<DataSchemaNode> schemaNodes) {
 961         if ((schemaNodes !== null) && (parent !== null)) {
 962             for (schemaNode : schemaNodes) {
 963                 if (!schemaNode.augmenting && !schemaNode.addedByUses) {
 964                     addSchemaNodeToBuilderAsMethod(basePackageName, schemaNode, parent, childOf, module);
 965                 }
 966             }
 967         }
 968         return parent;
 969     }
 970
 971     /**
 972      * Adds the methods to <code>typeBuilder</code> what represents subnodes of
 973      * node for which <code>typeBuilder</code> was created.
 974      *
 975      * @param module current module
 976      * @param basePackageName
 977      *            string contains the module package name
 978      * @param typeBuilder
 979      *            generated type builder which represents any node. The subnodes
 980      *            of this node are added to the <code>typeBuilder</code> as
 981      *            methods. The subnode can be of type leaf, leaf-list, list,
 982      *            container, choice.
 983      * @param childOf parent type
 984      * @param schemaNodes
 985      *            set of data schema nodes which are the children of the node
 986      *            for which <code>typeBuilder</code> was created
 987      * @return generated type builder which is the same object as the input
 988      *         parameter <code>typeBuilder</code>. The getter method could be
 989      *         added to it.
 990      */
 991     private def GeneratedTypeBuilder augSchemaNodeToMethods(Module module, String basePackageName,
 992         GeneratedTypeBuilder typeBuilder, GeneratedTypeBuilder childOf, Set<DataSchemaNode> schemaNodes) {
 993         if ((schemaNodes !== null) && (typeBuilder !== null)) {
 994             for (schemaNode : schemaNodes) {
 995                 if (!schemaNode.isAugmenting()) {
 996                     addSchemaNodeToBuilderAsMethod(basePackageName, schemaNode, typeBuilder, childOf, module);
 997                 }
 998             }
 999         }
1000         return typeBuilder;
1001     }
1002
1003     /**
1004      * Adds to <code>typeBuilder</code> a method which is derived from
1005      * <code>schemaNode</code>.
1006      *
1007      * @param basePackageName
1008      *            string with the module package name
1009      * @param node
1010      *            data schema node which is added to <code>typeBuilder</code> as
1011      *            a method
1012      * @param typeBuilder
1013      *            generated type builder to which is <code>schemaNode</code>
1014      *            added as a method.
1015      * @param childOf parent type
1016      * @param module current module
1017      */
1018     private def void addSchemaNodeToBuilderAsMethod(String basePackageName, DataSchemaNode node,
1019         GeneratedTypeBuilder typeBuilder, GeneratedTypeBuilder childOf, Module module) {
1020         if (node !== null && typeBuilder !== null) {
1021             switch (node) {
1022                 case node instanceof LeafSchemaNode:
1023                     resolveLeafSchemaNodeAsMethod(typeBuilder, node as LeafSchemaNode)
1024                 case node instanceof LeafListSchemaNode:
1025                     resolveLeafListSchemaNode(typeBuilder, node as LeafListSchemaNode)
1026                 case node instanceof ContainerSchemaNode:
1027                     containerToGenType(module, basePackageName, typeBuilder, childOf, node as ContainerSchemaNode)
1028                 case node instanceof ListSchemaNode:
1029                     listToGenType(module, basePackageName, typeBuilder, childOf, node as ListSchemaNode)
1030                 case node instanceof ChoiceNode:
1031                     choiceToGeneratedType(module, basePackageName, typeBuilder, node as ChoiceNode)
1032             }
1033         }
1034     }
1035
1036     /**
1037      * Converts <code>choiceNode</code> to the list of generated types for
1038      * choice and its cases.
1039      *
1040      * The package names for choice and for its cases are created as
1041      * concatenation of the module package (<code>basePackageName</code>) and
1042      * names of all parents node.
1043      *
1044      * @param module current module
1045      * @param basePackageName
1046      *            string with the module package name
1047      * @param parent parent type
1048      * @param childOf concrete parent for case child nodes
1049      * @param choiceNode
1050      *            choice node which is mapped to generated type. Also child
1051      *            nodes - cases are mapped to generated types.
1052      * @throws IllegalArgumentException
1053      *             <ul>
1054      *             <li>if <code>basePackageName</code> equals null</li>
1055      *             <li>if <code>choiceNode</code> equals null</li>
1056      *             </ul>
1057      *
1058      */
1059     private def void choiceToGeneratedType(Module module, String basePackageName, GeneratedTypeBuilder parent,
1060         ChoiceNode choiceNode) {
1061         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1062         checkArgument(choiceNode !== null, "Choice Schema Node cannot be NULL.");
1063
1064         if (!choiceNode.addedByUses) {
1065             val packageName = packageNameForGeneratedType(basePackageName, choiceNode.path);
1066             val choiceTypeBuilder = addRawInterfaceDefinition(packageName, choiceNode);
1067             constructGetter(parent, choiceNode.QName.localName, choiceNode.description, choiceTypeBuilder);
1068             choiceTypeBuilder.addImplementsType(DataContainer.typeForClass);
1069             genCtx.get(module).addChildNodeType(choiceNode.path, choiceTypeBuilder)
1070             generateTypesFromChoiceCases(module, basePackageName, parent, choiceTypeBuilder.toInstance, choiceNode);
1071         }
1072     }
1073
1074     /**
1075      * Converts <code>caseNodes</code> set to list of corresponding generated
1076      * types.
1077      *
1078      * For every <i>case</i> which isn't added through augment or <i>uses</i> is
1079      * created generated type builder. The package names for the builder is
1080      * created as concatenation of the module package (
1081      * <code>basePackageName</code>) and names of all parents nodes of the
1082      * concrete <i>case</i>. There is also relation "<i>implements type</i>"
1083      * between every case builder and <i>choice</i> type
1084      *
1085      * @param basePackageName
1086      *            string with the module package name
1087      * @param refChoiceType
1088      *            type which represents superior <i>case</i>
1089      * @param caseNodes
1090      *            set of choice case nodes which are mapped to generated types
1091      * @return list of generated types for <code>caseNodes</code>.
1092      * @throws IllegalArgumentException
1093      *             <ul>
1094      *             <li>if <code>basePackageName</code> equals null</li>
1095      *             <li>if <code>refChoiceType</code> equals null</li>
1096      *             <li>if <code>caseNodes</code> equals null</li>
1097      *             </ul>
1098      *             *
1099      */
1100     private def void generateTypesFromChoiceCases(Module module, String basePackageName,
1101         GeneratedTypeBuilder choiceParent, Type refChoiceType, ChoiceNode choiceNode) {
1102         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1103         checkArgument(refChoiceType !== null, "Referenced Choice Type cannot be NULL.");
1104         checkArgument(choiceNode !== null, "ChoiceNode cannot be NULL.");
1105
1106         val Set<ChoiceCaseNode> caseNodes = choiceNode.cases;
1107         if (caseNodes == null) {
1108             return
1109         }
1110
1111         for (caseNode : caseNodes) {
1112             if (caseNode !== null && !caseNode.isAddedByUses() && !caseNode.isAugmenting()) {
1113                 val packageName = packageNameForGeneratedType(basePackageName, caseNode.path)
1114                 val caseTypeBuilder = addDefaultInterfaceDefinition(packageName, caseNode)
1115                 caseTypeBuilder.addImplementsType(refChoiceType)
1116                 genCtx.get(module).addCaseType(caseNode.path, caseTypeBuilder)
1117                 val Set<DataSchemaNode> caseChildNodes = caseNode.childNodes
1118                 if (caseChildNodes !== null) {
1119                     var Object parentNode = null
1120                     val SchemaPath nodeSp = choiceNode.path
1121                     val List<QName> nodeNames = nodeSp.path
1122                     val List<QName> nodeNewNames = new ArrayList(nodeNames)
1123                     nodeNewNames.remove(nodeNewNames.size - 1)
1124                     val SchemaPath nodeNewSp = new SchemaPath(nodeNewNames, nodeSp.absolute)
1125                     parentNode = findDataSchemaNode(schemaContext, nodeNewSp)
1126
1127                     var SchemaNode parent
1128                     if (parentNode instanceof AugmentationSchema) {
1129                         val augSchema = parentNode as AugmentationSchema;
1130                         val targetPath = augSchema.targetPath;
1131                         var targetSchemaNode = findDataSchemaNode(schemaContext, targetPath)
1132                         if (targetSchemaNode instanceof DataSchemaNode &&
1133                             (targetSchemaNode as DataSchemaNode).isAddedByUses()) {
1134                             targetSchemaNode = findOriginal(targetSchemaNode as DataSchemaNode, schemaContext);
1135                             if (targetSchemaNode == null) {
1136                                 throw new NullPointerException(
1137                                     "Failed to find target node from grouping for augmentation " + augSchema +
1138                                         " in module " + module.name);
1139                             }
1140                         }
1141                         parent = targetSchemaNode
1142                     } else {
1143                         val SchemaPath sp = choiceNode.path
1144                         val List<QName> names = sp.path
1145                         val List<QName> newNames = new ArrayList(names)
1146                         newNames.remove(newNames.size - 1)
1147                         val SchemaPath newSp = new SchemaPath(newNames, sp.absolute)
1148                         parent = findDataSchemaNode(schemaContext, newSp)
1149                     }
1150                     var GeneratedTypeBuilder childOfType = findChildNodeByPath(parent.path)
1151                     resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, caseChildNodes)
1152                 }
1153             }
1154
1155             processUsesAugments(caseNode, module);
1156         }
1157     }
1158
1159     /**
1160      * Generates list of generated types for all the cases of a choice which are
1161      * added to the choice through the augment.
1162      *
1163      *
1164      * @param basePackageName
1165      *            string contains name of package to which augment belongs. If
1166      *            an augmented choice is from an other package (pcg1) than an
1167      *            augmenting choice (pcg2) then case's of the augmenting choice
1168      *            will belong to pcg2.
1169      * @param refChoiceType
1170      *            Type which represents the choice to which case belongs. Every
1171      *            case has to contain its choice in extend part.
1172      * @param caseNodes
1173      *            set of choice case nodes for which is checked if are/aren't
1174      *            added to choice through augmentation
1175      * @return list of generated types which represents augmented cases of
1176      *         choice <code>refChoiceType</code>
1177      * @throws IllegalArgumentException
1178      *             <ul>
1179      *             <li>if <code>basePackageName</code> equals null</li>
1180      *             <li>if <code>refChoiceType</code> equals null</li>
1181      *             <li>if <code>caseNodes</code> equals null</li>
1182      *             </ul>
1183      */
1184     private def void generateTypesFromAugmentedChoiceCases(Module module, String basePackageName, Type targetType,
1185         ChoiceNode targetNode, Set<DataSchemaNode> augmentedNodes) {
1186         checkArgument(basePackageName !== null, "Base Package Name cannot be NULL.");
1187         checkArgument(targetType !== null, "Referenced Choice Type cannot be NULL.");
1188         checkArgument(augmentedNodes !== null, "Set of Choice Case Nodes cannot be NULL.");
1189
1190         for (caseNode : augmentedNodes) {
1191             if (caseNode !== null) {
1192                 val packageName = packageNameForGeneratedType(basePackageName, caseNode.path);
1193                 val caseTypeBuilder = addDefaultInterfaceDefinition(packageName, caseNode);
1194                 caseTypeBuilder.addImplementsType(targetType);
1195
1196                 var SchemaNode parent = null
1197                 val SchemaPath nodeSp = targetNode.path
1198                 val List<QName> nodeNames = nodeSp.path
1199                 val List<QName> nodeNewNames = new ArrayList(nodeNames)
1200                 nodeNewNames.remove(nodeNewNames.size - 1)
1201                 val SchemaPath nodeNewSp = new SchemaPath(nodeNewNames, nodeSp.absolute)
1202                 parent = findDataSchemaNode(schemaContext, nodeNewSp)
1203
1204                 var GeneratedTypeBuilder childOfType = null;
1205                 if (parent instanceof Module) {
1206                     childOfType = genCtx.get(parent as Module).moduleNode
1207                 } else if (parent instanceof ChoiceCaseNode) {
1208                     childOfType = findCaseByPath(parent.path)
1209                 } else if (parent instanceof DataSchemaNode || parent instanceof NotificationDefinition) {
1210                     childOfType = findChildNodeByPath(parent.path)
1211                 } else if (parent instanceof GroupingDefinition) {
1212                     childOfType = findGroupingByPath(parent.path);
1213                 }
1214
1215                 if (childOfType == null) {
1216                     throw new IllegalArgumentException("Failed to find parent type of choice " + targetNode);
1217                 }
1218
1219                 if (caseNode instanceof DataNodeContainer) {
1220                     val DataNodeContainer dataNodeCase = caseNode as DataNodeContainer;
1221                     val Set<DataSchemaNode> childNodes = dataNodeCase.childNodes;
1222                     if (childNodes !== null) {
1223                         resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, childNodes);
1224                     }
1225                 } else {
1226                     val ChoiceCaseNode node = targetNode.getCaseNodeByName(caseNode.getQName().getLocalName());
1227                     val Set<DataSchemaNode> childNodes = node.childNodes;
1228                     if (childNodes !== null) {
1229                         resolveDataSchemaNodes(module, basePackageName, caseTypeBuilder, childOfType, childNodes);
1230                     }
1231                 }
1232
1233                 genCtx.get(module).addCaseType(caseNode.path, caseTypeBuilder)
1234             }
1235         }
1236
1237     }
1238
1239     /**
1240      * Converts <code>leaf</code> to the getter method which is added to
1241      * <code>typeBuilder</code>.
1242      *
1243      * @param typeBuilder
1244      *            generated type builder to which is added getter method as
1245      *            <code>leaf</code> mapping
1246      * @param leaf
1247      *            leaf schema node which is mapped as getter method which is
1248      *            added to <code>typeBuilder</code>
1249      * @return boolean value
1250      *         <ul>
1251      *         <li>false - if <code>leaf</code> or <code>typeBuilder</code> are
1252      *         null</li>
1253      *         <li>true - in other cases</li>
1254      *         </ul>
1255      */
1256     private def boolean resolveLeafSchemaNodeAsMethod(GeneratedTypeBuilder typeBuilder, LeafSchemaNode leaf) {
1257         if ((leaf !== null) && (typeBuilder !== null)) {
1258             val leafName = leaf.QName.localName;
1259             var String leafDesc = leaf.description;
1260             if (leafDesc === null) {
1261                 leafDesc = "";
1262             }
1263
1264             val parentModule = findParentModule(schemaContext, leaf);
1265             if (leafName !== null && !leaf.isAddedByUses()) {
1266                 val TypeDefinition<?> typeDef = leaf.type;
1267
1268                 var Type returnType = null;
1269                 var GeneratedTOBuilder genTOBuilder;
1270                 if (typeDef instanceof EnumTypeDefinition) {
1271                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf);
1272                     val enumTypeDef = typeDef as EnumTypeDefinition;
1273                     val enumBuilder = resolveInnerEnumFromTypeDefinition(enumTypeDef, leaf.QName, typeBuilder);
1274
1275                     if (enumBuilder !== null) {
1276                         returnType = new ReferencedTypeImpl(enumBuilder.packageName, enumBuilder.name);
1277                     }
1278                     (typeProvider as TypeProviderImpl).putReferencedType(leaf.path, returnType);
1279                 } else if (typeDef instanceof UnionType) {
1280                     genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, leaf, parentModule);
1281                     if (genTOBuilder !== null) {
1282                         returnType = createReturnTypeForUnion(genTOBuilder, typeDef, typeBuilder, parentModule)
1283                     }
1284                 } else if (typeDef instanceof BitsTypeDefinition) {
1285                     genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, leaf, parentModule);
1286                     if (genTOBuilder !== null) {
1287                         returnType = new ReferencedTypeImpl(genTOBuilder.packageName, genTOBuilder.name);
1288                     }
1289                 } else {
1290                     val Restrictions restrictions = BindingGeneratorUtil.getRestrictions(typeDef);
1291                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf, restrictions);
1292                 }
1293                 if (returnType !== null) {
1294                     val MethodSignatureBuilder getter = constructGetter(typeBuilder, leafName, leafDesc, returnType);
1295                     processContextRefExtension(leaf, getter, parentModule);
1296                     return true;
1297                 }
1298             }
1299         }
1300         return false;
1301     }
1302
1303     private def void processContextRefExtension(LeafSchemaNode leaf, MethodSignatureBuilder getter, Module module) {
1304         for (node : leaf.unknownSchemaNodes) {
1305             val nodeType = node.nodeType;
1306             if ("context-reference".equals(nodeType.localName)) {
1307                 val nodeParam = node.nodeParameter;
1308                 var IdentitySchemaNode identity = null;
1309                 var String basePackageName = null;
1310                 val String[] splittedElement = nodeParam.split(":");
1311                 if (splittedElement.length == 1) {
1312                     identity = findIdentityByName(module.identities, splittedElement.get(0));
1313                     basePackageName = moduleNamespaceToPackageName(module);
1314                 } else if (splittedElement.length == 2) {
1315                     var prefix = splittedElement.get(0);
1316                     val Module dependentModule = findModuleFromImports(module.imports, prefix)
1317                     if (dependentModule == null) {
1318                         throw new IllegalArgumentException(
1319                             "Failed to process context-reference: unknown prefix " + prefix);
1320                     }
1321                     identity = findIdentityByName(dependentModule.identities, splittedElement.get(1));
1322                     basePackageName = moduleNamespaceToPackageName(dependentModule);
1323                 } else {
1324                     throw new IllegalArgumentException(
1325                         "Failed to process context-reference: unknown identity " + nodeParam);
1326                 }
1327                 if (identity == null) {
1328                     throw new IllegalArgumentException(
1329                         "Failed to process context-reference: unknown identity " + nodeParam);
1330                 }
1331
1332                 val Class<RoutingContext> clazz = typeof(RoutingContext);
1333                 val AnnotationTypeBuilder rc = getter.addAnnotation(clazz.package.name, clazz.simpleName);
1334                 val packageName = packageNameForGeneratedType(basePackageName, identity.path);
1335                 val genTypeName = BindingMapping.getClassName(identity.QName.localName);
1336                 rc.addParameter("value", packageName + "." + genTypeName + ".class");
1337             }
1338         }
1339     }
1340
1341     private def IdentitySchemaNode findIdentityByName(Set<IdentitySchemaNode> identities, String name) {
1342         for (id : identities) {
1343             if (id.QName.localName.equals(name)) {
1344                 return id;
1345             }
1346         }
1347         return null;
1348     }
1349
1350     private def Module findModuleFromImports(Set<ModuleImport> imports, String prefix) {
1351         for (imp : imports) {
1352             if (imp.prefix.equals(prefix)) {
1353                 return schemaContext.findModuleByName(imp.moduleName, imp.revision);
1354             }
1355         }
1356         return null;
1357     }
1358
1359     /**
1360      * Converts <code>leaf</code> schema node to property of generated TO
1361      * builder.
1362      *
1363      * @param toBuilder
1364      *            generated TO builder to which is <code>leaf</code> added as
1365      *            property
1366      * @param leaf
1367      *            leaf schema node which is added to <code>toBuilder</code> as
1368      *            property
1369      * @param isReadOnly
1370      *            boolean value which says if leaf property is|isn't read only
1371      * @return boolean value
1372      *         <ul>
1373      *         <li>false - if <code>leaf</code>, <code>toBuilder</code> or leaf
1374      *         name equals null or if leaf is added by <i>uses</i>.</li>
1375      *         <li>true - other cases</li>
1376      *         </ul>
1377      */
1378     private def boolean resolveLeafSchemaNodeAsProperty(GeneratedTOBuilder toBuilder, LeafSchemaNode leaf,
1379         boolean isReadOnly, Module module) {
1380         if ((leaf !== null) && (toBuilder !== null)) {
1381             val leafName = leaf.QName.localName;
1382             var String leafDesc = leaf.description;
1383             if (leafDesc === null) {
1384                 leafDesc = "";
1385             }
1386
1387             if (leafName !== null) {
1388                 var Type returnType = null;
1389                 val TypeDefinition<?> typeDef = leaf.type;
1390                 if (typeDef instanceof UnionTypeDefinition) {
1391                     // GeneratedType for this type definition should be already created
1392                     var qname = typeDef.QName
1393                     var Module unionModule = null
1394                     if (qname.prefix == null || qname.prefix.empty) {
1395                         unionModule = module
1396                     } else {
1397                         unionModule = findModuleFromImports(module.imports, qname.prefix)
1398                     }
1399                     val ModuleContext mc = genCtx.get(unionModule)
1400                     returnType = mc.typedefs.get(typeDef.path)
1401                 } else {
1402                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, leaf);
1403                 }
1404
1405                 if (returnType !== null) {
1406                     val propBuilder = toBuilder.addProperty(parseToValidParamName(leafName));
1407                     propBuilder.setReadOnly(isReadOnly);
1408                     propBuilder.setReturnType(returnType);
1409                     propBuilder.setComment(leafDesc);
1410                     toBuilder.addEqualsIdentity(propBuilder);
1411                     toBuilder.addHashIdentity(propBuilder);
1412                     toBuilder.addToStringProperty(propBuilder);
1413                     return true;
1414                 }
1415             }
1416         }
1417         return false;
1418     }
1419
1420     /**
1421      * Converts <code>node</code> leaf list schema node to getter method of
1422      * <code>typeBuilder</code>.
1423      *
1424      * @param typeBuilder
1425      *            generated type builder to which is <code>node</code> added as
1426      *            getter method
1427      * @param node
1428      *            leaf list schema node which is added to
1429      *            <code>typeBuilder</code> as getter method
1430      * @return boolean value
1431      *         <ul>
1432      *         <li>true - if <code>node</code>, <code>typeBuilder</code>,
1433      *         nodeName equal null or <code>node</code> is added by <i>uses</i></li>
1434      *         <li>false - other cases</li>
1435      *         </ul>
1436      */
1437     private def boolean resolveLeafListSchemaNode(GeneratedTypeBuilder typeBuilder, LeafListSchemaNode node) {
1438         if ((node !== null) && (typeBuilder !== null)) {
1439             val nodeName = node.QName;
1440             var String nodeDesc = node.description;
1441             if (nodeDesc === null) {
1442                 nodeDesc = "";
1443             }
1444             if (nodeName !== null && !node.isAddedByUses()) {
1445                 val TypeDefinition<?> typeDef = node.type;
1446                 val parentModule = findParentModule(schemaContext, node);
1447
1448                 var Type returnType = null;
1449                 if (typeDef instanceof EnumTypeDefinition) {
1450                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, node);
1451                     val enumTypeDef = typeDef as EnumTypeDefinition;
1452                     val enumBuilder = resolveInnerEnumFromTypeDefinition(enumTypeDef, nodeName, typeBuilder);
1453                     returnType = new ReferencedTypeImpl(enumBuilder.packageName, enumBuilder.name);
1454                     (typeProvider as TypeProviderImpl).putReferencedType(node.path, returnType);
1455                 } else if (typeDef instanceof UnionType) {
1456                     val genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, node, parentModule);
1457                     if (genTOBuilder !== null) {
1458                         returnType = createReturnTypeForUnion(genTOBuilder, typeDef, typeBuilder, parentModule)
1459                     }
1460                 } else if (typeDef instanceof BitsTypeDefinition) {
1461                     val genTOBuilder = addTOToTypeBuilder(typeDef, typeBuilder, node, parentModule);
1462                     returnType = new ReferencedTypeImpl(genTOBuilder.packageName, genTOBuilder.name);
1463                 } else {
1464                     val Restrictions restrictions = BindingGeneratorUtil.getRestrictions(typeDef);
1465                     returnType = typeProvider.javaTypeForSchemaDefinitionType(typeDef, node, restrictions);
1466                 }
1467
1468                 val listType = Types.listTypeFor(returnType);
1469                 constructGetter(typeBuilder, nodeName.localName, nodeDesc, listType);
1470                 return true;
1471             }
1472         }
1473         return false;
1474     }
1475
1476     private def Type createReturnTypeForUnion(GeneratedTOBuilder genTOBuilder, TypeDefinition<?> typeDef,
1477         GeneratedTypeBuilder typeBuilder, Module parentModule) {
1478         val Type returnType = new ReferencedTypeImpl(genTOBuilder.packageName, genTOBuilder.name);
1479         genTOBuilder.setTypedef(true);
1480         genTOBuilder.setIsUnion(true);
1481         (typeProvider as TypeProviderImpl).addUnitsToGenTO(genTOBuilder, typeDef.getUnits());
1482
1483         // union builder
1484         val GeneratedTOBuilder unionBuilder = new GeneratedTOBuilderImpl(typeBuilder.getPackageName(),
1485             genTOBuilder.getName() + "Builder");
1486         unionBuilder.setIsUnionBuilder(true);
1487         val MethodSignatureBuilder method = unionBuilder.addMethod("getDefaultInstance");
1488         method.setReturnType(returnType);
1489         method.addParameter(Types.STRING, "defaultValue");
1490         method.setAccessModifier(AccessModifier.PUBLIC);
1491         method.setStatic(true);
1492
1493         val Set<Type> types = (typeProvider as TypeProviderImpl).additionalTypes.get(parentModule);
1494         if (types == null) {
1495             (typeProvider as TypeProviderImpl).additionalTypes.put(parentModule,
1496                 Sets.newHashSet(unionBuilder.toInstance))
1497         } else {
1498             types.add(unionBuilder.toInstance)
1499         }
1500         return returnType
1501     }
1502
1503     private def GeneratedTypeBuilder addDefaultInterfaceDefinition(String packageName, SchemaNode schemaNode) {
1504         return addDefaultInterfaceDefinition(packageName, schemaNode, null);
1505     }
1506
1507     /**
1508      * Instantiates generated type builder with <code>packageName</code> and
1509      * <code>schemaNode</code>.
1510      *
1511      * The new builder always implements
1512      * {@link org.opendaylight.yangtools.yang.binding.DataObject DataObject}.<br />
1513      * If <code>schemaNode</code> is instance of GroupingDefinition it also
1514      * implements {@link org.opendaylight.yangtools.yang.binding.Augmentable
1515      * Augmentable}.<br />
1516      * If <code>schemaNode</code> is instance of
1517      * {@link org.opendaylight.yangtools.yang.model.api.DataNodeContainer
1518      * DataNodeContainer} it can also implement nodes which are specified in
1519      * <i>uses</i>.
1520      *
1521      * @param packageName
1522      *            string with the name of the package to which
1523      *            <code>schemaNode</code> belongs.
1524      * @param schemaNode
1525      *            schema node for which is created generated type builder
1526      * @param parent parent type (can be null)
1527      * @return generated type builder <code>schemaNode</code>
1528      */
1529     private def GeneratedTypeBuilder addDefaultInterfaceDefinition(String packageName, SchemaNode schemaNode,
1530         Type parent) {
1531         val it = addRawInterfaceDefinition(packageName, schemaNode, "");
1532         qnameConstant(BindingMapping.QNAME_STATIC_FIELD_NAME,schemaNode.QName);
1533         if (parent === null) {
1534             addImplementsType(DATA_OBJECT);
1535         } else {
1536             addImplementsType(BindingTypes.childOf(parent));
1537         }
1538         if (!(schemaNode instanceof GroupingDefinition)) {
1539             addImplementsType(augmentable(it));
1540         }
1541
1542         if (schemaNode instanceof DataNodeContainer) {
1543             addImplementedInterfaceFromUses(schemaNode as DataNodeContainer, it);
1544         }
1545
1546         return it;
1547     }
1548
1549     /**
1550      * Wraps the calling of the same overloaded method.
1551      *
1552      * @param packageName
1553      *            string with the package name to which returning generated type
1554      *            builder belongs
1555      * @param schemaNode
1556      *            schema node which provide data about the schema node name
1557      * @return generated type builder for <code>schemaNode</code>
1558      */
1559     private def GeneratedTypeBuilder addRawInterfaceDefinition(String packageName, SchemaNode schemaNode) {
1560         return addRawInterfaceDefinition(packageName, schemaNode, "");
1561     }
1562
1563     /**
1564      * Returns reference to generated type builder for specified
1565      * <code>schemaNode</code> with <code>packageName</code>.
1566      *
1567      * Firstly the generated type builder is searched in
1568      * {@link BindingGeneratorImpl#genTypeBuilders genTypeBuilders}. If it isn't
1569      * found it is created and added to <code>genTypeBuilders</code>.
1570      *
1571      * @param packageName
1572      *            string with the package name to which returning generated type
1573      *            builder belongs
1574      * @param schemaNode
1575      *            schema node which provide data about the schema node name
1576      * @param prefix return type name prefix
1577      * @return generated type builder for <code>schemaNode</code>
1578      * @throws IllegalArgumentException
1579      *             <ul>
1580      *             <li>if <code>schemaNode</code> equals null</li>
1581      *             <li>if <code>packageName</code> equals null</li>
1582      *             <li>if Q name of schema node is null</li>
1583      *             <li>if schema node name is null</li>
1584      *             </ul>
1585      *
1586      */
1587     private def GeneratedTypeBuilder addRawInterfaceDefinition(String packageName, SchemaNode schemaNode,
1588         String prefix) {
1589         checkArgument(schemaNode !== null, "Data Schema Node cannot be NULL.");
1590         checkArgument(packageName !== null, "Package Name for Generated Type cannot be NULL.");
1591         checkArgument(schemaNode.QName !== null, "QName for Data Schema Node cannot be NULL.");
1592         val schemaNodeName = schemaNode.QName.localName;
1593         checkArgument(schemaNodeName !== null, "Local Name of QName for Data Schema Node cannot be NULL.");
1594
1595         var String genTypeName;
1596         if (prefix === null) {
1597             genTypeName = BindingMapping.getClassName(schemaNodeName);
1598         } else {
1599             genTypeName = prefix + BindingMapping.getClassName(schemaNodeName);
1600         }
1601
1602         //FIXME: Validation of name conflict
1603         val newType = new GeneratedTypeBuilderImpl(packageName, genTypeName);
1604         if (!genTypeBuilders.containsKey(packageName)) {
1605             val Map<String, GeneratedTypeBuilder> builders = new HashMap();
1606             builders.put(genTypeName, newType);
1607             genTypeBuilders.put(packageName, builders);
1608         } else {
1609             val Map<String, GeneratedTypeBuilder> builders = genTypeBuilders.get(packageName);
1610             if (!builders.containsKey(genTypeName)) {
1611                 builders.put(genTypeName, newType);
1612             }
1613         }
1614         return newType;
1615     }
1616
1617     /**
1618      * Creates the name of the getter method from <code>methodName</code>.
1619      *
1620      * @param methodName
1621      *            string with the name of the getter method
1622      * @param returnType return type
1623      * @return string with the name of the getter method for
1624      *         <code>methodName</code> in JAVA method format
1625      */
1626     public static def String getterMethodName(String localName, Type returnType) {
1627         val method = new StringBuilder();
1628         if (BOOLEAN.equals(returnType)) {
1629             method.append("is");
1630         } else {
1631             method.append("get");
1632         }
1633         method.append(BindingMapping.getPropertyName(localName).toFirstUpper);
1634         return method.toString();
1635     }
1636
1637     /**
1638      * Created a method signature builder as part of
1639      * <code>interfaceBuilder</code>.
1640      *
1641      * The method signature builder is created for the getter method of
1642      * <code>schemaNodeName</code>. Also <code>comment</code> and
1643      * <code>returnType</code> information are added to the builder.
1644      *
1645      * @param interfaceBuilder
1646      *            generated type builder for which the getter method should be
1647      *            created
1648      * @param schemaNodeName
1649      *            string with schema node name. The name will be the part of the
1650      *            getter method name.
1651      * @param comment
1652      *            string with comment for the getter method
1653      * @param returnType
1654      *            type which represents the return type of the getter method
1655      * @return method signature builder which represents the getter method of
1656      *         <code>interfaceBuilder</code>
1657      */
1658     private def MethodSignatureBuilder constructGetter(GeneratedTypeBuilder interfaceBuilder, String schemaNodeName,
1659         String comment, Type returnType) {
1660         val getMethod = interfaceBuilder.addMethod(getterMethodName(schemaNodeName, returnType));
1661         getMethod.setComment(comment);
1662         getMethod.setReturnType(returnType);
1663         return getMethod;
1664     }
1665
1666     /**
1667      * Adds <code>schemaNode</code> to <code>typeBuilder</code> as getter method
1668      * or to <code>genTOBuilder</code> as property.
1669      *
1670      * @param basePackageName
1671      *            string contains the module package name
1672      * @param schemaNode
1673      *            data schema node which should be added as getter method to
1674      *            <code>typeBuilder</code> or as a property to
1675      *            <code>genTOBuilder</code> if is part of the list key
1676      * @param typeBuilder
1677      *            generated type builder for the list schema node
1678      * @param genTOBuilder
1679      *            generated TO builder for the list keys
1680      * @param listKeys
1681      *            list of string which contains names of the list keys
1682      * @param module current module
1683      * @throws IllegalArgumentException
1684      *             <ul>
1685      *             <li>if <code>schemaNode</code> equals null</li>
1686      *             <li>if <code>typeBuilder</code> equals null</li>
1687      *             </ul>
1688      */
1689     private def void addSchemaNodeToListBuilders(String basePackageName, DataSchemaNode schemaNode,
1690         GeneratedTypeBuilder typeBuilder, GeneratedTOBuilder genTOBuilder, List<String> listKeys, Module module) {
1691         checkArgument(schemaNode !== null, "Data Schema Node cannot be NULL.");
1692         checkArgument(typeBuilder !== null, "Generated Type Builder cannot be NULL.");
1693
1694         if (schemaNode instanceof LeafSchemaNode) {
1695             val leaf = schemaNode as LeafSchemaNode;
1696             val leafName = leaf.QName.localName;
1697             resolveLeafSchemaNodeAsMethod(typeBuilder, leaf);
1698             if (listKeys.contains(leafName)) {
1699                 resolveLeafSchemaNodeAsProperty(genTOBuilder, leaf, true, module)
1700             }
1701         } else if (!schemaNode.addedByUses) {
1702             if (schemaNode instanceof LeafListSchemaNode) {
1703                 resolveLeafListSchemaNode(typeBuilder, schemaNode as LeafListSchemaNode);
1704             } else if (schemaNode instanceof ContainerSchemaNode) {
1705                 containerToGenType(module, basePackageName, typeBuilder, typeBuilder, schemaNode as ContainerSchemaNode);
1706             } else if (schemaNode instanceof ChoiceNode) {
1707                 choiceToGeneratedType(module, basePackageName, typeBuilder, schemaNode as ChoiceNode);
1708             } else if (schemaNode instanceof ListSchemaNode) {
1709                 listToGenType(module, basePackageName, typeBuilder, typeBuilder, schemaNode as ListSchemaNode);
1710             }
1711         }
1712     }
1713
1714     private def typeBuildersToGenTypes(Module module, GeneratedTypeBuilder typeBuilder, GeneratedTOBuilder genTOBuilder) {
1715         checkArgument(typeBuilder !== null, "Generated Type Builder cannot be NULL.");
1716
1717         if (genTOBuilder !== null) {
1718             val genTO = genTOBuilder.toInstance();
1719             constructGetter(typeBuilder, "key", "Returns Primary Key of Yang List Type", genTO);
1720             genCtx.get(module).addGeneratedTOBuilder(genTOBuilder)
1721         }
1722     }
1723
1724     /**
1725      * Selects the names of the list keys from <code>list</code> and returns
1726      * them as the list of the strings
1727      *
1728      * @param list
1729      *            of string with names of the list keys
1730      * @return list of string which represents names of the list keys. If the
1731      *         <code>list</code> contains no keys then the empty list is
1732      *         returned.
1733      */
1734     private def listKeys(ListSchemaNode list) {
1735         val List<String> listKeys = new ArrayList();
1736
1737         if (list.keyDefinition !== null) {
1738             val keyDefinitions = list.keyDefinition;
1739             for (keyDefinition : keyDefinitions) {
1740                 listKeys.add(keyDefinition.localName);
1741             }
1742         }
1743         return listKeys;
1744     }
1745
1746     /**
1747      * Generates for the <code>list</code> which contains any list keys special
1748      * generated TO builder.
1749      *
1750      * @param packageName
1751      *            string with package name to which the list belongs
1752      * @param list
1753      *            list schema node which is source of data about the list name
1754      * @return generated TO builder which represents the keys of the
1755      *         <code>list</code> or null if <code>list</code> is null or list of
1756      *         key definitions is null or empty.
1757      */
1758     private def GeneratedTOBuilder resolveListKeyTOBuilder(String packageName, ListSchemaNode list) {
1759         var GeneratedTOBuilder genTOBuilder = null;
1760         if ((list.keyDefinition !== null) && (!list.keyDefinition.isEmpty())) {
1761             val listName = list.QName.localName + "Key";
1762             val String genTOName = BindingMapping.getClassName(listName);
1763             genTOBuilder = new GeneratedTOBuilderImpl(packageName, genTOName);
1764         }
1765         return genTOBuilder;
1766     }
1767
1768     /**
1769      * Builds generated TO builders for <code>typeDef</code> of type
1770      * {@link org.opendaylight.yangtools.yang.model.util.UnionType UnionType} or
1771      * {@link org.opendaylight.yangtools.yang.model.api.type.BitsTypeDefinition
1772      * BitsTypeDefinition} which are also added to <code>typeBuilder</code> as
1773      * enclosing transfer object.
1774      *
1775      * If more then one generated TO builder is created for enclosing then all
1776      * of the generated TO builders are added to <code>typeBuilder</code> as
1777      * enclosing transfer objects.
1778      *
1779      * @param typeDef
1780      *            type definition which can be of type <code>UnionType</code> or
1781      *            <code>BitsTypeDefinition</code>
1782      * @param typeBuilder
1783      *            generated type builder to which is added generated TO created
1784      *            from <code>typeDef</code>
1785      * @param leafName
1786      *            string with name for generated TO builder
1787      * @param leaf
1788      * @param parentModule
1789      * @return generated TO builder for <code>typeDef</code>
1790      */
1791     private def GeneratedTOBuilder addTOToTypeBuilder(TypeDefinition<?> typeDef, GeneratedTypeBuilder typeBuilder,
1792         DataSchemaNode leaf, Module parentModule) {
1793         val classNameFromLeaf = BindingMapping.getClassName(leaf.QName);
1794         val List<GeneratedTOBuilder> genTOBuilders = new ArrayList();
1795         val packageName = typeBuilder.fullyQualifiedName;
1796         if (typeDef instanceof UnionTypeDefinition) {
1797             val List<GeneratedTOBuilder> types = (typeProvider as TypeProviderImpl).
1798                     provideGeneratedTOBuildersForUnionTypeDef(packageName, (typeDef as UnionTypeDefinition),
1799                         classNameFromLeaf, leaf);
1800             genTOBuilders.addAll(types);
1801
1802
1803         var GeneratedTOBuilder resultTOBuilder = null;
1804         if (!types.isEmpty()) {
1805             resultTOBuilder = types.remove(0);
1806             for (GeneratedTOBuilder genTOBuilder : types) {
1807                 resultTOBuilder.addEnclosingTransferObject(genTOBuilder);
1808             }
1809         }
1810
1811         val GeneratedPropertyBuilder genPropBuilder = resultTOBuilder.addProperty("value");
1812         genPropBuilder.setReturnType(Types.primitiveType("char[]", null));
1813         resultTOBuilder.addEqualsIdentity(genPropBuilder);
1814         resultTOBuilder.addHashIdentity(genPropBuilder);
1815         resultTOBuilder.addToStringProperty(genPropBuilder);
1816
1817         } else if (typeDef instanceof BitsTypeDefinition) {
1818             genTOBuilders.add(
1819                 ((typeProvider as TypeProviderImpl) ).
1820                     provideGeneratedTOBuilderForBitsTypeDefinition(packageName, typeDef, classNameFromLeaf));
1821         }
1822         if (genTOBuilders !== null && !genTOBuilders.isEmpty()) {
1823             for (genTOBuilder : genTOBuilders) {
1824                 typeBuilder.addEnclosingTransferObject(genTOBuilder);
1825             }
1826             return genTOBuilders.get(0);
1827         }
1828         return null;
1829
1830     }
1831
1832     /**
1833      * Adds the implemented types to type builder.
1834      *
1835      * The method passes through the list of <i>uses</i> in
1836      * {@code dataNodeContainer}. For every <i>use</i> is obtained corresponding
1837      * generated type from {@link BindingGeneratorImpl#allGroupings
1838      * allGroupings} which is added as <i>implements type</i> to
1839      * <code>builder</code>
1840      *
1841      * @param dataNodeContainer
1842      *            element which contains the list of used YANG groupings
1843      * @param builder
1844      *            builder to which are added implemented types according to
1845      *            <code>dataNodeContainer</code>
1846      * @return generated type builder with all implemented types
1847      */
1848     private def addImplementedInterfaceFromUses(DataNodeContainer dataNodeContainer, GeneratedTypeBuilder builder) {
1849         for (usesNode : dataNodeContainer.uses) {
1850             if (usesNode.groupingPath !== null) {
1851                 val genType = findGroupingByPath(usesNode.groupingPath).toInstance
1852                 if (genType === null) {
1853                     throw new IllegalStateException(
1854                         "Grouping " + usesNode.groupingPath + "is not resolved for " + builder.name);
1855                 }
1856                 builder.addImplementsType(genType);
1857             }
1858         }
1859         return builder;
1860     }
1861
1862     private def GeneratedTypeBuilder findChildNodeByPath(SchemaPath path) {
1863         for (ctx : genCtx.values) {
1864             var result = ctx.getChildNode(path)
1865             if (result !== null) {
1866                 return result
1867             }
1868         }
1869         return null
1870     }
1871
1872     private def GeneratedTypeBuilder findGroupingByPath(SchemaPath path) {
1873         for (ctx : genCtx.values) {
1874             var result = ctx.getGrouping(path)
1875             if (result !== null) {
1876                 return result
1877             }
1878         }
1879         return null
1880     }
1881
1882     private def GeneratedTypeBuilder findCaseByPath(SchemaPath path) {
1883         for (ctx : genCtx.values) {
1884             var result = ctx.getCase(path)
1885             if (result !== null) {
1886                 return result
1887             }
1888         }
1889         return null
1890     }
1891
1892     public def getModuleContexts() {
1893         genCtx;
1894     }
1895
1896 }