csit/libraries/Genius.robot

   1 *** Settings ***
   2 Documentation     This suite is a common keywords file for genius project.
   3 Library           Collections
   4 Library           OperatingSystem
   5 Library           re
   6 Library           RequestsLibrary
   7 Library           SSHLibrary
   8 Library           string
   9 Resource          ClusterManagement.robot
  10 Resource          DataModels.robot
  11 Resource          KarafKeywords.robot
  12 Resource          OVSDB.robot
  13 Resource          Utils.robot
  14 Resource          VpnOperations.robot
  15 Resource          ../variables/Variables.robot
  16 Resource          ../variables/netvirt/Variables.robot
  17
  18 *** Variables ***
  19 @{itm_created}    TZA
  20 ${genius_config_dir}    ${CURDIR}/../variables/genius
  21 ${Bridge-1}       BR1
  22 ${Bridge-2}       BR2
  23 ${DEFAULT_MONITORING_INTERVAL}    Tunnel Monitoring Interval (for VXLAN tunnels): 1000
  24 @{GENIUS_DIAG_SERVICES}    OPENFLOW    IFM    ITM    DATASTORE    OVSDB
  25 ${vlan}           0
  26 ${gateway-ip}     0.0.0.0
  27
  28 *** Keywords ***
  29 Genius Suite Setup
  30     [Documentation]    Create Rest Session to http://${ODL_SYSTEM_IP}:${RESTCONFPORT}
  31     Start Suite
  32     Create Session    session    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    headers=${HEADERS}    timeout=5
  33
  34 Genius Suite Teardown
  35     [Documentation]    Delete all sessions
  36     Delete All Sessions
  37     Stop Suite
  38
  39 Start Suite
  40     [Documentation]    Initial setup for Genius test suites
  41     Run_Keyword_If_At_Least_Oxygen    Wait Until Keyword Succeeds    60    2    ClusterManagement.Check Status of Services    @{GENIUS_DIAG_SERVICES}
  42     Log    Start the tests
  43     ${conn_id_1}=    Open Connection    ${TOOLS_SYSTEM_IP}    prompt=${DEFAULT_LINUX_PROMPT}    timeout=30s
  44     Set Global Variable    ${conn_id_1}
  45     KarafKeywords.Setup_Karaf_Keywords
  46     ${karaf_debug_enabled}    BuiltIn.Get_Variable_Value    ${KARAF_DEBUG}    ${False}
  47     BuiltIn.run_keyword_if    ${karaf_debug_enabled}    KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set DEBUG org.opendaylight.genius
  48     BuiltIn.Run Keyword And Ignore Error    KarafKeywords.Log_Test_Suite_Start_To_Controller_Karaf
  49     Login With Public Key    ${TOOLS_SYSTEM_USER}    ${USER_HOME}/.ssh/${SSH_KEY}    any
  50     Log    ${conn_id_1}
  51     Execute Command    sudo ovs-vsctl add-br BR1
  52     Execute Command    sudo ovs-vsctl set bridge BR1 protocols=OpenFlow13
  53     Execute Command    sudo ovs-vsctl set-controller BR1 tcp:${ODL_SYSTEM_IP}:6633
  54     Execute Command    sudo ifconfig BR1 up
  55     Execute Command    sudo ovs-vsctl add-port BR1 tap8ed70586-6c -- set Interface tap8ed70586-6c type=tap
  56     Execute Command    sudo ovs-vsctl set-manager tcp:${ODL_SYSTEM_IP}:6640
  57     ${output_1}    Execute Command    sudo ovs-vsctl show
  58     Log    ${output_1}
  59     ${check}    Wait Until Keyword Succeeds    30    10    check establishment    ${conn_id_1}    6633
  60     log    ${check}
  61     ${check_2}    Wait Until Keyword Succeeds    30    10    check establishment    ${conn_id_1}    6640
  62     log    ${check_2}
  63     Log    >>>>>Switch 2 configuration <<<<<
  64     ${conn_id_2}=    Open Connection    ${TOOLS_SYSTEM_2_IP}    prompt=${DEFAULT_LINUX_PROMPT}    timeout=30s
  65     Set Global Variable    ${conn_id_2}
  66     Login With Public Key    ${TOOLS_SYSTEM_USER}    ${USER_HOME}/.ssh/${SSH_KEY}    any
  67     Log    ${conn_id_2}
  68     Execute Command    sudo ovs-vsctl add-br BR2
  69     Execute Command    sudo ovs-vsctl set bridge BR2 protocols=OpenFlow13
  70     Execute Command    sudo ovs-vsctl set-controller BR2 tcp:${ODL_SYSTEM_IP}:6633
  71     Execute Command    sudo ifconfig BR2 up
  72     Execute Command    sudo ovs-vsctl set-manager tcp:${ODL_SYSTEM_IP}:6640
  73     ${output_2}    Execute Command    sudo ovs-vsctl show
  74     Log    ${output_2}
  75
  76 Stop Suite
  77     Log    Stop the tests
  78     Switch Connection    ${conn_id_1}
  79     Log    ${conn_id_1}
  80     Execute Command    sudo ovs-vsctl del-br BR1
  81     Execute Command    sudo ovs-vsctl del-manager
  82     Write    exit
  83     close connection
  84     Switch Connection    ${conn_id_2}
  85     Log    ${conn_id_2}
  86     Execute Command    sudo ovs-vsctl del-br BR2
  87     Execute Command    sudo ovs-vsctl del-manager
  88     Write    exit
  89     close connection
  90
  91 check establishment
  92     [Arguments]    ${conn_id}    ${port}
  93     Switch Connection    ${conn_id}
  94     ${check_establishment}    Execute Command    netstat -anp | grep ${port}
  95     Should contain    ${check_establishment}    ESTABLISHED
  96     [Return]    ${check_establishment}
  97
  98 Create Vteps
  99     [Arguments]    ${Dpn_id_1}    ${Dpn_id_2}    ${TOOLS_SYSTEM_IP}    ${TOOLS_SYSTEM_2_IP}    ${vlan}    ${gateway-ip}
 100     [Documentation]    This keyword creates VTEPs between ${TOOLS_SYSTEM_IP} and ${TOOLS_SYSTEM_2_IP}
 101     ${body}    OperatingSystem.Get File    ${genius_config_dir}/Itm_creation_no_vlan.json
 102     ${substr}    Should Match Regexp    ${TOOLS_SYSTEM_IP}    [0-9]\{1,3}\.[0-9]\{1,3}\.[0-9]\{1,3}\.
 103     ${subnet}    Catenate    ${substr}0
 104     Log    ${subnet}
 105     Set Global Variable    ${subnet}
 106     ${vlan}=    Set Variable    ${vlan}
 107     ${gateway-ip}=    Set Variable    ${gateway-ip}
 108     ${body}    Genius.Set Json    ${Dpn_id_1}    ${Dpn_id_2}    ${TOOLS_SYSTEM_IP}    ${TOOLS_SYSTEM_2_IP}    ${vlan}
 109     ...    ${gateway-ip}    ${subnet}
 110     ${vtep_body}    Set Variable    ${body}
 111     Set Global Variable    ${vtep_body}
 112     ${resp}    RequestsLibrary.Post Request    session    ${CONFIG_API}/itm:transport-zones/    data=${body}
 113     Log    ${resp.status_code}
 114     should be equal as strings    ${resp.status_code}    204
 115
 116 Set Json
 117     [Arguments]    ${Dpn_id_1}    ${Dpn_id_2}    ${TOOLS_SYSTEM_IP}    ${TOOLS_SYSTEM_2_IP}    ${vlan}    ${gateway-ip}
 118     ...    ${subnet}
 119     [Documentation]    Sets Json with the values passed for it.
 120     ${body}    OperatingSystem.Get File    ${genius_config_dir}/Itm_creation_no_vlan.json
 121     ${body}    replace string    ${body}    1.1.1.1    ${subnet}
 122     ${body}    replace string    ${body}    "dpn-id": 101    "dpn-id": ${Dpn_id_1}
 123     ${body}    replace string    ${body}    "dpn-id": 102    "dpn-id": ${Dpn_id_2}
 124     ${body}    replace string    ${body}    "ip-address": "2.2.2.2"    "ip-address": "${TOOLS_SYSTEM_IP}"
 125     ${body}    replace string    ${body}    "ip-address": "3.3.3.3"    "ip-address": "${TOOLS_SYSTEM_2_IP}"
 126     ${body}    replace string    ${body}    "vlan-id": 0    "vlan-id": ${vlan}
 127     ${body}    replace string    ${body}    "gateway-ip": "0.0.0.0"    "gateway-ip": "${gateway-ip}"
 128     Log    ${body}
 129     [Return]    ${body}    # returns complete json that has been updated
 130
 131 Get Dpn Ids
 132     [Arguments]    ${connection_id}
 133     [Documentation]    This keyword gets the DPN id of the switch after configuring bridges on it.It returns the captured DPN id.
 134     Switch connection    ${connection_id}
 135     ${cmd}    set Variable    sudo ovs-vsctl show | grep Bridge | awk -F "\\"" '{print $2}'
 136     ${Bridgename1}    Execute command    ${cmd}
 137     log    ${Bridgename1}
 138     ${output1}    Execute command    sudo ovs-ofctl show -O Openflow13 ${Bridgename1} | head -1 | awk -F "dpid:" '{ print $2 }'
 139     log    ${output1}
 140     # "echo \$\(\(16\#${output1}\)\) command below converts ovs dpnid (i.e., output1) from hexadecimal to decimal."
 141     ${Dpn_id}    Execute command    echo \$\(\(16\#${output1}\)\)
 142     log    ${Dpn_id}
 143     [Return]    ${Dpn_id}
 144
 145 BFD Suite Stop
 146     [Documentation]    Run at end of BFD suite
 147     Delete All Vteps
 148     Stop Suite
 149
 150 Delete All Vteps
 151     [Documentation]    This will delete vtep.
 152     ${resp}    RequestsLibrary.Delete Request    session    ${CONFIG_API}/itm:transport-zones/    data=${vtep_body}
 153     Should Be Equal As Strings    ${resp.status_code}    200
 154     Log    "Before disconnecting CSS with controller"
 155     ${output} =    Issue Command On Karaf Console    ${TEP_SHOW}
 156     BuiltIn.Wait Until Keyword Succeeds    30    5    Verify All Tunnel Delete on DS
 157
 158 Genius Test Setup
 159     [Documentation]    Genius test case setup
 160     BuiltIn.Run Keyword And Ignore Error    KarafKeywords.Log_Testcase_Start_To_Controller_Karaf
 161
 162 Genius Test Teardown
 163     [Arguments]    ${data_models}
 164     OVSDB.Get DumpFlows And Ovsconfig    ${conn_id_1}    BR1
 165     OVSDB.Get DumpFlows And Ovsconfig    ${conn_id_2}    BR2
 166     BuiltIn.Run Keyword And Ignore Error    DataModels.Get Model Dump    ${ODL_SYSTEM_IP}    ${data_models}
 167
 168 ITM Direct Tunnels Start Suite
 169     [Documentation]    start suite for itm scalability
 170     ClusterManagement.ClusterManagement_Setup
 171     ClusterManagement.Stop_Members_From_List_Or_All
 172     Run Command On Remote System And Log    ${ODL_SYSTEM_IP}    sed -i -- 's/<itm-direct-tunnels>false/<itm-direct-tunnels>true/g' ${GENIUS_IFM_CONFIG_FLAG}
 173     ClusterManagement.Start_Members_From_List_Or_All
 174     Genius Suite Setup
 175
 176 ITM Direct Tunnels Stop Suite
 177     Run Command On Remote System And Log    ${ODL_SYSTEM_IP}    sed -i -- 's/<itm-direct-tunnels>true/<itm-direct-tunnels>false/g' ${GENIUS_IFM_CONFIG_FLAG}
 178     Genius Suite Teardown
 179
 180 Verify Tunnel Monitoring is on
 181     [Documentation]    This keyword will get tep:show output and verify tunnel monitoring status
 182     ${output}=    Issue Command On Karaf Console    ${TEP_SHOW}
 183     Should Contain    ${output}    ${TUNNEL_MONITOR_ON}
 184
 185 Ovs Verification For 2 Dpn
 186     [Arguments]    ${connection_id}    ${local}    ${remote-1}    ${tunnel}    ${tunnel-type}
 187     [Documentation]    Checks whether the created Interface is seen on OVS or not.
 188     Switch Connection    ${connection_id}
 189     ${check}    Execute Command    sudo ovs-vsctl show
 190     Log    ${check}
 191     Should Contain    ${check}    local_ip="${local}"    remote_ip="${remote-1}"    ${tunnel}    ${tunnel-type}
 192     [Return]    ${check}
 193
 194 Get ITM
 195     [Arguments]    ${itm_created[0]}    ${subnet}    ${vlan}    ${Dpn_id_1}    ${TOOLS_SYSTEM_IP}    ${Dpn_id_2}
 196     ...    ${TOOLS_SYSTEM_2_IP}
 197     [Documentation]    It returns the created ITM Transport zone with the passed values during the creation is done.
 198     Log    ${itm_created[0]},${subnet}, ${vlan}, ${Dpn_id_1},${TOOLS_SYSTEM_IP}, ${Dpn_id_2}, ${TOOLS_SYSTEM_2_IP}
 199     @{Itm-no-vlan}    Create List    ${itm_created[0]}    ${subnet}    ${vlan}    ${Dpn_id_1}    ${Bridge-1}-eth1
 200     ...    ${TOOLS_SYSTEM_IP}    ${Dpn_id_2}    ${Bridge-2}-eth1    ${TOOLS_SYSTEM_2_IP}
 201     Check For Elements At URI    ${TUNNEL_TRANSPORTZONE}/transport-zone/${itm_created[0]}    ${Itm-no-vlan}
 202
 203 Check Tunnel Delete On OVS
 204     [Arguments]    ${connection-id}    ${tunnel}
 205     [Documentation]    Verifies the Tunnel is deleted from OVS.
 206     Switch Connection    ${connection-id}
 207     ${return} =    Execute Command    sudo ovs-vsctl show
 208     log    ${return}
 209     Should Not Contain    ${return}    ${tunnel}
 210     [Return]    ${return}
 211
 212 Check Table0 Entry For 2 Dpn
 213     [Arguments]    ${connection_id}    ${Bridgename}    ${port-num1}
 214     [Documentation]    Checks the Table 0 entry in the OVS when flows are dumped.
 215     Switch Connection    ${connection_id}
 216     Log    ${connection_id}
 217     ${check}    Execute Command    sudo ovs-ofctl -O OpenFlow13 dump-flows ${Bridgename}
 218     Log    ${check}
 219     Should Contain    ${check}    in_port=${port-num1}
 220     [Return]    ${check}
 221
 222 Check ITM Tunnel State
 223     [Arguments]    ${tunnel1}    ${tunnel2}
 224     [Documentation]    Verifies the Tunnel is deleted from datastore
 225     ${resp}    RequestsLibrary.Get Request    session    ${OPERATIONAL_API}/itm-state:tunnels_state/
 226     Should Not Contain    ${resp.content}    ${tunnel1}    ${tunnel2}
 227
 228 Verify Tunnel Status as UP
 229     [Arguments]    ${Transport_zone}
 230     [Documentation]    Verify that the number of tunnels are UP
 231     ${No_of_Teps}    Issue_Command_On_Karaf_Console    ${TEP_SHOW}
 232     ${Lines_of_TZA}    Get Lines Containing String    ${No_of_Teps}    ${Transport_zone}
 233     ${Expected_Node_Count}    Get Line Count    ${Lines_of_TZA}
 234     ${no_of_tunnels}    Issue_Command_On_Karaf_Console    ${TEP_SHOW_STATE}
 235     ${lines_of_VXLAN}    Get Lines Containing String    ${no_of_tunnels}    VXLAN
 236     Should Contain    ${no_of_tunnels}    ${STATE_UP}
 237     Should Not Contain    ${no_of_tunnels}    ${STATE_DOWN}
 238     Should Not Contain    ${no_of_tunnels}    ${STATE_UNKNOWN}
 239     ${Actual_Tunnel_Count}    Get Line Count    ${lines_of_VXLAN}
 240     ${Expected_Tunnel_Count}    Set Variable    ${Expected_Node_Count*${Expected_Node_Count - 1}}
 241     Should Be Equal As Strings    ${Actual_Tunnel_Count}    ${Expected_Tunnel_Count}
 242
 243 Verify Tunnel Status
 244     [Arguments]    ${tunnel_names}    ${tunnel_status}
 245     [Documentation]    Verifies if all tunnels in the input, has the expected status(UP/DOWN/UNKNOWN)
 246     ${tep_result} =    KarafKeywords.Issue_Command_On_Karaf_Console    ${TEP_SHOW_STATE}
 247     : FOR    ${tunnel}    IN    @{tunnel_names}
 248     \    ${tep_output} =    String.Get Lines Containing String    ${tep_result}    ${tunnel}
 249     \    BuiltIn.Should Contain    ${tep_output}    ${tunnel_status}
 250
 251 Get Tunnels On OVS
 252     [Arguments]    ${connection_id}
 253     [Documentation]    Retrieves the list of tunnel ports present on OVS
 254     SSHLibrary.Switch Connection    ${connection_id}
 255     ${ovs_result} =    Utils.Write Commands Until Expected Prompt    sudo ovs-vsctl show    ${DEFAULT_LINUX_PROMPT_STRICT}
 256     ${tunnel_names}    BuiltIn.Create List
 257     ${tunnels} =    String.Get Lines Matching Regexp    ${ovs_result}    Interface "tun.*"    True
 258     @{tunnels_list} =    String.Split To Lines    ${tunnels}
 259     : FOR    ${tun}    IN    @{tunnels_list}
 260     \    ${tun_list}    BuiltIn.Should Match Regexp    @{tunnels_list}    tun.*\\w
 261     \    Collections.Append To List    ${tunnel_names}    ${tun_list}
 262     ${items_in_list} =    BuiltIn.Get Length    ${tunnel_names}
 263     [Return]    ${Tunnel_Names}
 264
 265 Get Tunnel
 266     [Arguments]    ${src}    ${dst}    ${type}
 267     [Documentation]    This keyword returns tunnel interface name between source DPN and destination DPN.
 268     ${resp} =    RequestsLibrary.Get Request    session    ${CONFIG_API}/itm-state:tunnel-list/internal-tunnel/${src}/${dst}/${type}/
 269     BuiltIn.Should Be Equal As Strings    ${resp.status_code}    ${RESP_CODE}
 270     BuiltIn.Should Contain    ${resp.content}    ${src}
 271     BuiltIn.Should Contain    ${resp.content}    ${dst}
 272     ${json} =    Utils.Json Parse From String    ${resp.content}
 273     ${tunnel} =    BuiltIn.Run Keyword If    "tunnel-interface-names" in "${json}"    Get Tunnel Interface Name    ${json["internal-tunnel"][0]}    tunnel-interface-names
 274     [Return]    ${tunnel}
 275
 276 Get Tunnel Interface Name
 277     [Arguments]    ${json}    ${expected_tunnel_interface_name}
 278     [Documentation]    This keyword extracts tunnel interface name from json given as input.
 279     ${tunnels} =    Collections.Get From Dictionary    ${json}    ${expected_tunnel_interface_name}
 280     [Return]    ${tunnels[0]}
 281
 282 Verify All Tunnel Delete on DS
 283     [Documentation]    This keyword confirms that tunnels are not present by giving command from karaf console.
 284     Verify Tunnel Delete on DS    tun
 285
 286 Verify Tunnel Delete on DS
 287     [Arguments]    ${tunnel}
 288     [Documentation]    This keyword confirms that specified tunnel is not present by giving command from karaf console.
 289     ${output} =    KarafKeywords.Issue Command On Karaf Console    ${TEP_SHOW_STATE}
 290     BuiltIn.Should Not Contain    ${output}    ${tunnel}
 291
 292 SRM Start Suite
 293     [Documentation]    Start suite for service recovery.
 294     Genius Suite Setup
 295     ${dpn_Id_1} =    Genius.Get Dpn Ids    ${conn_id_1}
 296     ${dpn_Id_2} =    Genius.Get Dpn Ids    ${conn_id_2}
 297     Genius.Create Vteps    ${dpn_Id_1}    ${dpn_Id_2}    ${TOOLS_SYSTEM_IP}    ${TOOLS_SYSTEM_2_IP}    ${vlan}    ${gateway-ip}
 298     ${tunnel} =    BuiltIn.Wait Until Keyword Succeeds    40    20    Genius.Get Tunnel    ${dpn_Id_1}    ${dpn_Id_2}
 299     ...    odl-interface:tunnel-type-vxlan
 300     BuiltIn.Wait Until Keyword Succeeds    60s    5s    Genius.Verify Tunnel Status as UP    TZA
 301     Genius Test Teardown    ${data_models}
 302
 303 SRM Stop Suite
 304     [Documentation]    Stop suite for service recovery.
 305     Delete All Vteps
 306     Genius Test Teardown    ${data_models}
 307     Genius Suite Teardown