csit/suites/bgpcep/bgpingest/manypeers_changecount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from many iBGP peers, data change counter is used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py processes as iBGP peers.
  12 ...               This is analogue of single peer performance suite, which uses many peers.
  13 ...               Each peer is of ibgp type, and they contribute to the same example-bgp-rib,
  14 ...               and thus to the same single example-ipv4-topology.
  15 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  16 ...
  17 ...               This suite requires odl-bgpcep-data-change-counter to be installed so
  18 ...               make sure it is added to "install-features" of any jobs that are going to invoke it.
  19 ...               Use the other version of the suite (manypeers_prefixcount.robot) if the feature does not work.
  20 ...
  21 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  22 ...               Data change counter is a lightweight way to detect "work is being done".
  23 ...               WaitUtils provide a nice Keyword to wait for stability, but it needs
  24 ...               initial value, that is why Store_Change_Count appears just before work-inducing action.
  25 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  26 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  27 ...
  28 ...               TODO: Currently, if a bug causes zero increase of data changes,
  29 ...               affected test cases will wait for max time. Reconsider.
  30 ...               If zero increase is allowed as stable, higher number of repetitions should be required.
  31 ...
  32 ...               ODL distinguishes peers by their IP addresses.
  33 ...               Currently, this suite requires python utils to be started on ODL System,
  34 ...               to guarantee IP address block is available for them to bind to.
  35 ...               TODO: Figure out how to use Docker and docker IP pool available in RelEng.
  36 ...
  37 ...               Currently, 127.0.0.1 is hardcoded as the first peer address to use.
  38 ...               TODO: Figure out how to make it configurable.
  39 ...               As peer IP adresses are set incrementally, we need ipaddr to be used in Robot somehow.
  40 ...
  41 ...               TODO: Is there a need for version of this suite where ODL connects to pers?
  42 ...               Note that configuring ODL is slow, which may affect measured performance singificantly.
  43 ...               Advanced TODO: Give manager ability to start pushing on trigger long after connections are established.
  44 Suite Setup       Setup_Everything
  45 Suite Teardown    Teardown_Everything
  46 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  47 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  48 Library           DateTime
  49 Library           RequestsLibrary
  50 Library           SSHLibrary    timeout=10s
  51 Variables         ${CURDIR}/../../../variables/Variables.py
  52 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  53 Resource          ${CURDIR}/../../../libraries/ChangeCounter.robot
  54 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  55 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  56 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  57 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  58 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  59 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  60
  61 *** Variables ***
  62 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  63 ${HOLDTIME}       180
  64 ${HOLDTIME_CHANGE_COUNT}    ${HOLDTIME}
  65 ${COUNT}          1000000
  66 ${COUNT_CHANGE_COUNT}    ${COUNT}
  67 ${FIRST_PEER_IP}    127.0.0.1
  68 ${MULTIPLICITY}    2    # May be increased after Bug 4488 is fixed.
  69 ${MULTIPLICITY_CHANGE_COUNT}    ${MULTIPLICITY}
  70 ${CHECK_PERIOD}    1
  71 ${CHECK_PERIOD_CHANGE_COUNT}    ${CHECK_PERIOD}
  72 ${REPETITIONS}    5
  73 # TODO: Figure out reliable value. Even without Bug 4488 hitting, something
  74 # (OperationLimiter or garbage collection) is causing failures when low value is used.
  75 ${REPETITIONS_CHANGE_COUNT}    ${REPETITIONS}
  76 # TODO: Option names can be better.
  77 ${last_change_count}    -1
  78
  79 *** Test Cases ***
  80 Check_For_Empty_Ipv4_Topology_Before_Talking
  81     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  82     [Tags]    critical
  83     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  84     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  85
  86 Reconfigure_ODL_To_Accept_Connections
  87     [Documentation]    Configure BGP peer modules with initiate-connection set to false.
  88     : FOR    ${index}    IN RANGE    1    ${MULTIPLICITY}+1
  89     \    ${peer_name} =    BuiltIn.Set_Variable    example-bgp-peer-${index}
  90     \    ${peer_ip} =    BuiltIn.Evaluate    str(ipaddr.IPAddress('${FIRST_PEER_IP}') + ${index} - 1)    modules=ipaddr
  91     \    ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': '${peer_name}', 'IP': '${peer_ip}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'HOLDTIME': '${HOLDTIME_CHANGE_COUNT}', 'INITIATE': 'false'}
  92     \    ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
  93     # FIXME: Add testcase to change bgpcep and protocol log levels, when a Keyword that does it without messing with current connection is ready.
  94
  95 Wait_For_Data_Change_Counter_Ready
  96     [Documentation]    Data change counter might have been slower to start than ipv4 topology, wait for it.
  97     BuiltIn.Wait_Until_Keyword_Succeeds    60s    1s    ChangeCounter.Get_Change_Count
  98
  99 Reconfigure_Data_Change_Counter
 100     [Documentation]    Configure data change counter to count transactions in example-ipv4-topology instead of example-linkstate-topology.
 101     ChangeCounter.Reconfigure_Topology_Name    example-ipv4-topology
 102
 103 Set_Logging_Levels
 104     [Documentation]    For Bug 4488 examination, more verbose logging may be needed.
 105     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${BGPCEP_LOG_LEVEL}    protocol_level=${PROTOCOL_LOG_LEVEL}
 106
 107 Start_Talking_BGP_Manager
 108     [Documentation]    Start Python manager to connect speakers to ODL.
 109     Store_Change_Count
 110     # Myport value is needed for checking whether connection at precise port was established.
 111     BGPSpeaker.Start_BGP_Manager    --amount=${COUNT_CHANGE_COUNT} --multiplicity=${MULTIPLICITY} --myip=${FIRST_PEER_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT}
 112
 113 Wait_For_Stable_Talking_Ipv4_Topology
 114     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking stability of the change counter.
 115     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT}    repetitions=${REPETITIONS_CHANGE_COUNT}    count_to_overcome=${last_change_count}
 116
 117 Check_Talking_Ipv4_Topology_Count
 118     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 119     [Tags]    critical
 120     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT}
 121
 122 Kill_Talking_BGP_Speakers
 123     [Documentation]    Abort the Python speakers. Also, attempt to stop failing fast.
 124     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 125     Store_Change_Count
 126     BGPSpeaker.Kill_BGP_Speaker
 127     FailFast.Do_Not_Fail_Fast_From_Now_On
 128     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 129     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 130
 131 Wait_For_Stable_Ipv4_Topology_After_Talking
 132     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 133     [Tags]    critical
 134     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT}    repetitions=${REPETITIONS_CHANGE_COUNT}    count_to_overcome=${last_change_count}
 135
 136 Check_For_Empty_Ipv4_Topology_After_Talking
 137     [Documentation]    Example-ipv4-topology should be empty now.
 138     [Tags]    critical
 139     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 140
 141 Restore_Logging_Levels
 142     [Documentation]    Set logging on bgpcep and protocol to default values.
 143     KarafKeywords.Set_Bgpcep_Log_Levels
 144
 145 Restore_Data_Change_Counter_Configuration
 146     [Documentation]    Configure data change counter back to count transactions affecting example-linkstate-topology.
 147     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 148     ChangeCounter.Reconfigure_Topology_Name    example-linkstate-topology
 149
 150 Delete_Bgp_Peer_Configuration
 151     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 152     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 153     # TODO: Is it useful to extract peer naming logic to separate Keyword?
 154     : FOR    ${index}    IN RANGE    1    ${MULTIPLICITY}+1
 155     \    ${template_as_string}=    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer-${index}'}
 156     \    ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLESFOLDER}${/}bgp_peer    ${template_as_string}
 157
 158 *** Keywords ***
 159 Setup_Everything
 160     [Documentation]    Setup imported resources, SSH-login to ODL system,
 161     ...    create HTTP session, put Python tool to ODL system.
 162     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 163     ConfigViaRestconf.Setup_Config_Via_Restconf
 164     ChangeCounter.CC_Setup
 165     PrefixCounting.PC_Setup
 166     KarafKeywords.Open Controller Karaf Console On Background
 167     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 168     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}
 169     Utils.Flexible_Controller_Login
 170     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 171     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 172     # TODO: Alternatively, create variable in Variables which starts with http.
 173     # Both TODOs would probably need to update every suite relying on current Variables.
 174     SSHKeywords.Require_Python
 175     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 176     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/manage_play.py
 177     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 178     # Calculate the timeout value based on how many routes are going to be pushed
 179     ${period} =    DateTime.Convert_Time    ${CHECK_PERIOD_CHANGE_COUNT}    result_format=number
 180     ${timeout} =    BuiltIn.Evaluate    ${COUNT_CHANGE_COUNT} * 3 / 10000 + ${period} * (${REPETITIONS_CHANGE_COUNT} + 1)
 181     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 182     ${timeout} =    BuiltIn.Evaluate    ${COUNT_CHANGE_COUNT} * 2 / 10000 + ${period} * (${REPETITIONS_CHANGE_COUNT} + 1)
 183     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${timeout}
 184
 185 Teardown_Everything
 186     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 187     KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 188     ConfigViaRestconf.Teardown_Config_Via_Restconf
 189     RequestsLibrary.Delete_All_Sessions
 190     SSHLibrary.Close_All_Connections
 191
 192 Store_Change_Count
 193     [Documentation]    Get the count of changes from BGP change counter. Ignore error or store the value.
 194     ${status}    ${count} =    BuiltIn.Run_Keyword_And_Ignore_Error    ChangeCounter.Get_Change_Count
 195     BuiltIn.Run_Keyword_If    '${status}' == 'PASS'    BuiltIn.Set_Suite_Variable    ${last_change_count}    ${count}