csit/suites/bgpcep/bgpingest/singlepeer_prefixcount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is NOT used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py as single iBGP peer.
  12 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  13 ...
  14 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  15 ...               State of "work is being done" is detected by increasing value of prefixes in topology.
  16 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  17 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  18 ...
  19 ...               Brief description how to configure BGP peer can be found here:
  20 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:User_Guide#BGP_Peer
  21 ...               http://docs.opendaylight.org/en/stable-boron/user-guide/bgp-user-guide.html#bgp-peering
  22 ...
  23 ...               TODO: Currently, if a bug causes prefix count to remain at zero,
  24 ...               affected test cases will wait for max time. Reconsider.
  25 ...               If zero is allowed as stable, higher period or repetitions would be required.
  26 ...
  27 ...               The prefix counting is quite heavyweight and may induce large variation in time.
  28 ...               Try the other version of the suite (singlepeer_changecount.robot) to get better precision.
  29 Suite Setup       Setup_Everything
  30 Suite Teardown    Teardown_Everything
  31 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  32 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  33 Library           SSHLibrary    timeout=10s
  34 Library           RequestsLibrary
  35 Resource          ${CURDIR}/../../../variables/Variables.robot
  36 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  37 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  38 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  39 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  40 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  41 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  42 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  43
  44 *** Variables ***
  45 ${BGP_TOOL_LOG_LEVEL}    info
  46 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  47 ${CHECK_PERIOD}    1
  48 ${CHECK_PERIOD_PREFIX_COUNT}    ${CHECK_PERIOD}
  49 ${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    ${CHECK_PERIOD_PREFIX_COUNT}
  50 ${COUNT}          1000000
  51 ${COUNT_PREFIX_COUNT}    ${COUNT}
  52 ${COUNT_PREFIX_COUNT_SINGLE}    ${COUNT_PREFIX_COUNT}
  53 ${HOLDTIME}       180
  54 ${HOLDTIME_PREFIX_COUNT}    ${HOLDTIME}
  55 ${HOLDTIME_PREFIX_COUNT_SINGLE}    ${HOLDTIME_PREFIX_COUNT}
  56 ${INSERT}         1
  57 ${KARAF_LOG_LEVEL}    INFO
  58 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  59 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  60 ${PREFILL}        0
  61 ${REPETITIONS}    1
  62 ${REPETITIONS_PREFIX_COUNT}    ${REPETITIONS}
  63 ${REPETITIONS_PREFIX_COUNT_SINGLE}    ${REPETITIONS_PREFIX_COUNT}
  64 ${RESULTS_FILE_NAME}    bgp.csv
  65 ${TEST_DURATION_MULTIPLIER}    1
  66 ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT}    ${TEST_DURATION_MULTIPLIER}
  67 ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_SINGLE}    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT}
  68 ${UPDATE}         single
  69 ${WITHDRAW}       0
  70 ${RIB_INSTANCE}    example-bgp-rib
  71 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  72 ${DEVICE_NAME}    controller-config
  73 ${BGP_PEER_NAME}    example-bgp-peer
  74 # TODO: Option names can be better.
  75
  76 *** Test Cases ***
  77 Check_For_Empty_Ipv4_Topology_Before_Talking
  78     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  79     [Tags]    critical
  80     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  81     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  82
  83 Reconfigure_ODL_To_Accept_Connection
  84     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  85     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME_PREFIX_COUNT_SINGLE}    PEER_PORT=${BGP_TOOL_PORT}
  86     ...    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  87     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
  88
  89 Change_Karaf_Logging_Levels
  90     [Documentation]    We may want to set more verbose logging here after configuration is done.
  91     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
  92
  93 Start_Talking_BGP_Speaker
  94     [Documentation]    Start Python speaker to connect to ODL.
  95     # Myport value is needed for checking whether connection at precise port was established.
  96     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_PREFIX_COUNT_SINGLE} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
  97
  98 Wait_For_Stable_Talking_Ipv4_Topology
  99     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking stability of prefix count.
 100     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    repetitions=${REPETITIONS_PREFIX_COUNT_SINGLE}    excluded_count=0
 101
 102 Check_Talking_Ipv4_Topology_Count
 103     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 104     [Tags]    critical
 105     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 106     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_PREFIX_COUNT_SINGLE}
 107
 108 Kill_Talking_BGP_Speaker
 109     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 110     [Tags]    critical
 111     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 112     BGPSpeaker.Kill_BGP_Speaker
 113     FailFast.Do_Not_Fail_Fast_From_Now_On
 114     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 115     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 116
 117 Store_Results_For_Talking_BGP_Speaker
 118     [Documentation]    Store results for plotting
 119     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 120     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 121     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 122     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    prefixcount-talking-totals-${RESULTS_FILE_NAME}
 123     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    prefixcount-talking-performance-${RESULTS_FILE_NAME}
 124
 125 Wait_For_Stable_Ipv4_Topology_After_Talking
 126     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 127     [Tags]    critical
 128     # TODO: Is is possible to have failed at Check_Talking_Ipv4_Topology_Count and still have initial period of constant count?
 129     # FIXME: If yes, do count here to get the initial value and use it (if nonzero).
 130     # TODO: If yes, decide whether access to the FailFast state should have keyword or just variable name.
 131     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    repetitions=${REPETITIONS_PREFIX_COUNT_SINGLE}    excluded_count=${COUNT_PREFIX_COUNT_SINGLE}
 132
 133 Check_For_Empty_Ipv4_Topology_After_Talking
 134     [Documentation]    Example-ipv4-topology should be empty now.
 135     [Tags]    critical
 136     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 137     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 138
 139 Start_Listening_BGP_Speaker
 140     [Documentation]    Start Python speaker in listening mode.
 141     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_PREFIX_COUNT_SINGLE} --listen --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 142
 143 Reconfigure_ODL_To_Initiate_Connection
 144     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
 145     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME_PREFIX_COUNT_SINGLE}    PEER_PORT=${BGP_TOOL_PORT}
 146     ...    INITIATE=true    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=false    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 147     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 148
 149 Wait_For_Stable_Listening_Ipv4_Topology
 150     [Documentation]    Wait until example-ipv4-topology becomes stable.
 151     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    repetitions=${REPETITIONS_PREFIX_COUNT_SINGLE}    excluded_count=0
 152
 153 Check_Listening_Ipv4_Topology_Count
 154     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 155     [Tags]    critical
 156     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 157     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_PREFIX_COUNT_SINGLE}
 158
 159 Kill_Listening_BGP_Speaker
 160     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 161     [Tags]    critical
 162     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 163     BGPSpeaker.Kill_BGP_Speaker
 164     FailFast.Do_Not_Fail_Fast_From_Now_On
 165     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 166     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 167
 168 Store_Results_For_Listening_BGP_Speaker
 169     [Documentation]    Store results for plotting
 170     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 171     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 172     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 173     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    prefixcount-listening-totals-${RESULTS_FILE_NAME}
 174     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    prefixcount-listening-performance-${RESULTS_FILE_NAME}
 175
 176 Wait_For_Stable_Ipv4_Topology_After_Listening
 177     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 178     [Tags]    critical
 179     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT_SINGLE}    repetitions=${REPETITIONS_PREFIX_COUNT_SINGLE}    excluded_count=${COUNT_PREFIX_COUNT_SINGLE}
 180
 181 Check_For_Empty_Ipv4_Topology_After_Listening
 182     [Documentation]    Example-ipv4-topology should be empty now.
 183     [Tags]    critical
 184     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 185     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 186
 187 Restore_Karaf_Logging_Levels
 188     [Documentation]    Set logging on bgpcep and protocol to the global value.
 189     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 190
 191 Delete_Bgp_Peer_Configuration
 192     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 193     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 194     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 195     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 196
 197 *** Keywords ***
 198 Setup_Everything
 199     [Documentation]    Setup imported resources, SSH-login to tools system,
 200     ...    create HTTP session, put Python tool to tools system.
 201     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 202     TemplatedRequests.Create_Default_Session
 203     PrefixCounting.PC_Setup
 204     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    timeout=125    max_retries=0
 205     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 206     # TODO: Alternatively, create variable in Variables which starts with http.
 207     # Both TODOs would probably need to update every suite relying on current Variables.
 208     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 209     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
 210     SSHKeywords.Flexible_Mininet_Login
 211     SSHKeywords.Require_Python
 212     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 213     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 214     # Calculate the timeout value based on how many routes are going to be pushed
 215     # TODO: Replace 20 with some formula from period and repetitions.
 216     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_PREFIX_COUNT_SINGLE} * (${COUNT_PREFIX_COUNT_SINGLE} * 9.0 / 10000 + 20)
 217     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 218     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 219
 220 Teardown_Everything
 221     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 222     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 223     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 224     RequestsLibrary.Delete_All_Sessions
 225     SSHLibrary.Close_All_Connections
 226
 227 Store_File_To_Workspace
 228     [Arguments]    ${src_file_name}    ${dst_file_name}
 229     [Documentation]    Store the provided file from the SSH client to workspace.
 230     ${files}=    SSHLibrary.List Files In Directory    .
 231     ${output_log}=    SSHLibrary.Execute_Command    cat ${src_file_name}
 232     BuiltIn.Log    ${output_log}
 233     Create File    ${dst_file_name}    ${output_log}