csit/suites/bgpcep/bgpuser/ebgp_peers_basic.robot

   1 *** Settings ***
   2 Documentation     Basic tests for eBGP application peers.
   3 ...
   4 ...               Copyright (c) 2015-2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               Test suite performs basic eBGP functional tests:
  11 ...               Two eBGP peers advertise the same group of prefixes (aka BGP HA)
  12 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:BGP
  13 ...               Reported bugs:
  14 ...               Bug 4834 - ODL controller announces the same route twice (two eBGP scenario aka HA)
  15 ...               Bug 4835 - Routes not withdrawn when eBGP peers are disconnected (the same prefixes announced)
  16 ...
  17 ...               For versions Fluorine and above, there are test cases:
  18 ...               TC_LAS (test case local AS)
  19 ...               - configuration of ebgp with local-as and ibgp without local-as
  20 ...               - connect bgp speakers (play.py) to both peers and check their connection
  21 ...               - check adj-rib-out on both peers, expecting local-as in as-sequence on both peers.
  22 ...
  23 ...               TODO: Extend testsuite by tests dedicated to path selection algorithm
  24 ...               TODO: Choose keywords used by more than one test suite to be placed in a common place.
  25 Suite Setup       Setup_Everything
  26 Suite Teardown    BgpOperations.Teardown_Everything
  27 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  28 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  29 Library           Collections
  30 Library           OperatingSystem
  31 Library           RequestsLibrary
  32 Resource          ../../../libraries/BGPcliKeywords.robot
  33 Resource          ../../../libraries/BgpOperations.robot
  34 Resource          ../../../libraries/BGPSpeaker.robot
  35 Resource          ../../../libraries/CompareStream.robot
  36 Resource          ../../../libraries/FailFast.robot
  37 Resource          ../../../libraries/KillPythonTool.robot
  38 Resource          ../../../libraries/SetupUtils.robot
  39 Resource          ../../../libraries/SSHKeywords.robot
  40 Resource          ../../../libraries/TemplatedRequests.robot
  41 Resource          ../../../variables/Variables.robot
  42 Resource          ../../../libraries/WaitForFailure.robot
  43 Variables         ../../../variables/bgpuser/variables.py    ${TOOLS_SYSTEM_IP}    ${ODL_STREAM}
  44
  45 *** Variables ***
  46 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  47 ${HOLDTIME}       180
  48 ${BGP_PEER_LOG_LEVEL}    debug
  49 ${ODL_LOG_LEVEL}    INFO
  50 ${ODL_BGP_LOG_LEVEL}    DEFAULT
  51 ${iBGP_PEER1_IP}    127.0.0.1
  52 ${eBGP_PEER1_IP}    127.0.0.3
  53 ${eBGP_PEER2_IP}    127.0.0.4
  54 ${iBGP_PEER1_FIRST_PREFIX_IP}    8.1.0.0
  55 ${eBGP_PEERS_FIRST_PREFIX_IP}    8.0.0.0
  56 ${eBGP_PEER1_FIRST_PREFIX_IP}    ${eBGP_PEERS_FIRST_PREFIX_IP}
  57 ${eBGP_PEER2_FIRST_PREFIX_IP}    ${eBGP_PEERS_FIRST_PREFIX_IP}
  58 ${eBGP_PEER1_NEXT_HOP}    1.1.1.1
  59 ${eBGP_PEER2_NEXT_HOP}    2.2.2.2
  60 ${PREFIX_LEN}     28
  61 ${iBGP_PEER1_PREFIX_LEN}    ${PREFIX_LEN}
  62 ${eBGP_PEER1_PREFIX_LEN}    ${PREFIX_LEN}
  63 ${eBGP_PEER2_PREFIX_LEN}    ${PREFIX_LEN}
  64 ${PREFIX_COUNT}    2
  65 ${iBGP_PEER1_PREFIX_COUNT}    0
  66 ${eBGP_PEER1_PREFIX_COUNT}    ${PREFIX_COUNT}
  67 ${eBGP_PEER2_PREFIX_COUNT}    ${PREFIX_COUNT}
  68 ${eBGP_PEERS_AS}    32768
  69 ${eBGP_PEER1_AS}    ${eBGP_PEERS_AS}
  70 ${eBGP_PEER2_AS}    ${eBGP_PEERS_AS}
  71 ${iBGP_PEER1_LOG_FILE}    bgp_peer1.log
  72 ${eBGP_PEER1_LOG_FILE}    ebgp_peer1.log
  73 ${eBGP_PEER2_LOG_FILE}    ebgp_peer2.log
  74 ${iBGP_PEER1_COMMAND}    python play.py --firstprefix ${iBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${iBGP_PEER1_PREFIX_LEN} --amount ${iBGP_PEER1_PREFIX_COUNT} --myip=${iBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --${BGP_PEER_LOG_LEVEL} --logfile ${iBGP_PEER1_LOG_FILE}
  75 ${eBGP_PEER1_COMMAND}    python play.py --firstprefix ${eBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${eBGP_PEER1_PREFIX_LEN} --amount ${eBGP_PEER1_PREFIX_COUNT} --myip=${eBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --nexthop ${eBGP_PEER1_NEXT_HOP} --asnumber ${eBGP_PEER1_AS} --${BGP_PEER_LOG_LEVEL} --logfile ${eBGP_PEER1_LOG_FILE}
  76 ${eBGP_PEER2_COMMAND}    python play.py --firstprefix ${eBGP_PEER2_FIRST_PREFIX_IP} --prefixlen ${eBGP_PEER2_PREFIX_LEN} --amount ${eBGP_PEER2_PREFIX_COUNT} --myip=${eBGP_PEER2_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --nexthop ${eBGP_PEER2_NEXT_HOP} --asnumber ${eBGP_PEER2_AS} --${BGP_PEER_LOG_LEVEL} --logfile ${eBGP_PEER2_LOG_FILE}
  77 ${iBGP_PEER1_OPTIONS}    &>${iBGP_PEER1_LOG_FILE}
  78 ${eBGP_PEER1_OPTIONS}    &>${eBGP_PEER1_LOG_FILE}
  79 ${eBGP_PEER2_OPTIONS}    &>${eBGP_PEER2_LOG_FILE}
  80 ${DEFAULT_LOG_CHECK_TIMEOUT}    20s
  81 ${DEFAULT_LOG_CHECK_PERIOD}    1s
  82 ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    10s
  83 ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    1s
  84 ${RIB_INSTANCE}    example-bgp-rib
  85 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  86 ${DEVICE_NAME}    controller-config
  87 ${DEFAULT_AS}     64496
  88 ${LOCAL_AS}       65432
  89 ${eBGP_AS}        64497
  90
  91 *** Test Cases ***
  92 Configure_BGP_Peers
  93     [Documentation]    Configure an iBGP and two eBGP peers
  94     [Tags]    critical
  95     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ibgp-peer1    IP=${iBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  96     ...    PEER_ROLE=ibgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  97     ...    RR_CLIENT=false
  98     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}
  99     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ebgp-peer1    IP=${eBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
 100     ...    PEER_ROLE=ebgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 101     ...    RR_CLIENT=false    AS_NUMBER=${eBGP_PEER1_AS}
 102     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 103     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ebgp-peer2    IP=${eBGP_PEER2_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
 104     ...    PEER_ROLE=ebgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 105     ...    RR_CLIENT=false    AS_NUMBER=${eBGP_PEER2_AS}
 106     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 107
 108 Connect_iBGP_Peer1
 109     [Documentation]    Connect BGP peer
 110     [Tags]    critical
 111     SSHLibrary.Switch Connection    ibgp_peer1_console
 112     Start_Console_Tool    ${iBGP_PEER1_COMMAND}    ${iBGP_PEER1_OPTIONS}
 113     Read_And_Fail_If_Prompt_Is_Seen
 114     BgpOperations.Check_Example_IPv4_Topology_Does_Not_Contain    prefix
 115
 116 Connect_eBGP_Peer1
 117     [Documentation]    Connect BGP peer
 118     [Tags]    critical
 119     SSHLibrary.Switch Connection    ebgp_peer1_console
 120     Start_Console_Tool    ${eBGP_PEER1_COMMAND}    ${eBGP_PEER1_OPTIONS}
 121     Read_And_Fail_If_Prompt_Is_Seen
 122
 123 Check_IPv4_Topology_For_First_Path
 124     [Documentation]    The IPv4 topology shall contain the route announced by the first eBGP
 125     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    "node-id":"${eBGP_PEER1_NEXT_HOP}"
 126     BgpOperations.Check_Example_IPv4_Topology_Content    "prefix":"${eBGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}"
 127
 128 iBGP_Check_Log_For_Introduced_Prefixes
 129     [Documentation]    Check incomming updates for introduced routes
 130     [Tags]    critical
 131     SSHLibrary.Switch Connection    ibgp_peer1_console
 132     ${total_prefix_count}=    BuiltIn.Evaluate    ${eBGP_PEER1_PREFIX_COUNT}
 133     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${total_prefix_count}
 134     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER1_NEXT_HOP}
 135     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER1_PREFIX_COUNT}
 136     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER2_NEXT_HOP}
 137     BuiltIn.Should_Be_Equal_As_Integers    ${count}    0
 138
 139 Connect_eBGP_Peer2
 140     [Documentation]    Connect BGP peer and check empty topology
 141     [Tags]    critical
 142     SSHLibrary.Switch Connection    ebgp_peer2_console
 143     Start_Console_Tool    ${eBGP_PEER2_COMMAND}    ${eBGP_PEER2_OPTIONS}
 144     Read_And_Fail_If_Prompt_Is_Seen
 145
 146 Disconnect_eBGP_Peer1
 147     [Documentation]    Stop BGP peer, log topology and store logs
 148     [Tags]    critical
 149     SSHLibrary.Switch Connection    ebgp_peer1_console
 150     Stop_Console_Tool
 151     Store_File_To_Workspace    ${eBGP_PEER1_LOG_FILE}    ${eBGP_PEER1_LOG_FILE}
 152
 153 Check_IPv4_Topology_For_Second_Path
 154     [Documentation]    The IPv4 topology shall contain the route announced by the second eBGP now
 155     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    "node-id":"${eBGP_PEER2_NEXT_HOP}"
 156     BgpOperations.Check_Example_IPv4_Topology_Content    "prefix":"${eBGP_PEER2_FIRST_PREFIX_IP}/${PREFIX_LEN}"
 157
 158 iBGP_Check_Log_For_Updated_Prefixes
 159     [Documentation]    Check incomming updates for updated routes
 160     [Tags]    critical
 161     SSHLibrary.Switch Connection    ibgp_peer1_console
 162     ${total_prefix_count}=    BuiltIn.Evaluate    ${eBGP_PEER1_PREFIX_COUNT} + ${eBGP_PEER2_PREFIX_COUNT}
 163     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${total_prefix_count}
 164     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER1_NEXT_HOP}
 165     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER1_PREFIX_COUNT}
 166     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER2_NEXT_HOP}
 167     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER2_PREFIX_COUNT}
 168     [Teardown]    Report_Failure_Due_To_Bug    4834
 169
 170 Disconnect_eBGP_Peer2
 171     [Documentation]    Stop BGP peer, store logs and wait for empty topology
 172     [Tags]    critical
 173     SSHLibrary.Switch Connection    ebgp_peer2_console
 174     Stop_Console_Tool
 175     Store_File_To_Workspace    ${eBGP_PEER2_LOG_FILE}    ${eBGP_PEER2_LOG_FILE}
 176
 177 Check_For_Empty_IPv4_Topology
 178     [Documentation]    The IPv4 topology shall be empty
 179     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Does_Not_Contain    prefix
 180     [Teardown]    Report_Failure_Due_To_Bug    4835
 181
 182 iBGP_Check_Log_For_Withdrawn_Prefixes
 183     [Documentation]    Check incomming updates for withdrawn routes
 184     [Tags]    critical
 185     SSHLibrary.Switch Connection    ibgp_peer1_console
 186     ${prefixes_to_be_removed}=    BuiltIn.Evaluate    max(${eBGP_PEER1_PREFIX_COUNT}, ${eBGP_PEER2_PREFIX_COUNT})
 187     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    withdrawn_prefix_received:    ${prefixes_to_be_removed}
 188     [Teardown]    Report_Failure_Due_To_Bug    4835
 189
 190 Disconnect_iBGP_Peer1
 191     [Documentation]    Stop BGP peer, log topology and store logs
 192     [Tags]    critical
 193     SSHLibrary.Switch Connection    ibgp_peer1_console
 194     Stop_Console_Tool
 195     Store_File_To_Workspace    ${iBGP_PEER1_LOG_FILE}    ${iBGP_PEER1_LOG_FILE}
 196
 197 Delete_BGP_Peers_Configuration
 198     [Documentation]    Delete all previously configured BGP peers.
 199     [Tags]    critical
 200     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ibgp-peer1    IP=${iBGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 201     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}
 202     Collections.Set To Dictionary    ${mapping}    NAME=example-ebgp-peer1    IP=${eBGP_PEER1_IP}
 203     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 204     Collections.Set To Dictionary    ${mapping}    NAME=example-ebgp-peer2    IP=${eBGP_PEER2_IP}
 205     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 206
 207 TC_LAS_Reconfigure_Odl_To_Accept_Connection
 208     [Documentation]    Configure neighbors. One ibgp and one ebgp neighbor with local-as configured.
 209     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 210     &{mapping}    Create Dictionary    IP=${iBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 211     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 212     &{mapping}    Create Dictionary    IP=${eBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 213     ...    AS_NUMBER=${LOCAL_AS}    PEER_AS=${eBGP_AS}
 214     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}local_as/ebgp_peer    mapping=${mapping}
 215     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 216
 217 TC_LAS_Start_iBgp_Speaker_And_Verify_Connected
 218     [Documentation]    Verify that peer is present in odl's rib. Peer is configured with local-as.
 219     [Tags]    critical
 220     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 221     SSHLibrary.Switch Connection    ibgp_peer1_console
 222     ${speaker_args}    BuiltIn.Set_Variable    --firstprefix ${iBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${PREFIX_LEN} --amount 1 --myip=${iBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --debug
 223     ${output}    BGPSpeaker.Start_BGP_Speaker_And_Verify_Connected    ${speaker_args}    session=default    speaker_ip=${iBGP_PEER1_IP}
 224     BuiltIn.Log    ${output}
 225
 226 TC_LAS_Start_eBgp_Speaker_And_Verify_Connected
 227     [Documentation]    Verify that peer is present in odl's rib. Peer is configured with local-as.
 228     [Tags]    critical
 229     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 230     SSHLibrary.Switch Connection    ebgp_peer1_console
 231     ${speaker_args}    BuiltIn.Set_Variable    --firstprefix ${eBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${PREFIX_LEN} --amount 1 --asnumber=${eBGP_AS} --myip=${eBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --debug
 232     ${output}    BGPSpeaker.Start_BGP_Speaker_And_Verify_Connected    ${speaker_args}    session=default    speaker_ip=${eBGP_PEER1_IP}
 233     BuiltIn.Log    ${output}
 234
 235 TC_LAS_Verify_iBGP_Rib_Out
 236     [Documentation]    Verifies iBGP's adj-rib-out output. Expects local-as, and ebgp peer-as presence.
 237     [Tags]    critical
 238     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 239     &{mapping}    Create Dictionary    IP=${iBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 240     ...    AS_NUMBER=${LOCAL_AS}    PEER_AS=${eBGP_AS}    PREFIXLEN=${eBGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}
 241     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    TemplatedRequests.Get_As_Json_Templated    ${BGP_VARIABLES_FOLDER}${/}local_as/adj_rib_out    mapping=${mapping}    verify=True
 242
 243 TC_LAS_Verify_eBGP_Rib_Out
 244     [Documentation]    Verifies eBGP's adj-rib-out output. Expects local-as, and ibgp peer-as presence.
 245     [Tags]    critical
 246     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 247     &{mapping}    Create Dictionary    IP=${eBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 248     ...    AS_NUMBER=${LOCAL_AS}    PEER_AS=${DEFAULT_AS}    PREFIXLEN=${iBGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}
 249     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    TemplatedRequests.Get_As_Json_Templated    ${BGP_VARIABLES_FOLDER}${/}local_as/adj_rib_out    mapping=${mapping}    verify=True
 250
 251 TC_LAS_Kill_iBgp_Speaker_After_Talking
 252     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 253     [Tags]    critical
 254     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 255     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 256     SSHLibrary.Switch Connection    ibgp_peer1_console
 257     BGPSpeaker.Kill_BGP_Speaker
 258     FailFast.Do_Not_Fail_Fast_From_Now_On
 259     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 260     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 261
 262 TC_LAS_Kill_eBgp_Speaker_After_Talking
 263     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 264     [Tags]    critical
 265     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 266     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 267     SSHLibrary.Switch Connection    ebgp_peer1_console
 268     BGPSpeaker.Kill_BGP_Speaker
 269     FailFast.Do_Not_Fail_Fast_From_Now_On
 270     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 271     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 272
 273 TC_LAS_Delete_Bgp_Peer_Configurations
 274     [Documentation]    Delete peer configuration.
 275     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 276     &{mapping}    Create Dictionary    IP=${iBGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 277     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 278     &{mapping}    Create Dictionary    IP=${eBGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 279     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}local_as/ebgp_peer    mapping=${mapping}
 280     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 281
 282 *** Keywords ***
 283 Setup_Everything
 284     [Documentation]    Initialize SetupUtils. SSH-login to mininet machine, create HTTP session,
 285     ...    prepare directories for responses, put Python tool to mininet machine, setup imported resources.
 286     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 287     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 288     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ibgp_peer1_console
 289     SSHKeywords.Flexible_Controller_Login
 290     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ebgp_peer1_console
 291     SSHKeywords.Flexible_Controller_Login
 292     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ebgp_peer2_console
 293     SSHKeywords.Flexible_Controller_Login
 294     SSHKeywords.Require_Python
 295     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 296     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 297     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_TOPO_API}    auth=${AUTH}
 298     TemplatedRequests.Create_Default_Session
 299     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_LOG_LEVEL}
 300     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_BGP_LOG_LEVEL} org.opendaylight.bgpcep
 301     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_BGP_LOG_LEVEL} org.opendaylight.protocol
 302
 303 Read_Text_Before_Prompt
 304     [Documentation]    Log text gathered by SSHLibrary.Read_Until_Prompt.
 305     ...    This needs to be a separate keyword just because how Read_And_Fail_If_Prompt_Is_Seen is implemented.
 306     ${text}=    SSHLibrary.Read_Until_Prompt
 307     BuiltIn.Log    ${text}
 308
 309 Store_File_To_Workspace
 310     [Arguments]    ${source_file_name}    ${target_file_name}
 311     [Documentation]    Store the ${source_file_name} to the workspace as ${target_file_name}.
 312     ${output_log}=    SSHLibrary.Execute_Command    cat ${source_file_name}
 313     BuiltIn.Log    ${output_log}
 314     Create File    ${target_file_name}    ${output_log}