csit/suites/bgpcep/bgpuser/ibgp_peers_basic.robot

   1 *** Settings ***
   2 Documentation     Basic tests for iBGP peers.
   3 ...
   4 ...               Copyright (c) 2015-2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               Test suite performs basic iBGP functional test cases for
  11 ...               BGP peers in different roles (iBGP, iBGP RR-client):
  12 ...
  13 ...               Test Case 1: Two iBGP RR-client peers introduce prefixes
  14 ...               Expected result: controller forwards updates towards both peers
  15 ...
  16 ...               Test Case 2: Two iBGP peers: one RR client and one non-client introduces prefixes
  17 ...               Expected result: controller forwards updates towards both peers
  18 ...
  19 ...               Test Case 3: Two iBGP RR non-client peers introduce prefixes
  20 ...               Expected result: controller does not forward any update towards peers
  21 ...
  22 ...               For polices see: https://wiki.opendaylight.org/view/BGP_LS_PCEP:BGP
  23 ...
  24 ...               Covered bugs:
  25 ...               Bug 4791 - BGPSessionImpl: Failed to send message Update logged even all UPDATE mesages received by iBGP peer
  26 ...               Bug 4819 - No routes advertised to one of newly configured iBGP RR-client peer
  27 Suite Setup       Setup_Everything
  28 Suite Teardown    BgpOperations.Teardown_Everything
  29 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  30 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  31 Library           OperatingSystem
  32 Library           RequestsLibrary
  33 Library           DateTime
  34 Variables         ${CURDIR}/../../../variables/Variables.py
  35 Variables         ${CURDIR}/../../../variables/bgpuser/variables.py    ${TOOLS_SYSTEM_IP}    ${ODL_STREAM}
  36 Resource          ${CURDIR}/../../../libraries/BGPcliKeywords.robot
  37 Resource          ${CURDIR}/../../../libraries/BgpOperations.robot
  38 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  39 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  40 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  41 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  42 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  43 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  44 Resource          ${CURDIR}/../../../libraries/Utils.robot
  45 Resource          ${CURDIR}/../../../libraries/WaitForFailure.robot
  46
  47 *** Variables ***
  48 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  49 ${HOLDTIME}       180
  50 ${BGP_PEER_LOG_LEVEL}    debug
  51 ${ODL_LOG_LEVEL}    INFO
  52 ${ODL_BGP_LOG_LEVEL}    DEFAULT
  53 ${DEVICE_NAME}    controller-config
  54 ${BGP_PEER1_IP}    127.0.0.1
  55 ${BGP_PEER2_IP}    127.0.0.2
  56 ${BGP_PEER1_FIRST_PREFIX_IP}    8.1.0.0
  57 ${BGP_PEER2_FIRST_PREFIX_IP}    8.2.0.0
  58 ${PREFIX_LEN}     28
  59 ${BGP_PEER1_PREFIX_LEN}    ${PREFIX_LEN}
  60 ${BGP_PEER2_PREFIX_LEN}    ${PREFIX_LEN}
  61 ${PREFIX_COUNT}    3
  62 ${BGP_PEER1_PREFIX_COUNT}    ${PREFIX_COUNT}
  63 ${BGP_PEER2_PREFIX_COUNT}    ${PREFIX_COUNT}
  64 ${BGP_PEER1_LOG_FILE}    bgp_peer1.log
  65 ${BGP_PEER2_LOG_FILE}    bgp_peer2.log
  66 ${BGP_PEER1_COMMAND}    python play.py --firstprefix ${BGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${BGP_PEER1_PREFIX_LEN} --amount ${BGP_PEER1_PREFIX_COUNT} --myip=${BGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --${BGP_PEER_LOG_LEVEL} --logfile ${BGP_PEER1_LOG_FILE}
  67 ${BGP_PEER2_COMMAND}    python play.py --firstprefix ${BGP_PEER2_FIRST_PREFIX_IP} --prefixlen ${BGP_PEER2_PREFIX_LEN} --amount ${BGP_PEER2_PREFIX_COUNT} --myip=${BGP_PEER2_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --${BGP_PEER_LOG_LEVEL} --logfile ${BGP_PEER2_LOG_FILE}
  68 ${BGP_PEER1_OPTIONS}    &>${BGP_PEER1_LOG_FILE}
  69 ${BGP_PEER2_OPTIONS}    &>${BGP_PEER2_LOG_FILE}
  70 ${DEFAULT_LOG_CHECK_TIMEOUT}    20s
  71 ${DEFAULT_LOG_CHECK_PERIOD}    1s
  72 ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    10s
  73 ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    1s
  74 ${CONFIG_SESSION}    session
  75 ${RIB_INSTANCE}    example-bgp-rib
  76 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  77 ${DEVICE_NAME}    controller-config
  78
  79 *** Test Cases ***
  80 TC1_Configure_Two_iBGP_Route_Reflector_Client_Peers
  81     [Documentation]    Configure two iBGP peers as routing reflector clients.
  82     [Tags]    critical
  83     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer1    IP=${BGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  84     ...    PEER_ROLE=rr-client    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  85     ...    RR_CLIENT=true
  86     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
  87     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer2    IP=${BGP_PEER2_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  88     ...    PEER_ROLE=rr-client    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  89     ...    RR_CLIENT=true
  90     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
  91
  92 TC1_Connect_BGP_Peer1
  93     [Documentation]    Connect BGP peer
  94     [Tags]    critical
  95     SSHLibrary.Switch Connection    bgp_peer1_console
  96     Start_Console_Tool    ${BGP_PEER1_COMMAND}    ${BGP_PEER1_OPTIONS}
  97     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    {"prefix":"${BGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}"}
  98
  99 TC1_Connect_BGP_Peer2
 100     [Documentation]    Connect BGP peer
 101     [Tags]    critical
 102     SSHLibrary.Switch Connection    bgp_peer2_console
 103     Start_Console_Tool    ${BGP_PEER2_COMMAND}    ${BGP_PEER2_OPTIONS}
 104     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    {"prefix":"${BGP_PEER2_FIRST_PREFIX_IP}/${PREFIX_LEN}"}
 105
 106 TC1_BGP_Peer1_Check_Log_For_Introduced_Prefixes
 107     [Documentation]    Check incomming updates for new routes
 108     [Tags]    critical
 109     SSHLibrary.Switch Connection    bgp_peer1_console
 110     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${BGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${BGP_PEER2_PREFIX_COUNT}
 111     Check_File_For_Word_Count    ${BGP_PEER1_LOG_FILE}    nlri_prefix_received: ${BGP_PEER2_FIRST_PREFIX_IP}/${BGP_PEER2_PREFIX_LEN}    1
 112     Check_File_For_Word_Count    ${BGP_PEER1_LOG_FILE}    withdrawn_prefix_received:    0
 113     [Teardown]    Report_Failure_Due_To_Bug    4819
 114
 115 TC1_BGP_Peer2_Check_Log_For_Introduced_Prefixes
 116     [Documentation]    Check incomming updates for new routes
 117     [Tags]    critical
 118     SSHLibrary.Switch Connection    bgp_peer2_console
 119     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    nlri_prefix_received:    ${BGP_PEER1_PREFIX_COUNT}
 120     Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    nlri_prefix_received: ${BGP_PEER1_FIRST_PREFIX_IP}/${BGP_PEER1_PREFIX_LEN}    1
 121     Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    withdrawn_prefix_received:    0
 122     [Teardown]    Report_Failure_Due_To_Bug    4819
 123
 124 TC1_Disconnect_BGP_Peer1
 125     [Documentation]    Stop BGP peer & store logs
 126     [Tags]    critical
 127     SSHLibrary.Switch Connection    bgp_peer1_console
 128     Stop_Console_Tool
 129     Store_File_To_Workspace    ${BGP_PEER1_LOG_FILE}    tc1_${BGP_PEER1_LOG_FILE}
 130
 131 TC1_BGP_Peer2_Check_Log_For_Withdrawn_Prefixes
 132     [Documentation]    Check incomming updates for withdrawn routes
 133     [Tags]    critical
 134     SSHLibrary.Switch Connection    bgp_peer2_console
 135     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    withdrawn_prefix_received:    ${BGP_PEER1_PREFIX_COUNT}
 136     Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    withdrawn_prefix_received: ${BGP_PEER1_FIRST_PREFIX_IP}/${BGP_PEER1_PREFIX_LEN}    1
 137     [Teardown]    Report_Failure_Due_To_Bug    4819
 138
 139 TC1_Disconnect_BGP_Peer2
 140     [Documentation]    Stop BGP peer & store logs
 141     [Tags]    critical
 142     SSHLibrary.Switch Connection    bgp_peer2_console
 143     Stop_Console_Tool
 144     Store_File_To_Workspace    ${BGP_PEER2_LOG_FILE}    tc1_${BGP_PEER2_LOG_FILE}
 145
 146 TC_1_Check_for_Empty_IPv4_Topology
 147     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Does_Not_Contain    prefix
 148
 149 TC1_Delete_BGP_Peers_Configuration
 150     [Documentation]    Delete all previously configured BGP peers.
 151     [Tags]    critical
 152     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer1    IP=${BGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 153     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 154     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer2    IP=${BGP_PEER2_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 155     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 156
 157 TC2_Configure_One_iBGP_Route_Reflector_Client_And_One_iBGP_Non_Client
 158     [Documentation]    Configure iBGP peers: 1st one as RR client, 2nd one as RR non-client.
 159     [Tags]    critical
 160     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer1    IP=${BGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
 161     ...    PEER_ROLE=rr-client    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 162     ...    RR_CLIENT=true
 163     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 164     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer2    IP=${BGP_PEER2_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
 165     ...    PEER_ROLE=ibgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 166     ...    RR_CLIENT=false
 167     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 168
 169 TC2_Connect_BGP_Peer1
 170     [Documentation]    Connect BGP peer
 171     [Tags]    critical
 172     SSHLibrary.Switch Connection    bgp_peer1_console
 173     Start_Console_Tool    ${BGP_PEER1_COMMAND}    ${BGP_PEER1_OPTIONS}
 174     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    {"prefix":"${BGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}"}
 175
 176 TC2_Connect_BGP_Peer2
 177     [Documentation]    Connect BGP peer
 178     [Tags]    critical
 179     SSHLibrary.Switch Connection    bgp_peer2_console
 180     Start_Console_Tool    ${BGP_PEER2_COMMAND}    ${BGP_PEER2_OPTIONS}
 181     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    {"prefix":"${BGP_PEER2_FIRST_PREFIX_IP}/${PREFIX_LEN}"}
 182
 183 TC2_BGP_Peer1_Check_Log_For_Introduced_Prefixes
 184     [Documentation]    Check incomming updates for new routes
 185     [Tags]    critical
 186     SSHLibrary.Switch Connection    bgp_peer1_console
 187     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${BGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${BGP_PEER2_PREFIX_COUNT}
 188     Check_File_For_Word_Count    ${BGP_PEER1_LOG_FILE}    nlri_prefix_received: ${BGP_PEER2_FIRST_PREFIX_IP}/${BGP_PEER2_PREFIX_LEN}    1
 189     Check_File_For_Word_Count    ${BGP_PEER1_LOG_FILE}    withdrawn_prefix_received:    0
 190
 191 TC2_BGP_Peer2_Check_Log_For_Introduced_Prefixes
 192     [Documentation]    Check incomming updates for new routes
 193     [Tags]    critical
 194     SSHLibrary.Switch Connection    bgp_peer2_console
 195     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    nlri_prefix_received:    ${BGP_PEER1_PREFIX_COUNT}
 196     Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    nlri_prefix_received: ${BGP_PEER1_FIRST_PREFIX_IP}/${BGP_PEER1_PREFIX_LEN}    1
 197     Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    withdrawn_prefix_received:    0
 198     [Teardown]    Report_Failure_Due_To_Bug    4791
 199
 200 TC2_Disconnect_BGP_Peer1
 201     [Documentation]    Stop BGP peer & store logs
 202     [Tags]    critical
 203     SSHLibrary.Switch Connection    bgp_peer1_console
 204     Stop_Console_Tool
 205     Store_File_To_Workspace    ${BGP_PEER1_LOG_FILE}    tc2_${BGP_PEER1_LOG_FILE}
 206
 207 TC2_BGP_Peer2_Check_Log_For_Withdrawn_Prefixes
 208     [Documentation]    Check incomming updates for withdrawn routes
 209     [Tags]    critical
 210     SSHLibrary.Switch Connection    bgp_peer2_console
 211     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    withdrawn_prefix_received:    ${BGP_PEER1_PREFIX_COUNT}
 212     Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    withdrawn_prefix_received: ${BGP_PEER1_FIRST_PREFIX_IP}/${BGP_PEER1_PREFIX_LEN}    1
 213
 214 TC2_Disconnect_BGP_Peer2
 215     [Documentation]    Stop BGP peer & store logs
 216     [Tags]    critical
 217     SSHLibrary.Switch Connection    bgp_peer2_console
 218     Stop_Console_Tool
 219     Store_File_To_Workspace    ${BGP_PEER2_LOG_FILE}    tc2_${BGP_PEER2_LOG_FILE}
 220
 221 TC_2_Check_for_Empty_IPv4_Topology
 222     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Does_Not_Contain    prefix
 223
 224 TC2_Delete_BGP_Peers_Configuration
 225     [Documentation]    Delete all previously configured BGP peers.
 226     [Tags]    critical
 227     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer1    IP=${BGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 228     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 229     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer2    IP=${BGP_PEER2_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 230     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 231
 232 TC3_Configure_Two_iBGP_Non_Client_Peers
 233     [Documentation]    Configure iBGP peers: 1st one as RR client, 2nd one as RR non-client.
 234     [Tags]    critical
 235     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer1    IP=${BGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
 236     ...    PEER_ROLE=ibgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 237     ...    RR_CLIENT=false
 238     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 239     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer2    IP=${BGP_PEER2_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
 240     ...    PEER_ROLE=ibgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 241     ...    RR_CLIENT=false
 242     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 243
 244 TC3_Connect_BGP_Peer1
 245     [Documentation]    Connect BGP peer
 246     [Tags]    critical
 247     SSHLibrary.Switch Connection    bgp_peer1_console
 248     Start_Console_Tool    ${BGP_PEER1_COMMAND}    ${BGP_PEER1_OPTIONS}
 249     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    {"prefix":"${BGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}"}
 250
 251 TC3_Connect_BGP_Peer2
 252     [Documentation]    Connect BGP peer
 253     [Tags]    critical
 254     SSHLibrary.Switch Connection    bgp_peer2_console
 255     Start_Console_Tool    ${BGP_PEER2_COMMAND}    ${BGP_PEER2_OPTIONS}
 256     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    {"prefix":"${BGP_PEER2_FIRST_PREFIX_IP}/${PREFIX_LEN}"}
 257
 258 TC3_BGP_Peer1_Check_Log_For_No_Updates
 259     [Documentation]    Check for no updates received by iBGP peer No. 1
 260     [Tags]    critical
 261     SSHLibrary.Switch Connection    bgp_peer1_console
 262     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${BGP_PEER1_LOG_FILE}    total_received_update_message_counter: 0    2
 263
 264 TC3_Disconnect_BGP_Peer1
 265     [Documentation]    Stop BGP peer & store logs
 266     [Tags]    critical
 267     SSHLibrary.Switch Connection    bgp_peer1_console
 268     Stop_Console_Tool
 269     Store_File_To_Workspace    ${BGP_PEER1_LOG_FILE}    tc3_${BGP_PEER1_LOG_FILE}
 270
 271 TC3_BGP_Peer2_Check_Log_For_No_Updates
 272     [Documentation]    Consequent check for no updates received by iBGP peer No. 2
 273     [Tags]    critical
 274     SSHLibrary.Switch Connection    bgp_peer2_console
 275     ${log_check_timeout}=    DateTime.Convert_Time    ${DEFAULT_LOG_CHECK_TIMEOUT}    result_format=number
 276     BuiltIn.Wait_Until_Keyword_Succeeds    ${log_check_timeout*2}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${BGP_PEER2_LOG_FILE}    total_received_update_message_counter: 0    4
 277
 278 TC3_Disconnect_BGP_Peer2
 279     [Documentation]    Stop BGP peer & store logs
 280     [Tags]    critical
 281     SSHLibrary.Switch Connection    bgp_peer2_console
 282     Stop_Console_Tool
 283     Store_File_To_Workspace    ${BGP_PEER2_LOG_FILE}    tc3_${BGP_PEER2_LOG_FILE}
 284
 285 TC_3_Check_for_Empty_IPv4_Topology
 286     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Does_Not_Contain    prefix
 287
 288 TC3_Delete_BGP_Peers_Configuration
 289     [Documentation]    Delete all previously configured BGP peers.
 290     [Tags]    critical
 291     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer1    IP=${BGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 292     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 293     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer2    IP=${BGP_PEER2_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 294     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}    session=${CONFIG_SESSION}
 295
 296 *** Keywords ***
 297 Setup_Everything
 298     [Documentation]    Initialize SetupUtils. SSH-login to mininet machine, create HTTP session,
 299     ...    prepare directories for responses, put Python tool to mininet machine, setup imported resources.
 300     # TODO: Choose keywords used by more than one test suite to be placed in a common place.
 301     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 302     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 303     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=bgp_peer1_console
 304     Utils.Flexible_Controller_Login
 305     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=bgp_peer2_console
 306     Utils.Flexible_Controller_Login
 307     SSHKeywords.Require_Python
 308     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 309     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 310     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_TOPO_API}    auth=${AUTH}
 311     RequestsLibrary.Create_Session    ${CONFIG_SESSION}    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}
 312     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_LOG_LEVEL}
 313     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_BGP_LOG_LEVEL} org.opendaylight.bgpcep
 314     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_BGP_LOG_LEVEL} org.opendaylight.protocol