csit/suites/controller/Clustering_Datastore/car_failover_crud.robot

   1 *** Settings ***
   2 Documentation     Suite mixing basic operations with restart of car Leader.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This test kills the current leader of the "car" shard and then executes CRD
  12 ...               operations on the new leader and a new follower. The killed member is brought back.
  13 ...               This suite uses 3 different car sets, same size but different starting ID.
  14 ...
  15 ...               Other models and shards (people, car-people) are not accessed by this suite.
  16 ...
  17 ...               All data is deleted at the end of the suite.
  18 ...               This suite expects car module to have a separate Shard.
  19 Suite Setup       Setup
  20 Default Tags      clustering    carpeople    critical
  21 Library           Collections
  22 Resource          ${CURDIR}/../../../libraries/CarPeople.robot
  23 Resource          ${CURDIR}/../../../libraries/ClusterManagement.robot
  24 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  25 Variables         ${CURDIR}/../../../variables/Variables.py
  26
  27 *** Variables ***
  28 ${CAR_ITEMS}      30
  29 ${FOLLOWER_2NODE_START_I}    300
  30 ${LEADER_2NODE_START_I}    200
  31 ${MEMBER_START_TIMEOUT}    300s
  32 ${ORIGINAL_START_I}    100
  33 @{SHARD_NAME_LIST}    car
  34 ${VAR_DIR}        ${CURDIR}/../../../variables/carpeople/crud
  35
  36 *** Test Cases ***
  37 Add_Original_Cars_On_Old_Leader
  38     [Documentation]    Add initial cars on car Leader.
  39     TemplatedRequests.Put_As_Json_Templated    folder=${VAR_DIR}/cars    session=${car_leader_session}    iterations=${CAR_ITEMS}    iter_start=${ORIGINAL_START_I}
  40
  41 Kill_Original_Car_Leader
  42     [Documentation]    Kill the car Leader to cause a new leader to get elected.
  43     ClusterManagement.Kill_Single_Member    ${car_leader_index}    confirm=True
  44
  45 Wait_For_New_Leader
  46     [Documentation]    Wait until new car Leader is elected.
  47     BuiltIn.Wait_Until_Keyword_Succeeds    30s    2s    Set_Variables_For_Less_Nodes    member_index_list=${car_follower_indices}
  48
  49 See_Original_Cars_On_New_Leader
  50     [Documentation]    GET cars from new Leader, should be the initial ones.
  51     TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${ORIGINAL_START_I}
  52
  53 See_Original_Cars_On_New_Followers
  54     [Documentation]    The same check on other existing member(s).
  55     : FOR    ${session}    IN    @{new_follower_sessions}
  56     \    TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${ORIGINAL_START_I}
  57
  58 Delete_Original_Cars_On_New_Leader
  59     [Documentation]    Delete cars on the new Leader.
  60     TemplatedRequests.Delete_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}
  61
  62 Add_Leader_Cars_On_New_Leader
  63     [Documentation]    Add cars on the new Leader.
  64     TemplatedRequests.Put_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}    iterations=${CAR_ITEMS}    iter_start=${LEADER_2NODE_START_I}
  65
  66 See_Leader_Cars_On_New_Leader
  67     [Documentation]    GET cars from new Leader, should be the new ones.
  68     TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${LEADER_2NODE_START_I}
  69
  70 See_Leader_Cars_On_New_Followers
  71     [Documentation]    The same check on other existing members.
  72     : FOR    ${session}    IN    @{new_follower_sessions}
  73     \    TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${LEADER_2NODE_START_I}
  74
  75 Delete_Leader_Cars_On_New_First_Follower
  76     [Documentation]    Delete cars in new first Follower.
  77     TemplatedRequests.Delete_Templated    folder=${VAR_DIR}/cars    session=${new_first_follower_session}
  78
  79 Add_Follower_Cars_On_New_First_Follower
  80     [Documentation]    Add cars on the new first Follower.
  81     TemplatedRequests.Put_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_first_follower_session}    iterations=${CAR_ITEMS}    iter_start=${FOLLOWER_2NODE_START_I}
  82
  83 See_Folower_Cars_On_New_Leader
  84     [Documentation]    Get cars from the new Leader, should be the ones added on follower.
  85     TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${FOLLOWER_2NODE_START_I}
  86
  87 See_Follower_Cars_On_New_Followers
  88     [Documentation]    The same check on other existing members.
  89     : FOR    ${session}    IN    @{new_follower_sessions}
  90     \    TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${FOLLOWER_2NODE_START_I}
  91
  92 Start_Old_Car_Leader
  93     [Documentation]    Start the killed member without deleting the persisted data.
  94     ClusterManagement.Start_Single_Member    ${car_leader_index}    wait_for_sync=True    timeout=${MEMBER_START_TIMEOUT}
  95     BuiltIn.Wait_Until_Keyword_Succeeds    30s    2s    ClusterManagement.Verify_Leader_Exists_For_Each_Shard    shard_name_list=${SHARD_NAME_LIST}    shard_type=config
  96
  97 See_Folower_Cars_On_Old_Leader
  98     [Documentation]    GET cars from the restarted member, should be the ones added on follower.
  99     TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${car_leader_session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${FOLLOWER_2NODE_START_I}
 100
 101 Delete_Follower_Cars_On_New_Leader
 102     [Documentation]    Delete cars on the last Leader.
 103     TemplatedRequests.Delete_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}
 104
 105 *** Keywords ***
 106 Setup
 107     [Documentation]    Initialize resources, memorize car shard leader and followers.
 108     ClusterManagement.ClusterManagement_Setup
 109     CarPeople.Set_Variables_For_Shard    shard_name=car
 110
 111 Set_Variables_For_Less_Nodes
 112     [Arguments]    ${member_index_list}
 113     [Documentation]    Get current leader and followers for car shard, set additional suite variables.
 114     ${leader}    ${follower_list} =    ClusterManagement.Get_Leader_And_Followers_For_Shard    shard_name=car    shard_type=config    member_index_list=${member_index_list}
 115     ${leader_session} =    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${leader}
 116     BuiltIn.Set_Suite_Variable    \${new_leader_session}    ${leader_session}
 117     ${sessions} =    BuiltIn.Create_List
 118     : FOR    ${follower_index}    IN    @{follower_list}
 119     \    ${follower_session} =    ClusterManagement.Resolve_Http_Session_For_Member    member_index=${follower_index}
 120     \    Collections.Append_To_List    ${sessions}    ${follower_session}
 121     BuiltIn.Set_Suite_Variable    \${new_follower_sessions}    ${sessions}
 122     ${first_follower_session} =    Collections.Get_From_List    ${sessions}    0
 123     BuiltIn.Set_Suite_Variable    \${new_first_follower_session}    ${first_follower_session}