csit/suites/netconf/scale/getmulti.robot

   1 *** Settings ***
   2 Documentation     netconf-connector scaling test suite (multi-threaded GET requests).
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Performs scaling tests:
  12 ...               - Send configurations of the devices one by one (via restconf).
  13 ...               - Wait for the devices to become connected.
  14 ...               - Send requests for configuration data using ${WORKER_COUNT} worker threads
  15 ...               (using external Python tool).
  16 ...               - Deconfigure the devices one by one.
  17 Suite Setup       Setup_Everything
  18 Suite Teardown    Teardown_Everything
  19 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  20 Library           Collections
  21 Library           String
  22 Library           SSHLibrary    timeout=10s
  23 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  24 Resource          ${CURDIR}/../../../libraries/NetconfKeywords.robot
  25 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  26 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  27 Variables         ${CURDIR}/../../../variables/Variables.py
  28
  29 *** Variables ***
  30 ${DEVICE_COUNT}    500
  31 ${WORKER_COUNT}    10
  32 ${TIMEOUT_FACTOR}    10
  33 ${device_name_base}    netconf-scaling-device
  34 ${device_type}    full-uri-device
  35 ${base_port}      17830
  36
  37 *** Test Cases ***
  38 Start_Test_Tool
  39     [Documentation]    Deploy and start test tool, then wait for all its devices to become online.
  40     NetconfKeywords.Install_And_Start_Testtool    device-count=${DEVICE_COUNT}    mdsal=false
  41
  42 Configure_Devices_On_Netconf
  43     [Documentation]    Make requests to configure the testtool devices.
  44     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*${TIMEOUT_FACTOR}
  45     NetconfKeywords.Perform_Operation_On_Each_Device    Configure_Device    timeout=${timeout}
  46
  47 Wait_For_Devices_To_Connect
  48     [Documentation]    Wait for the devices to become connected.
  49     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*${TIMEOUT_FACTOR}
  50     NetconfKeywords.Perform_Operation_On_Each_Device    Wait_Connected    timeout=${timeout}
  51
  52 Issue_Requests_On_Devices
  53     [Documentation]    Spawn the specified count of worker threads to issue a GET request to each of the devices.
  54     ${current_ssh_connection}=    SSHLibrary.Get Connection
  55     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
  56     SSHKeywords.Flexible_Mininet_Login
  57     SSHLibrary.Write    python getter.py --odladdress=${ODL_SYSTEM_IP} --count=${DEVICE_COUNT} --name=${device_name_base} --workers=${WORKER_COUNT}
  58     : FOR    ${number}    IN RANGE    1    ${DEVICE_COUNT}+1
  59     \    Read_Python_Tool_Operation_Result    ${number}
  60     SSHLibrary.Read_Until_Prompt
  61     SSHLibrary.Close_Connection
  62     SSHKeywords.Restore Current SSH Connection From Index    ${current_ssh_connection.index}
  63
  64 Deconfigure_Devices
  65     [Documentation]    Make requests to deconfigure the testtool devices.
  66     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*${TIMEOUT_FACTOR}
  67     NetconfKeywords.Perform_Operation_On_Each_Device    Deconfigure_Device    timeout=${timeout}
  68     [Teardown]    Report_Failure_Due_To_Bug    4547
  69
  70 Check_Devices_Are_Deconfigured
  71     [Documentation]    Check there are no netconf connectors or other stuff related to the testtool devices.
  72     ${timeout}=    BuiltIn.Evaluate    ${DEVICE_COUNT}*${TIMEOUT_FACTOR}
  73     NetconfKeywords.Perform_Operation_On_Each_Device    Check_Device_Deconfigured    timeout=${timeout}
  74
  75 *** Keywords ***
  76 Setup_Everything
  77     [Documentation]    Setup everything needed for the test cases.
  78     # Setup resources used by the suite.
  79     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
  80     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
  81     SetupUtils.Setup_Utils_For_Setup_And_Teardown
  82     NetconfKeywords.Setup_Netconf_Keywords
  83     # Deploy testing tools.
  84     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/netconf_tools/getter.py
  85     SSHLibrary.Put_File    ${CURDIR}/../../../libraries/AuthStandalone.py
  86     ${device_type}=    BuiltIn.Set_Variable_If    ${USE_NETCONF_CONNECTOR}==${True}    default    ${device_type}
  87     BuiltIn.Set_Suite_Variable    ${device_type}
  88
  89 Teardown_Everything
  90     [Documentation]    Teardown the test infrastructure, perform cleanup and release all resources.
  91     RequestsLibrary.Delete_All_Sessions
  92     NetconfKeywords.Stop_Testtool
  93
  94 Configure_Device
  95     [Arguments]    ${current_name}
  96     [Documentation]    Operation for configuring the device.
  97     KarafKeywords.Log_Message_To_Controller_Karaf    Configuring device ${current_name} to Netconf
  98     NetconfKeywords.Configure_Device_In_Netconf    ${current_name}    device_type=${device_type}    device_port=${current_port}
  99     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} configured
 100
 101 Wait_Connected
 102     [Arguments]    ${current_name}
 103     [Documentation]    Operation for waiting until the device is connected.
 104     KarafKeywords.Log_Message_To_Controller_Karaf    Waiting for device ${current_name} to connect
 105     NetconfKeywords.Wait_Device_Connected    ${current_name}    period=0.5s    timeout=120s
 106     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} connected
 107
 108 Read_Python_Tool_Operation_Result
 109     [Arguments]    ${number}
 110     [Documentation]    Read and process a report line emitted from the Python tool that corresponds to the device with the given number.
 111     ${test}=    SSHLibrary.Read_Until_Regexp    \\n
 112     ${test}=    String.Split_String    ${test}    |
 113     ${response}=    Collections.Get_From_List    ${test}    0
 114     ${message}=    Collections.Get_From_List    ${test}    1
 115     BuiltIn.Run_Keyword_If    '${response}' == 'ERROR'    Fail    Error getting data: ${message}
 116     ${start}=    Collections.Get_From_List    ${test}    1
 117     ${stop}=    Collections.Get_From_List    ${test}    2
 118     ${ellapsed}=    Collections.Get_From_List    ${test}    3
 119     BuiltIn.Log    DATA REQUEST RESULT: Device=${number} StartTime=${start} StopTime=${stop} EllapsedTime=${ellapsed}
 120     ${data}=    Collections.Get_From_List    ${test}    4
 121     ${expected}=    BuiltIn.Set_Variable    '<data xmlns="${ODL_NETCONF_NAMESPACE}"></data>'
 122     BuiltIn.Should_Be_Equal_As_Strings    ${data}    ${expected}
 123
 124 Deconfigure_Device
 125     [Arguments]    ${current_name}
 126     [Documentation]    Operation for deconfiguring the device.
 127     KarafKeywords.Log_Message_To_Controller_Karaf    Deconfiguring device ${current_name}
 128     NetconfKeywords.Remove_Device_From_Netconf    ${current_name}
 129     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} deconfigured
 130
 131 Check_Device_Deconfigured
 132     [Arguments]    ${current_name}
 133     [Documentation]    Operation for making sure the device is really deconfigured.
 134     KarafKeywords.Log_Message_To_Controller_Karaf    Waiting for device ${current_name} to disappear
 135     NetconfKeywords.Wait_Device_Fully_Removed    ${current_name}    period=0.5s    timeout=120s
 136     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} removed