csit/suites/netvirt/upgrade/upgrade.robot

   1 *** Settings ***
   2 Documentation     Test suite for ODL Upgrade. It is assumed that OLD + OpenStack
   3 ...               integrated environment is deployed and ready.
   4 Suite Setup       OpenStackOperations.OpenStack Suite Setup
   5 Suite Teardown    Upgrade Suite Teardown
   6 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
   7 Test Teardown     Get Test Teardown Debugs
   8 Library           OperatingSystem
   9 Library           RequestsLibrary
  10 Library           SSHLibrary
  11 Resource          ../../../libraries/ClusterManagement.robot
  12 Resource          ../../../libraries/DevstackUtils.robot
  13 Resource          ../../../libraries/KarafKeywords.robot
  14 Resource          ../../../libraries/OpenStackOperations.robot
  15 Resource          ../../../libraries/OVSDB.robot
  16 Resource          ../../../libraries/SetupUtils.robot
  17 Resource          ../../../libraries/Utils.robot
  18
  19 *** Variables ***
  20 ${SECURITY_GROUP}    upgrade_sg
  21 @{NETWORKS}       upgrade_net_1    upgrade_net_2
  22 @{SUBNETS}        upgrade_sub_1    upgrade_sub_2
  23 @{NET_1_VMS}      upgrade_net_1_vm_1    upgrade_net_1_vm_2
  24 @{NET_2_VMS}      upgrade_net_2_vm_1    upgrade_net_2_vm_2
  25 @{SUBNETS_RANGE}    91.0.0.0/24    92.0.0.0/24
  26 ${ROUTER}         upgrade_router_1
  27 ${TYPE}           tun
  28 ${PASSIVE_MANAGER}    ptcp:6641:127.0.0.1
  29 @{DEBUG_LOG_COMPONENTS}    org.opendaylight.ovsdb    org.opendaylight.ovsdb.lib    org.opendaylight.netvirt    org.opendaylight.genius
  30
  31 *** Test Cases ***
  32 Create Setup And Verify Instance Connectivity
  33     [Documentation]    Create 2 VXLAN networks, subnets with 2 VMs each and a router. Ping all 4 VMs.
  34     Create Resources
  35     Check Resource Connectivity
  36     DevstackUtils.Set Node Data For Control Only Node Setup
  37     Dump Debug With Annotations    POST_SETUP
  38
  39 Stop ODL
  40     ClusterManagement.Stop_Members_From_List_Or_All
  41
  42 Disconnect OVS
  43     [Documentation]    Delete OVS manager, controller and groups and tun ports
  44     : FOR    ${node}    IN    @{OS_ALL_IPS}
  45     \    OVSDB.Delete OVS Manager    ${node}
  46     \    OVSDB.Delete OVS Controller    ${node}
  47     \    OVSDB.Delete Groups On Bridge    ${node}    ${INTEGRATION_BRIDGE}
  48     \    OVSDB.Delete Ports On Bridge By Type    ${node}    ${INTEGRATION_BRIDGE}    ${TYPE}
  49
  50 Wipe Local Data
  51     [Documentation]    Delete data/, journal/, snapshots/
  52     ClusterManagement.Clean_Journals_Data_And_Snapshots_On_List_Or_All
  53
  54 Start ODL
  55     [Documentation]    Start controller, wait for it to come "UP" and make sure netvirt is installed
  56     ClusterManagement.Start_Members_From_List_Or_All    wait_for_sync=True
  57     Wait Until Keyword Succeeds    100s    5s    Utils.Check Diagstatus
  58     BuiltIn.Set_Suite_Variable    \${ClusterManagement__has_setup_run}    False
  59     KarafKeywords.Verify_Feature_Is_Installed    odl-netvirt-openstack
  60     Set Custom Component Logging To    DEBUG
  61
  62 Wait For Full Sync
  63     [Documentation]    Wait for networking_odl to sync neutron configuration
  64     Wait Until Keyword Succeeds    90s    5s    Canary Network Should Exist
  65
  66 Set OVS Manager And Controller
  67     [Documentation]    Set controller and manager on each OpenStack node and check that egress flows are present
  68     : FOR    ${node}    IN    @{OS_ALL_IPS}
  69     \    Run Command On Remote System    ${node}    sudo ovs-vsctl set-manager tcp:${ODL_SYSTEM_IP}:${OVSDBPORT} ${PASSIVE_MANAGER}
  70     Wait Until Keyword Succeeds    180s    15s    Check OVS Nodes Have Egress Flows
  71
  72 Check Connectivity With Previously Created Resources And br-int Info
  73     [Documentation]    Check that pre-existing instance connectivity still works after the new controller is brought
  74     ...    up and config is sync'd
  75     Dump Debug With Annotations    POST_UPGRADE
  76     Wait Until Keyword Succeeds    90s    10s    Check Resource Connectivity
  77
  78 *** Keywords ***
  79 Create Resources
  80     [Documentation]    Create 2 VXLAN networks, subnets with 2 VMs each and a router. Ping all 4 VMs.
  81     : FOR    ${net}    IN    @{NETWORKS}
  82     \    OpenStackOperations.Create Network    ${net}
  83     OpenStackOperations.Create SubNet    @{NETWORKS}[0]    @{SUBNETS}[0]    @{SUBNETS_RANGE}[0]
  84     OpenStackOperations.Create SubNet    @{NETWORKS}[1]    @{SUBNETS}[1]    @{SUBNETS_RANGE}[1]
  85     OpenStackOperations.Create Allow All SecurityGroup    ${SECURITY_GROUP}
  86     OpenStackOperations.Create Nano Flavor
  87     : FOR    ${vm}    IN    @{NET_1_VMS}
  88     \    OpenStackOperations.Create Vm Instance On Compute Node    @{NETWORKS}[0]    ${vm}    ${OS_CMP1_HOSTNAME}    sg=${SECURITY_GROUP}
  89     : FOR    ${vm}    IN    @{NET_2_VMS}
  90     \    OpenStackOperations.Create Vm Instance On Compute Node    @{NETWORKS}[1]    ${vm}    ${OS_CMP2_HOSTNAME}    sg=${SECURITY_GROUP}
  91     OpenStackOperations.Create Router    ${ROUTER}
  92     : FOR    ${interface}    IN    @{SUBNETS}
  93     \    OpenStackOperations.Add Router Interface    ${ROUTER}    ${interface}
  94     @{NET1_VM_IPS}    ${NET1_DHCP_IP} =    OpenStackOperations.Get VM IPs    @{NET_1_VMS}
  95     @{NET2_VM_IPS}    ${NET2_DHCP_IP} =    OpenStackOperations.Get VM IPs    @{NET_2_VMS}
  96     BuiltIn.Set Suite Variable    @{NET1_VM_IPS}
  97     BuiltIn.Set Suite Variable    @{NET2_VM_IPS}
  98     BuiltIn.Should Not Contain    ${NET1_VM_IPS}    None
  99     BuiltIn.Should Not Contain    ${NET2_VM_IPS}    None
 100     BuiltIn.Should Not Contain    ${NET1_DHCP_IP}    None
 101     BuiltIn.Should Not Contain    ${NET2_DHCP_IP}    None
 102
 103 Check Resource Connectivity
 104     [Documentation]    Ping 2 VMs in the same net and 1 from another net.
 105     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_1    @{NET1_VM_IPS}[0]
 106     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_1    @{NET1_VM_IPS}[1]
 107     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_1    @{NET2_VM_IPS}[0]
 108     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_2    @{NET2_VM_IPS}[0]
 109     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_2    @{NET2_VM_IPS}[1]
 110     OpenStackOperations.Ping Vm From DHCP Namespace    upgrade_net_2    @{NET1_VM_IPS}[0]
 111
 112 Check OVS Nodes Have Egress Flows
 113     [Documentation]    Loop over all openstack nodes to ensure they have the proper flows installed.
 114     : FOR    ${node}    IN    @{OS_ALL_IPS}
 115     \    Does OVS Have Multiple Egress Flows    ${node}
 116
 117 Does OVS Have Multiple Egress Flows
 118     [Arguments]    ${ip}
 119     [Documentation]    Verifies that at least 1 flow exists on the node for the ${EGRESS_L2_FWD_TABLE}
 120     ${flows} =    Utils.Run Command On Remote System    ${ip}    sudo ovs-ofctl -O OpenFlow13 dump-flows ${INTEGRATION_BRIDGE}
 121     ${egress_flows} =    String.Get Lines Containing String    ${flows}    table=${EGRESS_LPORT_DISPATCHER_TABLE}
 122     ${num_egress_flows} =    String.Get Line Count    ${egress_flows}
 123     BuiltIn.Should Be True    ${num_egress_flows} > 1
 124
 125 Set Custom Component Logging To
 126     [Arguments]    ${level}
 127     SetupUtils.Setup_Logging_For_Debug_Purposes_On_List_Or_All    ${level}    ${DEBUG_LOG_COMPONENTS}
 128     KarafKeywords.Issue_Command_On_Karaf_Console    log:list
 129
 130 Dump Debug With Annotations
 131     [Arguments]    ${tag}
 132     [Documentation]    Dump tons of debug logs for each OS node but also emit tags to make parsing easier
 133     Builtin.Log    Start dumping at phase ${tag}
 134     : FOR    ${node}    IN    @{OS_ALL_IPS}
 135     \    ${conn_id} =    DevstackUtils.Open Connection    ${node}_CONNECTION_NAME    ${node}
 136     \    Builtin.Log    Start dumping for ${node} at phase ${tag}
 137     \    OpenStackOperations.Get DumpFlows And Ovsconfig    ${conn_id}
 138     \    Builtin.Log    End dumping for ${node} at phase ${tag}
 139     \    SSHLibrary.Close Connection
 140     Builtin.Log    End dumping at phase ${tag}
 141
 142 Canary Network Should Exist
 143     OpenStackOperations.Get Neutron Network Rest    bd8db3a8-2b30-4083-a8b3-b3fd46401142
 144
 145 Upgrade Suite Teardown
 146     Set Custom Component Logging To    INFO
 147     OpenStackOperations.OpenStack Suite Teardown