csit/suites/openflowplugin/Performance/010_Cbench.robot

   1 *** Settings ***
   2 Documentation     Cbench Latency and Throughput tests can be run from an external
   3 ...               cbench.
   4 ...               If cbench is run with a medium number of switches or higher (e.g. 32+)
   5 ...               the normal openflow operations seem to break.
   6 ...               BUG: https://bugs.opendaylight.org/show_bug.cgi?id=2897
   7 Suite Setup       Cbench Suite Setup
   8 Test Teardown     Log Results As Zero If Cbench Timed Out
   9 Force Tags        cbench
  10 Library           String
  11 Library           Process
  12 Resource          ../../../libraries/Utils.robot
  13 Resource          ../../../libraries/KarafKeywords.robot
  14
  15 *** Variables ***
  16 ${throughput_threshold}    30000
  17 ${latency_threshold}    10000
  18 ${switch_count}    16
  19 ${duration_in_secs}    10
  20 ${loops}          10
  21 ${num_of_unique_macs}    100
  22 ${start_delay}    5000
  23 ${cbench_system}    ${TOOLS_SYSTEM_IP}
  24 ${cbench_executable}    /usr/local/bin/cbench
  25 ${throughput_results_file}    throughput.csv
  26 ${latency_results_file}    latency.csv
  27
  28 *** Testcases ***
  29 Cbench Latency Test
  30     [Documentation]    cbench executed in default latency mode. Test parameters have defaults, but can be overridden
  31     ...    on the pybot command line
  32     [Tags]    latency
  33     [Timeout]    ${test_timeout}
  34     Log    Cbench tests using ${loops} iterations of ${duration_in_secs} second tests. Switch Count: ${switch_count}. Unique MACS to cycle: ${num_of_unique_macs}
  35     Run Cbench And Log Results    -m ${duration_in_ms} -M ${num_of_unique_macs} -s ${switch_count} -l ${loops} -D ${start_delay}    ${latency_threshold}    ${latency_results_file}
  36     # We have to give some time for the controller to recover. See bug 6176.
  37     Sleep    10
  38
  39 Cbench Throughput Test
  40     [Documentation]    cbench executed in throughput mode (-t). Test parameters have defaults, but can be overridden
  41     ...    on the pybot command line
  42     [Tags]    throughput
  43     [Timeout]    ${test_timeout}
  44     Log    Cbench tests using ${loops} iterations of ${duration_in_secs} second tests. Switch Count: ${switch_count}. Unique MACS to cycle: ${num_of_unique_macs}
  45     Run Cbench And Log Results    -t -m ${duration_in_ms} -M ${num_of_unique_macs} -s ${switch_count} -l ${loops} -D ${start_delay}    ${throughput_threshold}    ${throughput_results_file}
  46     # We have to give some time for the controller to recover. See bug 6176.
  47     Sleep    10
  48
  49 Rerun Latency Test To Check Bug 6176
  50     [Documentation]    cbench executed in latency mode to see if controller is healthy
  51     [Tags]    latency
  52     [Timeout]    ${test_timeout}
  53     Log    Cbench tests using ${loops} iterations of ${duration_in_secs} second tests. Switch Count: ${switch_count}. Unique MACS to cycle: ${num_of_unique_macs}
  54     Run Cbench And Log Results    -m ${duration_in_ms} -M ${num_of_unique_macs} -s ${switch_count} -l ${loops} -D ${start_delay}    ${latency_threshold}    bug.csv
  55     # We have to give some time for the controller to recover. See bug 6176.
  56     Sleep    10
  57
  58 *** Keywords ***
  59 Run Cbench And Log Results
  60     [Arguments]    ${cbench_args}    ${average_threshold}    ${output_filename}=results.csv
  61     ##If the cbench command fails to return, the keyword to run it will time out.    The test tear
  62     ##down can catch this problem and log the results as zero.    However, we need to know which
  63     ##file to log to, so setting it as a suite variable here.
  64     Set Suite Variable    ${output_filename}
  65     ${output}=    Run Keyword If    "${cbench_system}" == "localhost"    Run Process    ${cbench_executable}    -c    ${ODL_SYSTEM_IP}
  66     ...    ${cbench_args}
  67     ...    ELSE    Run Command On Remote System    ${cbench_system}    ${cbench_executable} -c ${ODL_SYSTEM_IP} ${cbench_args}    prompt_timeout=${test_timeout}
  68     Log    ${output}
  69     Should Contain    ${output}    RESULT
  70     ${result_line}=    Get Lines Containing String    ${output}    RESULT
  71     @{results_list}=    Split String    ${result_line}
  72     Log    ${results_list[5]}
  73     Log    ${results_list[7]}
  74     @{result_name_list}=    Split String    ${results_list[5]}    /
  75     @{result_value_list}=    Split String    ${results_list[7]}    /
  76     ${num_stats}=    Get Length    ${result_name_list}
  77     : FOR    ${i}    IN RANGE    0    ${num_stats}
  78     \    Log    ${result_name_list[${i}]} :: ${result_value_list[${i}]}
  79     ${min}=    Set Variable    ${result_value_list[${0}]}
  80     ${max}=    Set Variable    ${result_value_list[${1}]}
  81     ${average}=    Set Variable    ${result_value_list[${2}]}
  82     ${stdev}=    Set Variable    ${result_value_list[${3}]}
  83     ${date}=    Get Time    d,m,s
  84     Log    CBench Result: ${date},${cbench_args},${min},${max},${average},${stdev}
  85     Log Results And Determine Status    ${min}    ${max}    ${average}    ${average_threshold}    ${output_filename}
  86
  87 Cbench Suite Setup
  88     Wait Until Keyword Succeeds    3x    1s    KarafKeywords.Issue Command On Karaf Console    log:set ERROR
  89     Append To File    ${latency_results_file}    LATENCY_MIN,LATENCY_MAX,LATENCY_AVERAGE\n
  90     Append To File    ${throughput_results_file}    THROUGHPUT_MIN,THROUGHPUT_MAX,THROUGHPUT_AVERAGE\n
  91     ${duration_in_ms}    Evaluate    ${duration_in_secs} * 1000
  92     Set Suite Variable    ${duration_in_ms}
  93     ##Setting the test timeout dynamically in case larger values on command line override default
  94     ${test_timeout}    Evaluate    (${loops} * ${duration_in_secs}) * 1.5
  95     Set Suite Variable    ${test_timeout}
  96     Run Keyword If    "${cbench_system}" == "localhost"    File Should Exist    ${cbench_executable}
  97     ...    ELSE    Verify File Exists On Remote System    ${cbench_system}    ${cbench_executable}
  98     Should Be True    ${loops} >= 2    If number of loops is less than 2, cbench will not run
  99     Verify Feature Is Installed    odl-openflowplugin-drop-test
 100     Issue Command On Karaf Console    dropallpacketsrpc on
 101
 102 Log Results And Determine Status
 103     [Arguments]    ${min}    ${max}    ${average}    ${threshold}    ${output_file}
 104     Append To File    ${output_file}    ${min},${max},${average}\n
 105     Should Be True    ${average} > ${threshold}    ${average} flow_mods per/sec did not exceed threshold of ${threshold}
 106
 107 Log Results As Zero If Cbench Timed Out
 108     Run Keyword If Timeout Occurred    Log Results And Determine Status    0    0    0    0    ${output_filename}