csit/suites/vtn/VTN_C_OF10/040__vtn_vbrif_audit.robot

   1 *** Settings ***
   2 Documentation       Test suite for VTN Coordinator
   3
   4 Resource            ../../../libraries/VtnCoKeywords.robot
   5 Resource            ../../../libraries/WaitForFailure.robot
   6
   7 Suite Setup         Start SuiteVtnCoTest
   8 Suite Teardown      Stop SuiteVtnCoTest
   9
  10
  11 *** Test Cases ***
  12 Add a ODL Controller with Invalid IP
  13     [Documentation]    Add a Controller
  14     Add a Controller    odc_test    10.0.0.1
  15
  16 Verify the Controller Status is down
  17     [Documentation]    Check Controller status
  18     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout
  19     ...    12s
  20     ...    1s
  21     ...    Check Controller Status
  22     ...    odc_test
  23     ...    down
  24
  25 Add a Vtn Tenant1
  26     [Documentation]    Create Vtn Tenant1
  27     Add a VTN    Tenant1    VTN_TEST
  28
  29 Create VBR in VTN Tenant1
  30     [Documentation]    Create a VBR in Tenant1 as Vbr_audit
  31     Create VBR in VTN    Tenant1    Vbr_audit    odc_test
  32
  33 Create VBRIF in VBRIDGE Vbr_audit Interface1
  34     [Documentation]    Create an interface to Vbr_audit
  35     Create VBRIF in VBR    Tenant1    Vbr_audit    Interface1    Interface1    202
  36
  37 Create VBRIF in VBRIDGE Vbr_audit Interface2
  38     [Documentation]    Create an interface to Vbr_audit
  39     Create VBRIF in VBR    Tenant1    Vbr_audit    Interface2    Interface2    202
  40
  41 Update controller to Valid IP
  42     [Documentation]    Update Controller ip to valid from invalid
  43     Update Controller    odc_test    ${ODL_SYSTEM_IP}    valid_IP
  44
  45 Verify the Controller State is in waiting_audit
  46     [Documentation]    Check Controller status
  47     Wait Until Keyword Succeeds    12s    2s    Check Controller Status    odc_test    waiting_audit
  48
  49 Audit a controller manually
  50     [Documentation]    Trigger update audit
  51     Audit Controller    odc_test
  52
  53 Define Portmap for Interface1
  54     [Documentation]    Map Interface1 to a logical port
  55     Define Portmap for VBRIF    Tenant1    Vbr_audit    Interface1    PP-OF:openflow:2-s2-eth1
  56
  57 Define Portmap for Interface2
  58     [Documentation]    Map Interface2 to a logical port
  59     Define Portmap for VBRIF    Tenant1    Vbr_audit    Interface2    PP-OF:openflow:2-s2-eth2
  60
  61 Test Ping for Configuration1
  62     [Documentation]    ping between hosts in mininet
  63     Wait Until Keyword Succeeds    20s    1s    Test Ping    h1    h2
  64
  65 Delete a VTN Tenant1
  66     [Documentation]    Delete Vtn Tenant1
  67     Delete a VTN    Tenant1
  68
  69 Delete a Controller odc1
  70     [Documentation]    Delete Controller odc1
  71     Remove Controller    odc_test