yang/yang-parser-impl/src/main/antlr/YangParser.g4

   1 //
   2 // Copyright (c) 2013 Cisco Systems, Inc. and others.  All rights reserved.
   3 //
   4 // This program and the accompanying materials are made available under the
   5 // terms of the Eclipse Public License v1.0 which accompanies this distribution,
   6 // and is available at http://www.eclipse.org/legal/epl-v10.html
   7 //
   8 parser grammar YangParser;
   9
  10 @header {
  11 package org.opendaylight.yangtools.antlrv4.code.gen;
  12 }
  13
  14 options{
  15     tokenVocab=YangLexer;
  16
  17 }
  18
  19
  20 yang : module_stmt | submodule_stmt ;
  21
  22 string : STRING (PLUS STRING)*;
  23
  24 // string validated in YangParserListenerImpl.handleUnknownNode()
  25 identifier_stmt : IDENTIFIER string? (stmtend | (LEFT_BRACE unknown_statement* RIGHT_BRACE));
  26 // string validated in YangParserListenerImpl.handleUnknownNode()
  27 unknown_statement : (YIN_ELEMENT_KEYWORD | YANG_VERSION_KEYWORD | WHEN_KEYWORD | VALUE_KEYWORD | USES_KEYWORD | UNITS_KEYWORD | UNIQUE_KEYWORD |
  28                     TYPEDEF_KEYWORD | TYPE_KEYWORD | SUBMODULE_KEYWORD | RPC_KEYWORD | REVISION_DATE_KEYWORD | REVISION_KEYWORD |
  29                     REQUIRE_INSTANCE_KEYWORD | REFINE_KEYWORD | RANGE_KEYWORD | PRESENCE_KEYWORD | PREFIX_KEYWORD |
  30                     POSITION_KEYWORD | PATTERN_KEYWORD | PATH_KEYWORD | OUTPUT_KEYWORD | ORGANIZATION_KEYWORD|  ORDERED_BY_KEYWORD | NOTIFICATION_KEYWORD|
  31                     NAMESPACE_KEYWORD | MUST_KEYWORD | MODULE_KEYWORD | MIN_ELEMENTS_KEYWORD | MAX_ELEMENTS_KEYWORD | MANDATORY_KEYWORD | LIST_KEYWORD |
  32                     LENGTH_KEYWORD | LEAF_LIST_KEYWORD | LEAF_KEYWORD | KEY_KEYWORD | INPUT_KEYWORD | INCLUDE_KEYWORD | IMPORT_KEYWORD | IF_FEATURE_KEYWORD |
  33                     IDENTITY_KEYWORD | GROUPING_KEYWORD | FRACTION_DIGITS_KEYWORD | FEATURE_KEYWORD | DEVIATE_KEYWORD | DEVIATION_KEYWORD | EXTENSION_KEYWORD |
  34                     ERROR_MESSAGE_KEYWORD | ERROR_APP_TAG_KEYWORD | ENUM_KEYWORD | DESCRIPTION_KEYWORD | STATUS_KEYWORD | DEFAULT_KEYWORD | CONTAINER_KEYWORD | CONTACT_KEYWORD |
  35                     CONFIG_KEYWORD | CHOICE_KEYWORD |  CASE_KEYWORD | BIT_KEYWORD | BELONGS_TO_KEYWORD | BASE_KEYWORD | AUGMENT_KEYWORD |
  36                     ANYXML_KEYWORD | REFERENCE_KEYWORD | IDENTIFIER) string? (SEMICOLON | (LEFT_BRACE
  37                     (unknown_statement |
  38                     identifier_stmt)* RIGHT_BRACE)*);
  39
  40 stmtend : (SEMICOLON) | (LEFT_BRACE identifier_stmt? RIGHT_BRACE);
  41
  42 /* DO NOT replace stmtsep in rest of grammar with identifier_stmt!!! It might seems as code duplicity here, but this one is necessary.
  43    Body of identifier_stmt generated from this grammar in YangParserListener is implemented in YangParserListenerImpl.
  44    To ensure that all of the identifier_stmts will be resolved correctly the YangParserListenerImpl contains code that handles
  45    specifcly identifier_stmts -> i.e. transforms identifier_stmt into QName. The stmtsep is used for parsing extension statements
  46    placed outside of body_stmt.
  47  */
  48 stmtsep : IDENTIFIER string? (stmtend | (LEFT_BRACE unknown_statement* RIGHT_BRACE));
  49 // string validated in DeviationBuilder.setDeviate() as REPLACE_KEYWORD
  50 deviate_replace_stmt : DEVIATE_KEYWORD string (SEMICOLON | (LEFT_BRACE (identifier_stmt |type_stmt | units_stmt | default_stmt | config_stmt | mandatory_stmt | min_elements_stmt | max_elements_stmt )* RIGHT_BRACE));
  51 // string validated in DeviationBuilder.setDeviate() as DELETE_KEYWORD
  52 deviate_delete_stmt : DEVIATE_KEYWORD string (SEMICOLON | (LEFT_BRACE (identifier_stmt |units_stmt | must_stmt | unique_stmt | default_stmt )* RIGHT_BRACE));
  53 // string validated in DeviationBuilder.setDeviate() as ADD_KEYWORD
  54 deviate_add_stmt : DEVIATE_KEYWORD string (SEMICOLON | (LEFT_BRACE (identifier_stmt |units_stmt | must_stmt | unique_stmt | default_stmt | config_stmt | mandatory_stmt  | min_elements_stmt  | max_elements_stmt )* RIGHT_BRACE));
  55 // string validated in DeviationBuilder.setDeviate() as NOT_SUPPORTED_KEYWORD
  56 deviate_not_supported_stmt : DEVIATE_KEYWORD string (SEMICOLON | (LEFT_BRACE identifier_stmt? RIGHT_BRACE));
  57 // string validated in YangModelBasicValidationListener.enterDeviation_stmt()
  58 deviation_stmt : DEVIATION_KEYWORD string LEFT_BRACE (identifier_stmt |description_stmt | reference_stmt | deviate_not_supported_stmt | deviate_add_stmt | deviate_replace_stmt | deviate_delete_stmt)+ RIGHT_BRACE;
  59 // string validated in YangModelBasicValidationListener.enterNotification_stmt()
  60 notification_stmt : NOTIFICATION_KEYWORD string (SEMICOLON | (LEFT_BRACE (identifier_stmt |if_feature_stmt | status_stmt | description_stmt | reference_stmt | typedef_stmt | grouping_stmt | data_def_stmt )* RIGHT_BRACE));
  61 output_stmt : OUTPUT_KEYWORD LEFT_BRACE (identifier_stmt |typedef_stmt | grouping_stmt | data_def_stmt )* RIGHT_BRACE;
  62 input_stmt : INPUT_KEYWORD LEFT_BRACE (identifier_stmt |typedef_stmt | grouping_stmt | data_def_stmt )* RIGHT_BRACE;
  63 // string valided in YangModelBasicValidationListener.enterRpc_stmt()
  64 rpc_stmt : RPC_KEYWORD string (SEMICOLON | (LEFT_BRACE (identifier_stmt |if_feature_stmt  | status_stmt | description_stmt | reference_stmt | typedef_stmt | grouping_stmt | input_stmt | output_stmt )* RIGHT_BRACE));
  65 // string validated in ParserListenerUtils.stringFromStringContext()
  66 when_stmt : WHEN_KEYWORD string (SEMICOLON | (LEFT_BRACE (identifier_stmt |description_stmt | reference_stmt )* RIGHT_BRACE));
  67
  68 // string validated in YangModelBasicValidationListener.enterAugment_stmt()
  69 augment_stmt : AUGMENT_KEYWORD string LEFT_BRACE  (identifier_stmt |when_stmt | if_feature_stmt | status_stmt | description_stmt | reference_stmt | data_def_stmt | case_stmt)* RIGHT_BRACE;
  70 // string not validated
  71 uses_augment_stmt : AUGMENT_KEYWORD string LEFT_BRACE (identifier_stmt |when_stmt | if_feature_stmt | status_stmt | description_stmt | reference_stmt | data_def_stmt | case_stmt)* RIGHT_BRACE;
  72 refine_anyxml_stmts : (identifier_stmt |must_stmt | config_stmt | mandatory_stmt | description_stmt | reference_stmt )*;
  73 refine_case_stmts : (identifier_stmt |description_stmt | reference_stmt )*;
  74 refine_choice_stmts : (identifier_stmt |default_stmt | config_stmt | mandatory_stmt | description_stmt | reference_stmt )*;
  75 refine_list_stmts : (identifier_stmt |must_stmt | config_stmt | min_elements_stmt | max_elements_stmt | description_stmt | reference_stmt )*;
  76 refine_leaf_list_stmts : (identifier_stmt |must_stmt | config_stmt | min_elements_stmt | max_elements_stmt | description_stmt | reference_stmt )*;
  77 refine_leaf_stmts : (identifier_stmt |must_stmt | default_stmt | config_stmt | mandatory_stmt | description_stmt | reference_stmt )*;
  78 refine_container_stmts : (identifier_stmt |must_stmt | presence_stmt | config_stmt | description_stmt | reference_stmt )*;
  79 refine_pom : (refine_container_stmts | refine_leaf_stmts | refine_leaf_list_stmts | refine_list_stmts | refine_choice_stmts | refine_case_stmts | refine_anyxml_stmts);
  80 // string validated in YangModelBasicValidationListener.enterRefine_stmt()
  81 refine_stmt : REFINE_KEYWORD string (SEMICOLON | (LEFT_BRACE  (refine_pom) RIGHT_BRACE));
  82 // string validated in YangModelBasicValidationListener.enterUses_stmt()
  83 uses_stmt : USES_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |when_stmt | if_feature_stmt | status_stmt | description_stmt | reference_stmt | refine_stmt | uses_augment_stmt )* RIGHT_BRACE));
  84 // string validated in YangModelBasicValidationListener.enterAnyxml_stmt()
  85 anyxml_stmt : ANYXML_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |when_stmt | if_feature_stmt | must_stmt | config_stmt | mandatory_stmt | status_stmt | description_stmt | reference_stmt )* RIGHT_BRACE));
  86 // string validated in YangModelBasicValidationListener.enterCase_stmt()
  87 case_stmt : CASE_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |when_stmt | if_feature_stmt | status_stmt | description_stmt | reference_stmt | data_def_stmt )* RIGHT_BRACE));
  88 short_case_stmt : container_stmt | leaf_stmt | leaf_list_stmt | list_stmt | anyxml_stmt;
  89 // string validated in YangModelBasicValidationListener.enterChoice_stmt()
  90 choice_stmt : CHOICE_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |when_stmt | if_feature_stmt | default_stmt | config_stmt | mandatory_stmt | status_stmt | description_stmt | reference_stmt | short_case_stmt | case_stmt)* RIGHT_BRACE));
  91 // string validated in YangModelBasicValidationListener.enterUnique_stmt()
  92 unique_stmt : UNIQUE_KEYWORD string stmtend;
  93 // string validated in YangModelBasicValidationListener.enterKey_stmt()
  94 key_stmt : KEY_KEYWORD string stmtend;
  95 // string validated in YangModelBasicValidationListener.enterList_stmt()
  96 list_stmt : LIST_KEYWORD string LEFT_BRACE  (when_stmt | if_feature_stmt | must_stmt | key_stmt | unique_stmt | config_stmt | min_elements_stmt | max_elements_stmt | ordered_by_stmt | status_stmt | description_stmt | reference_stmt | typedef_stmt | grouping_stmt | data_def_stmt | identifier_stmt)* RIGHT_BRACE;
  97 // string validated in YangModelBasicValidationListener.enterLeaf_list_stmt()
  98 leaf_list_stmt : LEAF_LIST_KEYWORD string LEFT_BRACE  (identifier_stmt |when_stmt | if_feature_stmt | type_stmt | units_stmt | must_stmt | config_stmt | min_elements_stmt | max_elements_stmt | ordered_by_stmt | status_stmt | description_stmt | reference_stmt )* RIGHT_BRACE;
  99 // string validated in YangModelBasicValidationListener.enterLeaf_stmt()
 100 leaf_stmt : LEAF_KEYWORD string LEFT_BRACE  (identifier_stmt |when_stmt | if_feature_stmt | type_stmt | units_stmt | must_stmt | default_stmt | config_stmt | mandatory_stmt | status_stmt | description_stmt | reference_stmt )* RIGHT_BRACE;
 101 // string validated in YangModelBasicValidationListener.enterContainer_stmt()
 102 container_stmt : CONTAINER_KEYWORD string (SEMICOLON | (LEFT_BRACE  (when_stmt | if_feature_stmt | must_stmt | presence_stmt | config_stmt | status_stmt | description_stmt | reference_stmt | typedef_stmt | grouping_stmt | data_def_stmt | identifier_stmt)* RIGHT_BRACE));
 103 // string validated in YangModelBasicValidationListener.enterGrouping_stmt()
 104 grouping_stmt : GROUPING_KEYWORD string (SEMICOLON | (LEFT_BRACE (status_stmt | description_stmt | reference_stmt | typedef_stmt | grouping_stmt | data_def_stmt | identifier_stmt)* RIGHT_BRACE));
 105 // string validated in ParserListenerUtils.createEnumPair()
 106 value_stmt : VALUE_KEYWORD string stmtend;
 107 // string validated in ParserListenerUtils.parseMaxElements()
 108 max_value_arg : string;
 109 // string validated in ParserListenerUtils.parseMinElements()
 110 min_value_arg : string;
 111 max_elements_stmt : MAX_ELEMENTS_KEYWORD max_value_arg stmtend;
 112 min_elements_stmt : MIN_ELEMENTS_KEYWORD min_value_arg stmtend;
 113 // string validated in ParserListenerUtils.parseMust()
 114 error_app_tag_stmt : ERROR_APP_TAG_KEYWORD string stmtend;
 115 // string validated in ParserListenerUtils.parseMust()
 116 error_message_stmt : ERROR_MESSAGE_KEYWORD string stmtend;
 117 // string validated in ParserListenerUtils.parseMust()
 118 must_stmt : MUST_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |error_message_stmt | error_app_tag_stmt | description_stmt | reference_stmt )* RIGHT_BRACE));
 119 // string validated in YangModelBasicValidationListener.enterOrdered_by_arg() as USER_KEYWORD | SYSTEM_KEYWORD
 120 ordered_by_arg : string;
 121 ordered_by_stmt : ORDERED_BY_KEYWORD ordered_by_arg stmtend;
 122 // string not validated
 123 presence_stmt : PRESENCE_KEYWORD string stmtend;
 124 // string validated in YangModelBasicValidationListener.enterMandatory_arg() as TRUE_KEYWORD | FALSE_KEYWORD
 125 mandatory_arg :string;
 126 mandatory_stmt : MANDATORY_KEYWORD mandatory_arg stmtend;
 127 // string validated in YangModelBasicValidationListener.enterConfig_arg() as TRUE_KEYWORD | FALSE_KEYWORD
 128 config_arg : string;
 129 config_stmt : CONFIG_KEYWORD config_arg stmtend;
 130 // string validated in YangModelBasicValidationListener.enterStatus_arg() as CURRENT_KEYWORD | OBSOLETE_KEYWORD | DEPRECATED_KEYWORD
 131 status_arg : string;
 132 status_stmt : STATUS_KEYWORD status_arg stmtend;
 133 // string validated in ParserListenerUtils.parseBit()
 134 position_stmt : POSITION_KEYWORD string stmtend;
 135 // string validated in ParserListenerUtils.parseBit()
 136 bit_stmt : BIT_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |position_stmt | status_stmt | description_stmt | reference_stmt )* RIGHT_BRACE));
 137 bits_specification : bit_stmt (bit_stmt | identifier_stmt)*;
 138 union_specification : type_stmt (identifier_stmt | type_stmt )*;
 139 identityref_specification : base_stmt  ;
 140 instance_identifier_specification : (require_instance_stmt )?;
 141 // string validated in ParserListenerUtils.isRequireInstance() as TRUE_KEYWORD | FALSE_KEYWORD
 142 require_instance_arg :string;
 143 require_instance_stmt : REQUIRE_INSTANCE_KEYWORD require_instance_arg stmtend;
 144 // string validated in ParserListenerUtils.parseLeafrefPath()
 145 path_stmt : PATH_KEYWORD string stmtend;
 146 leafref_specification : path_stmt;
 147 // string validated in ParserListenerUtils.createEnumPair()
 148 enum_stmt : ENUM_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |value_stmt | status_stmt | description_stmt | reference_stmt )* RIGHT_BRACE));
 149 enum_specification : enum_stmt (identifier_stmt | enum_stmt )*;
 150 // string not validated
 151 default_stmt : DEFAULT_KEYWORD string stmtend;
 152 // string validated in ParserListenerUtils.parsePatternConstraint()
 153 pattern_stmt : PATTERN_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |error_message_stmt | error_app_tag_stmt | description_stmt | reference_stmt )* RIGHT_BRACE));
 154 // string validated in ParserListenerUtils.parseLengthConstraints()
 155 length_stmt : LENGTH_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |error_message_stmt | error_app_tag_stmt | description_stmt | reference_stmt )* RIGHT_BRACE));
 156 string_restrictions : (length_stmt | pattern_stmt )*;
 157 // string validated in ParserListenerUtils.parseFractionDigits()
 158 fraction_digits_stmt : FRACTION_DIGITS_KEYWORD string stmtend;
 159 decimal64_specification : (numerical_restrictions? (identifier_stmt)* fraction_digits_stmt | fraction_digits_stmt (identifier_stmt)* numerical_restrictions?);
 160 // string validated in ParserListenerUtils.parseRangeConstraints()
 161 range_stmt : RANGE_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt |error_message_stmt | error_app_tag_stmt | description_stmt | reference_stmt )* RIGHT_BRACE));
 162 numerical_restrictions : range_stmt ;
 163 type_body_stmts : (identifier_stmt)* (numerical_restrictions | decimal64_specification | string_restrictions | enum_specification | leafref_specification | identityref_specification | instance_identifier_specification | bits_specification | union_specification) (identifier_stmt)*;
 164 // string validated in YangModelBasicValidationListener.enterType_stmt()
 165 type_stmt : TYPE_KEYWORD string (SEMICOLON | (LEFT_BRACE  type_body_stmts RIGHT_BRACE));
 166 // string validated in YangModelBasicValidationListener.enterTypedef_stmt()
 167 typedef_stmt : TYPEDEF_KEYWORD string LEFT_BRACE  (identifier_stmt | type_stmt | units_stmt | default_stmt | status_stmt | description_stmt | reference_stmt )+ RIGHT_BRACE;
 168 // string validated in YangModelBasicValidationListener.enterIf_feature_stmt()
 169 if_feature_stmt : IF_FEATURE_KEYWORD string stmtend;
 170 // string validated in YangModelBasicValidationListener.enterFeature_stmt()
 171 feature_stmt : FEATURE_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt | if_feature_stmt | status_stmt | description_stmt | reference_stmt )* RIGHT_BRACE));
 172 // string validated in YangModelBasicValidationListener.enterBase_stmt()
 173 base_stmt : BASE_KEYWORD string stmtend;
 174 // string validated in YangModelBasicValidationListener.enterIdentity_stmt()
 175 identity_stmt : IDENTITY_KEYWORD string (SEMICOLON | (LEFT_BRACE  (identifier_stmt | base_stmt | status_stmt | description_stmt | reference_stmt )* RIGHT_BRACE));
 176 // string validated in YangModelBasicValidationListener.enterYin_element_arg() as TRUE_KEYWORD | FALSE_KEYWORD
 177 yin_element_arg : string;
 178 yin_element_stmt : YIN_ELEMENT_KEYWORD yin_element_arg stmtend;
 179
 180 // string validated in YangModelBasicValidationListener.enterArgument_stmt()
 181 argument_stmt : ARGUMENT_KEYWORD string (SEMICOLON | (LEFT_BRACE identifier_stmt* yin_element_stmt? identifier_stmt* RIGHT_BRACE));
 182 // string validated in YangModelBasicValidationListener.enterExtension_stmt()
 183 extension_stmt : EXTENSION_KEYWORD string (SEMICOLON | (LEFT_BRACE  (argument_stmt | status_stmt | description_stmt | reference_stmt | unknown_statement)* RIGHT_BRACE));
 184 // string validated in YangModelBasicValidationListener.enterRevision_date_stmt()
 185 revision_date_stmt : REVISION_DATE_KEYWORD string stmtend;
 186 // string validated in YangModelBasicValidationListener.enterRevision_stmt()
 187 revision_stmt : REVISION_KEYWORD string (SEMICOLON | (LEFT_BRACE stmtsep* (description_stmt )? (reference_stmt )? (unknown_statement)? RIGHT_BRACE));
 188 // string not validated
 189 units_stmt : UNITS_KEYWORD string stmtend;
 190 // string not validated
 191 reference_stmt : REFERENCE_KEYWORD string stmtend;
 192 // string not validated
 193 description_stmt : DESCRIPTION_KEYWORD string stmtend;
 194 // string not validated
 195 contact_stmt : CONTACT_KEYWORD string stmtend;
 196 // string not validated
 197 organization_stmt : ORGANIZATION_KEYWORD string stmtend;
 198 // string validated in YangModelBasicValidationListener.enterBelongs_to_stmt()
 199 belongs_to_stmt : BELONGS_TO_KEYWORD string LEFT_BRACE  stmtsep* prefix_stmt  RIGHT_BRACE;
 200 // string validated in YangModelBasicValidationListener.enterPrefix_stmt()
 201 prefix_stmt : PREFIX_KEYWORD string stmtend;
 202 // string validated in YangModelBasicValidationListener.enterNamespace_stmt()
 203 namespace_stmt : NAMESPACE_KEYWORD string stmtend;
 204 // string validated in YangModelBasicValidationListener.enterInclude_stmt()
 205 include_stmt : INCLUDE_KEYWORD string (SEMICOLON | (LEFT_BRACE stmtsep* (revision_date_stmt )? RIGHT_BRACE));
 206 // string validated in YangModelBasicValidationListener.enterImport_stmt()
 207 import_stmt : IMPORT_KEYWORD string LEFT_BRACE stmtsep* prefix_stmt  (revision_date_stmt )? RIGHT_BRACE;
 208 // string validated in YangModelBasicValidationListener.enterModule_header_stmts() and/or YangModelBasicValidationListener.enterSubmodule_header_stmts()
 209 yang_version_stmt : YANG_VERSION_KEYWORD string stmtend;
 210 data_def_stmt : container_stmt | leaf_stmt | leaf_list_stmt | list_stmt | choice_stmt | anyxml_stmt | uses_stmt;
 211 body_stmts : (( identifier_stmt| extension_stmt | feature_stmt | identity_stmt | typedef_stmt | grouping_stmt | data_def_stmt | augment_stmt | rpc_stmt | notification_stmt | deviation_stmt) )*;
 212 revision_stmts :  (revision_stmt | stmtsep)*;
 213 linkage_stmts : (import_stmt stmtsep* | include_stmt stmtsep*)*;
 214 meta_stmts : (organization_stmt stmtsep* | contact_stmt stmtsep* | description_stmt stmtsep* | reference_stmt stmtsep*)*;
 215 submodule_header_stmts : (yang_version_stmt stmtsep* | belongs_to_stmt stmtsep*)+ ;
 216 module_header_stmts :  (yang_version_stmt stmtsep* | namespace_stmt stmtsep* | prefix_stmt stmtsep*)+ ;
 217 // string validated in YangModelBasicValidationListener.enterSubmodule_stmt()
 218 submodule_stmt : SUBMODULE_KEYWORD string LEFT_BRACE stmtsep* submodule_header_stmts linkage_stmts meta_stmts revision_stmts body_stmts RIGHT_BRACE;
 219 // string validated in YangModelBasicValidationListener.enterModule_stmt()
 220 module_stmt : MODULE_KEYWORD string LEFT_BRACE stmtsep* module_header_stmts linkage_stmts meta_stmts revision_stmts body_stmts RIGHT_BRACE;