+ @VisibleForTesting
+ def generateBindingHashCode() '''
+ «val augmentable = analyzeType»
+ «IF augmentable || !typeAnalysis.value.empty»
+ /**
+ * Default implementation of {@link «Object.importedName»#hashCode()} contract for this interface.
+ * Implementations of this interface are encouraged to defer to this method to get consistent hashing
+ * results across all implementations.
+ *
+ * @param obj Object for which to generate hashCode() result.
+ * @return Hash code value of data modeled by this interface.
+ * @throws «NPE.importedName» if {@code obj} is null
+ */
+ static int «BINDING_HASHCODE_NAME»(final «type.fullyQualifiedNonNull» obj) {
+ final int prime = 31;
+ int result = 1;
+ «FOR property : typeAnalysis.value»
+ result = prime * result + «property.importedUtilClass».hashCode(obj.«property.getterMethodName»());
+ «ENDFOR»
+ «IF augmentable»
+ for (var augmentation : obj.augmentations().values()) {
+ result += augmentation.hashCode();
+ }
+ «ENDIF»
+ return result;
+ }
+ «ENDIF»
+ '''
+
+ def private generateBindingEquals() '''
+ «val augmentable = analyzeType»
+ «IF augmentable || !typeAnalysis.value.isEmpty»
+ /**
+ * Default implementation of {@link «Object.importedName»#equals(«Object.importedName»)} contract for this interface.
+ * Implementations of this interface are encouraged to defer to this method to get consistent equality
+ * results across all implementations.
+ *
+ * @param thisObj Object acting as the receiver of equals invocation
+ * @param obj Object acting as argument to equals invocation
+ * @return True if thisObj and obj are considered equal
+ * @throws «NPE.importedName» if {@code thisObj} is null
+ */
+ static boolean «BINDING_EQUALS_NAME»(final «type.fullyQualifiedNonNull» thisObj, final «Types.objectType().importedName» obj) {
+ if (thisObj == obj) {
+ return true;
+ }
+ final «type.fullyQualifiedName» other = «CODEHELPERS.importedName».checkCast(«type.fullyQualifiedName».class, obj);
+ if (other == null) {
+ return false;
+ }
+ «FOR property : ByTypeMemberComparator.sort(typeAnalysis.value)»
+ if (!«property.importedUtilClass».equals(thisObj.«property.getterName»(), other.«property.getterName»())) {
+ return false;
+ }
+ «ENDFOR»
+ return «IF augmentable»thisObj.augmentations().equals(other.augmentations())«ELSE»true«ENDIF»;
+ }
+ «ENDIF»
+ '''
+
+ def generateBindingToString() '''
+ «val augmentable = analyzeType»
+ /**
+ * Default implementation of {@link «Object.importedName»#toString()} contract for this interface.
+ * Implementations of this interface are encouraged to defer to this method to get consistent string
+ * representations across all implementations.
+ *
+ * @param obj Object for which to generate toString() result.
+ * @return {@link «STRING.importedName»} value of data modeled by this interface.
+ * @throws «NPE.importedName» if {@code obj} is null
+ */
+ static «STRING.importedName» «BINDING_TO_STRING_NAME»(final «type.fullyQualifiedNonNull» obj) {
+ final var helper = «MOREOBJECTS.importedName».toStringHelper("«type.name»");
+ «FOR property : typeAnalysis.value»
+ «CODEHELPERS.importedName».appendValue(helper, "«property.name»", obj.«property.getterName»());
+ «ENDFOR»
+ «IF augmentable»
+ «CODEHELPERS.importedName».appendAugmentations(helper, "«AUGMENTATION_FIELD»", obj);
+ «ENDIF»
+ return helper.toString();
+ }
+ '''
+