csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015,2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 ...
  15 ...               TODO: RemoteBash.robot contains logic which could be reused here.
  16 Library           Collections
  17 Library           DateTime
  18 Library           RequestsLibrary
  19 Library           SSHLibrary
  20 Resource          NexusKeywords.robot
  21 Resource          SSHKeywords.robot
  22 Resource          TemplatedRequests.robot
  23 Resource          Utils.robot
  24 Resource          RemoteBash.robot
  25 Resource          CompareStream.robot
  26
  27 *** Variables ***
  28 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx1G -XX:MaxPermSize=256M -Dorg.apache.sshd.registerBouncyCastle=false
  29 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  30 ${FIRST_TESTTOOL_PORT}    17830
  31 ${BASE_NETCONF_DEVICE_PORT}    17830
  32 ${DEVICE_NAME_BASE}    netconf-scaling-device
  33 ${TESTTOOL_DEFAULT_URL}    https://nexus.opendaylight.org/content/repositories/opendaylight.release/org/opendaylight/netconf/netconf-testtool/1.3.2/netconf-testtool-1.3.2-executable.jar
  34 ${TESTTOOL_BOOT_TIMEOUT}    60s
  35 ${ENABLE_NETCONF_TEST_TIMEOUT}    ${ENABLE_GLOBAL_TEST_DEADLINES}
  36
  37 *** Keywords ***
  38 Setup_NetconfKeywords
  39     [Arguments]    ${create_session_for_templated_requests}=True
  40     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  41     ${tmp}=    BuiltIn.Create_Dictionary
  42     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  43     BuiltIn.Run_Keyword_If    ${create_session_for_templated_requests}    TemplatedRequests.Create_Default_Session    timeout=2
  44     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
  45
  46 Configure_Device_In_Netconf
  47     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}    ${device_address}=${TOOLS_SYSTEM_IP}    ${device_user}=admin    ${device_password}=topsecret
  48     ...    ${session}=default    ${schema_directory}=/tmp/schema    ${http_timeout}=${EMPTY}    ${http_method}=put
  49     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  50     ${mapping}=    BuiltIn.Create_dictionary    DEVICE_IP=${device_address}    DEVICE_NAME=${device_name}    DEVICE_PORT=${device_port}    DEVICE_USER=${device_user}    DEVICE_PASSWORD=${device_password}
  51     ...    SCHEMA_DIRECTORY=${schema_directory}
  52     # TODO: Is it possible to use &{kwargs} as a mapping directly?
  53     Run Keyword if    '${http_method}'=='post'    TemplatedRequests.Post_As_Xml_Templated    folder=${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    mapping=${mapping}    session=${session}    http_timeout=${http_timeout}
  54     ...    ELSE    TemplatedRequests.Put_As_Xml_Templated    folder=${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    mapping=${mapping}    session=${session}    http_timeout=${http_timeout}
  55     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  56
  57 Count_Netconf_Connectors_For_Device
  58     [Arguments]    ${device_name}    ${session}=default
  59     [Documentation]    Count all instances of the specified device in the Netconf topology (usually 0 or 1).
  60     # FIXME: This no longer counts netconf connectors, it counts "device instances in Netconf topology".
  61     # This keyword should be renamed but without an automatic keyword naming standards checker this is
  62     # potentially destabilizing change so right now it is as FIXME. Proposed new name:
  63     # Count_Device_Instances_In_Netconf_Topology
  64     ${mounts}=    TemplatedRequests.Get_As_Json_From_Uri    ${OPERATIONAL_API}/network-topology:network-topology/topology/topology-netconf    session=${session}
  65     Builtin.Log    ${mounts}
  66     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id": "${device_name}"'))-1
  67     Builtin.Return_From_Keyword    ${actual_count}
  68
  69 Check_Device_Has_No_Netconf_Connector
  70     [Arguments]    ${device_name}    ${session}=default
  71     [Documentation]    Check that there are no instances of the specified device in the Netconf topology.
  72     # FIXME: Similarlt to "Count_Netconf_Connectors_For_Device", this does not check whether the device has
  73     # no netconf connector but whether the device is present in the netconf topology or not. Rename, proposed
  74     # new name: Check_Device_Not_Present_In_Netconf_Topology
  75     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}    session=${session}
  76     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  77
  78 Check_Device_Completely_Gone
  79     [Arguments]    ${device_name}    ${session}=default
  80     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  81     Check_Device_Has_No_Netconf_Connector    ${device_name}    session=${session}
  82     ${uri}=    Builtin.Set_Variable    ${CONFIG_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}
  83     ${status}    ${response}=    BuiltIn.Run_Keyword_And_Ignore_Error    TemplatedRequests.Get_As_Xml_From_Uri    ${uri}    session=${session}
  84     BuiltIn.Should_Be_Equal_As_Strings    ${status}    FAIL
  85     BuiltIn.Should_Contain    ${response}    404
  86
  87 Check_Device_Connected
  88     [Arguments]    ${device_name}    ${session}=default
  89     [Documentation]    Check that the specified device is accessible from Netconf.
  90     ${device_status}=    TemplatedRequests.Get_As_Json_From_Uri    ${OPERATIONAL_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}    session=${session}
  91     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status": "connected"
  92
  93 Wait_Device_Connected
  94     [Arguments]    ${device_name}    ${timeout}=20s    ${period}=1s    ${session}=default
  95     [Documentation]    Wait for the device to become connected.
  96     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  97     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}    session=${session}
  98
  99 Remove_Device_From_Netconf
 100     [Arguments]    ${device_name}    ${session}=default    ${location}=location
 101     [Documentation]    Tell Netconf to deconfigure the specified device
 102     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
 103     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 104     TemplatedRequests.Delete_Templated    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}    session=${session}    location=${location}
 105
 106 Wait_Device_Fully_Removed
 107     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s    ${session}=default
 108     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
 109     ...    Call of Remove_Device_From_Netconf returns before netconf gets
 110     ...    around deleting the device's connector. To ensure the device is
 111     ...    really gone from netconf, use this keyword to make sure all
 112     ...    connectors disappear. If a call to Remove_Device_From_Netconf
 113     ...    is not made before using this keyword, the wait will fail.
 114     ...    Using this keyword is more readable than putting the WUKS below
 115     ...    into a test case.
 116     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}    session=${session}
 117
 118 NetconfKeywords__Deploy_Additional_Schemas
 119     [Arguments]    ${schemas}
 120     [Documentation]    Internal keyword for Install_And_Start_TestTool
 121     ...    This deploys the additional schemas if any and returns a
 122     ...    command line argument to be added to the testtool commandline
 123     ...    to tell it to load them. While this code could be integrated
 124     ...    into its only user, I considered the resulting code to be too
 125     ...    unreadable as the actions are quite different in the two
 126     ...    possibilities (additional schemas present versus no additional
 127     ...    schemas present), therefore a separate keyword is used.
 128     # Make sure there is no schemas directory on the remote machine. A
 129     # previous test suite might have left some debris there and that might
 130     # lead to spurious failures, so it is better to make sure we start with a
 131     # clean slate. Additionally when the caller did not specify any
 132     # additional schemas for testtool, we want to make extra sure none are
 133     # used.
 134     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 135     BuiltIn.Log    ${response}
 136     # Drop out of the keyword, returning no command line argument when there
 137     # are no additional schemas to deploy.
 138     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 139     # Deploy the additional schemas into a standard directory on the remote
 140     # machine and construct a command line argument pointing to that
 141     # directory from the point of view of the process running on that
 142     # machine.
 143     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 144     [Return]    --schemas-dir ./schemas
 145
 146 NetconfKeywords__Check_Device_Is_Up
 147     [Arguments]    ${last-port}
 148     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 149     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 150
 151 NetconfKeywords__Wait_Device_Is_Up_And_Running
 152     [Arguments]    ${device_name}
 153     ${number}=    BuiltIn.Evaluate    '${device_name}'.split('-').pop()
 154     BuiltIn.Wait_Until_Keyword_Succeeds    ${TESTTOOL_BOOT_TIMEOUT}    1s    Check_Device_Up_And_Running    ${number}
 155
 156 Install_And_Start_Testtool
 157     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}    ${mdsal}=true
 158     [Documentation]    Install and run testtool. Also arrange to collect its output into a log file.
 159     ...    When the ${schemas} argument is set to 'none', it signifies that
 160     ...    there are no additional schemas to be deployed, so the directory
 161     ...    for the additional schemas is deleted on the remote machine and
 162     ...    the additional schemas argument is left out.
 163     # Install test tool on the machine.
 164     # Note that after nitrogen we have to use nitrogen release version because tool is broken in oxygen onwards.
 165     ${explicit_url}=    CompareStream.Set_Variable_If_At_Most_Nitrogen    ${EMPTY}    ${TESTTOOL_DEFAULT_URL}
 166     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf    netconf-testtool    explicit_url=${explicit_url}
 167     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 168     # Start the testtool
 169     ${command}=    NexusKeywords.Compose_Full_Java_Command    ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option} --md-sal ${mdsal}
 170     BuiltIn.Log    Running testtool: ${command}
 171     ${logfile}=    Utils.Get_Log_File_Name    testtool
 172     BuiltIn.Set_Suite_Variable    ${testtool_log}    ${logfile}
 173     SSHLibrary.Write    ${command} >${logfile} 2>&1
 174     # Store information needed by other keywords.
 175     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 176     # Wait for the testtool to boot up.
 177     Perform_Operation_On_Each_Device    NetconfKeywords__Wait_Device_Is_Up_And_Running
 178
 179 Check_Device_Up_And_Running
 180     [Arguments]    ${device-number}
 181     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 182     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 183     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 184
 185 Stop_Testtool
 186     [Documentation]    Stop testtool and download its log.
 187     RemoteBash.Write_Bare_Ctrl_C
 188     SSHLibrary.Read_Until_Prompt
 189     # TODO: Unify with play.py and pcc-mock handling.
 190     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 191     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 192     # the log file to get.
 193     SSHLibrary.Get_File    ${testtool_log}
 194
 195 NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired
 196     [Arguments]    ${deadline_Date}
 197     BuiltIn.Return_From_Keyword_If    not ${ENABLE_NETCONF_TEST_TIMEOUT}
 198     ${current_Date}=    DateTime.Get_Current_Date
 199     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 200     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 201
 202 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 203     [Arguments]    ${operation}    ${deadline_Date}
 204     NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired    ${deadline_Date}
 205     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 206     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 207     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 208     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 209
 210 Perform_Operation_On_Each_Device
 211     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m
 212     ${current_Date}=    DateTime.Get_Current_Date
 213     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 214     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 215     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}