csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015,2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 ...
  15 ...               TODO: RemoteBash.robot contains logic which could be reused here.
  16 Library           Collections
  17 Library           DateTime
  18 Library           RequestsLibrary
  19 Library           SSHLibrary
  20 Resource          NexusKeywords.robot
  21 Resource          Restconf.robot
  22 Resource          SSHKeywords.robot
  23 Resource          TemplatedRequests.robot
  24 Resource          Utils.robot
  25 Resource          RemoteBash.robot
  26
  27 *** Variables ***
  28 ${MAX_HEAP}       1G
  29 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx${MAX_HEAP}
  30 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  31 ${FIRST_TESTTOOL_PORT}    17830
  32 ${BASE_NETCONF_DEVICE_PORT}    17830
  33 ${DEVICE_NAME_BASE}    netconf-scaling-device
  34 ${TESTTOOL_BOOT_TIMEOUT}    60s
  35 ${ENABLE_NETCONF_TEST_TIMEOUT}    ${ENABLE_GLOBAL_TEST_DEADLINES}
  36
  37 *** Keywords ***
  38 Setup_NetconfKeywords
  39     [Arguments]    ${create_session_for_templated_requests}=True
  40     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  41     ${tmp}=    BuiltIn.Create_Dictionary
  42     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  43     BuiltIn.Run_Keyword_If    ${create_session_for_templated_requests}    TemplatedRequests.Create_Default_Session    timeout=2
  44     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
  45
  46 Configure_Device_In_Netconf
  47     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}    ${device_address}=${TOOLS_SYSTEM_IP}    ${device_user}=admin    ${device_password}=topsecret
  48     ...    ${device_key}=device-key    ${session}=default    ${schema_directory}=/tmp/schema    ${http_timeout}=${EMPTY}    ${http_method}=put
  49     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  50     ${mapping}=    BuiltIn.Create_dictionary    DEVICE_IP=${device_address}    DEVICE_NAME=${device_name}    DEVICE_PORT=${device_port}    DEVICE_USER=${device_user}    DEVICE_PASSWORD=${device_password}
  51     ...    DEVICE_KEY=${device_key}    SCHEMA_DIRECTORY=${schema_directory}
  52     # TODO: Is it possible to use &{kwargs} as a mapping directly?
  53     Run Keyword if    '${http_method}'=='post'    TemplatedRequests.Post_As_Xml_Templated    folder=${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    mapping=${mapping}    session=${session}    http_timeout=${http_timeout}
  54     ...    ELSE    TemplatedRequests.Put_As_Xml_Templated    folder=${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    mapping=${mapping}    session=${session}    http_timeout=${http_timeout}
  55     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  56
  57 Configure_Device
  58     [Arguments]    ${current_name}    ${log_response}=True
  59     [Documentation]    Operation for configuring the device.
  60     KarafKeywords.Log_Message_To_Controller_Karaf    Configuring device ${current_name} to Netconf
  61     Configure_Device_In_Netconf    ${current_name}    device_type=${device_type}    device_port=${current_port}
  62     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} configured
  63
  64 Configure_Device_And_Verify
  65     [Arguments]    ${current_name}    ${log_response}=True
  66     [Documentation]    Operation for configuring the device in the Netconf subsystem and connecting to it.
  67     Configure_Device    ${current_name}    ${log_response}
  68     KarafKeywords.Log_Message_To_Controller_Karaf    Waiting for device ${current_name} to connect
  69     Wait_Device_Connected    ${current_name}    period=0.5s
  70     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} connected
  71
  72 Count_Netconf_Connectors_For_Device
  73     [Arguments]    ${device_name}    ${session}=default
  74     [Documentation]    Count all instances of the specified device in the Netconf topology (usually 0 or 1).
  75     # FIXME: This no longer counts netconf connectors, it counts "device instances in Netconf topology".
  76     # This keyword should be renamed but without an automatic keyword naming standards checker this is
  77     # potentially destabilizing change so right now it is as FIXME. Proposed new name:
  78     # Count_Device_Instances_In_Netconf_Topology
  79     ${uri} =    Restconf.Generate URI    network-topology:network-topology    operational
  80     ${mounts}=    TemplatedRequests.Get_As_Json_From_Uri    ${uri}    session=${session}
  81     Builtin.Log    ${mounts}
  82     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id": "${device_name}"'))-1
  83     Builtin.Return_From_Keyword    ${actual_count}
  84
  85 Wait_Connected
  86     [Arguments]    ${current_name}    ${log_response}=True
  87     [Documentation]    Operation for waiting until the device is connected.
  88     KarafKeywords.Log_Message_To_Controller_Karaf    Waiting for device ${current_name} to connect
  89     Wait_Device_Connected    ${current_name}    period=0.5s    timeout=300s
  90     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} connected
  91
  92 Check_Device_Has_No_Netconf_Connector
  93     [Arguments]    ${device_name}    ${session}=default
  94     [Documentation]    Check that there are no instances of the specified device in the Netconf topology.
  95     # FIXME: Similarlt to "Count_Netconf_Connectors_For_Device", this does not check whether the device has
  96     # no netconf connector but whether the device is present in the netconf topology or not. Rename, proposed
  97     # new name: Check_Device_Not_Present_In_Netconf_Topology
  98     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}    session=${session}
  99     Builtin.Should_Be_Equal_As_Strings    ${count}    0
 100
 101 Check_Device_Completely_Gone
 102     [Arguments]    ${device_name}    ${session}=default    ${log_response}=True
 103     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
 104     Check_Device_Has_No_Netconf_Connector    ${device_name}    session=${session}
 105     ${uri} =    Restconf.Generate URI    network-topology:network-topology    config    topology=topology-netconf    node=${device_name}
 106     Utils.No Content From URI    ${session}    ${uri}
 107
 108 Check_Device_Connected
 109     [Arguments]    ${device_name}    ${session}=default    ${log_response}=True
 110     [Documentation]    Check that the specified device is accessible from Netconf.
 111     ${uri} =    Restconf.Generate URI    network-topology:network-topology    operational    topology=topology-netconf    node=${device_name}
 112     ${device_status}=    TemplatedRequests.Get_As_Json_From_Uri    ${uri}    session=${session}    log_response=${log_response}
 113     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status": "connected"
 114
 115 Wait_Device_Connected
 116     [Arguments]    ${device_name}    ${timeout}=20s    ${period}=1s    ${session}=default    ${log_response}=True
 117     [Documentation]    Wait for the device to become connected.
 118     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
 119     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}    session=${session}    log_response=${log_response}
 120
 121 Remove_Device_From_Netconf
 122     [Arguments]    ${device_name}    ${session}=default    ${location}=location
 123     [Documentation]    Tell Netconf to deconfigure the specified device
 124     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
 125     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 126     TemplatedRequests.Delete_Templated    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}    session=${session}    location=${location}
 127
 128 Deconfigure_Device
 129     [Arguments]    ${current_name}    ${log_response}=True
 130     [Documentation]    Operation for deconfiguring the device.
 131     KarafKeywords.Log_Message_To_Controller_Karaf    Deconfiguring device ${current_name}
 132     Remove_Device_From_Netconf    ${current_name}
 133     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} deconfigured
 134
 135 Deconfigure_Device_And_Verify
 136     [Arguments]    ${current_name}    ${log_response}=True
 137     [Documentation]    Operation for deconfiguring the device from Netconf.
 138     Deconfigure_Device    ${current_name}    ${log_response}
 139     Check_Device_Deconfigured    ${current_name}
 140
 141 Check_Device_Deconfigured
 142     [Arguments]    ${current_name}    ${log_response}=True
 143     [Documentation]    Operation for making sure the device is really deconfigured.
 144     KarafKeywords.Log_Message_To_Controller_Karaf    Waiting for device ${current_name} to disappear
 145     Wait_Device_Fully_Removed    ${current_name}    period=0.5s    timeout=120s
 146     KarafKeywords.Log_Message_To_Controller_Karaf    Device ${current_name} removed
 147
 148 Wait_Device_Fully_Removed
 149     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s    ${session}=default    ${log_response}=True
 150     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
 151     ...    Call of Remove_Device_From_Netconf returns before netconf gets
 152     ...    around deleting the device's connector. To ensure the device is
 153     ...    really gone from netconf, use this keyword to make sure all
 154     ...    connectors disappear. If a call to Remove_Device_From_Netconf
 155     ...    is not made before using this keyword, the wait will fail.
 156     ...    Using this keyword is more readable than putting the WUKS below
 157     ...    into a test case.
 158     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}    session=${session}    log_response=${log_response}
 159
 160 NetconfKeywords__Deploy_Additional_Schemas
 161     [Arguments]    ${schemas}
 162     [Documentation]    Internal keyword for Install_And_Start_TestTool
 163     ...    This deploys the additional schemas if any and returns a
 164     ...    command line argument to be added to the testtool commandline
 165     ...    to tell it to load them. While this code could be integrated
 166     ...    into its only user, I considered the resulting code to be too
 167     ...    unreadable as the actions are quite different in the two
 168     ...    possibilities (additional schemas present versus no additional
 169     ...    schemas present), therefore a separate keyword is used.
 170     # Make sure there is no schemas directory on the remote machine. A
 171     # previous test suite might have left some debris there and that might
 172     # lead to spurious failures, so it is better to make sure we start with a
 173     # clean slate. Additionally when the caller did not specify any
 174     # additional schemas for testtool, we want to make extra sure none are
 175     # used.
 176     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 177     BuiltIn.Log    ${response}
 178     # Drop out of the keyword, returning no command line argument when there
 179     # are no additional schemas to deploy.
 180     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 181     # Deploy the additional schemas into a standard directory on the remote
 182     # machine and construct a command line argument pointing to that
 183     # directory from the point of view of the process running on that
 184     # machine.
 185     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 186     SSHLibrary.List_Directory    ./schemas
 187     [Return]    --schemas-dir ./schemas
 188
 189 NetconfKeywords__Deploy_Custom_RPC
 190     [Arguments]    ${rpc_config}
 191     [Documentation]    Internal keyword for Install_And_Start_TestTool
 192     ...    This deploys the optional custom rpc file.
 193     ...    Drop out of the keyword, returning no command line argument when there
 194     ...    is no rpc file to deploy.
 195     BuiltIn.Return_From_Keyword_If    '${rpc_config}' == 'none'    ${EMPTY}
 196     SSHKeywords.Copy_File_To_Tools_System    ${TOOLS_SYSTEM_1_IP}    ${rpc_config}    /tmp
 197     [Return]    --rpc-config /tmp/customaction.xml
 198
 199 NetconfKeywords__Check_Device_Is_Up
 200     [Arguments]    ${last-port}
 201     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 202     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 203
 204 NetconfKeywords__Wait_Device_Is_Up_And_Running
 205     [Arguments]    ${device_name}    ${log_response}=True
 206     ${number}=    BuiltIn.Evaluate    '${device_name}'.split('-').pop()
 207     BuiltIn.Wait_Until_Keyword_Succeeds    ${TESTTOOL_BOOT_TIMEOUT}    1s    Check_Device_Up_And_Running    ${number}
 208
 209 Install_And_Start_Testtool
 210     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${rpc_config}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}
 211     ...    ${mdsal}=true
 212     [Documentation]    Install and run testtool.
 213     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf    netconf-testtool
 214     Start_Testtool    ${filename}    ${device-count}    ${debug}    ${schemas}    ${rpc_config}    ${tool_options}
 215     ...    ${java_options}    ${mdsal}
 216
 217 Start_Testtool
 218     [Arguments]    ${filename}    ${device-count}=10    ${debug}=true    ${schemas}=none    ${rpc_config}=none    ${tool_options}=${EMPTY}
 219     ...    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}    ${mdsal}=true
 220     [Documentation]    Arrange to collect tool's output into a log file.
 221     ...    Will use specific ${schemas} unless argument resolves to 'none',
 222     ...    which signifies that there are no additional schemas to be deployed.
 223     ...    If so the directory for the additional schemas is deleted on the
 224     ...    remote machine and the additional schemas argument is left out.
 225     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 226     ${rpc_config_option}=    NetconfKeywords__Deploy_Custom_RPC    ${rpc_config}
 227     ${command}=    NexusKeywords.Compose_Full_Java_Command    ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option} ${rpc_config_option} --md-sal ${mdsal}
 228     BuiltIn.Log    Running testtool: ${command}
 229     ${logfile}=    Utils.Get_Log_File_Name    testtool
 230     BuiltIn.Set_Suite_Variable    ${testtool_log}    ${logfile}
 231     SSHLibrary.Write    ${command} >${logfile} 2>&1
 232     # Store information needed by other keywords.
 233     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 234     # Wait for the testtool to boot up.
 235     Perform_Operation_On_Each_Device    NetconfKeywords__Wait_Device_Is_Up_And_Running
 236
 237 Check_Device_Up_And_Running
 238     [Arguments]    ${device-number}
 239     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 240     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 241     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 242
 243 Stop_Testtool
 244     [Documentation]    Stop testtool and download its log.
 245     RemoteBash.Write_Bare_Ctrl_C
 246     SSHLibrary.Read_Until_Prompt
 247     # TODO: Unify with play.py and pcc-mock handling.
 248     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 249     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 250     # the log file to get.
 251     SSHLibrary.Get_File    ${testtool_log}
 252
 253 NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired
 254     [Arguments]    ${deadline_Date}
 255     BuiltIn.Return_From_Keyword_If    not ${ENABLE_NETCONF_TEST_TIMEOUT}
 256     ${current_Date}=    DateTime.Get_Current_Date
 257     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 258     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 259
 260 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 261     [Arguments]    ${operation}    ${deadline_Date}    ${log_response}=True
 262     NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired    ${deadline_Date}
 263     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 264     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}    log_response=${log_response}
 265     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 266     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 267
 268 Perform_Operation_On_Each_Device
 269     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m    ${log_response}=True
 270     ${current_Date}=    DateTime.Get_Current_Date
 271     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 272     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 273     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}    log_response=${log_response}