csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015,2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 ...
  15 ...               TODO: RemoteBash.robot contains logic which could be reused here.
  16 Library           Collections
  17 Library           DateTime
  18 Library           RequestsLibrary
  19 Library           SSHLibrary
  20 Resource          NexusKeywords.robot
  21 Resource          SSHKeywords.robot
  22 Resource          TemplatedRequests.robot
  23 Resource          Utils.robot
  24 Resource          RemoteBash.robot
  25
  26 *** Variables ***
  27 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx1G -XX:MaxPermSize=256M -Dorg.apache.sshd.registerBouncyCastle=false
  28 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  29 ${FIRST_TESTTOOL_PORT}    17830
  30 ${BASE_NETCONF_DEVICE_PORT}    17830
  31 ${DEVICE_NAME_BASE}    netconf-scaling-device
  32 ${TESTTOOL_BOOT_TIMEOUT}    60s
  33 ${ENABLE_NETCONF_TEST_TIMEOUT}    ${ENABLE_GLOBAL_TEST_DEADLINES}
  34
  35 *** Keywords ***
  36 Setup_NetconfKeywords
  37     [Arguments]    ${create_session_for_templated_requests}=True
  38     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  39     ${tmp}=    BuiltIn.Create_Dictionary
  40     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  41     BuiltIn.Run_Keyword_If    ${create_session_for_templated_requests}    TemplatedRequests.Create_Default_Session    timeout=2
  42     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
  43
  44 Configure_Device_In_Netconf
  45     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}    ${device_address}=${TOOLS_SYSTEM_IP}    ${device_user}=admin    ${device_password}=topsecret
  46     ...    ${session}=default    ${schema_directory}=/tmp/schema    ${http_timeout}=${EMPTY}
  47     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  48     ${mapping}=    BuiltIn.Create_dictionary    DEVICE_IP=${device_address}    DEVICE_NAME=${device_name}    DEVICE_PORT=${device_port}    DEVICE_USER=${device_user}    DEVICE_PASSWORD=${device_password}
  49     ...    SCHEMA_DIRECTORY=${schema_directory}
  50     # TODO: Is it possible to use &{kwargs} as a mapping directly?
  51     TemplatedRequests.Put_As_Xml_Templated    folder=${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    mapping=${mapping}    session=${session}    http_timeout=${http_timeout}
  52     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  53
  54 Count_Netconf_Connectors_For_Device
  55     [Arguments]    ${device_name}    ${session}=default
  56     [Documentation]    Count all instances of the specified device in the Netconf topology (usually 0 or 1).
  57     # FIXME: This no longer counts netconf connectors, it counts "device instances in Netconf topology".
  58     # This keyword should be renamed but without an automatic keyword naming standards checker this is
  59     # potentially destabilizing change so right now it is as FIXME. Proposed new name:
  60     # Count_Device_Instances_In_Netconf_Topology
  61     ${mounts}=    TemplatedRequests.Get_As_Json_From_Uri    ${OPERATIONAL_API}/network-topology:network-topology/topology/topology-netconf    session=${session}
  62     Builtin.Log    ${mounts}
  63     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id": "${device_name}"'))-1
  64     Builtin.Return_From_Keyword    ${actual_count}
  65
  66 Check_Device_Has_No_Netconf_Connector
  67     [Arguments]    ${device_name}    ${session}=default
  68     [Documentation]    Check that there are no instances of the specified device in the Netconf topology.
  69     # FIXME: Similarlt to "Count_Netconf_Connectors_For_Device", this does not check whether the device has
  70     # no netconf connector but whether the device is present in the netconf topology or not. Rename, proposed
  71     # new name: Check_Device_Not_Present_In_Netconf_Topology
  72     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}    session=${session}
  73     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  74
  75 Check_Device_Completely_Gone
  76     [Arguments]    ${device_name}    ${session}=default
  77     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  78     Check_Device_Has_No_Netconf_Connector    ${device_name}    session=${session}
  79     ${uri}=    Builtin.Set_Variable    ${CONFIG_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}
  80     ${status}    ${response}=    BuiltIn.Run_Keyword_And_Ignore_Error    TemplatedRequests.Get_As_Xml_From_Uri    ${uri}    session=${session}
  81     BuiltIn.Should_Be_Equal_As_Strings    ${status}    FAIL
  82     BuiltIn.Should_Contain    ${response}    404
  83
  84 Check_Device_Connected
  85     [Arguments]    ${device_name}    ${session}=default
  86     [Documentation]    Check that the specified device is accessible from Netconf.
  87     ${device_status}=    TemplatedRequests.Get_As_Json_From_Uri    ${OPERATIONAL_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}    session=${session}
  88     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status": "connected"
  89
  90 Wait_Device_Connected
  91     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s    ${session}=default
  92     [Documentation]    Wait for the device to become connected.
  93     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  94     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}    session=${session}
  95
  96 Remove_Device_From_Netconf
  97     [Arguments]    ${device_name}    ${session}=default
  98     [Documentation]    Tell Netconf to deconfigure the specified device
  99     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
 100     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 101     TemplatedRequests.Delete_Templated    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}    session=${session}
 102
 103 Wait_Device_Fully_Removed
 104     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s    ${session}=default
 105     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
 106     ...    Call of Remove_Device_From_Netconf returns before netconf gets
 107     ...    around deleting the device's connector. To ensure the device is
 108     ...    really gone from netconf, use this keyword to make sure all
 109     ...    connectors disappear. If a call to Remove_Device_From_Netconf
 110     ...    is not made before using this keyword, the wait will fail.
 111     ...    Using this keyword is more readable than putting the WUKS below
 112     ...    into a test case.
 113     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}    session=${session}
 114
 115 NetconfKeywords__Deploy_Additional_Schemas
 116     [Arguments]    ${schemas}
 117     [Documentation]    Internal keyword for Install_And_Start_TestTool
 118     ...    This deploys the additional schemas if any and returns a
 119     ...    command line argument to be added to the testtool commandline
 120     ...    to tell it to load them. While this code could be integrated
 121     ...    into its only user, I considered the resulting code to be too
 122     ...    unreadable as the actions are quite different in the two
 123     ...    possibilities (additional schemas present versus no additional
 124     ...    schemas present), therefore a separate keyword is used.
 125     # Make sure there is no schemas directory on the remote machine. A
 126     # previous test suite might have left some debris there and that might
 127     # lead to spurious failures, so it is better to make sure we start with a
 128     # clean slate. Additionally when the caller did not specify any
 129     # additional schemas for testtool, we want to make extra sure none are
 130     # used.
 131     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 132     BuiltIn.Log    ${response}
 133     # Drop out of the keyword, returning no command line argument when there
 134     # are no additional schemas to deploy.
 135     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 136     # Deploy the additional schemas into a standard directory on the remote
 137     # machine and construct a command line argument pointing to that
 138     # directory from the point of view of the process running on that
 139     # machine.
 140     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 141     [Return]    --schemas-dir ./schemas
 142
 143 NetconfKeywords__Check_Device_Is_Up
 144     [Arguments]    ${last-port}
 145     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 146     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 147
 148 NetconfKeywords__Wait_Device_Is_Up_And_Running
 149     [Arguments]    ${device_name}
 150     ${number}=    BuiltIn.Evaluate    '${device_name}'.split('-').pop()
 151     BuiltIn.Wait_Until_Keyword_Succeeds    ${TESTTOOL_BOOT_TIMEOUT}    1s    Check_Device_Up_And_Running    ${number}
 152
 153 Install_And_Start_Testtool
 154     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}    ${mdsal}=true
 155     [Documentation]    Install and run testtool. Also arrange to collect its output into a log file.
 156     ...    When the ${schemas} argument is set to 'none', it signifies that
 157     ...    there are no additional schemas to be deployed, so the directory
 158     ...    for the additional schemas is deleted on the remote machine and
 159     ...    the additional schemas argument is left out.
 160     # Install test tool on the machine.
 161     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf    netconf-testtool
 162     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 163     # Start the testtool
 164     ${command}=    NexusKeywords.Compose_Full_Java_Command    ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option} --md-sal ${mdsal}
 165     BuiltIn.Log    Running testtool: ${command}
 166     ${logfile}=    Utils.Get_Log_File_Name    testtool
 167     BuiltIn.Set_Suite_Variable    ${testtool_log}    ${logfile}
 168     SSHLibrary.Write    ${command} >${logfile} 2>&1
 169     # Store information needed by other keywords.
 170     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 171     # Wait for the testtool to boot up.
 172     Perform_Operation_On_Each_Device    NetconfKeywords__Wait_Device_Is_Up_And_Running
 173
 174 Check_Device_Up_And_Running
 175     [Arguments]    ${device-number}
 176     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 177     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 178     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 179
 180 Stop_Testtool
 181     [Documentation]    Stop testtool and download its log.
 182     RemoteBash.Write_Bare_Ctrl_C
 183     SSHLibrary.Read_Until_Prompt
 184     # TODO: Unify with play.py and pcc-mock handling.
 185     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 186     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 187     # the log file to get.
 188     SSHLibrary.Get_File    ${testtool_log}
 189
 190 NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired
 191     [Arguments]    ${deadline_Date}
 192     BuiltIn.Return_From_Keyword_If    not ${ENABLE_NETCONF_TEST_TIMEOUT}
 193     ${current_Date}=    DateTime.Get_Current_Date
 194     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 195     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 196
 197 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 198     [Arguments]    ${operation}    ${deadline_Date}
 199     NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired    ${deadline_Date}
 200     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 201     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 202     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 203     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 204
 205 Perform_Operation_On_Each_Device
 206     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m
 207     ${current_Date}=    DateTime.Get_Current_Date
 208     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 209     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 210     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}