csit/libraries/NetconfKeywords.robot

   1 *** Settings ***
   2 Documentation     Perform complex operations on netconf.
   3 ...
   4 ...               Copyright (c) 2015,2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               netconf operations into reusable keywords to make writing netconf
  13 ...               test suites easier.
  14 ...
  15 ...               TODO: RemoteBash.robot contains logic which could be reused here.
  16 Library           Collections
  17 Library           DateTime
  18 Library           RequestsLibrary
  19 Library           SSHLibrary
  20 Resource          NexusKeywords.robot
  21 Resource          SSHKeywords.robot
  22 Resource          TemplatedRequests.robot
  23 Resource          Utils.robot
  24
  25 *** Variables ***
  26 ${TESTTOOL_DEFAULT_JAVA_OPTIONS}    -Xmx1G -XX:MaxPermSize=256M -Dorg.apache.sshd.registerBouncyCastle=false
  27 ${DIRECTORY_WITH_DEVICE_TEMPLATES}    ${CURDIR}/../variables/netconf/device
  28 ${FIRST_TESTTOOL_PORT}    17830
  29 ${BASE_NETCONF_DEVICE_PORT}    17830
  30 ${DEVICE_NAME_BASE}    netconf-scaling-device
  31 ${TESTTOOL_BOOT_TIMEOUT}    60s
  32 ${ENABLE_NETCONF_TEST_TIMEOUT}    ${ENABLE_GLOBAL_TEST_DEADLINES}
  33
  34 *** Keywords ***
  35 Setup_NetconfKeywords
  36     [Arguments]    ${create_session_for_templated_requests}=True
  37     [Documentation]    Setup the environment for the other keywords of this Resource to work properly.
  38     ${tmp}=    BuiltIn.Create_Dictionary
  39     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__mounted_device_types}    ${tmp}
  40     BuiltIn.Run_Keyword_If    ${create_session_for_templated_requests}    TemplatedRequests.Create_Default_Session    timeout=2
  41     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
  42
  43 Configure_Device_In_Netconf
  44     [Arguments]    ${device_name}    ${device_type}=default    ${device_port}=${FIRST_TESTTOOL_PORT}    ${device_address}=${TOOLS_SYSTEM_IP}    ${device_user}=admin    ${device_password}=topsecret
  45     ...    ${session}=default    ${schema_directory}=/tmp/schema
  46     [Documentation]    Tell Netconf about the specified device so it can add it into its configuration.
  47     ${mapping}=    BuiltIn.Create_dictionary    DEVICE_IP=${device_address}    DEVICE_NAME=${device_name}    DEVICE_PORT=${device_port}    DEVICE_USER=${device_user}    DEVICE_PASSWORD=${device_password}
  48     ...    SCHEMA_DIRECTORY=${schema_directory}
  49     # TODO: Is it possible to use &{kwargs} as a mapping directly?
  50     TemplatedRequests.Put_As_Xml_Templated    folder=${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    mapping=${mapping}    session=${session}
  51     Collections.Set_To_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}    ${device_type}
  52
  53 Count_Netconf_Connectors_For_Device
  54     [Arguments]    ${device_name}    ${session}=default
  55     [Documentation]    Count all instances of the specified device in the Netconf topology (usually 0 or 1).
  56     # FIXME: This no longer counts netconf connectors, it counts "device instances in Netconf topology".
  57     # This keyword should be renamed but without an automatic keyword naming standards checker this is
  58     # potentially destabilizing change so right now it is as FIXME. Proposed new name:
  59     # Count_Device_Instances_In_Netconf_Topology
  60     ${mounts}=    TemplatedRequests.Get_As_Json_From_Uri    ${OPERATIONAL_API}/network-topology:network-topology/topology/topology-netconf    session=${session}
  61     Builtin.Log    ${mounts}
  62     ${actual_count}=    Builtin.Evaluate    len('''${mounts}'''.split('"node-id": "${device_name}"'))-1
  63     Builtin.Return_From_Keyword    ${actual_count}
  64
  65 Check_Device_Has_No_Netconf_Connector
  66     [Arguments]    ${device_name}    ${session}=default
  67     [Documentation]    Check that there are no instances of the specified device in the Netconf topology.
  68     # FIXME: Similarlt to "Count_Netconf_Connectors_For_Device", this does not check whether the device has
  69     # no netconf connector but whether the device is present in the netconf topology or not. Rename, proposed
  70     # new name: Check_Device_Not_Present_In_Netconf_Topology
  71     ${count}    Count_Netconf_Connectors_For_Device    ${device_name}    session=${session}
  72     Builtin.Should_Be_Equal_As_Strings    ${count}    0
  73
  74 Check_Device_Completely_Gone
  75     [Arguments]    ${device_name}    ${session}=default
  76     [Documentation]    Check that the specified device has no Netconf connectors nor associated data.
  77     Check_Device_Has_No_Netconf_Connector    ${device_name}    session=${session}
  78     ${uri}=    Builtin.Set_Variable    ${CONFIG_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}
  79     ${status}    ${response}=    BuiltIn.Run_Keyword_And_Ignore_Error    TemplatedRequests.Get_As_Xml_From_Uri    ${uri}    session=${session}
  80     BuiltIn.Should_Be_Equal_As_Strings    ${status}    FAIL
  81     BuiltIn.Should_Contain    ${response}    404
  82
  83 Check_Device_Connected
  84     [Arguments]    ${device_name}    ${session}=default
  85     [Documentation]    Check that the specified device is accessible from Netconf.
  86     ${device_status}=    TemplatedRequests.Get_As_Json_From_Uri    ${OPERATIONAL_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}    session=${session}
  87     Builtin.Should_Contain    ${device_status}    "netconf-node-topology:connection-status": "connected"
  88
  89 Wait_Device_Connected
  90     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s    ${session}=default
  91     [Documentation]    Wait for the device to become connected.
  92     ...    It is more readable to use this keyword in a test case than to put the whole WUKS below into it.
  93     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Connected    ${device_name}    session=${session}
  94
  95 Remove_Device_From_Netconf
  96     [Arguments]    ${device_name}    ${session}=default
  97     [Documentation]    Tell Netconf to deconfigure the specified device
  98     ${device_type}=    Collections.Pop_From_Dictionary    ${NetconfKeywords__mounted_device_types}    ${device_name}
  99     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 100     TemplatedRequests.Delete_Templated    ${DIRECTORY_WITH_DEVICE_TEMPLATES}${/}${device_type}    ${template_as_string}    session=${session}
 101
 102 Wait_Device_Fully_Removed
 103     [Arguments]    ${device_name}    ${timeout}=10s    ${period}=1s    ${session}=default
 104     [Documentation]    Wait until all netconf connectors for the device with the given name disappear.
 105     ...    Call of Remove_Device_From_Netconf returns before netconf gets
 106     ...    around deleting the device's connector. To ensure the device is
 107     ...    really gone from netconf, use this keyword to make sure all
 108     ...    connectors disappear. If a call to Remove_Device_From_Netconf
 109     ...    is not made before using this keyword, the wait will fail.
 110     ...    Using this keyword is more readable than putting the WUKS below
 111     ...    into a test case.
 112     BuiltIn.Wait_Until_Keyword_Succeeds    ${timeout}    ${period}    Check_Device_Completely_Gone    ${device_name}    session=${session}
 113
 114 NetconfKeywords__Deploy_Additional_Schemas
 115     [Arguments]    ${schemas}
 116     [Documentation]    Internal keyword for Install_And_Start_TestTool
 117     ...    This deploys the additional schemas if any and returns a
 118     ...    command line argument to be added to the testtool commandline
 119     ...    to tell it to load them. While this code could be integrated
 120     ...    into its only user, I considered the resulting code to be too
 121     ...    unreadable as the actions are quite different in the two
 122     ...    possibilities (additional schemas present versus no additional
 123     ...    schemas present), therefore a separate keyword is used.
 124     # Make sure there is no schemas directory on the remote machine. A
 125     # previous test suite might have left some debris there and that might
 126     # lead to spurious failures, so it is better to make sure we start with a
 127     # clean slate. Additionally when the caller did not specify any
 128     # additional schemas for testtool, we want to make extra sure none are
 129     # used.
 130     ${response}=    SSHLibrary.Execute_Command    rm -rf schemas 2>&1
 131     BuiltIn.Log    ${response}
 132     # Drop out of the keyword, returning no command line argument when there
 133     # are no additional schemas to deploy.
 134     BuiltIn.Return_From_Keyword_If    '${schemas}' == 'none'    ${EMPTY}
 135     # Deploy the additional schemas into a standard directory on the remote
 136     # machine and construct a command line argument pointing to that
 137     # directory from the point of view of the process running on that
 138     # machine.
 139     SSHLibrary.Put_Directory    ${schemas}    destination=./schemas
 140     [Return]    --schemas-dir ./schemas
 141
 142 NetconfKeywords__Check_Device_Is_Up
 143     [Arguments]    ${last-port}
 144     ${count}=    SSHKeywords.Count_Port_Occurences    ${last-port}    LISTEN    java
 145     BuiltIn.Should_Be_Equal_As_Integers    ${count}    1
 146
 147 NetconfKeywords__Wait_Device_Is_Up_And_Running
 148     [Arguments]    ${device_name}
 149     ${number}=    BuiltIn.Evaluate    '${device_name}'.split('-').pop()
 150     BuiltIn.Wait_Until_Keyword_Succeeds    ${TESTTOOL_BOOT_TIMEOUT}    1s    Check_Device_Up_And_Running    ${number}
 151
 152 Install_And_Start_Testtool
 153     [Arguments]    ${device-count}=10    ${debug}=true    ${schemas}=none    ${tool_options}=${EMPTY}    ${java_options}=${TESTTOOL_DEFAULT_JAVA_OPTIONS}    ${mdsal}=true
 154     [Documentation]    Install and run testtool. Also arrange to collect its output into a log file.
 155     ...    When the ${schemas} argument is set to 'none', it signifies that
 156     ...    there are no additional schemas to be deployed, so the directory
 157     ...    for the additional schemas is deleted on the remote machine and
 158     ...    the additional schemas argument is left out.
 159     # Install test tool on the machine.
 160     ${filename}=    NexusKeywords.Deploy_Test_Tool    netconf    netconf-testtool
 161     ${schemas_option}=    NetconfKeywords__Deploy_Additional_Schemas    ${schemas}
 162     # Start the testtool
 163     ${command}=    NexusKeywords.Compose_Full_Java_Command    ${java_options} -jar ${filename} ${tool_options} --device-count ${device-count} --debug ${debug} ${schemas_option} --md-sal ${mdsal}
 164     BuiltIn.Log    Running testtool: ${command}
 165     ${logfile}=    Utils.Get_Log_File_Name    testtool
 166     BuiltIn.Set_Suite_Variable    ${testtool_log}    ${logfile}
 167     SSHLibrary.Write    ${command} >${logfile} 2>&1
 168     # Store information needed by other keywords.
 169     BuiltIn.Set_Suite_Variable    ${NetconfKeywords__testtool_device_count}    ${device-count}
 170     # Wait for the testtool to boot up.
 171     Perform_Operation_On_Each_Device    NetconfKeywords__Wait_Device_Is_Up_And_Running
 172
 173 Check_Device_Up_And_Running
 174     [Arguments]    ${device-number}
 175     [Documentation]    Query netstat on remote machine whether testtool device with the specified number has its port open and fail if not.
 176     ${device-port}=    BuiltIn.Evaluate    ${FIRST_TESTTOOL_PORT}+${device-number}-1
 177     NetconfKeywords__Check_Device_Is_Up    ${device-port}
 178
 179 Stop_Testtool
 180     [Documentation]    Stop testtool and download its log.
 181     Utils.Write_Bare_Ctrl_C
 182     SSHLibrary.Read_Until_Prompt
 183     # TODO: Unify with play.py and pcc-mock handling.
 184     # TODO: Maybe this keyword's content shall be moved into SSHUtils and named somewhat like
 185     # "Interrupt_Program_And_Download_Its_Log" which will get an argument stating the name of
 186     # the log file to get.
 187     SSHLibrary.Get_File    ${testtool_log}
 188
 189 NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired
 190     [Arguments]    ${deadline_Date}
 191     BuiltIn.Return_From_Keyword_If    not ${ENABLE_NETCONF_TEST_TIMEOUT}
 192     ${current_Date}=    DateTime.Get_Current_Date
 193     ${ellapsed_seconds}=    DateTime.Subtract_Date_From_Date    ${deadline_Date}    ${current_Date}
 194     BuiltIn.Run_Keyword_If    ${ellapsed_seconds}<0    Fail    The global time out period expired
 195
 196 NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device
 197     [Arguments]    ${operation}    ${deadline_Date}
 198     NetconfKeywords__Check_Netconf_Test_Timeout_Not_Expired    ${deadline_Date}
 199     ${number}=    BuiltIn.Evaluate    ${current_port}-${BASE_NETCONF_DEVICE_PORT}+1
 200     BuiltIn.Run_Keyword    ${operation}    ${DEVICE_NAME_BASE}-${number}
 201     ${next}=    BuiltIn.Evaluate    ${current_port}+1
 202     BuiltIn.Set_Suite_Variable    ${current_port}    ${next}
 203
 204 Perform_Operation_On_Each_Device
 205     [Arguments]    ${operation}    ${count}=${NetconfKeywords__testtool_device_count}    ${timeout}=30m
 206     ${current_Date}=    DateTime.Get_Current_Date
 207     ${deadline_Date}=    DateTime.Add_Time_To_Date    ${current_Date}    ${timeout}
 208     BuiltIn.Set_Suite_Variable    ${current_port}    ${BASE_NETCONF_DEVICE_PORT}
 209     BuiltIn.Repeat_Keyword    ${count} times    NetconfKeywords__Perform_Operation_With_Checking_On_Next_Device    ${operation}    ${deadline_Date}