csit/libraries/NexusKeywords.robot

   1 *** Settings ***
   2 Documentation     Nexus repository access keywords, and supporting Java and Maven handling.
   3 ...
   4 ...               Copyright (c) 2015,2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               Nexus operations into reusable keywords to make writing test suites easier.
  13 ...
  14 ...               Currently, Java version detection is incorporated so that Java tools can be run reliably.
  15 ...               Also, suport for installing and running Maven is added, as that needs the Java detection.
  16 ...               TODO: Move Java detection and Maven to a separate Resource, or rename this Resource.
  17 Library           Collections
  18 Library           OperatingSystem
  19 Library           SSHLibrary
  20 Library           String
  21 Library           XML
  22 Library           Collections
  23 Library           RequestsLibrary
  24 Resource          ${CURDIR}/CompareStream.robot
  25 Resource          ${CURDIR}/SSHKeywords.robot
  26 Resource          ${CURDIR}/Utils.robot
  27
  28 *** Variables ***
  29 &{COMPONENT_MAPPING}    netconf=netconf-impl    bgpcep=pcep-impl    carpeople=clustering-it-model    yangtools=yang-data-impl    bindingv1=mdsal-binding-generator-impl
  30 @{RELEASE_INTEGRATED_COMPONENTS}    mdsal    odlparent    yangtools    carpeople
  31 ${JDKVERSION}     None
  32 ${JAVA_8_HOME_CENTOS}    /usr/lib/jvm/java-1.8.0
  33 ${JAVA_8_HOME_UBUNTU}    /usr/lib/jvm/java-8-openjdk-amd64
  34 ${JAVA_11_HOME_CENTOS}    /usr/lib/jvm/java-11-openjdk
  35 ${JAVA_11_HOME_UBUNTU}    /usr/lib/jvm/java-11-openjdk-amd64
  36 ${JAVA_OPTIONS}    -Xmx2560m    # Note that '-Xmx=3g' is wrong syntax. Also 3GB heap may not fit in 4GB RAM.
  37 ${MAVEN_DEFAULT_OUTPUT_FILENAME}    default_maven.log
  38 ${MAVEN_OPTIONS}    -Pq -Djenkins
  39 ${MAVEN_REPOSITORY_PATH}    /tmp/r
  40 ${MAVEN_SETTINGS_URL}    https://raw.githubusercontent.com/opendaylight/odlparent/master/settings.xml
  41 ${MAVEN_VERSION}    3.3.9
  42 ${NEXUS_FALLBACK_URL}    ${NEXUSURL_PREFIX}/content/repositories/opendaylight.snapshot
  43 ${NEXUS_RELEASE_BASE_URL}    https://nexus.opendaylight.org/content/repositories/opendaylight.release
  44 ${NEXUS_RELEASES_URL}    ${NEXUS_RELEASE_BASE_URL}/org/opendaylight/integration/opendaylight
  45
  46 *** Keywords ***
  47 Initialize_Artifact_Deployment_And_Usage
  48     [Arguments]    ${tools_system_connect}=True
  49     [Documentation]    Places search utility to ODL system, which will be needed for version detection.
  50     ...    By default also initialize a SSH connection to Tools system,
  51     ...    as following Keywords assume a working connection towards target system.
  52     # Connect to the ODL machine.
  53     ${odl} =    SSHKeywords.Open_Connection_To_ODL_System
  54     # Deploy the search tool.
  55     SSHLibrary.Put_File    ${CURDIR}/../../tools/deployment/search.sh
  56     SSHLibrary.Close_Connection
  57     # Optionally connect to the Tools System machine.
  58     BuiltIn.Return_From_Keyword_If    not (${tools_system_connect})    # the argument may be a convoluted Python expression
  59     SSHKeywords.Open_Connection_To_Tools_System
  60
  61 NexusKeywords__Get_Items_To_Look_At
  62     [Arguments]    ${component}
  63     [Documentation]    Get a list of items that might contain the version number that we are looking for.
  64     ...
  65     ...    &{COMPONENT_MAPPING} is the centralized place to maintain the mapping
  66     ...    from a stream independent component nickname to the list of artifact names to search for.
  67     Collections.Dictionary_Should_Contain_Key    ${COMPONENT_MAPPING}    ${component}    Component not supported by NexusKeywords version detection: ${component}
  68     BuiltIn.Run_Keyword_And_Return    Collections.Get_From_Dictionary    ${COMPONENT_MAPPING}    ${component}
  69
  70 NexusKeywords__Detect_Version_To_Pull
  71     [Arguments]    ${component}
  72     [Documentation]    Determine the exact Nexus directory to be used as a source for a particular test tool
  73     ...    Figure out what version of the tool needs to be pulled out of the
  74     ...    Nexus by looking at the version directory of the subsystem from
  75     ...    which the tool is being pulled. This code is REALLY UGLY but there
  76     ...    is no way around it until the bug
  77     ...    https://bugs.opendaylight.org/show_bug.cgi?id=5206 gets fixed.
  78     ...    I also don't want to depend on maven-metadata-local.xml and other
  79     ...    bits and pieces of ODL distribution which are not required for ODL
  80     ...    to function properly.
  81     ${itemlist} =    NexusKeywords__Get_Items_To_Look_At    ${component}
  82     ${current_ssh_connection} =    SSHLibrary.Get Connection
  83     SSHKeywords.Open_Connection_To_ODL_System
  84     ${version}    ${result} =    SSHLibrary.Execute_Command    sh search.sh ${WORKSPACE}/${BUNDLEFOLDER}/system ${itemlist}    return_rc=True
  85     SSHLibrary.Close_Connection
  86     SSHKeywords.Restore Current SSH Connection From Index    ${current_ssh_connection.index}
  87     BuiltIn.Log    ${version}
  88     BuiltIn.Run_Keyword_If    ${result}!=0    BuiltIn.Fail    Component "${component}": searching for "${itemlist}" found no version, cannot locate test tool.
  89     ${version}    ${location} =    String.Split_String    ${version}    max_split=1
  90     [Return]    ${version}    ${location}
  91
  92 Deploy_From_Url
  93     [Arguments]    ${url}
  94     [Documentation]    On active SSH conenction execute download ${url} command, log output, check RC and return file name.
  95     ${filename} =    String.Fetch_From_Right    ${url}    /
  96     ${response}    ${result} =    SSHLibrary.Execute_Command    wget -q -N '${url}' 2>&1    return_rc=True
  97     BuiltIn.Log    ${response}
  98     BuiltIn.Run_Keyword_If    ${result} != 0    BuiltIn.Fail    File ${filename} could not be downloaded from ${url}
  99     [Return]    ${filename}
 100
 101 Deploy_Artifact
 102     [Arguments]    ${component}    ${artifact}    ${name_prefix}=${artifact}-    ${name_suffix}=-executable.jar    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 103     [Documentation]    Deploy the specified artifact from Nexus to the cwd of the machine to which the active SSHLibrary connection points.
 104     ...    ${component} is a name part of an artifact present in system/ of ODl installation with the same version as ${artifact} should have.
 105     ...    Must have ${BUNDLE_URL} variable set to the URL from which the
 106     ...    tested ODL distribution was downloaded and this place must be
 107     ...    inside a repository created by a standard distribution
 108     ...    construction job. If this is detected to ne be the case, fallback URL is used.
 109     ...    If ${explicit_url} is non-empty, Deploy_From_Utrl is called instead.
 110     ...    TODO: Allow deploying to a specific directory, we have SSHKeywords.Execute_Command_At_Cwd_Should_Pass now.
 111     BuiltIn.Run_Keyword_And_Return_If    """${explicit_url}""" != ""    Deploy_From_Url    ${explicit_url}
 112     ${urlbase} =    String.Fetch_From_Left    ${BUNDLE_URL}    /org/opendaylight
 113     # If the BUNDLE_URL points somewhere else (perhaps *patch-test* job in Jenkins),
 114     # ${urlbase} is the whole ${BUNDLE_URL}, in which case we use the ${fallback_url}
 115     # If we are working with a "release integrated" project, we always will want to look for
 116     # a released version, not in the snapshots
 117     ${urlbase} =    BuiltIn.Set_Variable_If    '${urlbase}' != '${BUNDLE_URL}'    ${urlbase}    ${fallback_url}
 118     CompareStream.Run_Keyword_If_At_Most_Magnesium    Collections.Remove_Values_From_List    ${RELEASE_INTEGRATED_COMPONENTS}    carpeople
 119     ${urlbase} =    BuiltIn.Set_Variable_If    '${component}' in @{RELEASE_INTEGRATED_COMPONENTS}    ${NEXUS_RELEASE_BASE_URL}    ${urlbase}
 120     ${version}    ${location} =    NexusKeywords__Detect_Version_To_Pull    ${component}
 121     # TODO: Use RequestsLibrary and String instead of curl and bash utilities?
 122     ${url} =    BuiltIn.Set_Variable    ${urlbase}/${location}/${artifact}/${version}
 123     # TODO: Review SSHKeywords for current best keywords to call.
 124     ${metadata} =    SSHKeywords.Execute_Command_Should_Pass    curl -L ${url}/maven-metadata.xml
 125     ${status}    ${namepart} =    BuiltIn.Run_Keyword_And_Ignore_Error    SSHKeywords.Execute_Command_Should_Pass    echo "${metadata}" | grep value | head -n 1 | cut -d '>' -f 2 | cut -d '<' -f 1    stderr_must_be_empty=${True}
 126     ${length} =    BuiltIn.Get_Length    ${namepart}
 127     ${namepart} =    BuiltIn.Set_Variable_If    "${status}" != "PASS" or ${length} == 0    ${version}    ${namepart}
 128     ${filename} =    BuiltIn.Set_Variable    ${name_prefix}${namepart}${name_suffix}
 129     BuiltIn.Log    ${filename}
 130     ${url} =    BuiltIn.Set_Variable    ${url}/${filename}
 131     ${response}    ${result} =    SSHLibrary.Execute_Command    wget -q -N '${url}' 2>&1    return_rc=True
 132     BuiltIn.Log    ${response}
 133     BuiltIn.Run_Keyword_If    ${result} != 0    BuiltIn.Fail    Artifact "${artifact}" in component "${component}" could not be downloaded from ${url}
 134     [Return]    ${filename}
 135
 136 Deploy_Test_Tool
 137     [Arguments]    ${component}    ${artifact}    ${suffix}=executable    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 138     [Documentation]    Deploy a test tool.
 139     ...    The test tools have naming convention of the form
 140     ...    "<repository_url>/some/dir/somewhere/<tool-name>/<tool-name>-<version-tag>-${suffix}.jar"
 141     ...    where "<tool-name>" is the name of the tool and "<version-tag>" is
 142     ...    the version tag that is digged out of the maven metadata. This
 143     ...    keyword calculates ${name_prefix} and ${name_suffix} for
 144     ...    "Deploy_Artifact" and then calls "Deploy_Artifact" to do the real
 145     ...    work of deploying the artifact.
 146     ${name_prefix} =    BuiltIn.Set_Variable    ${artifact}-
 147     ${name_suffix} =    BuiltIn.Set_Variable_If    "${suffix}" != ""    -${suffix}.jar    .jar
 148     ${filename} =    Deploy_Artifact    ${component}    ${artifact}    ${name_prefix}    ${name_suffix}    ${fallback_url}
 149     ...    ${explicit_url}
 150     [Return]    ${filename}
 151
 152 Install_And_Start_Java_Artifact
 153     [Arguments]    ${component}    ${artifact}    ${suffix}=executable    ${tool_options}=${EMPTY}    ${java_options}=${EMPTY}    ${openjdk}=${JDKVERSION}
 154     ...    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 155     [Documentation]    Deploy the artifact, assign name for log file, figure out java command, write the command to active SSH connection and return the log name.
 156     ...    This keyword does not examine whether the artifact was started successfully or whether is still running upon return.
 157     # TODO: Unify this keyword with what NexusKeywords.Install_And_Start_Testtool does.
 158     ${actual_java_options} =    BuiltIn.Set_Variable_If    """${java_options}""" != ""    ${java_options}    ${JAVA_OPTIONS}
 159     ${filename} =    Deploy_Test_Tool    ${component}    ${artifact}    ${suffix}    ${fallback_url}    ${explicit_url}
 160     ${command} =    Compose_Full_Java_Command    ${actual_java_options} -jar ${filename} ${tool_options}
 161     ${logfile} =    Utils.Get_Log_File_Name    ${artifact}
 162     SSHLibrary.Write    ${command} >${logfile} 2>&1
 163     [Return]    ${logfile}
 164
 165 Compose_Dilemma_Filepath
 166     [Arguments]    ${default_path}    ${specific_path}
 167     [Documentation]    Query active SSH connection, return specific path if it exists else default path.
 168     ${out}    ${rc} =    SSHLibrary.Execute_Command    ls -lA ${specific_path} 2>&1    return_rc=True
 169     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${specific_path}
 170     BuiltIn.Return_From_Keyword    ${default_path}
 171
 172 Compose_Base_Java_Command
 173     [Arguments]    ${openjdk}=${JDKVERSION}
 174     [Documentation]    Return string suitable for launching Java programs over SSHLibrary, depending on JRE version needed.
 175     ...    This requires that the SSH connection on which the command is going to be used is active as it is needed for querying files.
 176     ...    Commands composed for one SSH connection shall not be reused on other SSH connections as the two connections may have different Java setups.
 177     ...    Not directly related to Nexus, but versioned Java tools may need this.
 178     # Check whether the user set the override and return it if yes.
 179     BuiltIn.Run_Keyword_And_Return_If    """${openjdk}""" == "openjdk8"    Compose_Dilemma_Filepath    ${JAVA_8_HOME_CENTOS}/bin/java    ${JAVA_8_HOME_UBUNTU}/bin/java
 180     BuiltIn.Run_Keyword_And_Return_If    """${openjdk}""" == "openjdk11"    Compose_Dilemma_Filepath    ${JAVA_11_HOME_CENTOS}/bin/java    ${JAVA_11_HOME_UBUNTU}/bin/java
 181     # Attempt to call plain "java" command directly. If it works, return it.
 182     ${out}    ${rc} =    SSHLibrary.Execute_Command    java -version 2>&1    return_rc=True
 183     BuiltIn.Return_From_Keyword_If    ${rc} == 0    java
 184     # Query the virtual machine for the JAVA_HOME environment variable and
 185     # use it to assemble a (hopefully) working command. If that worked out,
 186     # return the result.
 187     ${java} =    SSHLibrary.Execute_Command    echo $JAVA_HOME/bin/java 2>&1
 188     ${out}    ${rc} =    SSHLibrary.Execute_Command    ${java} -version 2>&1    return_rc=True
 189     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${java}
 190     # There are bizzare test environment setups where the (correct) JAVA_HOME
 191     # is set in the VM where Robot is running but not in the VM where the
 192     # tools are supposed to run (usually because these two are really one
 193     # and the same system and idiosyncracies of BASH prevent easy injection
 194     # of the JAVA_HOME environment variable into a place where connections
 195     # made by SSHLibrary would pick it up). So try to use that value to
 196     # create a java command and check that it works.
 197     ${JAVA_HOME} =    OperatingSystem.Get_Environment_Variable    JAVA_HOME    ${EMPTY}
 198     ${java} =    BuiltIn.Set_Variable_If    """${JAVA_HOME}"""!=""    ${JAVA_HOME}/bin/java    false
 199     ${out}    ${rc} =    SSHLibrary.Execute_Command    ${java} -version 2>&1    return_rc=True
 200     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${java}
 201     # Nothing works, most likely java is not installed at all on the target
 202     # machine or it is hopelesly lost. Bail out with a helpful message
 203     # telling the user how to make it accessible for the script.
 204     BuiltIn.Fail    Unable to find Java; specify \${JDKVERSION}, put it to your PATH or set JAVA_HOME environment variable.
 205
 206 Compose_Full_Java_Command
 207     [Arguments]    ${options}    ${openjdk}=${JDKVERSION}
 208     [Documentation]    Return full Bash command to run Java with given options.
 209     ...    This requires that the SSH connection on which the command is going to be used is active as it is needed for querying files.
 210     ...    The options may include JVM options, application command line arguments, Bash redirects and other constructs.
 211     ${base_command} =    Compose_Base_Java_Command    openjdk=${openjdk}
 212     ${full_command} =    BuiltIn.Set_Variable    ${base_command} ${options}
 213     BuiltIn.Log    ${full_command}
 214     [Return]    ${full_command}
 215
 216 Compose_Java_Home
 217     [Arguments]    ${openjdk}=${JDKVERSION}
 218     [Documentation]    Compose base java command and strip trailing "/bin/java".
 219     ${java_command} =    Compose_Base_Java_Command
 220     ${java_home}    ${bin}    ${java} =    String.Split_String_From_Right    ${java_command}    separator=/    max_split=2
 221     [Return]    ${java_home}
 222
 223 Install_Maven_Bare
 224     [Arguments]    ${maven_version}=3.3.9    ${openjdk}=${JDKVERSION}
 225     [Documentation]    Download and unpack Maven, prepare launch command with proper Java version and download settings file.
 226     ...    This Keyword requires an active SSH connection to target machine.
 227     ...    This Keyword sets global variables, so that suites can reuse existing installation.
 228     ...    This Keyword can only place Maven (and settings) to remote current working directory.
 229     ...    This Keyword does not perform any initial or final cleanup.
 230     # Avoid multiple initialization by several downstream libraries.
 231     ${installed_version} =    BuiltIn.Get_Variable_Value    \${Maven__installed_version}    None
 232     BuiltIn.Return_From_Keyword_If    """${installed_version}""" == """${maven_version}"""
 233     BuiltIn.Set_Global_Variable    \${Maven__installed_version}    ${maven_version}
 234     BuiltIn.Set_Global_Variable    \${maven_directory}    apache-maven-${maven_version}
 235     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    rm -rf '${maven_directory}'
 236     ${maven_archive_filename} =    BuiltIn.Set_Variable    ${maven_directory}-bin.tar.gz
 237     ${maven_download_url} =    BuiltIn.Set_Variable    http://www-us.apache.org/dist/maven/maven-3/${maven_version}/binaries/${maven_archive_filename}
 238     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget -N '${maven_download_url}'    stderr_must_be_empty=False
 239     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    tar xvf '${maven_archive_filename}'
 240     ${java_home} =    NexusKeywords.Compose_Java_Home    openjdk=${openjdk}
 241     BuiltIn.Set_Global_Variable    \${maven_bash_command}    export JAVA_HOME='${java_home}' && export MAVEN_OPTS='${JAVA_OPTIONS}' && ./${maven_directory}/bin/mvn
 242     # TODO: Get settings files from Jenkins settings provider, somehow.
 243     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget '${MAVEN_SETTINGS_URL}' -O settings.xml    stderr_must_be_empty=False
 244
 245 Install_Maven
 246     [Arguments]    ${maven_version}=3.3.9    ${openjdk}=${JDKVERSION}    ${branch}=${EMPTY}    ${patches}=${EMPTY}
 247     [Documentation]    Install Maven.
 248     ...    Depending on arguments, perform a multipatch build to populate local Maven repository with patched artifacts.
 249     Install_Maven_Bare    maven_version=${maven_version}    openjdk=${openjdk}
 250     BuiltIn.Return_From_Keyword_If    """${patches}""" == ""    No post-install build requested.
 251     BuiltIn.Run_Keyword_If    """${branch}""" == ""    BuiltIn.Fail    BRANCH needs to be specified for multipatch builds.
 252     ${script_name} =    BuiltIn.Set_Variable    include-raw-integration-multipatch-distribution-test.sh
 253     ${script_url} =    BuiltIn.Set_Variable    https://raw.githubusercontent.com/opendaylight/releng-builder/master/jjb/integration/${script_name}
 254     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget -N '${script_url}'    stderr_must_be_empty=False
 255     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    export WORKSPACE='${WORKSPACE}' && export BRANCH='${branch}' && export PATCHES_TO_BUILD='${patches}' && bash '${script_name}'    stderr_must_be_empty=False
 256     Run_Maven    pom_file=${WORKSPACE}/patch_tester/pom.xml
 257
 258 Run_Maven
 259     [Arguments]    ${pom_file}=pom.xml    ${log_file}=${MAVEN_DEFAULT_OUTPUT_FILENAME}
 260     [Documentation]    Determine arguments to use and call mvn command against given pom file.
 261     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    mkdir -p '${MAVEN_REPOSITORY_PATH}'
 262     ${maven_repository_options} =    BuiltIn.Set_Variable    -Dmaven.repo.local=${MAVEN_REPOSITORY_PATH} -Dorg.ops4j.pax.url.mvn.localRepository=${MAVEN_REPOSITORY_PATH}
 263     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    ${maven_bash_command} clean install dependency:tree -V -B -DoutputFile=dependency_tree.log -s './settings.xml' -f '${pom_file}' ${MAVEN_OPTIONS} ${maven_repository_options} > '${log_file}'
 264
 265 Get_ODL_Versions_From_Nexus
 266     [Documentation]    Returns name of last release found on nexus and list of all versions.
 267     RequestsLibrary.Create_Session    nexus    ${NEXUS_RELEASES_URL}    verify=${TRUE}
 268     ${uri}=    BuiltIn.Set_Variable    maven-metadata.xml
 269     ${response}=    RequestsLibrary.Get_Request    nexus    ${uri}
 270     BuiltIn.Log    ${response.text}
 271     ${root}=    XML.Parse_XML    ${response.text}
 272     ${element}=    XML.Get_Element    ${root}    versioning/latest
 273     ${latest}=    BuiltIn.Set_Variable    ${element.text}
 274     BuiltIn.Log    ${latest}
 275     @{elements}=    XML.Get_Elements    ${root}    .//version
 276     ${versions}=    BuiltIn.Create_List
 277     FOR    ${element}    IN    @{elements}
 278         Collections.Append_To_List    ${versions}    ${element.text}
 279     END
 280     Collections.Sort_List    ${versions}
 281     BuiltIn.Log_Many    @{versions}
 282     [Return]    ${latest}    @{versions}
 283
 284 Get_Latest_ODL_Release_From_Nexus
 285     [Documentation]    Returns name of last release found on nexus
 286     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 287     [Return]    ${latest}
 288
 289 Get_Latest_ODL_Stream_Release
 290     [Arguments]    ${stream}=latest
 291     [Documentation]    Returns name for last release for specified stream.
 292     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 293     BuiltIn.Return_From_Keyword_If    '${stream}'=='latest'    ${latest}
 294     ${latest_version}=    BuiltIn.Set_Variable    xxx
 295     FOR    ${version}    IN    @{versions}
 296         ${latest_version}=    BuiltIn.Set_Variable_If    '${stream}'.title() in '${version}'    ${version}    ${latest_version}
 297     END
 298     BuiltIn.Run_Keyword_If    '${latest_version}'=='xxx'    BuiltIn.Fail    Could not find latest release for stream ${stream}
 299     BuiltIn.Log    ${latest_version}
 300     [Return]    ${latest_version}
 301
 302 Get_Latest_ODL_Stream_Release_URL
 303     [Arguments]    ${stream}=latest    ${format}=.zip
 304     [Documentation]    Returns URL for last release for specified stream. Default format is .zip.
 305     ${latest_version}=    Get_Latest_ODL_Stream_Release    ${stream}
 306     ${url}=    BuiltIn.Set_Variable    ${NEXUS_RELEASES_URL}/${latest_version}/opendaylight-${latest_version}${format}
 307     BuiltIn.Log    ${url}
 308     [Return]    ${url}
 309
 310 Get_Latest_ODL_Previous_Stream_Release
 311     [Arguments]    ${stream}=${ODL_STREAM}
 312     [Documentation]    Returns name for last release for previous stream of specified stream.
 313     ...    Note: If specified stream is not found on nexus, then it is taken as new one (not released yet).
 314     ...    So in this case, latest release version is return.
 315     ...
 316     ...    NOTE: the below logic is stripping the initial 0. values from the 0.x.x version string that is
 317     ...    the current (and future) version numbering scheme. There is always a leading 0. to the version
 318     ...    strings and stripping it makes is easier to do int comparison to find the largest version in the
 319     ...    list. Comparing as strings does not work. There are some python libs like distutils.version
 320     ...    or packaging that can do a better job comparing versions, but since ODL version numbering is simple
 321     ...    at this point, this convention will suffice. The leading 0. will be added back after the the latest
 322     ...    version is found from the list. The CompareStream.robot library keeps a mapping of major version
 323     ...    numbers to the global variable ${ODL_STREAM} so that is used to ensure we get a major version that is
 324     ...    older than the current running major version.
 325     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 326     ${current_version}=    BuiltIn.Set_Variable    ${Stream_dict}[${ODL_STREAM}].0
 327     ${latest_version}=    BuiltIn.Set_Variable    0.0
 328     FOR    ${version}    IN    @{versions}
 329         ${version} =    String.Replace String Using Regexp    ${version}    ^0\.    ${EMPTY}
 330         ${latest_version}=    Set Variable If    ${version} > ${latest_version} and ${version} < ${current_version}    ${version}    ${latest_version}
 331     END
 332     ${latest_version}=    Set Variable    0.${latest_version}
 333     BuiltIn.Run_Keyword_If    '${latest_version}'=='0.0.0'    BuiltIn.Fail    Could not find latest previous release for stream ${stream}
 334     BuiltIn.Log    ${latest_version}
 335     [Return]    ${latest_version}
 336
 337 Get_Latest_ODL_Previous_Stream_Release_URL
 338     [Arguments]    ${stream}=${ODL_STREAM}    ${format}=.zip
 339     [Documentation]    Returns URL for last release for previous stream of specified stream. Default format is .zip.
 340     ${latest_version}=    Get_Latest_ODL_Previous_Stream_Release    ${stream}
 341     ${url}=    BuiltIn.Set_Variable    ${NEXUS_RELEASES_URL}/${latest_version}/opendaylight-${latest_version}${format}
 342     BuiltIn.Log    ${url}
 343     [Return]    ${url}