csit/libraries/NexusKeywords.robot

   1 *** Settings ***
   2 Documentation     Nexus repository access keywords, and supporting Java and Maven handling.
   3 ...
   4 ...               Copyright (c) 2015,2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               Nexus operations into reusable keywords to make writing test suites easier.
  13 ...
  14 ...               Currently, Java version detection is incorporated so that Java tools can be run reliably.
  15 ...               Also, suport for installing and running Maven is added, as that needs the Java detection.
  16 ...               TODO: Move Java detection and Maven to a separate Resource, or rename this Resource.
  17 Library           Collections
  18 Library           OperatingSystem
  19 Library           SSHLibrary
  20 Library           String
  21 Library           XML
  22 Library           Collections
  23 Library           RequestsLibrary
  24 Resource          ${CURDIR}/SSHKeywords.robot
  25 Resource          ${CURDIR}/Utils.robot
  26
  27 *** Variables ***
  28 &{COMPONENT_MAPPING}    netconf=netconf-impl    bgpcep=pcep-impl    carpeople=clustering-it-model    yangtools=yang-data-impl    bindingv1=mdsal-binding-generator-impl
  29 ${JDKVERSION}     None
  30 ${JAVA_7_HOME_CENTOS}    /usr/lib/jvm/java-1.7.0
  31 ${JAVA_7_HOME_UBUNTU}    /usr/lib/jvm/java-7-openjdk-amd64
  32 ${JAVA_8_HOME_CENTOS}    /usr/lib/jvm/java-1.8.0
  33 ${JAVA_8_HOME_UBUNTU}    /usr/lib/jvm/java-8-openjdk-amd64
  34 ${JAVA_OPTIONS}    -Xmx2560m    # Note that '-Xmx=3g' is wrong syntax. Also 3GB heap may not fit in 4GB RAM.
  35 ${JAVA_7_OPTIONS}    -Xmx2048m -XX:MaxPermSize=512m
  36 ${MAVEN_DEFAULT_OUTPUT_FILENAME}    default_maven.log
  37 ${MAVEN_OPTIONS}    -Pq -Djenkins
  38 ${MAVEN_REPOSITORY_PATH}    /tmp/r
  39 ${MAVEN_SETTINGS_URL}    https://raw.githubusercontent.com/opendaylight/odlparent/master/settings.xml
  40 ${MAVEN_VERSION}    3.3.9
  41 ${NEXUS_FALLBACK_URL}    ${NEXUSURL_PREFIX}/content/repositories/opendaylight.snapshot
  42 ${NEXUS_RELEASES_URL}    https://nexus.opendaylight.org/content/repositories/opendaylight.release/org/opendaylight/integration/distribution-karaf
  43
  44 *** Keywords ***
  45 Initialize_Artifact_Deployment_And_Usage
  46     [Arguments]    ${tools_system_connect}=True
  47     [Documentation]    Places search utility to ODL system, which will be needed for version detection.
  48     ...    By default also initialize a SSH connection to Tools system,
  49     ...    as following Keywords assume a working connection towards target system.
  50     # Connect to the ODL machine.
  51     ${odl} =    SSHKeywords.Open_Connection_To_ODL_System
  52     # Deploy the search tool.
  53     SSHLibrary.Put_File    ${CURDIR}/../../tools/deployment/search.sh
  54     SSHLibrary.Close_Connection
  55     # Optionally connect to the Tools System machine.
  56     BuiltIn.Return_From_Keyword_If    not (${tools_system_connect})    # the argument may be a convoluted Python expression
  57     SSHKeywords.Open_Connection_To_Tools_System
  58
  59 NexusKeywords__Get_Items_To_Look_At
  60     [Arguments]    ${component}
  61     [Documentation]    Get a list of items that might contain the version number that we are looking for.
  62     ...
  63     ...    &{COMPONENT_MAPPING} is the centralized place to maintain the mapping
  64     ...    from a stream independent component nickname to the list of artifact names to search for.
  65     Collections.Dictionary_Should_Contain_Key    ${COMPONENT_MAPPING}    ${component}    Component not supported by NexusKeywords version detection: ${component}
  66     BuiltIn.Run_Keyword_And_Return    Collections.Get_From_Dictionary    ${COMPONENT_MAPPING}    ${component}
  67
  68 NexusKeywords__Detect_Version_To_Pull
  69     [Arguments]    ${component}
  70     [Documentation]    Determine the exact Nexus directory to be used as a source for a particular test tool
  71     ...    Figure out what version of the tool needs to be pulled out of the
  72     ...    Nexus by looking at the version directory of the subsystem from
  73     ...    which the tool is being pulled. This code is REALLY UGLY but there
  74     ...    is no way around it until the bug
  75     ...    https://bugs.opendaylight.org/show_bug.cgi?id=5206 gets fixed.
  76     ...    I also don't want to depend on maven-metadata-local.xml and other
  77     ...    bits and pieces of ODL distribution which are not required for ODL
  78     ...    to function properly.
  79     ${itemlist} =    NexusKeywords__Get_Items_To_Look_At    ${component}
  80     ${current_ssh_connection} =    SSHLibrary.Get Connection
  81     SSHKeywords.Open_Connection_To_ODL_System
  82     ${version}    ${result} =    SSHLibrary.Execute_Command    sh search.sh ${WORKSPACE}/${BUNDLEFOLDER}/system ${itemlist}    return_rc=True
  83     SSHLibrary.Close_Connection
  84     SSHKeywords.Restore Current SSH Connection From Index    ${current_ssh_connection.index}
  85     BuiltIn.Log    ${version}
  86     BuiltIn.Run_Keyword_If    ${result}!=0    BuiltIn.Fail    Component "${component}": searching for "${itemlist}" found no version, cannot locate test tool.
  87     ${version}    ${location} =    String.Split_String    ${version}    max_split=1
  88     [Return]    ${version}    ${location}
  89
  90 Deploy_From_Url
  91     [Arguments]    ${url}
  92     [Documentation]    On active SSH conenction execute download ${url} command, log output, check RC and return file name.
  93     ${filename} =    String.Fetch_From_Right    ${url}    /
  94     ${response}    ${result} =    SSHLibrary.Execute_Command    wget -q -N '${url}' 2>&1    return_rc=True
  95     BuiltIn.Log    ${response}
  96     BuiltIn.Run_Keyword_If    ${result} != 0    BuiltIn.Fail    File ${filename} could not be downloaded from ${url}
  97     [Return]    ${filename}
  98
  99 Deploy_Artifact
 100     [Arguments]    ${component}    ${artifact}    ${name_prefix}=${artifact}-    ${name_suffix}=-executable.jar    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 101     [Documentation]    Deploy the specified artifact from Nexus to the cwd of the machine to which the active SSHLibrary connection points.
 102     ...    ${component} is a name part of an artifact present in system/ of ODl installation with the same version as ${artifact} should have.
 103     ...    Must have ${BUNDLE_URL} variable set to the URL from which the
 104     ...    tested ODL distribution was downloaded and this place must be
 105     ...    inside a repository created by a standard distribution
 106     ...    construction job. If this is detected to ne be the case, fallback URL is used.
 107     ...    If ${explicit_url} is non-empty, Deploy_From_Utrl is called instead.
 108     ...    TODO: Allow deploying to a specific directory, we have SSHKeywords.Execute_Command_At_Cwd_Should_Pass now.
 109     BuiltIn.Run_Keyword_And_Return_If    """${explicit_url}""" != ""    Deploy_From_Url    ${explicit_url}
 110     ${urlbase} =    String.Fetch_From_Left    ${BUNDLE_URL}    /org/opendaylight
 111     # If the BUNDLE_URL points somewhere else (perhaps *patch-test* job in Jenkins),
 112     # ${urlbase} is the whole ${BUNDLE_URL}, in which case we use the ${fallback_url}
 113     ${urlbase} =    BuiltIn.Set_Variable_If    '${urlbase}' != '${BUNDLE_URL}'    ${urlbase}    ${fallback_url}
 114     ${version}    ${location} =    NexusKeywords__Detect_Version_To_Pull    ${component}
 115     # TODO: Use RequestsLibrary and String instead of curl and bash utilities?
 116     ${url} =    BuiltIn.Set_Variable    ${urlbase}/${location}/${artifact}/${version}
 117     # TODO: Review SSHKeywords for current best keywords to call.
 118     ${metadata} =    SSHKeywords.Execute_Command_Should_Pass    curl -L ${url}/maven-metadata.xml
 119     ${status}    ${namepart} =    BuiltIn.Run_Keyword_And_Ignore_Error    SSHKeywords.Execute_Command_Should_Pass    echo "${metadata}" | grep value | head -n 1 | cut -d '>' -f 2 | cut -d '<' -f 1    stderr_must_be_empty=${True}
 120     ${length} =    BuiltIn.Get_Length    ${namepart}
 121     ${namepart} =    BuiltIn.Set_Variable_If    "${status}" != "PASS" or ${length} == 0    ${version}    ${namepart}
 122     ${filename} =    BuiltIn.Set_Variable    ${name_prefix}${namepart}${name_suffix}
 123     BuiltIn.Log    ${filename}
 124     ${url} =    BuiltIn.Set_Variable    ${url}/${filename}
 125     ${response}    ${result} =    SSHLibrary.Execute_Command    wget -q -N '${url}' 2>&1    return_rc=True
 126     BuiltIn.Log    ${response}
 127     BuiltIn.Run_Keyword_If    ${result} != 0    BuiltIn.Fail    Artifact "${artifact}" in component "${component}" could not be downloaded from ${url}
 128     [Return]    ${filename}
 129
 130 Deploy_Test_Tool
 131     [Arguments]    ${component}    ${artifact}    ${suffix}=executable    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 132     [Documentation]    Deploy a test tool.
 133     ...    The test tools have naming convention of the form
 134     ...    "<repository_url>/some/dir/somewhere/<tool-name>/<tool-name>-<version-tag>-${suffix}.jar"
 135     ...    where "<tool-name>" is the name of the tool and "<version-tag>" is
 136     ...    the version tag that is digged out of the maven metadata. This
 137     ...    keyword calculates ${name_prefix} and ${name_suffix} for
 138     ...    "Deploy_Artifact" and then calls "Deploy_Artifact" to do the real
 139     ...    work of deploying the artifact.
 140     ${name_prefix} =    BuiltIn.Set_Variable    ${artifact}-
 141     ${name_suffix} =    BuiltIn.Set_Variable_If    "${suffix}" != ""    -${suffix}.jar    .jar
 142     ${filename} =    Deploy_Artifact    ${component}    ${artifact}    ${name_prefix}    ${name_suffix}    ${fallback_url}
 143     ...    ${explicit_url}
 144     [Return]    ${filename}
 145
 146 Install_And_Start_Java_Artifact
 147     [Arguments]    ${component}    ${artifact}    ${suffix}=executable    ${tool_options}=${EMPTY}    ${java_options}=${EMPTY}    ${openjdk}=${JDKVERSION}
 148     ...    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 149     [Documentation]    Deploy the artifact, assign name for log file, figure out java command, write the command to active SSH connection and return the log name.
 150     ...    This keyword does not examine whether the artifact was started successfully or whether is still running upon return.
 151     # TODO: Unify this keyword with what NexusKeywords.Install_And_Start_Testtool does.
 152     ${default_java_options} =    Default_Java_Options    ${openjdk}
 153     ${actual_java_options} =    BuiltIn.Set_Variable_If    """${java_options}""" != ""    ${java_options}    ${default_java_options}
 154     ${filename} =    Deploy_Test_Tool    ${component}    ${artifact}    ${suffix}    ${fallback_url}    ${explicit_url}
 155     ${command} =    Compose_Full_Java_Command    ${actual_java_options} -jar ${filename} ${tool_options}
 156     ${logfile} =    Utils.Get_Log_File_Name    ${artifact}
 157     SSHLibrary.Write    ${command} >${logfile} 2>&1
 158     [Return]    ${logfile}
 159
 160 Compose_Dilemma_Filepath
 161     [Arguments]    ${default_path}    ${specific_path}
 162     [Documentation]    Query active SSH connection, return specific path if it exists else default path.
 163     ${out}    ${rc} =    SSHLibrary.Execute_Command    ls -lA ${specific_path} 2>&1    return_rc=True
 164     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${specific_path}
 165     BuiltIn.Return_From_Keyword    ${default_path}
 166
 167 Compose_Base_Java_Command
 168     [Arguments]    ${openjdk}=${JDKVERSION}
 169     [Documentation]    Return string suitable for launching Java programs over SSHLibrary, depending on JRE version needed.
 170     ...    This requires that the SSH connection on which the command is going to be used is active as it is needed for querying files.
 171     ...    Commands composed for one SSH connection shall not be reused on other SSH connections as the two connections may have different Java setups.
 172     ...    Not directly related to Nexus, but versioned Java tools may need this.
 173     # Check whether the user set the override and return it if yes.
 174     BuiltIn.Run_Keyword_And_Return_If    """${openjdk}""" == "openjdk8"    Compose_Dilemma_Filepath    ${JAVA_8_HOME_CENTOS}/bin/java    ${JAVA_8_HOME_UBUNTU}/bin/java
 175     BuiltIn.Run_Keyword_And_Return_If    """${openjdk}""" == "openjdk7"    Compose_Dilemma_Filepath    ${JAVA_7_HOME_CENTOS}/bin/java    ${JAVA_7_HOME_UBUNTU}/bin/java
 176     # Attempt to call plain "java" command directly. If it works, return it.
 177     ${out}    ${rc} =    SSHLibrary.Execute_Command    java -version 2>&1    return_rc=True
 178     BuiltIn.Return_From_Keyword_If    ${rc} == 0    java
 179     # Query the virtual machine for the JAVA_HOME environment variable and
 180     # use it to assemble a (hopefully) working command. If that worked out,
 181     # return the result.
 182     ${java} =    SSHLibrary.Execute_Command    echo \$JAVA_HOME/bin/java 2>&1
 183     ${out}    ${rc} =    SSHLibrary.Execute_Command    ${java} -version 2>&1    return_rc=True
 184     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${java}
 185     # There are bizzare test environment setups where the (correct) JAVA_HOME
 186     # is set in the VM where Robot is running but not in the VM where the
 187     # tools are supposed to run (usually because these two are really one
 188     # and the same system and idiosyncracies of BASH prevent easy injection
 189     # of the JAVA_HOME environment variable into a place where connections
 190     # made by SSHLibrary would pick it up). So try to use that value to
 191     # create a java command and check that it works.
 192     ${JAVA_HOME} =    OperatingSystem.Get_Environment_Variable    JAVA_HOME    ${EMPTY}
 193     ${java} =    BuiltIn.Set_Variable_If    """${JAVA_HOME}"""!=""    ${JAVA_HOME}/bin/java    false
 194     ${out}    ${rc} =    SSHLibrary.Execute_Command    ${java} -version 2>&1    return_rc=True
 195     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${java}
 196     # Nothing works, most likely java is not installed at all on the target
 197     # machine or it is hopelesly lost. Bail out with a helpful message
 198     # telling the user how to make it accessible for the script.
 199     BuiltIn.Fail    Unable to find Java; specify \${JDKVERSION}, put it to your PATH or set JAVA_HOME environment variable.
 200
 201 Compose_Full_Java_Command
 202     [Arguments]    ${options}    ${openjdk}=${JDKVERSION}
 203     [Documentation]    Return full Bash command to run Java with given options.
 204     ...    This requires that the SSH connection on which the command is going to be used is active as it is needed for querying files.
 205     ...    The options may include JVM options, application command line arguments, Bash redirects and other constructs.
 206     ${base_command} =    Compose_Base_Java_Command    openjdk=${openjdk}
 207     ${full_command} =    BuiltIn.Set_Variable    ${base_command} ${options}
 208     BuiltIn.Log    ${full_command}
 209     [Return]    ${full_command}
 210
 211 Compose_Java_Home
 212     [Arguments]    ${openjdk}=${JDKVERSION}
 213     [Documentation]    Compose base java command and strip trailing "/bin/java".
 214     ${java_command} =    Compose_Base_Java_Command
 215     ${java_home}    ${bin}    ${java} =    String.Split_String_From_Right    ${java_command}    separator=/    max_split=2
 216     [Return]    ${java_home}
 217
 218 Default_Java_Options
 219     [Arguments]    ${openjdk}=${JDKVERSION}
 220     [Documentation]    Return Java options suitable for current JDK version.
 221     ${java_actual_options} =    BuiltIn.Set_Variable_If    """${openjdk}""" == "openjdk7"    ${JAVA_7_OPTIONS}    ${JAVA_OPTIONS}
 222     [Return]    ${java_actual_options}
 223
 224 Install_Maven_Bare
 225     [Arguments]    ${maven_version}=3.3.9    ${openjdk}=${JDKVERSION}
 226     [Documentation]    Download and unpack Maven, prepare launch command with proper Java version and download settings file.
 227     ...    This Keyword requires an active SSH connection to target machine.
 228     ...    This Keyword sets global variables, so that suites can reuse existing installation.
 229     ...    This Keyword can only place Maven (and settings) to remote current working directory.
 230     ...    This Keyword does not perform any initial or final cleanup.
 231     # Avoid multiple initialization by several downstream libraries.
 232     ${installed_version} =    BuiltIn.Get_Variable_Value    \${Maven__installed_version}    None
 233     BuiltIn.Return_From_Keyword_If    """${installed_version}""" == """${maven_version}"""
 234     BuiltIn.Set_Global_Variable    \${Maven__installed_version}    ${maven_version}
 235     BuiltIn.Set_Global_Variable    \${maven_directory}    apache-maven-${maven_version}
 236     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    rm -rf '${maven_directory}'
 237     ${maven_archive_filename} =    BuiltIn.Set_Variable    ${maven_directory}-bin.tar.gz
 238     ${maven_download_url} =    BuiltIn.Set_Variable    http://www-us.apache.org/dist/maven/maven-3/${maven_version}/binaries/${maven_archive_filename}
 239     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget -N '${maven_download_url}'    stderr_must_be_empty=False
 240     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    tar xvf '${maven_archive_filename}'
 241     ${java_home} =    NexusKeywords.Compose_Java_Home    openjdk=${openjdk}
 242     ${java_actual_options} =    Default_Java_Options    ${openjdk}
 243     BuiltIn.Set_Global_Variable    \${maven_bash_command}    export JAVA_HOME='${java_home}' && export MAVEN_OPTS='${java_actual_options}' && ./${maven_directory}/bin/mvn
 244     # TODO: Get settings files from Jenkins settings provider, somehow.
 245     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget '${MAVEN_SETTINGS_URL}' -O settings.xml    stderr_must_be_empty=False
 246
 247 Install_Maven
 248     [Arguments]    ${maven_version}=3.3.9    ${openjdk}=${JDKVERSION}    ${branch}=${EMPTY}    ${patches}=${EMPTY}
 249     [Documentation]    Install Maven.
 250     ...    Depending on arguments, perform a multipatch build to populate local Maven repository with patched artifacts.
 251     Install_Maven_Bare    maven_version=${maven_version}    openjdk=${openjdk}
 252     BuiltIn.Return_From_Keyword_If    """${patches}""" == ""    No post-install build requested.
 253     BuiltIn.Run_Keyword_If    """${branch}""" == ""    BuiltIn.Fail    BRANCH needs to be specified for multipatch builds.
 254     ${script_name} =    BuiltIn.Set_Variable    include-raw-integration-multipatch-distribution-test.sh
 255     ${script_url} =    BuiltIn.Set_Variable    https://raw.githubusercontent.com/opendaylight/releng-builder/master/jjb/integration/${script_name}
 256     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget -N '${script_url}'    stderr_must_be_empty=False
 257     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    export WORKSPACE='${WORKSPACE}' && export BRANCH='${branch}' && export PATCHES_TO_BUILD='${patches}' && bash '${script_name}'    stderr_must_be_empty=False
 258     Run_Maven    pom_file=${WORKSPACE}/patch_tester/pom.xml
 259
 260 Run_Maven
 261     [Arguments]    ${pom_file}=pom.xml    ${log_file}=${MAVEN_DEFAULT_OUTPUT_FILENAME}
 262     [Documentation]    Determine arguments to use and call mvn command against given pom file.
 263     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    mkdir -p '${MAVEN_REPOSITORY_PATH}'
 264     ${maven_repository_options} =    BuiltIn.Set_Variable    -Dmaven.repo.local=${MAVEN_REPOSITORY_PATH} -Dorg.ops4j.pax.url.mvn.localRepository=${MAVEN_REPOSITORY_PATH}
 265     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    ${maven_bash_command} clean install dependency:tree -V -B -DoutputFile=dependency_tree.log -s './settings.xml' -f '${pom_file}' ${MAVEN_OPTIONS} ${maven_repository_options} > '${log_file}'
 266
 267 Get_ODL_Versions_From_Nexus
 268     [Documentation]    Returns name of last release found on nexus and list of all versions.
 269     RequestsLibrary.Create_Session    nexus    ${NEXUS_RELEASES_URL}    verify=${TRUE}
 270     ${uri}=    BuiltIn.Set_Variable    maven-metadata.xml
 271     ${response}=    RequestsLibrary.Get_Request    nexus    ${uri}
 272     BuiltIn.Log    ${response.text}
 273     ${root}=    XML.Parse_XML    ${response.text}
 274     ${element}=    XML.Get_Element    ${root}    versioning/latest
 275     ${latest}=    BuiltIn.Set_Variable    ${element.text}
 276     BuiltIn.Log    ${latest}
 277     @{elements}=    XML.Get_Elements    ${root}    .//version
 278     ${versions}=    BuiltIn.Create_List
 279     : FOR    ${element}    IN    @{elements}
 280     \    Collections.Append_To_List    ${versions}    ${element.text}
 281     Collections.Sort_List    ${versions}
 282     BuiltIn.Log_Many    @{versions}
 283     [Return]    ${latest}    @{versions}
 284
 285 Get_Latest_ODL_Release_From_Nexus
 286     [Documentation]    Returns name of last release found on nexus
 287     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 288     [Return]    ${latest}
 289
 290 Get_Latest_ODL_Stream_Release
 291     [Arguments]    ${stream}=latest
 292     [Documentation]    Returns name for last release for specified stream.
 293     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 294     BuiltIn.Return_From_Keyword_If    '${stream}'=='latest'    ${latest}
 295     ${latest_version}=    BuiltIn.Set_Variable    xxx
 296     : FOR    ${version}    IN    @{versions}
 297     \    ${latest_version}=    BuiltIn.Set_Variable_If    '${stream}'.title() in '${version}'    ${version}    ${latest_version}
 298     BuiltIn.Run_Keyword_If    '${latest_version}'=='xxx'    BuiltIn.Fail    Could not find latest release for stream ${stream}
 299     BuiltIn.Log    ${latest_version}
 300     [Return]    ${latest_version}
 301
 302 Get_Latest_ODL_Stream_Release_URL
 303     [Arguments]    ${stream}=latest    ${format}=.zip
 304     [Documentation]    Returns URL for last release for specified stream. Default format is .zip.
 305     ${latest_version}=    Get_Latest_ODL_Stream_Release    ${stream}
 306     ${url}=    BuiltIn.Set_Variable    ${NEXUS_RELEASES_URL}/${latest_version}/distribution-karaf-${latest_version}${format}
 307     BuiltIn.Log    ${url}
 308     [Return]    ${url}
 309
 310 Get_Latest_ODL_Previous_Stream_Release
 311     [Arguments]    ${stream}=${ODL_STREAM}
 312     [Documentation]    Returns name for last release for previous stream of specified stream.
 313     ...    Note: If specified stream is not found on nexus, then it is taken as new one (not released yet).
 314     ...    So in this case, latest release version is return.
 315     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 316     ${latest_version}=    BuiltIn.Set_Variable    xxx
 317     : FOR    ${version}    IN    @{versions}
 318     \    BuiltIn.Exit_For_Loop_If    '${stream}'.title() in '${version}'
 319     \    ${latest_version}=    BuiltIn.Set_Variable    ${version}
 320     BuiltIn.Run_Keyword_If    '${latest_version}'=='xxx'    BuiltIn.Fail    Could not find latest previous release for stream ${stream}
 321     BuiltIn.Log    ${latest_version}
 322     [Return]    ${latest_version}
 323
 324 Get_Latest_ODL_Previous_Stream_Release_URL
 325     [Arguments]    ${stream}=${ODL_STREAM}    ${format}=.zip
 326     [Documentation]    Returns URL for last release for previous stream of specified stream. Default format is .zip.
 327     ${latest_version}=    Get_Latest_ODL_Previous_Stream_Release    ${stream}
 328     ${url}=    BuiltIn.Set_Variable    ${NEXUS_RELEASES_URL}/${latest_version}/distribution-karaf-${latest_version}${format}
 329     BuiltIn.Log    ${url}
 330     [Return]    ${url}