csit/libraries/NexusKeywords.robot

   1 *** Settings ***
   2 Documentation     Nexus repository access keywords, and supporting Java and Maven handling.
   3 ...
   4 ...               Copyright (c) 2015,2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               Nexus operations into reusable keywords to make writing test suites easier.
  13 ...
  14 ...               Currently, Java version detection is incorporated so that Java tools can be run reliably.
  15 ...               Also, suport for installing and running Maven is added, as that needs the Java detection.
  16 ...               TODO: Move Java detection and Maven to a separate Resource, or rename this Resource.
  17 Library           Collections
  18 Library           OperatingSystem
  19 Library           SSHLibrary
  20 Library           String
  21 Library           XML
  22 Library           Collections
  23 Library           RequestsLibrary
  24 Resource          ${CURDIR}/CompareStream.robot
  25 Resource          ${CURDIR}/SSHKeywords.robot
  26 Resource          ${CURDIR}/Utils.robot
  27
  28 *** Variables ***
  29 &{COMPONENT_MAPPING}    netconf=netconf-impl    bgpcep=pcep-impl    carpeople=clustering-it-model    yangtools=yang-data-impl    bindingv1=mdsal-binding-generator-impl
  30 ${JDKVERSION}     None
  31 ${JAVA_7_HOME_CENTOS}    /usr/lib/jvm/java-1.7.0
  32 ${JAVA_7_HOME_UBUNTU}    /usr/lib/jvm/java-7-openjdk-amd64
  33 ${JAVA_8_HOME_CENTOS}    /usr/lib/jvm/java-1.8.0
  34 ${JAVA_8_HOME_UBUNTU}    /usr/lib/jvm/java-8-openjdk-amd64
  35 ${JAVA_11_HOME_CENTOS}    /usr/lib/jvm/java-11-openjdk
  36 ${JAVA_11_HOME_UBUNTU}    /usr/lib/jvm/java-11-openjdk-amd64
  37 ${JAVA_OPTIONS}    -Xmx2560m    # Note that '-Xmx=3g' is wrong syntax. Also 3GB heap may not fit in 4GB RAM.
  38 ${JAVA_7_OPTIONS}    -Xmx2048m -XX:MaxPermSize=512m
  39 ${MAVEN_DEFAULT_OUTPUT_FILENAME}    default_maven.log
  40 ${MAVEN_OPTIONS}    -Pq -Djenkins
  41 ${MAVEN_REPOSITORY_PATH}    /tmp/r
  42 ${MAVEN_SETTINGS_URL}    https://raw.githubusercontent.com/opendaylight/odlparent/master/settings.xml
  43 ${MAVEN_VERSION}    3.3.9
  44 ${NEXUS_FALLBACK_URL}    ${NEXUSURL_PREFIX}/content/repositories/opendaylight.snapshot
  45 ${NEXUS_RELEASE_BASE_URL}    https://nexus.opendaylight.org/content/repositories/opendaylight.release
  46 ${NEXUS_RELEASES_URL}    ${NEXUS_RELEASE_BASE_URL}/org/opendaylight/integration/opendaylight
  47
  48 *** Keywords ***
  49 Initialize_Artifact_Deployment_And_Usage
  50     [Arguments]    ${tools_system_connect}=True
  51     [Documentation]    Places search utility to ODL system, which will be needed for version detection.
  52     ...    By default also initialize a SSH connection to Tools system,
  53     ...    as following Keywords assume a working connection towards target system.
  54     # Connect to the ODL machine.
  55     ${odl} =    SSHKeywords.Open_Connection_To_ODL_System
  56     # Deploy the search tool.
  57     SSHLibrary.Put_File    ${CURDIR}/../../tools/deployment/search.sh
  58     SSHLibrary.Close_Connection
  59     # Optionally connect to the Tools System machine.
  60     BuiltIn.Return_From_Keyword_If    not (${tools_system_connect})    # the argument may be a convoluted Python expression
  61     SSHKeywords.Open_Connection_To_Tools_System
  62
  63 NexusKeywords__Get_Items_To_Look_At
  64     [Arguments]    ${component}
  65     [Documentation]    Get a list of items that might contain the version number that we are looking for.
  66     ...
  67     ...    &{COMPONENT_MAPPING} is the centralized place to maintain the mapping
  68     ...    from a stream independent component nickname to the list of artifact names to search for.
  69     Collections.Dictionary_Should_Contain_Key    ${COMPONENT_MAPPING}    ${component}    Component not supported by NexusKeywords version detection: ${component}
  70     BuiltIn.Run_Keyword_And_Return    Collections.Get_From_Dictionary    ${COMPONENT_MAPPING}    ${component}
  71
  72 NexusKeywords__Detect_Version_To_Pull
  73     [Arguments]    ${component}
  74     [Documentation]    Determine the exact Nexus directory to be used as a source for a particular test tool
  75     ...    Figure out what version of the tool needs to be pulled out of the
  76     ...    Nexus by looking at the version directory of the subsystem from
  77     ...    which the tool is being pulled. This code is REALLY UGLY but there
  78     ...    is no way around it until the bug
  79     ...    https://bugs.opendaylight.org/show_bug.cgi?id=5206 gets fixed.
  80     ...    I also don't want to depend on maven-metadata-local.xml and other
  81     ...    bits and pieces of ODL distribution which are not required for ODL
  82     ...    to function properly.
  83     ${itemlist} =    NexusKeywords__Get_Items_To_Look_At    ${component}
  84     ${current_ssh_connection} =    SSHLibrary.Get Connection
  85     SSHKeywords.Open_Connection_To_ODL_System
  86     ${version}    ${result} =    SSHLibrary.Execute_Command    sh search.sh ${WORKSPACE}/${BUNDLEFOLDER}/system ${itemlist}    return_rc=True
  87     SSHLibrary.Close_Connection
  88     SSHKeywords.Restore Current SSH Connection From Index    ${current_ssh_connection.index}
  89     BuiltIn.Log    ${version}
  90     BuiltIn.Run_Keyword_If    ${result}!=0    BuiltIn.Fail    Component "${component}": searching for "${itemlist}" found no version, cannot locate test tool.
  91     ${version}    ${location} =    String.Split_String    ${version}    max_split=1
  92     [Return]    ${version}    ${location}
  93
  94 Deploy_From_Url
  95     [Arguments]    ${url}
  96     [Documentation]    On active SSH conenction execute download ${url} command, log output, check RC and return file name.
  97     ${filename} =    String.Fetch_From_Right    ${url}    /
  98     ${response}    ${result} =    SSHLibrary.Execute_Command    wget -q -N '${url}' 2>&1    return_rc=True
  99     BuiltIn.Log    ${response}
 100     BuiltIn.Run_Keyword_If    ${result} != 0    BuiltIn.Fail    File ${filename} could not be downloaded from ${url}
 101     [Return]    ${filename}
 102
 103 Deploy_Artifact
 104     [Arguments]    ${component}    ${artifact}    ${name_prefix}=${artifact}-    ${name_suffix}=-executable.jar    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 105     [Documentation]    Deploy the specified artifact from Nexus to the cwd of the machine to which the active SSHLibrary connection points.
 106     ...    ${component} is a name part of an artifact present in system/ of ODl installation with the same version as ${artifact} should have.
 107     ...    Must have ${BUNDLE_URL} variable set to the URL from which the
 108     ...    tested ODL distribution was downloaded and this place must be
 109     ...    inside a repository created by a standard distribution
 110     ...    construction job. If this is detected to ne be the case, fallback URL is used.
 111     ...    If ${explicit_url} is non-empty, Deploy_From_Utrl is called instead.
 112     ...    TODO: Allow deploying to a specific directory, we have SSHKeywords.Execute_Command_At_Cwd_Should_Pass now.
 113     BuiltIn.Run_Keyword_And_Return_If    """${explicit_url}""" != ""    Deploy_From_Url    ${explicit_url}
 114     ${urlbase} =    String.Fetch_From_Left    ${BUNDLE_URL}    /org/opendaylight
 115     # If the BUNDLE_URL points somewhere else (perhaps *patch-test* job in Jenkins),
 116     # ${urlbase} is the whole ${BUNDLE_URL}, in which case we use the ${fallback_url}
 117     ${urlbase} =    BuiltIn.Set_Variable_If    '${urlbase}' != '${BUNDLE_URL}'    ${urlbase}    ${fallback_url}
 118     ${version}    ${location} =    NexusKeywords__Detect_Version_To_Pull    ${component}
 119     # TODO: Use RequestsLibrary and String instead of curl and bash utilities?
 120     ${url} =    BuiltIn.Set_Variable    ${urlbase}/${location}/${artifact}/${version}
 121     # TODO: Review SSHKeywords for current best keywords to call.
 122     ${metadata} =    SSHKeywords.Execute_Command_Should_Pass    curl -L ${url}/maven-metadata.xml
 123     ${status}    ${namepart} =    BuiltIn.Run_Keyword_And_Ignore_Error    SSHKeywords.Execute_Command_Should_Pass    echo "${metadata}" | grep value | head -n 1 | cut -d '>' -f 2 | cut -d '<' -f 1    stderr_must_be_empty=${True}
 124     ${length} =    BuiltIn.Get_Length    ${namepart}
 125     ${namepart} =    BuiltIn.Set_Variable_If    "${status}" != "PASS" or ${length} == 0    ${version}    ${namepart}
 126     ${filename} =    BuiltIn.Set_Variable    ${name_prefix}${namepart}${name_suffix}
 127     BuiltIn.Log    ${filename}
 128     ${url} =    BuiltIn.Set_Variable    ${url}/${filename}
 129     ${response}    ${result} =    SSHLibrary.Execute_Command    wget -q -N '${url}' 2>&1    return_rc=True
 130     BuiltIn.Log    ${response}
 131     BuiltIn.Run_Keyword_If    ${result} != 0    BuiltIn.Fail    Artifact "${artifact}" in component "${component}" could not be downloaded from ${url}
 132     [Return]    ${filename}
 133
 134 Deploy_Test_Tool
 135     [Arguments]    ${component}    ${artifact}    ${suffix}=executable    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 136     [Documentation]    Deploy a test tool.
 137     ...    The test tools have naming convention of the form
 138     ...    "<repository_url>/some/dir/somewhere/<tool-name>/<tool-name>-<version-tag>-${suffix}.jar"
 139     ...    where "<tool-name>" is the name of the tool and "<version-tag>" is
 140     ...    the version tag that is digged out of the maven metadata. This
 141     ...    keyword calculates ${name_prefix} and ${name_suffix} for
 142     ...    "Deploy_Artifact" and then calls "Deploy_Artifact" to do the real
 143     ...    work of deploying the artifact.
 144     ${name_prefix} =    BuiltIn.Set_Variable    ${artifact}-
 145     ${name_suffix} =    BuiltIn.Set_Variable_If    "${suffix}" != ""    -${suffix}.jar    .jar
 146     ${filename} =    Deploy_Artifact    ${component}    ${artifact}    ${name_prefix}    ${name_suffix}    ${fallback_url}
 147     ...    ${explicit_url}
 148     [Return]    ${filename}
 149
 150 Install_And_Start_Java_Artifact
 151     [Arguments]    ${component}    ${artifact}    ${suffix}=executable    ${tool_options}=${EMPTY}    ${java_options}=${EMPTY}    ${openjdk}=${JDKVERSION}
 152     ...    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 153     [Documentation]    Deploy the artifact, assign name for log file, figure out java command, write the command to active SSH connection and return the log name.
 154     ...    This keyword does not examine whether the artifact was started successfully or whether is still running upon return.
 155     # TODO: Unify this keyword with what NexusKeywords.Install_And_Start_Testtool does.
 156     ${default_java_options} =    Default_Java_Options    ${openjdk}
 157     ${actual_java_options} =    BuiltIn.Set_Variable_If    """${java_options}""" != ""    ${java_options}    ${default_java_options}
 158     ${filename} =    Deploy_Test_Tool    ${component}    ${artifact}    ${suffix}    ${fallback_url}    ${explicit_url}
 159     ${command} =    Compose_Full_Java_Command    ${actual_java_options} -jar ${filename} ${tool_options}
 160     ${logfile} =    Utils.Get_Log_File_Name    ${artifact}
 161     SSHLibrary.Write    ${command} >${logfile} 2>&1
 162     [Return]    ${logfile}
 163
 164 Compose_Dilemma_Filepath
 165     [Arguments]    ${default_path}    ${specific_path}
 166     [Documentation]    Query active SSH connection, return specific path if it exists else default path.
 167     ${out}    ${rc} =    SSHLibrary.Execute_Command    ls -lA ${specific_path} 2>&1    return_rc=True
 168     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${specific_path}
 169     BuiltIn.Return_From_Keyword    ${default_path}
 170
 171 Compose_Base_Java_Command
 172     [Arguments]    ${openjdk}=${JDKVERSION}
 173     [Documentation]    Return string suitable for launching Java programs over SSHLibrary, depending on JRE version needed.
 174     ...    This requires that the SSH connection on which the command is going to be used is active as it is needed for querying files.
 175     ...    Commands composed for one SSH connection shall not be reused on other SSH connections as the two connections may have different Java setups.
 176     ...    Not directly related to Nexus, but versioned Java tools may need this.
 177     # Check whether the user set the override and return it if yes.
 178     BuiltIn.Run_Keyword_And_Return_If    """${openjdk}""" == "openjdk8"    Compose_Dilemma_Filepath    ${JAVA_8_HOME_CENTOS}/bin/java    ${JAVA_8_HOME_UBUNTU}/bin/java
 179     BuiltIn.Run_Keyword_And_Return_If    """${openjdk}""" == "openjdk7"    Compose_Dilemma_Filepath    ${JAVA_7_HOME_CENTOS}/bin/java    ${JAVA_7_HOME_UBUNTU}/bin/java
 180     BuiltIn.Run_Keyword_And_Return_If    """${openjdk}""" == "openjdk11"    Compose_Dilemma_Filepath    ${JAVA_11_HOME_CENTOS}/bin/java    ${JAVA_11_HOME_UBUNTU}/bin/java
 181     # Attempt to call plain "java" command directly. If it works, return it.
 182     ${out}    ${rc} =    SSHLibrary.Execute_Command    java -version 2>&1    return_rc=True
 183     BuiltIn.Return_From_Keyword_If    ${rc} == 0    java
 184     # Query the virtual machine for the JAVA_HOME environment variable and
 185     # use it to assemble a (hopefully) working command. If that worked out,
 186     # return the result.
 187     ${java} =    SSHLibrary.Execute_Command    echo $JAVA_HOME/bin/java 2>&1
 188     ${out}    ${rc} =    SSHLibrary.Execute_Command    ${java} -version 2>&1    return_rc=True
 189     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${java}
 190     # There are bizzare test environment setups where the (correct) JAVA_HOME
 191     # is set in the VM where Robot is running but not in the VM where the
 192     # tools are supposed to run (usually because these two are really one
 193     # and the same system and idiosyncracies of BASH prevent easy injection
 194     # of the JAVA_HOME environment variable into a place where connections
 195     # made by SSHLibrary would pick it up). So try to use that value to
 196     # create a java command and check that it works.
 197     ${JAVA_HOME} =    OperatingSystem.Get_Environment_Variable    JAVA_HOME    ${EMPTY}
 198     ${java} =    BuiltIn.Set_Variable_If    """${JAVA_HOME}"""!=""    ${JAVA_HOME}/bin/java    false
 199     ${out}    ${rc} =    SSHLibrary.Execute_Command    ${java} -version 2>&1    return_rc=True
 200     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${java}
 201     # Nothing works, most likely java is not installed at all on the target
 202     # machine or it is hopelesly lost. Bail out with a helpful message
 203     # telling the user how to make it accessible for the script.
 204     BuiltIn.Fail    Unable to find Java; specify \${JDKVERSION}, put it to your PATH or set JAVA_HOME environment variable.
 205
 206 Compose_Full_Java_Command
 207     [Arguments]    ${options}    ${openjdk}=${JDKVERSION}
 208     [Documentation]    Return full Bash command to run Java with given options.
 209     ...    This requires that the SSH connection on which the command is going to be used is active as it is needed for querying files.
 210     ...    The options may include JVM options, application command line arguments, Bash redirects and other constructs.
 211     ${base_command} =    Compose_Base_Java_Command    openjdk=${openjdk}
 212     ${full_command} =    BuiltIn.Set_Variable    ${base_command} ${options}
 213     BuiltIn.Log    ${full_command}
 214     [Return]    ${full_command}
 215
 216 Compose_Java_Home
 217     [Arguments]    ${openjdk}=${JDKVERSION}
 218     [Documentation]    Compose base java command and strip trailing "/bin/java".
 219     ${java_command} =    Compose_Base_Java_Command
 220     ${java_home}    ${bin}    ${java} =    String.Split_String_From_Right    ${java_command}    separator=/    max_split=2
 221     [Return]    ${java_home}
 222
 223 Default_Java_Options
 224     [Arguments]    ${openjdk}=${JDKVERSION}
 225     [Documentation]    Return Java options suitable for current JDK version.
 226     ${java_actual_options} =    BuiltIn.Set_Variable_If    """${openjdk}""" == "openjdk7"    ${JAVA_7_OPTIONS}    ${JAVA_OPTIONS}
 227     [Return]    ${java_actual_options}
 228
 229 Install_Maven_Bare
 230     [Arguments]    ${maven_version}=3.3.9    ${openjdk}=${JDKVERSION}
 231     [Documentation]    Download and unpack Maven, prepare launch command with proper Java version and download settings file.
 232     ...    This Keyword requires an active SSH connection to target machine.
 233     ...    This Keyword sets global variables, so that suites can reuse existing installation.
 234     ...    This Keyword can only place Maven (and settings) to remote current working directory.
 235     ...    This Keyword does not perform any initial or final cleanup.
 236     # Avoid multiple initialization by several downstream libraries.
 237     ${installed_version} =    BuiltIn.Get_Variable_Value    \${Maven__installed_version}    None
 238     BuiltIn.Return_From_Keyword_If    """${installed_version}""" == """${maven_version}"""
 239     BuiltIn.Set_Global_Variable    \${Maven__installed_version}    ${maven_version}
 240     BuiltIn.Set_Global_Variable    \${maven_directory}    apache-maven-${maven_version}
 241     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    rm -rf '${maven_directory}'
 242     ${maven_archive_filename} =    BuiltIn.Set_Variable    ${maven_directory}-bin.tar.gz
 243     ${maven_download_url} =    BuiltIn.Set_Variable    http://www-us.apache.org/dist/maven/maven-3/${maven_version}/binaries/${maven_archive_filename}
 244     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget -N '${maven_download_url}'    stderr_must_be_empty=False
 245     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    tar xvf '${maven_archive_filename}'
 246     ${java_home} =    NexusKeywords.Compose_Java_Home    openjdk=${openjdk}
 247     ${java_actual_options} =    Default_Java_Options    ${openjdk}
 248     BuiltIn.Set_Global_Variable    \${maven_bash_command}    export JAVA_HOME='${java_home}' && export MAVEN_OPTS='${java_actual_options}' && ./${maven_directory}/bin/mvn
 249     # TODO: Get settings files from Jenkins settings provider, somehow.
 250     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget '${MAVEN_SETTINGS_URL}' -O settings.xml    stderr_must_be_empty=False
 251
 252 Install_Maven
 253     [Arguments]    ${maven_version}=3.3.9    ${openjdk}=${JDKVERSION}    ${branch}=${EMPTY}    ${patches}=${EMPTY}
 254     [Documentation]    Install Maven.
 255     ...    Depending on arguments, perform a multipatch build to populate local Maven repository with patched artifacts.
 256     Install_Maven_Bare    maven_version=${maven_version}    openjdk=${openjdk}
 257     BuiltIn.Return_From_Keyword_If    """${patches}""" == ""    No post-install build requested.
 258     BuiltIn.Run_Keyword_If    """${branch}""" == ""    BuiltIn.Fail    BRANCH needs to be specified for multipatch builds.
 259     ${script_name} =    BuiltIn.Set_Variable    include-raw-integration-multipatch-distribution-test.sh
 260     ${script_url} =    BuiltIn.Set_Variable    https://raw.githubusercontent.com/opendaylight/releng-builder/master/jjb/integration/${script_name}
 261     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget -N '${script_url}'    stderr_must_be_empty=False
 262     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    export WORKSPACE='${WORKSPACE}' && export BRANCH='${branch}' && export PATCHES_TO_BUILD='${patches}' && bash '${script_name}'    stderr_must_be_empty=False
 263     Run_Maven    pom_file=${WORKSPACE}/patch_tester/pom.xml
 264
 265 Run_Maven
 266     [Arguments]    ${pom_file}=pom.xml    ${log_file}=${MAVEN_DEFAULT_OUTPUT_FILENAME}
 267     [Documentation]    Determine arguments to use and call mvn command against given pom file.
 268     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    mkdir -p '${MAVEN_REPOSITORY_PATH}'
 269     ${maven_repository_options} =    BuiltIn.Set_Variable    -Dmaven.repo.local=${MAVEN_REPOSITORY_PATH} -Dorg.ops4j.pax.url.mvn.localRepository=${MAVEN_REPOSITORY_PATH}
 270     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    ${maven_bash_command} clean install dependency:tree -V -B -DoutputFile=dependency_tree.log -s './settings.xml' -f '${pom_file}' ${MAVEN_OPTIONS} ${maven_repository_options} > '${log_file}'
 271
 272 Get_ODL_Versions_From_Nexus
 273     [Documentation]    Returns name of last release found on nexus and list of all versions.
 274     RequestsLibrary.Create_Session    nexus    ${NEXUS_RELEASES_URL}    verify=${TRUE}
 275     ${uri}=    BuiltIn.Set_Variable    maven-metadata.xml
 276     ${response}=    RequestsLibrary.Get_Request    nexus    ${uri}
 277     BuiltIn.Log    ${response.text}
 278     ${root}=    XML.Parse_XML    ${response.text}
 279     ${element}=    XML.Get_Element    ${root}    versioning/latest
 280     ${latest}=    BuiltIn.Set_Variable    ${element.text}
 281     BuiltIn.Log    ${latest}
 282     @{elements}=    XML.Get_Elements    ${root}    .//version
 283     ${versions}=    BuiltIn.Create_List
 284     FOR    ${element}    IN    @{elements}
 285         Collections.Append_To_List    ${versions}    ${element.text}
 286     END
 287     Collections.Sort_List    ${versions}
 288     BuiltIn.Log_Many    @{versions}
 289     [Return]    ${latest}    @{versions}
 290
 291 Get_Latest_ODL_Release_From_Nexus
 292     [Documentation]    Returns name of last release found on nexus
 293     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 294     [Return]    ${latest}
 295
 296 Get_Latest_ODL_Stream_Release
 297     [Arguments]    ${stream}=latest
 298     [Documentation]    Returns name for last release for specified stream.
 299     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 300     BuiltIn.Return_From_Keyword_If    '${stream}'=='latest'    ${latest}
 301     ${latest_version}=    BuiltIn.Set_Variable    xxx
 302     FOR    ${version}    IN    @{versions}
 303         ${latest_version}=    BuiltIn.Set_Variable_If    '${stream}'.title() in '${version}'    ${version}    ${latest_version}
 304     END
 305     BuiltIn.Run_Keyword_If    '${latest_version}'=='xxx'    BuiltIn.Fail    Could not find latest release for stream ${stream}
 306     BuiltIn.Log    ${latest_version}
 307     [Return]    ${latest_version}
 308
 309 Get_Latest_ODL_Stream_Release_URL
 310     [Arguments]    ${stream}=latest    ${format}=.zip
 311     [Documentation]    Returns URL for last release for specified stream. Default format is .zip.
 312     ${latest_version}=    Get_Latest_ODL_Stream_Release    ${stream}
 313     ${url}=    BuiltIn.Set_Variable    ${NEXUS_RELEASES_URL}/${latest_version}/opendaylight-${latest_version}${format}
 314     BuiltIn.Log    ${url}
 315     [Return]    ${url}
 316
 317 Get_Latest_ODL_Previous_Stream_Release
 318     [Arguments]    ${stream}=${ODL_STREAM}
 319     [Documentation]    Returns name for last release for previous stream of specified stream.
 320     ...    Note: If specified stream is not found on nexus, then it is taken as new one (not released yet).
 321     ...    So in this case, latest release version is return.
 322     ...
 323     ...    NOTE: the below logic is stripping the initial 0. values from the 0.x.x version string that is
 324     ...    the current (and future) version numbering scheme. There is always a leading 0. to the version
 325     ...    strings and stripping it makes is easier to do int comparison to find the largest version in the
 326     ...    list. Comparing as strings does not work. There are some python libs like distutils.version
 327     ...    or packaging that can do a better job comparing versions, but since ODL version numbering is simple
 328     ...    at this point, this convention will suffice. The leading 0. will be added back after the the latest
 329     ...    version is found from the list. The CompareStream.robot library keeps a mapping of major version
 330     ...    numbers to the global variable ${ODL_STREAM} so that is used to ensure we get a major version that is
 331     ...    older than the current running major version.
 332     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 333     ${current_version}=    BuiltIn.Set_Variable    &{Stream_dict}[${ODL_STREAM}].0
 334     ${latest_version}=    BuiltIn.Set_Variable    0.0
 335     FOR    ${version}    IN    @{versions}
 336         ${version} =    String.Replace String Using Regexp    ${version}    ^0\.    ${EMPTY}
 337         ${latest_version}=    Set Variable If    ${version} > ${latest_version} and ${version} < ${current_version}    ${version}    ${latest_version}
 338     END
 339     ${latest_version}=    Set Variable    0.${latest_version}
 340     BuiltIn.Run_Keyword_If    '${latest_version}'=='0.0.0'    BuiltIn.Fail    Could not find latest previous release for stream ${stream}
 341     BuiltIn.Log    ${latest_version}
 342     [Return]    ${latest_version}
 343
 344 Get_Latest_ODL_Previous_Stream_Release_URL
 345     [Arguments]    ${stream}=${ODL_STREAM}    ${format}=.zip
 346     [Documentation]    Returns URL for last release for previous stream of specified stream. Default format is .zip.
 347     ${latest_version}=    Get_Latest_ODL_Previous_Stream_Release    ${stream}
 348     ${url}=    BuiltIn.Set_Variable    ${NEXUS_RELEASES_URL}/${latest_version}/opendaylight-${latest_version}${format}
 349     BuiltIn.Log    ${url}
 350     [Return]    ${url}