csit/libraries/NexusKeywords.robot

   1 *** Settings ***
   2 Documentation     Nexus repository access keywords, and supporting Java and Maven handling.
   3 ...
   4 ...               Copyright (c) 2015,2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This library encapsulates a bunch of somewhat complex and commonly used
  12 ...               Nexus operations into reusable keywords to make writing test suites easier.
  13 ...
  14 ...               Currently, Java version detection is incorporated so that Java tools can be run reliably.
  15 ...               Also, suport for installing and running Maven is added, as that needs the Java detection.
  16 ...               TODO: Move Java detection and Maven to a separate Resource, or rename this Resource.
  17 Library           Collections
  18 Library           OperatingSystem
  19 Library           SSHLibrary
  20 Library           String
  21 Library           XML
  22 Library           Collections
  23 Library           RequestsLibrary
  24 Resource          ${CURDIR}/CompareStream.robot
  25 Resource          ${CURDIR}/SSHKeywords.robot
  26 Resource          ${CURDIR}/Utils.robot
  27
  28 *** Variables ***
  29 &{COMPONENT_MAPPING}    netconf=netconf-impl    bgpcep=pcep-impl    carpeople=clustering-it-model    yangtools=yang-data-impl    bindingv1=mdsal-binding-generator-impl
  30 ${JDKVERSION}     None
  31 ${JAVA_8_HOME_CENTOS}    /usr/lib/jvm/java-1.8.0
  32 ${JAVA_8_HOME_UBUNTU}    /usr/lib/jvm/java-8-openjdk-amd64
  33 ${JAVA_11_HOME_CENTOS}    /usr/lib/jvm/java-11-openjdk
  34 ${JAVA_11_HOME_UBUNTU}    /usr/lib/jvm/java-11-openjdk-amd64
  35 ${JAVA_OPTIONS}    -Xmx2560m    # Note that '-Xmx=3g' is wrong syntax. Also 3GB heap may not fit in 4GB RAM.
  36 ${MAVEN_DEFAULT_OUTPUT_FILENAME}    default_maven.log
  37 ${MAVEN_OPTIONS}    -Pq -Djenkins
  38 ${MAVEN_REPOSITORY_PATH}    /tmp/r
  39 ${MAVEN_SETTINGS_URL}    https://raw.githubusercontent.com/opendaylight/odlparent/master/settings.xml
  40 ${MAVEN_VERSION}    3.3.9
  41 ${NEXUS_FALLBACK_URL}    ${NEXUSURL_PREFIX}/content/repositories/opendaylight.snapshot
  42 ${NEXUS_RELEASE_BASE_URL}    https://nexus.opendaylight.org/content/repositories/opendaylight.release
  43 ${NEXUS_RELEASES_URL}    ${NEXUS_RELEASE_BASE_URL}/org/opendaylight/integration/opendaylight
  44
  45 *** Keywords ***
  46 Initialize_Artifact_Deployment_And_Usage
  47     [Arguments]    ${tools_system_connect}=True
  48     [Documentation]    Places search utility to ODL system, which will be needed for version detection.
  49     ...    By default also initialize a SSH connection to Tools system,
  50     ...    as following Keywords assume a working connection towards target system.
  51     # Connect to the ODL machine.
  52     ${odl} =    SSHKeywords.Open_Connection_To_ODL_System
  53     # Deploy the search tool.
  54     SSHLibrary.Put_File    ${CURDIR}/../../tools/deployment/search.sh
  55     SSHLibrary.Close_Connection
  56     # Optionally connect to the Tools System machine.
  57     BuiltIn.Return_From_Keyword_If    not (${tools_system_connect})    # the argument may be a convoluted Python expression
  58     SSHKeywords.Open_Connection_To_Tools_System
  59
  60 NexusKeywords__Get_Items_To_Look_At
  61     [Arguments]    ${component}
  62     [Documentation]    Get a list of items that might contain the version number that we are looking for.
  63     ...
  64     ...    &{COMPONENT_MAPPING} is the centralized place to maintain the mapping
  65     ...    from a stream independent component nickname to the list of artifact names to search for.
  66     Collections.Dictionary_Should_Contain_Key    ${COMPONENT_MAPPING}    ${component}    Component not supported by NexusKeywords version detection: ${component}
  67     BuiltIn.Run_Keyword_And_Return    Collections.Get_From_Dictionary    ${COMPONENT_MAPPING}    ${component}
  68
  69 NexusKeywords__Detect_Version_To_Pull
  70     [Arguments]    ${component}
  71     [Documentation]    Determine the exact Nexus directory to be used as a source for a particular test tool
  72     ...    Figure out what version of the tool needs to be pulled out of the
  73     ...    Nexus by looking at the version directory of the subsystem from
  74     ...    which the tool is being pulled. This code is REALLY UGLY but there
  75     ...    is no way around it until the bug
  76     ...    https://bugs.opendaylight.org/show_bug.cgi?id=5206 gets fixed.
  77     ...    I also don't want to depend on maven-metadata-local.xml and other
  78     ...    bits and pieces of ODL distribution which are not required for ODL
  79     ...    to function properly.
  80     ${itemlist} =    NexusKeywords__Get_Items_To_Look_At    ${component}
  81     ${current_ssh_connection} =    SSHLibrary.Get Connection
  82     SSHKeywords.Open_Connection_To_ODL_System
  83     ${version}    ${result} =    SSHLibrary.Execute_Command    sh search.sh ${WORKSPACE}/${BUNDLEFOLDER}/system ${itemlist}    return_rc=True
  84     SSHLibrary.Close_Connection
  85     SSHKeywords.Restore Current SSH Connection From Index    ${current_ssh_connection.index}
  86     BuiltIn.Log    ${version}
  87     BuiltIn.Run_Keyword_If    ${result}!=0    BuiltIn.Fail    Component "${component}": searching for "${itemlist}" found no version, cannot locate test tool.
  88     ${version}    ${location} =    String.Split_String    ${version}    max_split=1
  89     [Return]    ${version}    ${location}
  90
  91 Deploy_From_Url
  92     [Arguments]    ${url}
  93     [Documentation]    On active SSH conenction execute download ${url} command, log output, check RC and return file name.
  94     ${filename} =    String.Fetch_From_Right    ${url}    /
  95     ${response}    ${result} =    SSHLibrary.Execute_Command    wget -q -N '${url}' 2>&1    return_rc=True
  96     BuiltIn.Log    ${response}
  97     BuiltIn.Run_Keyword_If    ${result} != 0    BuiltIn.Fail    File ${filename} could not be downloaded from ${url}
  98     [Return]    ${filename}
  99
 100 Deploy_Artifact
 101     [Arguments]    ${component}    ${artifact}    ${name_prefix}=${artifact}-    ${name_suffix}=-executable.jar    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 102     [Documentation]    Deploy the specified artifact from Nexus to the cwd of the machine to which the active SSHLibrary connection points.
 103     ...    ${component} is a name part of an artifact present in system/ of ODl installation with the same version as ${artifact} should have.
 104     ...    Must have ${BUNDLE_URL} variable set to the URL from which the
 105     ...    tested ODL distribution was downloaded and this place must be
 106     ...    inside a repository created by a standard distribution
 107     ...    construction job. If this is detected to ne be the case, fallback URL is used.
 108     ...    If ${explicit_url} is non-empty, Deploy_From_Utrl is called instead.
 109     ...    TODO: Allow deploying to a specific directory, we have SSHKeywords.Execute_Command_At_Cwd_Should_Pass now.
 110     BuiltIn.Run_Keyword_And_Return_If    """${explicit_url}""" != ""    Deploy_From_Url    ${explicit_url}
 111     ${urlbase} =    String.Fetch_From_Left    ${BUNDLE_URL}    /org/opendaylight
 112     # If the BUNDLE_URL points somewhere else (perhaps *patch-test* job in Jenkins),
 113     # ${urlbase} is the whole ${BUNDLE_URL}, in which case we use the ${fallback_url}
 114     ${urlbase} =    BuiltIn.Set_Variable_If    '${urlbase}' != '${BUNDLE_URL}'    ${urlbase}    ${fallback_url}
 115     ${version}    ${location} =    NexusKeywords__Detect_Version_To_Pull    ${component}
 116     # TODO: Use RequestsLibrary and String instead of curl and bash utilities?
 117     ${url} =    BuiltIn.Set_Variable    ${urlbase}/${location}/${artifact}/${version}
 118     # TODO: Review SSHKeywords for current best keywords to call.
 119     ${metadata} =    SSHKeywords.Execute_Command_Should_Pass    curl -L ${url}/maven-metadata.xml
 120     ${status}    ${namepart} =    BuiltIn.Run_Keyword_And_Ignore_Error    SSHKeywords.Execute_Command_Should_Pass    echo "${metadata}" | grep value | head -n 1 | cut -d '>' -f 2 | cut -d '<' -f 1    stderr_must_be_empty=${True}
 121     ${length} =    BuiltIn.Get_Length    ${namepart}
 122     ${namepart} =    BuiltIn.Set_Variable_If    "${status}" != "PASS" or ${length} == 0    ${version}    ${namepart}
 123     ${filename} =    BuiltIn.Set_Variable    ${name_prefix}${namepart}${name_suffix}
 124     BuiltIn.Log    ${filename}
 125     ${url} =    BuiltIn.Set_Variable    ${url}/${filename}
 126     ${response}    ${result} =    SSHLibrary.Execute_Command    wget -q -N '${url}' 2>&1    return_rc=True
 127     BuiltIn.Log    ${response}
 128     BuiltIn.Run_Keyword_If    ${result} != 0    BuiltIn.Fail    Artifact "${artifact}" in component "${component}" could not be downloaded from ${url}
 129     [Return]    ${filename}
 130
 131 Deploy_Test_Tool
 132     [Arguments]    ${component}    ${artifact}    ${suffix}=executable    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 133     [Documentation]    Deploy a test tool.
 134     ...    The test tools have naming convention of the form
 135     ...    "<repository_url>/some/dir/somewhere/<tool-name>/<tool-name>-<version-tag>-${suffix}.jar"
 136     ...    where "<tool-name>" is the name of the tool and "<version-tag>" is
 137     ...    the version tag that is digged out of the maven metadata. This
 138     ...    keyword calculates ${name_prefix} and ${name_suffix} for
 139     ...    "Deploy_Artifact" and then calls "Deploy_Artifact" to do the real
 140     ...    work of deploying the artifact.
 141     ${name_prefix} =    BuiltIn.Set_Variable    ${artifact}-
 142     ${name_suffix} =    BuiltIn.Set_Variable_If    "${suffix}" != ""    -${suffix}.jar    .jar
 143     ${filename} =    Deploy_Artifact    ${component}    ${artifact}    ${name_prefix}    ${name_suffix}    ${fallback_url}
 144     ...    ${explicit_url}
 145     [Return]    ${filename}
 146
 147 Install_And_Start_Java_Artifact
 148     [Arguments]    ${component}    ${artifact}    ${suffix}=executable    ${tool_options}=${EMPTY}    ${java_options}=${EMPTY}    ${openjdk}=${JDKVERSION}
 149     ...    ${fallback_url}=${NEXUS_FALLBACK_URL}    ${explicit_url}=${EMPTY}
 150     [Documentation]    Deploy the artifact, assign name for log file, figure out java command, write the command to active SSH connection and return the log name.
 151     ...    This keyword does not examine whether the artifact was started successfully or whether is still running upon return.
 152     # TODO: Unify this keyword with what NexusKeywords.Install_And_Start_Testtool does.
 153     ${actual_java_options} =    BuiltIn.Set_Variable_If    """${java_options}""" != ""    ${java_options}    ${JAVA_OPTIONS}
 154     ${filename} =    Deploy_Test_Tool    ${component}    ${artifact}    ${suffix}    ${fallback_url}    ${explicit_url}
 155     ${command} =    Compose_Full_Java_Command    ${actual_java_options} -jar ${filename} ${tool_options}
 156     ${logfile} =    Utils.Get_Log_File_Name    ${artifact}
 157     SSHLibrary.Write    ${command} >${logfile} 2>&1
 158     [Return]    ${logfile}
 159
 160 Compose_Dilemma_Filepath
 161     [Arguments]    ${default_path}    ${specific_path}
 162     [Documentation]    Query active SSH connection, return specific path if it exists else default path.
 163     ${out}    ${rc} =    SSHLibrary.Execute_Command    ls -lA ${specific_path} 2>&1    return_rc=True
 164     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${specific_path}
 165     BuiltIn.Return_From_Keyword    ${default_path}
 166
 167 Compose_Base_Java_Command
 168     [Arguments]    ${openjdk}=${JDKVERSION}
 169     [Documentation]    Return string suitable for launching Java programs over SSHLibrary, depending on JRE version needed.
 170     ...    This requires that the SSH connection on which the command is going to be used is active as it is needed for querying files.
 171     ...    Commands composed for one SSH connection shall not be reused on other SSH connections as the two connections may have different Java setups.
 172     ...    Not directly related to Nexus, but versioned Java tools may need this.
 173     # Check whether the user set the override and return it if yes.
 174     BuiltIn.Run_Keyword_And_Return_If    """${openjdk}""" == "openjdk8"    Compose_Dilemma_Filepath    ${JAVA_8_HOME_CENTOS}/bin/java    ${JAVA_8_HOME_UBUNTU}/bin/java
 175     BuiltIn.Run_Keyword_And_Return_If    """${openjdk}""" == "openjdk11"    Compose_Dilemma_Filepath    ${JAVA_11_HOME_CENTOS}/bin/java    ${JAVA_11_HOME_UBUNTU}/bin/java
 176     # Attempt to call plain "java" command directly. If it works, return it.
 177     ${out}    ${rc} =    SSHLibrary.Execute_Command    java -version 2>&1    return_rc=True
 178     BuiltIn.Return_From_Keyword_If    ${rc} == 0    java
 179     # Query the virtual machine for the JAVA_HOME environment variable and
 180     # use it to assemble a (hopefully) working command. If that worked out,
 181     # return the result.
 182     ${java} =    SSHLibrary.Execute_Command    echo $JAVA_HOME/bin/java 2>&1
 183     ${out}    ${rc} =    SSHLibrary.Execute_Command    ${java} -version 2>&1    return_rc=True
 184     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${java}
 185     # There are bizzare test environment setups where the (correct) JAVA_HOME
 186     # is set in the VM where Robot is running but not in the VM where the
 187     # tools are supposed to run (usually because these two are really one
 188     # and the same system and idiosyncracies of BASH prevent easy injection
 189     # of the JAVA_HOME environment variable into a place where connections
 190     # made by SSHLibrary would pick it up). So try to use that value to
 191     # create a java command and check that it works.
 192     ${JAVA_HOME} =    OperatingSystem.Get_Environment_Variable    JAVA_HOME    ${EMPTY}
 193     ${java} =    BuiltIn.Set_Variable_If    """${JAVA_HOME}"""!=""    ${JAVA_HOME}/bin/java    false
 194     ${out}    ${rc} =    SSHLibrary.Execute_Command    ${java} -version 2>&1    return_rc=True
 195     BuiltIn.Return_From_Keyword_If    ${rc} == 0    ${java}
 196     # Nothing works, most likely java is not installed at all on the target
 197     # machine or it is hopelesly lost. Bail out with a helpful message
 198     # telling the user how to make it accessible for the script.
 199     BuiltIn.Fail    Unable to find Java; specify \${JDKVERSION}, put it to your PATH or set JAVA_HOME environment variable.
 200
 201 Compose_Full_Java_Command
 202     [Arguments]    ${options}    ${openjdk}=${JDKVERSION}
 203     [Documentation]    Return full Bash command to run Java with given options.
 204     ...    This requires that the SSH connection on which the command is going to be used is active as it is needed for querying files.
 205     ...    The options may include JVM options, application command line arguments, Bash redirects and other constructs.
 206     ${base_command} =    Compose_Base_Java_Command    openjdk=${openjdk}
 207     ${full_command} =    BuiltIn.Set_Variable    ${base_command} ${options}
 208     BuiltIn.Log    ${full_command}
 209     [Return]    ${full_command}
 210
 211 Compose_Java_Home
 212     [Arguments]    ${openjdk}=${JDKVERSION}
 213     [Documentation]    Compose base java command and strip trailing "/bin/java".
 214     ${java_command} =    Compose_Base_Java_Command
 215     ${java_home}    ${bin}    ${java} =    String.Split_String_From_Right    ${java_command}    separator=/    max_split=2
 216     [Return]    ${java_home}
 217
 218 Install_Maven_Bare
 219     [Arguments]    ${maven_version}=3.3.9    ${openjdk}=${JDKVERSION}
 220     [Documentation]    Download and unpack Maven, prepare launch command with proper Java version and download settings file.
 221     ...    This Keyword requires an active SSH connection to target machine.
 222     ...    This Keyword sets global variables, so that suites can reuse existing installation.
 223     ...    This Keyword can only place Maven (and settings) to remote current working directory.
 224     ...    This Keyword does not perform any initial or final cleanup.
 225     # Avoid multiple initialization by several downstream libraries.
 226     ${installed_version} =    BuiltIn.Get_Variable_Value    \${Maven__installed_version}    None
 227     BuiltIn.Return_From_Keyword_If    """${installed_version}""" == """${maven_version}"""
 228     BuiltIn.Set_Global_Variable    \${Maven__installed_version}    ${maven_version}
 229     BuiltIn.Set_Global_Variable    \${maven_directory}    apache-maven-${maven_version}
 230     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    rm -rf '${maven_directory}'
 231     ${maven_archive_filename} =    BuiltIn.Set_Variable    ${maven_directory}-bin.tar.gz
 232     ${maven_download_url} =    BuiltIn.Set_Variable    http://www-us.apache.org/dist/maven/maven-3/${maven_version}/binaries/${maven_archive_filename}
 233     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget -N '${maven_download_url}'    stderr_must_be_empty=False
 234     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    tar xvf '${maven_archive_filename}'
 235     ${java_home} =    NexusKeywords.Compose_Java_Home    openjdk=${openjdk}
 236     ${java_actual_options} =    Default_Java_Options    ${openjdk}
 237     BuiltIn.Set_Global_Variable    \${maven_bash_command}    export JAVA_HOME='${java_home}' && export MAVEN_OPTS='${java_actual_options}' && ./${maven_directory}/bin/mvn
 238     # TODO: Get settings files from Jenkins settings provider, somehow.
 239     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget '${MAVEN_SETTINGS_URL}' -O settings.xml    stderr_must_be_empty=False
 240
 241 Install_Maven
 242     [Arguments]    ${maven_version}=3.3.9    ${openjdk}=${JDKVERSION}    ${branch}=${EMPTY}    ${patches}=${EMPTY}
 243     [Documentation]    Install Maven.
 244     ...    Depending on arguments, perform a multipatch build to populate local Maven repository with patched artifacts.
 245     Install_Maven_Bare    maven_version=${maven_version}    openjdk=${openjdk}
 246     BuiltIn.Return_From_Keyword_If    """${patches}""" == ""    No post-install build requested.
 247     BuiltIn.Run_Keyword_If    """${branch}""" == ""    BuiltIn.Fail    BRANCH needs to be specified for multipatch builds.
 248     ${script_name} =    BuiltIn.Set_Variable    include-raw-integration-multipatch-distribution-test.sh
 249     ${script_url} =    BuiltIn.Set_Variable    https://raw.githubusercontent.com/opendaylight/releng-builder/master/jjb/integration/${script_name}
 250     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    wget -N '${script_url}'    stderr_must_be_empty=False
 251     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    export WORKSPACE='${WORKSPACE}' && export BRANCH='${branch}' && export PATCHES_TO_BUILD='${patches}' && bash '${script_name}'    stderr_must_be_empty=False
 252     Run_Maven    pom_file=${WORKSPACE}/patch_tester/pom.xml
 253
 254 Run_Maven
 255     [Arguments]    ${pom_file}=pom.xml    ${log_file}=${MAVEN_DEFAULT_OUTPUT_FILENAME}
 256     [Documentation]    Determine arguments to use and call mvn command against given pom file.
 257     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    mkdir -p '${MAVEN_REPOSITORY_PATH}'
 258     ${maven_repository_options} =    BuiltIn.Set_Variable    -Dmaven.repo.local=${MAVEN_REPOSITORY_PATH} -Dorg.ops4j.pax.url.mvn.localRepository=${MAVEN_REPOSITORY_PATH}
 259     SSHKeywords.Execute_Command_At_Cwd_Should_Pass    ${maven_bash_command} clean install dependency:tree -V -B -DoutputFile=dependency_tree.log -s './settings.xml' -f '${pom_file}' ${MAVEN_OPTIONS} ${maven_repository_options} > '${log_file}'
 260
 261 Get_ODL_Versions_From_Nexus
 262     [Documentation]    Returns name of last release found on nexus and list of all versions.
 263     RequestsLibrary.Create_Session    nexus    ${NEXUS_RELEASES_URL}    verify=${TRUE}
 264     ${uri}=    BuiltIn.Set_Variable    maven-metadata.xml
 265     ${response}=    RequestsLibrary.Get_Request    nexus    ${uri}
 266     BuiltIn.Log    ${response.text}
 267     ${root}=    XML.Parse_XML    ${response.text}
 268     ${element}=    XML.Get_Element    ${root}    versioning/latest
 269     ${latest}=    BuiltIn.Set_Variable    ${element.text}
 270     BuiltIn.Log    ${latest}
 271     @{elements}=    XML.Get_Elements    ${root}    .//version
 272     ${versions}=    BuiltIn.Create_List
 273     FOR    ${element}    IN    @{elements}
 274         Collections.Append_To_List    ${versions}    ${element.text}
 275     END
 276     Collections.Sort_List    ${versions}
 277     BuiltIn.Log_Many    @{versions}
 278     [Return]    ${latest}    @{versions}
 279
 280 Get_Latest_ODL_Release_From_Nexus
 281     [Documentation]    Returns name of last release found on nexus
 282     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 283     [Return]    ${latest}
 284
 285 Get_Latest_ODL_Stream_Release
 286     [Arguments]    ${stream}=latest
 287     [Documentation]    Returns name for last release for specified stream.
 288     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 289     BuiltIn.Return_From_Keyword_If    '${stream}'=='latest'    ${latest}
 290     ${latest_version}=    BuiltIn.Set_Variable    xxx
 291     FOR    ${version}    IN    @{versions}
 292         ${latest_version}=    BuiltIn.Set_Variable_If    '${stream}'.title() in '${version}'    ${version}    ${latest_version}
 293     END
 294     BuiltIn.Run_Keyword_If    '${latest_version}'=='xxx'    BuiltIn.Fail    Could not find latest release for stream ${stream}
 295     BuiltIn.Log    ${latest_version}
 296     [Return]    ${latest_version}
 297
 298 Get_Latest_ODL_Stream_Release_URL
 299     [Arguments]    ${stream}=latest    ${format}=.zip
 300     [Documentation]    Returns URL for last release for specified stream. Default format is .zip.
 301     ${latest_version}=    Get_Latest_ODL_Stream_Release    ${stream}
 302     ${url}=    BuiltIn.Set_Variable    ${NEXUS_RELEASES_URL}/${latest_version}/opendaylight-${latest_version}${format}
 303     BuiltIn.Log    ${url}
 304     [Return]    ${url}
 305
 306 Get_Latest_ODL_Previous_Stream_Release
 307     [Arguments]    ${stream}=${ODL_STREAM}
 308     [Documentation]    Returns name for last release for previous stream of specified stream.
 309     ...    Note: If specified stream is not found on nexus, then it is taken as new one (not released yet).
 310     ...    So in this case, latest release version is return.
 311     ...
 312     ...    NOTE: the below logic is stripping the initial 0. values from the 0.x.x version string that is
 313     ...    the current (and future) version numbering scheme. There is always a leading 0. to the version
 314     ...    strings and stripping it makes is easier to do int comparison to find the largest version in the
 315     ...    list. Comparing as strings does not work. There are some python libs like distutils.version
 316     ...    or packaging that can do a better job comparing versions, but since ODL version numbering is simple
 317     ...    at this point, this convention will suffice. The leading 0. will be added back after the the latest
 318     ...    version is found from the list. The CompareStream.robot library keeps a mapping of major version
 319     ...    numbers to the global variable ${ODL_STREAM} so that is used to ensure we get a major version that is
 320     ...    older than the current running major version.
 321     ${latest}    @{versions}=    Get_ODL_Versions_From_Nexus
 322     ${current_version}=    BuiltIn.Set_Variable    &{Stream_dict}[${ODL_STREAM}].0
 323     ${latest_version}=    BuiltIn.Set_Variable    0.0
 324     FOR    ${version}    IN    @{versions}
 325         ${version} =    String.Replace String Using Regexp    ${version}    ^0\.    ${EMPTY}
 326         ${latest_version}=    Set Variable If    ${version} > ${latest_version} and ${version} < ${current_version}    ${version}    ${latest_version}
 327     END
 328     ${latest_version}=    Set Variable    0.${latest_version}
 329     BuiltIn.Run_Keyword_If    '${latest_version}'=='0.0.0'    BuiltIn.Fail    Could not find latest previous release for stream ${stream}
 330     BuiltIn.Log    ${latest_version}
 331     [Return]    ${latest_version}
 332
 333 Get_Latest_ODL_Previous_Stream_Release_URL
 334     [Arguments]    ${stream}=${ODL_STREAM}    ${format}=.zip
 335     [Documentation]    Returns URL for last release for previous stream of specified stream. Default format is .zip.
 336     ${latest_version}=    Get_Latest_ODL_Previous_Stream_Release    ${stream}
 337     ${url}=    BuiltIn.Set_Variable    ${NEXUS_RELEASES_URL}/${latest_version}/opendaylight-${latest_version}${format}
 338     BuiltIn.Log    ${url}
 339     [Return]    ${url}