csit/libraries/SxpLib.robot

   1 *** Settings ***
   2 Documentation     Library containing Keywords used for SXP testing
   3 Library           Collections
   4 Library           RequestsLibrary
   5 Library           SSHLibrary
   6 Library           String
   7 Library           ./Sxp.py
   8 Resource          CompareStream.robot
   9 Resource          KarafKeywords.robot
  10 Resource          Utils.robot
  11 Resource          TemplatedRequests.robot
  12 Variables         ../variables/Variables.py
  13
  14 *** Variables ***
  15 ${REST_CONTEXT}    /restconf/operations/sxp-controller
  16
  17 *** Keywords ***
  18 Post To Controller
  19     [Arguments]    ${session}    ${path}    ${DATA}
  20     [Documentation]    Post request to Controller and checks response
  21     ${resp}    Post Request    ${session}    ${REST_CONTEXT}:${path}    data=${DATA}    headers=${HEADERS_XML}
  22     Log    ${resp.content}
  23     Log    ${session}
  24     Log    ${path}
  25     Log    ${DATA}
  26     Should be Equal As Strings    ${resp.status_code}    200
  27     ${content}    Evaluate    json.loads('''${resp.content}''')    json
  28     ${content}    Get From Dictionary    ${content}    output
  29     ${content}    Get From Dictionary    ${content}    result
  30     Should Be True    ${content}
  31
  32 Add Node
  33     [Arguments]    ${node}    ${password}=${EMPTY}    ${version}=version4    ${port}=64999    ${session}=session    ${ip}=${EMPTY}
  34     ...    ${ssl_stores}=${EMPTY}
  35     [Documentation]    Add node via RPC to ODL
  36     ${DATA}    Add Node Xml    ${node}    ${port}    ${password}    ${version}    ${ip}
  37     ...    keystores=${ssl_stores}
  38     Post To Controller    ${session}    add-node    ${DATA}
  39
  40 Delete Node
  41     [Arguments]    ${node}    ${session}=session
  42     [Documentation]    Delete connection via RPC from node
  43     ${DATA}    Delete Node Xml    ${node}
  44     Post To Controller    ${session}    delete-node    ${DATA}
  45
  46 Add Connection
  47     [Arguments]    ${version}    ${mode}    ${ip}    ${port}    ${node}=127.0.0.1    ${password}=${EMPTY}
  48     ...    ${session}=session    ${domain}=global    ${security_mode}=${EMPTY}
  49     [Documentation]    Add connection via RPC to node
  50     ${DATA}    Add Connection Xml    ${version}    ${mode}    ${ip}    ${port}    ${node}
  51     ...    ${password}    ${domain}    security_mode=${security_mode}
  52     Post To Controller    ${session}    add-connection    ${DATA}
  53
  54 Get Connections
  55     [Arguments]    ${node}=127.0.0.1    ${session}=session    ${domain}=global
  56     [Documentation]    Gets all connections via RPC from node
  57     ${DATA}    Get Connections From Node Xml    ${node}    ${domain}
  58     ${resp}    Post Request    ${session}    ${REST_CONTEXT}:get-connections    data=${DATA}    headers=${HEADERS_XML}
  59     Should be Equal As Strings    ${resp.status_code}    200
  60     [Return]    ${resp.content}
  61
  62 Delete Connections
  63     [Arguments]    ${ip}    ${port}    ${node}=127.0.0.1    ${session}=session    ${domain}=global
  64     [Documentation]    Delete connection via RPC from node
  65     ${DATA}    Delete Connections Xml    ${ip}    ${port}    ${node}    ${domain}
  66     Post To Controller    ${session}    delete-connection    ${DATA}
  67
  68 Clean Connections
  69     [Arguments]    ${node}=127.0.0.1    ${session}=session    ${domain}=global
  70     [Documentation]    Delete all connections via RPC from node
  71     ${resp}    Get Connections    ${node}    ${session}    ${domain}
  72     @{connections}    Parse Connections    ${resp}
  73     : FOR    ${connection}    IN    @{connections}
  74     \    Delete Connections    ${connection['peer-address']}    ${connection['tcp-port']}    ${node}    ${session}    ${domain}
  75
  76 Verify Connection
  77     [Arguments]    ${version}    ${mode}    ${ip}    ${port}=64999    ${node}=127.0.0.1    ${state}=on
  78     ...    ${session}=session    ${domain}=global
  79     [Documentation]    Verify that connection is ON
  80     ${resp}    Get Connections    ${node}    ${session}    ${domain}
  81     Should Contain Connection    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}
  82
  83 Add Binding
  84     [Arguments]    ${sgt}    ${prefix}    ${node}=127.0.0.1    ${domain}=global    ${session}=session
  85     [Documentation]    Add binding via RPC to Master DB of node
  86     ${DATA}    Add Entry Xml    ${sgt}    ${prefix}    ${node}    ${domain}
  87     Post To Controller    ${session}    add-entry    ${DATA}
  88
  89 Get Bindings
  90     [Arguments]    ${node}=127.0.0.1    ${session}=session    ${domain}=global    ${scope}=all
  91     [Documentation]    Gets all binding via RPC from Master DB of node
  92     ${DATA}    Get Bindings From Node Xml    ${node}    ${scope}    ${domain}
  93     ${resp1}    CompareStream.Run_Keyword_If_At_Least_Boron    TemplatedRequests.Post_To_Uri    ${REST_CONTEXT}:get-node-bindings    data=${DATA}    accept=${ACCEPT_JSON}    content_type=${HEADERS_XML}
  94     ...    session=${session}
  95     ${resp2}    CompareStream.Run_Keyword_If_Less_Than_Boron    TemplatedRequests.Get_As_Json_From_Uri    /restconf/operational/network-topology:network-topology/topology/sxp/node/${node}/master-database/    session=${session}
  96     ${resp}    CompareStream.Set_Variable_If_At_Least_Boron    ${resp1}    ${resp2}
  97     [Return]    ${resp}
  98
  99 Clean Bindings
 100     [Arguments]    ${node}=127.0.0.1    ${session}=session    ${domain}=global
 101     [Documentation]    Delete all bindings via RPC from Master DB of node
 102     ${resp}    Get Bindings    ${node}    ${session}    ${domain}    local
 103     @{bindings}    CompareStream.Run_Keyword_If_At_Least_Else    boron    Parse Bindings    ${resp}
 104     ...    ELSE    Parse Prefix Groups    ${resp}    local
 105     : FOR    ${binding}    IN    @{bindings}
 106     \    CompareStream.Run_Keyword_If_At_Least_Boron    Clean Binding Default    ${binding}    ${node}    ${session}    ${domain}
 107     \    CompareStream.Run_Keyword_If_At_Most_Beryllium    Clean Binding At Most Be    ${binding}    ${node}    ${session}    ${domain}
 108
 109 Clean Binding Default
 110     [Arguments]    ${binding}    ${node}    ${session}    ${domain}
 111     [Documentation]    Clean binding
 112     Clean Binding    ${binding['sgt']}    ${binding['ip-prefix']}    ${node}    ${session}
 113
 114 Clean Binding At Most Be
 115     [Arguments]    ${binding}    ${node}    ${session}    ${domain}
 116     [Documentation]    Clean binding
 117     Clean Binding    ${binding}    ${binding['binding']}    ${node}    ${session}
 118
 119 Clean Binding
 120     [Arguments]    ${sgt}    ${prefixes}    ${node}    ${session}    ${domain}=global
 121     [Documentation]    Used for nester FOR loop
 122     : FOR    ${prefix}    IN    @{prefixes}
 123     \    CompareStream.Run_Keyword_If_At_Least_Boron    Delete Binding Default    ${sgt}    ${prefix}    ${node}    ${domain}
 124     \    ...    ${session}
 125     \    CompareStream.Run_Keyword_If_At_Most_Beryllium    Delete Binding Be    ${sgt}    ${prefix}    ${node}    ${domain}
 126     \    ...    ${session}
 127
 128 Update Binding
 129     [Arguments]    ${sgtOld}    ${prefixOld}    ${sgtNew}    ${prefixNew}    ${node}=127.0.0.1    ${session}=session
 130     ...    ${domain}=global
 131     [Documentation]    Updates value of binding via RPC in Master DB of node
 132     ${DATA}    Update Binding Xml    ${sgtOld}    ${prefixOld}    ${sgtNew}    ${prefixNew}    ${node}
 133     ...    ${domain}
 134     Post To Controller    ${session}    update-entry    ${DATA}
 135
 136 Delete Binding Default
 137     [Arguments]    ${sgt}    ${prefix}    ${node}    ${domain}    ${session}
 138     [Documentation]    Delete binding via RPC
 139     Delete Binding    ${sgt}    ${prefix}    ${node}    ${domain}    ${session}
 140
 141 Delete Binding Be
 142     [Arguments]    ${sgt}    ${prefix}    ${node}    ${domain}    ${session}
 143     [Documentation]    Delete binding via RPC
 144     Delete Binding    ${sgt['sgt']}    ${prefix['ip-prefix']}    ${node}    ${domain}    ${session}
 145
 146 Delete Binding
 147     [Arguments]    ${sgt}    ${prefix}    ${node}=127.0.0.1    ${domain}=global    ${session}=session
 148     [Documentation]    Delete binding via RPC from Master DB of node
 149     ${DATA}    Delete Binding Xml    ${sgt}    ${prefix}    ${node}    ${domain}
 150     Post To Controller    ${session}    delete-entry    ${DATA}
 151
 152 Add PeerGroup
 153     [Arguments]    ${name}    ${peers}=    ${node}=127.0.0.1    ${session}=session
 154     [Documentation]    Adds new PeerGroup via RPC to Node
 155     ${DATA}    Add Peer Group Xml    ${name}    ${peers}    ${node}
 156     Post To Controller    ${session}    add-peer-group    ${DATA}
 157
 158 Delete Peer Group
 159     [Arguments]    ${name}    ${node}=127.0.0.1    ${session}=session
 160     [Documentation]    Delete PeerGroup via RPC from Node
 161     ${DATA}    Delete Peer Group Xml    ${name}    ${node}
 162     Post To Controller    ${session}    delete-peer-group    ${DATA}
 163
 164 Get Peer Groups
 165     [Arguments]    ${node}=127.0.0.1    ${session}=session
 166     [Documentation]    Gets all PeerGroups via RPC from node
 167     ${DATA}    Get Peer Groups From Node Xml    ${node}
 168     ${resp}    Post Request    ${session}    ${REST_CONTEXT}:get-peer-groups    data=${DATA}    headers=${HEADERS_XML}
 169     Should be Equal As Strings    ${resp.status_code}    200
 170     [Return]    ${resp.content}
 171
 172 Clean Peer Groups
 173     [Arguments]    ${node}=127.0.0.1    ${session}=session
 174     [Documentation]    Delete all PeerGroups via RPC from node
 175     ${resp}    Get Peer Groups    ${node}    ${session}
 176     @{prefixes}    Parse Peer Groups    ${resp}
 177     : FOR    ${group}    IN    @{prefixes}
 178     \    Delete Peer Group    ${group['name']}    ${node}    ${session}
 179
 180 Add Filter
 181     [Arguments]    ${name}    ${type}    ${entries}    ${node}=127.0.0.1    ${session}=session    ${policy}=auto-update
 182     [Documentation]    Add Filter via RPC from Node
 183     ${DATA}    Run_Keyword_If_At_Least_Else    carbon    Add Filter Xml    ${name}    ${type}    ${entries}
 184     ...    ${node}    ${policy}
 185     ...    ELSE    Add Filter Xml    ${name}    ${type}    ${entries}    ${node}
 186     Post To Controller    ${session}    add-filter    ${DATA}
 187
 188 Add Domain Filter
 189     [Arguments]    ${name}    ${domains}    ${entries}    ${node}=127.0.0.1    ${filter_name}=base-domain-filter    ${session}=session
 190     [Documentation]    Add Domain Filter via RPC from Node
 191     ${DATA}    Add Domain Filter Xml    ${name}    ${domains}    ${entries}    ${node}    ${filter_name}
 192     Post To Controller    ${session}    add-domain-filter    ${DATA}
 193
 194 Delete Filter
 195     [Arguments]    ${name}    ${type}    ${node}=127.0.0.1    ${session}=session
 196     [Documentation]    Delete Filter via RPC from Node
 197     ${DATA}    Delete Filter Xml    ${name}    ${type}    ${node}
 198     Post To Controller    ${session}    delete-filter    ${DATA}
 199
 200 Delete Domain Filter
 201     [Arguments]    ${name}    ${node}=127.0.0.1    ${filter_name}=base-domain-filter    ${session}=session
 202     [Documentation]    Delete Filter via RPC from Node
 203     ${DATA}    Delete Domain Filter Xml    ${name}    ${node}    ${filter_name}
 204     Post To Controller    ${session}    delete-domain-filter    ${DATA}
 205
 206 Should Contain Binding
 207     [Arguments]    ${resp}    ${sgt}    ${prefix}    ${db_source}=any
 208     [Documentation]    Tests if data contains specified binding
 209     ${out}    CompareStream.Run_Keyword_If_At_Least_Else    boron    Find Binding    ${resp}    ${sgt}    ${prefix}
 210     ...    ELSE    Find Binding Legacy    ${resp}    ${sgt}    ${prefix}    ${db_source}
 211     ...    add
 212     Should Be True    ${out}    Doesn't have ${sgt} ${prefix}
 213
 214 Should Not Contain Binding
 215     [Arguments]    ${resp}    ${sgt}    ${prefix}    ${db_source}=any
 216     [Documentation]    Tests if data doesn't contains specified binding
 217     ${out}    CompareStream.Run_Keyword_If_At_Least_Else    boron    Find Binding    ${resp}    ${sgt}    ${prefix}
 218     ...    ELSE    Find Binding Legacy    ${resp}    ${sgt}    ${prefix}    ${db_source}
 219     ...    add
 220     Should Not Be True    ${out}    Should't have ${sgt} ${prefix}
 221
 222 Should Contain Connection
 223     [Arguments]    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}=none
 224     [Documentation]    Test if data contains specified connection
 225     ${out}    Find Connection    ${resp}    ${version}    ${mode}    ${ip}    ${port}
 226     ...    ${state}
 227     Should Be True    ${out}    Doesn't have ${ip}:${port} ${mode} ${version}
 228
 229 Should Not Contain Connection
 230     [Arguments]    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}=none
 231     [Documentation]    Test if data doesn't contains specified connection
 232     ${out}    Find Connection    ${resp}    ${version}    ${mode}    ${ip}    ${port}
 233     ...    ${state}
 234     Should Not Be True    ${out}    Shouldn't have ${ip}:${port} ${mode} ${version}
 235
 236 Bindings Should Contain
 237     [Arguments]    ${sgt}    ${prefix}    ${db_source}=any
 238     [Documentation]    Retrieves bindings and verifies they contain given binding
 239     ${resp}    Get Bindings
 240     Should Contain Binding    ${resp}    ${sgt}    ${prefix}    ${db_source}
 241
 242 Bindings Should Not Contain
 243     [Arguments]    ${sgt}    ${prefix}    ${db_source}=any
 244     [Documentation]    Retrieves bindings and verifies they do not contain given binding
 245     ${resp}    Get Bindings
 246     Should Not Contain Binding    ${resp}    ${sgt}    ${prefix}    ${db_source}
 247
 248 Connections Should Contain
 249     [Arguments]    ${ip}    ${port}    ${mode}    ${version}    ${state}=none
 250     [Documentation]    Retrieves connections and verifies they contain given connection
 251     ${resp}    Get Connections
 252     Should Contain Connection    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}
 253
 254 Connections Should Not Contain
 255     [Arguments]    ${ip}    ${port}    ${mode}    ${version}    ${state}=none
 256     [Documentation]    Retrieves connections and verifies they do not contain given connection
 257     ${resp}    Get Connections
 258     Should Not Contain Connection    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}
 259
 260 Setup Topology Complex
 261     [Arguments]    ${version}=version4    ${PASSWORD}=none
 262     : FOR    ${node}    IN RANGE    2    6
 263     \    Add Connection    ${version}    both    127.0.0.1    64999    127.0.0.${node}
 264     \    ...    ${PASSWORD}
 265     \    Add Connection    ${version}    both    127.0.0.${node}    64999    127.0.0.1
 266     \    ...    ${PASSWORD}
 267     \    Wait Until Keyword Succeeds    15    1    Verify Connection    ${version}    both
 268     \    ...    127.0.0.${node}
 269     \    Add Binding    ${node}0    10.10.10.${node}0/32    127.0.0.${node}
 270     \    Add Binding    ${node}0    10.10.${node}0.0/24    127.0.0.${node}
 271     \    Add Binding    ${node}0    10.${node}0.0.0/16    127.0.0.${node}
 272     \    Add Binding    ${node}0    ${node}0.0.0.0/8    127.0.0.${node}
 273     Add Binding    10    10.10.10.10/32    127.0.0.1
 274     Add Binding    10    10.10.10.0/24    127.0.0.1
 275     Add Binding    10    10.10.0.0/16    127.0.0.1
 276     Add Binding    10    10.0.0.0/8    127.0.0.1
 277
 278 Verify Snapshot Was Pushed
 279     [Arguments]    ${snapshot_string}=22-sxp-controller-one-node.xml
 280     [Documentation]    Will succeed if the ${snapshot_string} is found in the karaf logs
 281     ${output}    Run Command On Controller    ${ODL_SYSTEM_IP}    cat ${WORKSPACE}/${BUNDLEFOLDER}/data/log/karaf.log* | grep -c 'Successfully pushed configuration snapshot.*${snapshot_string}'
 282     Should Not Be Equal As Strings    ${output}    0
 283
 284 Prepare SSH Keys On Karaf
 285     [Arguments]    ${system}=${ODL_SYSTEM_IP}    ${user}=${ODL_SYSTEM_USER}    ${passwd}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}    ${system_workspace}=${WORKSPACE}
 286     [Documentation]    Executes client login on karaf VM in so that SSH keys will be generated by defualt karaf callback,
 287     ...    expecting echo affter succesfull login. TODO: test on multiple runs if this aproach reduce SSHExceptions in robotframework
 288     ${stdout}    Run Command On Remote System    ${system}    ${system_workspace}${/}${BUNDLEFOLDER}/bin/client echo READY    ${user}    ${passwd}    prompt=${prompt}
 289     Should Match    "${stdout}"    "*READY"
 290
 291 Setup SXP Session
 292     [Arguments]    ${session}=session    ${controller}=${ODL_SYSTEM_IP}
 293     [Documentation]    Create session to Controller
 294     Verify Feature Is Installed    odl-sxp-controller    ${controller}
 295     Create Session    ${session}    url=http://${controller}:${RESTCONFPORT}    auth=${AUTH}    headers=${HEADERS_XML}
 296     ${resp}    RequestsLibrary.Get Request    ${session}    ${MODULES_API}
 297     Should Be Equal As Strings    ${resp.status_code}    200
 298     Should Contain    ${resp.content}    ietf-restconf
 299
 300 Clean SXP Session
 301     [Documentation]    Destroy created sessions
 302     Delete All Sessions
 303
 304 Add Domain
 305     [Arguments]    ${domain_name}    ${node}=127.0.0.1    ${session}=session
 306     [Documentation]    Add Domain via RPC
 307     ${DATA}    Add Domain Xml    ${node}    ${domain_name}
 308     Post To Controller    ${session}    add-domain    ${DATA}
 309
 310 Delete Domain
 311     [Arguments]    ${domain_name}    ${node}=127.0.0.1    ${session}=session
 312     [Documentation]    Delete Domain via RPC
 313     ${DATA}    Delete Domain Xml    ${node}    ${domain_name}
 314     Post To Controller    ${session}    delete-domain    ${DATA}
 315
 316 Add Bindings
 317     [Arguments]    ${sgt}    ${prefixes}    ${node}=127.0.0.1    ${session}=session    ${domain}=global
 318     [Documentation]    Add bindings via RPC to Master DB of node
 319     ${DATA}    Add Bindings Xml    ${node}    ${domain}    ${sgt}    ${prefixes}
 320     Post To Controller    ${session}    add-bindings    ${DATA}
 321
 322 Delete Bindings
 323     [Arguments]    ${sgt}    ${prefixes}    ${node}=127.0.0.1    ${session}=session    ${domain}=global
 324     [Documentation]    Delete bindings via RPC from Master DB of node
 325     ${DATA}    Delete Bindings Xml    ${node}    ${domain}    ${sgt}    ${prefixes}
 326     Post To Controller    ${session}    delete-bindings    ${DATA}
 327
 328 Add Bindings Range
 329     [Arguments]    ${sgt}    ${start}    ${size}    ${node}=127.0.0.1
 330     [Documentation]    Add Bindings to Node specified by range
 331     ${prefixes}    Prefix Range    ${start}    ${size}
 332     Add Bindings    ${sgt}    ${prefixes}    ${node}
 333
 334 Delete Bindings Range
 335     [Arguments]    ${sgt}    ${start}    ${size}    ${node}=127.0.0.1
 336     [Documentation]    Delete Bindings to Node specified by range
 337     ${prefixes}    Prefix Range    ${start}    ${size}
 338     Delete Bindings    ${sgt}    ${prefixes}    ${node}
 339
 340 Check Binding Range
 341     [Arguments]    ${sgt}    ${start}    ${end}    ${node}=127.0.0.1
 342     [Documentation]    Check if Node contains Bindings specified by range
 343     ${resp}    Get Bindings    ${node}
 344     : FOR    ${num}    IN RANGE    ${start}    ${end}
 345     \    ${ip}    Get Ip From Number    ${num}
 346     \    Should Contain Binding    ${resp}    ${sgt}    ${ip}/32
 347
 348 Check Binding Range Negative
 349     [Arguments]    ${sgt}    ${start}    ${end}    ${node}=127.0.0.1
 350     [Documentation]    Check if Node does not contains Bindings specified by range
 351     ${resp}    Get Bindings    ${node}
 352     : FOR    ${num}    IN RANGE    ${start}    ${end}
 353     \    ${ip}    Get Ip From Number    ${num}
 354     \    Should Not Contain Binding    ${resp}    ${sgt}    ${ip}/32
 355
 356 Setup SXP Environment
 357     [Arguments]    ${node_range}=2
 358     [Documentation]    Create session to Controller, node_range parameter specifies number of nodes to be created plus one
 359     Setup SXP Session
 360     : FOR    ${num}    IN RANGE    1    ${node_range}
 361     \    ${ip}    Get Ip From Number    ${num}
 362     \    CompareStream.Run_Keyword_If_At_Least_Boron    Add Node    ${ip}
 363     \    CompareStream.Run_Keyword_If_At_Least_Boron    Wait Until Keyword Succeeds    20    1    Check Node Started    ${ip}
 364
 365 Check Node Started
 366     [Arguments]    ${node}    ${port}=64999    ${system}=${ODL_SYSTEM_IP}    ${session}=session    ${ip}=${node}
 367     [Documentation]    Verify that SxpNode has data writed to Operational datastore
 368     ${resp}    RequestsLibrary.Get Request    ${session}    /restconf/operational/network-topology:network-topology/topology/sxp/node/${node}/
 369     Should Be Equal As Strings    ${resp.status_code}    200
 370     ${rc}    Run Command On Remote System    ${system}    netstat -tln | grep -q ${ip}:${port} && echo 0 || echo 1    ${ODL_SYSTEM_USER}    ${ODL_SYSTEM_PASSWORD}    prompt=${ODL_SYSTEM_PROMPT}
 371     Should Be Equal As Strings    ${rc}    0
 372
 373 Clean SXP Environment
 374     [Arguments]    ${node_range}=2
 375     [Documentation]    Destroy created sessions
 376     : FOR    ${num}    IN RANGE    1    ${node_range}
 377     \    ${ip}    Get Ip From Number    ${num}
 378     \    CompareStream.Run_Keyword_If_At_Least_Boron    Delete Node    ${ip}
 379     Clean SXP Session
 380
 381 Get Routing Configuration From Controller
 382     [Arguments]    ${session}
 383     [Documentation]    Get Routing configuration from config DS
 384     ${resp}    RequestsLibrary.Get Request    ${session}    /restconf/config/sxp-cluster-route:sxp-cluster-route/    headers=${ACCEPT_XML}
 385     ${data}    Set Variable If    "${resp.status_code}" == "200"    ${resp.content}    ${EMPTY}
 386     [Return]    ${data}
 387
 388 Put Routing Configuration To Controller
 389     [Arguments]    ${DATA}    ${session}
 390     [Documentation]    Put Routing configuration to Config DS
 391     ${resp}    RequestsLibrary.Put Request    ${session}    /restconf/config/sxp-cluster-route:sxp-cluster-route/    data=${DATA}    headers=${HEADERS_XML}
 392     Should Match    "${resp.status_code}"    "20?"
 393
 394 Clean Routing Configuration To Controller
 395     [Arguments]    ${session}
 396     [Documentation]    Delete Routing configuration from Config DS
 397     ${resp}    RequestsLibrary.Get Request    ${session}    /restconf/config/sxp-cluster-route:sxp-cluster-route/    headers=${ACCEPT_XML}
 398     Run Keyword If    "${resp.status_code}" == "200"    RequestsLibrary.Delete Request    ${session}    /restconf/config/sxp-cluster-route:sxp-cluster-route/