csit/libraries/SxpLib.robot

   1 *** Settings ***
   2 Documentation     Library containing Keywords used for SXP testing
   3 Library           Collections
   4 Library           RequestsLibrary
   5 Library           SSHLibrary
   6 Library           String
   7 Library           ./Sxp.py
   8 Resource          CompareStream.robot
   9 Resource          KarafKeywords.robot
  10 Resource          Utils.robot
  11 Resource          TemplatedRequests.robot
  12 Variables         ../variables/Variables.py
  13
  14 *** Variables ***
  15 ${REST_CONTEXT}    /restconf/operations/sxp-controller
  16
  17 *** Keywords ***
  18 Post To Controller
  19     [Arguments]    ${session}    ${path}    ${DATA}    ${rest_context}=${REST_CONTEXT}
  20     [Documentation]    Post request to Controller and checks response
  21     ${resp}    Post Request    ${session}    ${rest_context}:${path}    data=${DATA}    headers=${HEADERS_XML}
  22     Log    ${resp.content}
  23     Log    ${session}
  24     Log    ${path}
  25     Log    ${DATA}
  26     Should be Equal As Strings    ${resp.status_code}    200
  27     ${content}    Evaluate    json.loads('''${resp.content}''')    json
  28     ${output}    Get From Dictionary    ${content}    output
  29     ${result}    Get From Dictionary    ${output}    result
  30     Should Be True    ${result}    RPC result is False
  31
  32 Add Node
  33     [Arguments]    ${node}    ${password}=${EMPTY}    ${version}=version4    ${port}=64999    ${session}=session    ${ip}=${EMPTY}
  34     ...    ${ssl_stores}=${EMPTY}    ${retry_open_timer}=1
  35     [Documentation]    Add node via RPC to ODL
  36     ${DATA}    Add Node Xml    ${node}    ${port}    ${password}    ${version}    ${ip}
  37     ...    keystores=${ssl_stores}    retry_open_timer=${retry_open_timer}
  38     Post To Controller    ${session}    add-node    ${DATA}
  39
  40 Delete Node
  41     [Arguments]    ${node}    ${session}=session
  42     [Documentation]    Delete connection via RPC from node
  43     ${DATA}    Delete Node Xml    ${node}
  44     Post To Controller    ${session}    delete-node    ${DATA}
  45
  46 Add Connection
  47     [Arguments]    ${version}    ${mode}    ${ip}    ${port}    ${node}=127.0.0.1    ${password}=${EMPTY}
  48     ...    ${session}=session    ${domain}=global    ${security_mode}=${EMPTY}
  49     [Documentation]    Add connection via RPC to node
  50     ${DATA}    Add Connection Xml    ${version}    ${mode}    ${ip}    ${port}    ${node}
  51     ...    ${password}    ${domain}    security_mode=${security_mode}
  52     Post To Controller    ${session}    add-connection    ${DATA}
  53
  54 Get Connections
  55     [Arguments]    ${node}=127.0.0.1    ${session}=session    ${domain}=global
  56     [Documentation]    Gets all connections via RPC from node
  57     ${DATA}    Get Connections From Node Xml    ${node}    ${domain}
  58     ${resp}    Post Request    ${session}    ${REST_CONTEXT}:get-connections    data=${DATA}    headers=${HEADERS_XML}
  59     Should be Equal As Strings    ${resp.status_code}    200
  60     [Return]    ${resp.content}
  61
  62 Delete Connections
  63     [Arguments]    ${ip}    ${port}    ${node}=127.0.0.1    ${session}=session    ${domain}=global
  64     [Documentation]    Delete connection via RPC from node
  65     ${DATA}    Delete Connections Xml    ${ip}    ${port}    ${node}    ${domain}
  66     Post To Controller    ${session}    delete-connection    ${DATA}
  67
  68 Clean Connections
  69     [Arguments]    ${node}=127.0.0.1    ${session}=session    ${domain}=global
  70     [Documentation]    Delete all connections via RPC from node
  71     ${resp}    Get Connections    ${node}    ${session}    ${domain}
  72     @{connections}    Parse Connections    ${resp}
  73     : FOR    ${connection}    IN    @{connections}
  74     \    Delete Connections    ${connection['peer-address']}    ${connection['tcp-port']}    ${node}    ${session}    ${domain}
  75
  76 Verify Connection
  77     [Arguments]    ${version}    ${mode}    ${ip}    ${port}=64999    ${node}=127.0.0.1    ${state}=on
  78     ...    ${session}=session    ${domain}=global
  79     [Documentation]    Verify that connection is ON
  80     ${resp}    Get Connections    ${node}    ${session}    ${domain}
  81     Should Contain Connection    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}
  82
  83 Add Bindings
  84     [Arguments]    ${sgt}    ${prefixes}    ${node}=127.0.0.1    ${session}=session    ${domain}=global
  85     [Documentation]    Add/Update one or more bindings via RPC to Master DB of the node
  86     ${DATA}    Add Bindings Xml    ${node}    ${domain}    ${sgt}    ${prefixes}
  87     Post To Controller    ${session}    add-bindings    ${DATA}
  88
  89 Get Bindings
  90     [Arguments]    ${node}=127.0.0.1    ${session}=session    ${domain}=global    ${scope}=all
  91     [Documentation]    Gets all binding via RPC from Master DB of node
  92     ${DATA}    Get Bindings From Node Xml    ${node}    ${scope}    ${domain}
  93     ${resp}    TemplatedRequests.Post_To_Uri    ${REST_CONTEXT}:get-node-bindings    data=${DATA}    accept=${ACCEPT_JSON}    content_type=${HEADERS_XML}    session=${session}
  94     [Return]    ${resp}
  95
  96 Clean Bindings
  97     [Arguments]    ${node}=127.0.0.1    ${session}=session    ${domain}=global
  98     [Documentation]    Delete all bindings via RPC from Master DB of node
  99     ${resp}    Get Bindings    ${node}    ${session}    ${domain}    local
 100     @{bindings}    Parse Bindings    ${resp}
 101     : FOR    ${binding}    IN    @{bindings}
 102     \    Clean Binding Default    ${binding}    ${node}    ${session}    ${domain}
 103
 104 Clean Binding Default
 105     [Arguments]    ${binding}    ${node}    ${session}    ${domain}
 106     [Documentation]    Clean binding
 107     Clean Binding    ${binding['sgt']}    ${binding['ip-prefix']}    ${node}    ${session}
 108
 109 Clean Binding At Most Be
 110     [Arguments]    ${binding}    ${node}    ${session}    ${domain}
 111     [Documentation]    Clean binding
 112     Clean Binding    ${binding}    ${binding['binding']}    ${node}    ${session}
 113
 114 Clean Binding
 115     [Arguments]    ${sgt}    ${prefixes}    ${node}    ${session}    ${domain}=global
 116     [Documentation]    Used for nester FOR loop
 117     : FOR    ${prefix}    IN    @{prefixes}
 118     \    Delete Bindings    ${sgt}    ${prefix}    ${node}    ${domain}    ${session}
 119
 120 Delete Bindings
 121     [Arguments]    ${sgt}    ${prefixes}    ${node}=127.0.0.1    ${domain}=global    ${session}=session
 122     [Documentation]    Delete one or more bindings via RPC from Master DB of node
 123     ${DATA}    Delete Bindings Xml    ${node}    ${domain}    ${sgt}    ${prefixes}
 124     Post To Controller    ${session}    delete-bindings    ${DATA}
 125
 126 Add PeerGroup
 127     [Arguments]    ${name}    ${peers}=    ${node}=127.0.0.1    ${session}=session
 128     [Documentation]    Adds new PeerGroup via RPC to Node
 129     ${DATA}    Add Peer Group Xml    ${name}    ${peers}    ${node}
 130     Post To Controller    ${session}    add-peer-group    ${DATA}
 131
 132 Delete Peer Group
 133     [Arguments]    ${name}    ${node}=127.0.0.1    ${session}=session
 134     [Documentation]    Delete PeerGroup via RPC from Node
 135     ${DATA}    Delete Peer Group Xml    ${name}    ${node}
 136     Post To Controller    ${session}    delete-peer-group    ${DATA}
 137
 138 Get Peer Groups
 139     [Arguments]    ${node}=127.0.0.1    ${session}=session
 140     [Documentation]    Gets all PeerGroups via RPC from node
 141     ${DATA}    Get Peer Groups From Node Xml    ${node}
 142     ${resp}    Post Request    ${session}    ${REST_CONTEXT}:get-peer-groups    data=${DATA}    headers=${HEADERS_XML}
 143     Should be Equal As Strings    ${resp.status_code}    200
 144     [Return]    ${resp.content}
 145
 146 Clean Peer Groups
 147     [Arguments]    ${node}=127.0.0.1    ${session}=session
 148     [Documentation]    Delete all PeerGroups via RPC from node
 149     ${resp}    Get Peer Groups    ${node}    ${session}
 150     @{prefixes}    Parse Peer Groups    ${resp}
 151     : FOR    ${group}    IN    @{prefixes}
 152     \    Delete Peer Group    ${group['name']}    ${node}    ${session}
 153
 154 Add Filter
 155     [Arguments]    ${name}    ${type}    ${entries}    ${node}=127.0.0.1    ${session}=session    ${policy}=auto-update
 156     [Documentation]    Add Filter via RPC from Node
 157     ${DATA}    Run_Keyword_If_At_Least_Else    carbon    Add Filter Xml    ${name}    ${type}    ${entries}
 158     ...    ${node}    ${policy}
 159     ...    ELSE    Add Filter Xml    ${name}    ${type}    ${entries}    ${node}
 160     Post To Controller    ${session}    add-filter    ${DATA}
 161
 162 Add Domain Filter
 163     [Arguments]    ${name}    ${domains}    ${entries}    ${node}=127.0.0.1    ${filter_name}=base-domain-filter    ${session}=session
 164     [Documentation]    Add Domain Filter via RPC from Node
 165     ${DATA}    Add Domain Filter Xml    ${name}    ${domains}    ${entries}    ${node}    ${filter_name}
 166     Post To Controller    ${session}    add-domain-filter    ${DATA}
 167
 168 Delete Filter
 169     [Arguments]    ${name}    ${type}    ${node}=127.0.0.1    ${session}=session
 170     [Documentation]    Delete Filter via RPC from Node
 171     ${DATA}    Delete Filter Xml    ${name}    ${type}    ${node}
 172     Post To Controller    ${session}    delete-filter    ${DATA}
 173
 174 Delete Domain Filter
 175     [Arguments]    ${name}    ${node}=127.0.0.1    ${filter_name}=base-domain-filter    ${session}=session
 176     [Documentation]    Delete Filter via RPC from Node
 177     ${DATA}    Delete Domain Filter Xml    ${name}    ${node}    ${filter_name}
 178     Post To Controller    ${session}    delete-domain-filter    ${DATA}
 179
 180 Should Contain Binding
 181     [Arguments]    ${resp}    ${sgt}    ${prefix}    ${db_source}=any
 182     [Documentation]    Tests if data contains specified binding
 183     ${out}    Find Binding    ${resp}    ${sgt}    ${prefix}
 184     Should Be True    ${out}    Doesn't have ${sgt} ${prefix}
 185
 186 Should Not Contain Binding
 187     [Arguments]    ${resp}    ${sgt}    ${prefix}    ${db_source}=any
 188     [Documentation]    Tests if data doesn't contains specified binding
 189     ${out}    Find Binding    ${resp}    ${sgt}    ${prefix}
 190     Should Not Be True    ${out}    Should't have ${sgt} ${prefix}
 191
 192 Should Contain Connection
 193     [Arguments]    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}=none
 194     [Documentation]    Test if data contains specified connection
 195     ${out}    Find Connection    ${resp}    ${version}    ${mode}    ${ip}    ${port}
 196     ...    ${state}
 197     Should Be True    ${out}    Doesn't have ${ip}:${port} ${mode} ${version}
 198
 199 Should Not Contain Connection
 200     [Arguments]    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}=none
 201     [Documentation]    Test if data doesn't contains specified connection
 202     ${out}    Find Connection    ${resp}    ${version}    ${mode}    ${ip}    ${port}
 203     ...    ${state}
 204     Should Not Be True    ${out}    Shouldn't have ${ip}:${port} ${mode} ${version}
 205
 206 Bindings Should Contain
 207     [Arguments]    ${sgt}    ${prefix}    ${db_source}=any
 208     [Documentation]    Retrieves bindings and verifies they contain given binding
 209     ${resp}    Get Bindings
 210     Should Contain Binding    ${resp}    ${sgt}    ${prefix}    ${db_source}
 211
 212 Bindings Should Not Contain
 213     [Arguments]    ${sgt}    ${prefix}    ${db_source}=any
 214     [Documentation]    Retrieves bindings and verifies they do not contain given binding
 215     ${resp}    Get Bindings
 216     Should Not Contain Binding    ${resp}    ${sgt}    ${prefix}    ${db_source}
 217
 218 Connections Should Contain
 219     [Arguments]    ${ip}    ${port}    ${mode}    ${version}    ${state}=none
 220     [Documentation]    Retrieves connections and verifies they contain given connection
 221     ${resp}    Get Connections
 222     Should Contain Connection    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}
 223
 224 Connections Should Not Contain
 225     [Arguments]    ${ip}    ${port}    ${mode}    ${version}    ${state}=none
 226     [Documentation]    Retrieves connections and verifies they do not contain given connection
 227     ${resp}    Get Connections
 228     Should Not Contain Connection    ${resp}    ${ip}    ${port}    ${mode}    ${version}    ${state}
 229
 230 Setup Topology Complex
 231     [Arguments]    ${version}=version4    ${PASSWORD}=none
 232     : FOR    ${node}    IN RANGE    2    6
 233     \    Add Connection    ${version}    both    127.0.0.1    64999    127.0.0.${node}
 234     \    ...    ${PASSWORD}
 235     \    Add Connection    ${version}    both    127.0.0.${node}    64999    127.0.0.1
 236     \    ...    ${PASSWORD}
 237     \    Wait Until Keyword Succeeds    15    1    Verify Connection    ${version}    both
 238     \    ...    127.0.0.${node}
 239     \    Add Bindings    ${node}0    10.10.10.${node}0/32    127.0.0.${node}
 240     \    Add Bindings    ${node}0    10.10.${node}0.0/24    127.0.0.${node}
 241     \    Add Bindings    ${node}0    10.${node}0.0.0/16    127.0.0.${node}
 242     \    Add Bindings    ${node}0    ${node}0.0.0.0/8    127.0.0.${node}
 243     Add Bindings    10    10.10.10.10/32    127.0.0.1
 244     Add Bindings    10    10.10.10.0/24    127.0.0.1
 245     Add Bindings    10    10.10.0.0/16    127.0.0.1
 246     Add Bindings    10    10.0.0.0/8    127.0.0.1
 247
 248 Verify Snapshot Was Pushed
 249     [Arguments]    ${snapshot_string}=22-sxp-controller-one-node.xml
 250     [Documentation]    Will succeed if the ${snapshot_string} is found in the karaf logs
 251     ${output}    Run Command On Controller    ${ODL_SYSTEM_IP}    cat ${WORKSPACE}/${BUNDLEFOLDER}/data/log/karaf.log* | grep -c 'Successfully pushed configuration snapshot.*${snapshot_string}'
 252     Should Not Be Equal As Strings    ${output}    0
 253
 254 Prepare SSH Keys On Karaf
 255     [Arguments]    ${system}=${ODL_SYSTEM_IP}    ${user}=${ODL_SYSTEM_USER}    ${passwd}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}    ${system_workspace}=${WORKSPACE}
 256     [Documentation]    Executes client login on karaf VM in so that SSH keys will be generated by defualt karaf callback,
 257     ...    expecting echo affter succesfull login. TODO: test on multiple runs if this aproach reduce SSHExceptions in robotframework
 258     ${stdout}    Run Command On Remote System    ${system}    ${system_workspace}${/}${BUNDLEFOLDER}/bin/client echo READY    ${user}    ${passwd}    prompt=${prompt}
 259     Should Match    "${stdout}"    "*READY"
 260
 261 Setup SXP Session
 262     [Arguments]    ${session}=session    ${controller}=${ODL_SYSTEM_IP}
 263     [Documentation]    Create session to Controller
 264     Verify Feature Is Installed    odl-sxp-controller    ${controller}
 265     Create Session    ${session}    url=http://${controller}:${RESTCONFPORT}    auth=${AUTH}    headers=${HEADERS_XML}
 266     ${resp}    RequestsLibrary.Get Request    ${session}    ${MODULES_API}
 267     Should Be Equal As Strings    ${resp.status_code}    200
 268     Should Contain    ${resp.content}    ietf-restconf
 269
 270 Clean SXP Session
 271     [Documentation]    Destroy created sessions
 272     Delete All Sessions
 273
 274 Add Domain
 275     [Arguments]    ${domain_name}    ${node}=127.0.0.1    ${session}=session
 276     [Documentation]    Add Domain via RPC
 277     ${DATA}    Add Domain Xml    ${node}    ${domain_name}
 278     Post To Controller    ${session}    add-domain    ${DATA}
 279
 280 Delete Domain
 281     [Arguments]    ${domain_name}    ${node}=127.0.0.1    ${session}=session
 282     [Documentation]    Delete Domain via RPC
 283     ${DATA}    Delete Domain Xml    ${node}    ${domain_name}
 284     Post To Controller    ${session}    delete-domain    ${DATA}
 285
 286 Add Bindings Range
 287     [Arguments]    ${sgt}    ${start}    ${size}    ${node}=127.0.0.1
 288     [Documentation]    Add Bindings to Node specified by range
 289     ${prefixes}    Prefix Range    ${start}    ${size}
 290     Add Bindings    ${sgt}    ${prefixes}    ${node}
 291
 292 Delete Bindings Range
 293     [Arguments]    ${sgt}    ${start}    ${size}    ${node}=127.0.0.1
 294     [Documentation]    Delete Bindings to Node specified by range
 295     ${prefixes}    Prefix Range    ${start}    ${size}
 296     Delete Bindings    ${sgt}    ${prefixes}    ${node}
 297
 298 Check Binding Range
 299     [Arguments]    ${sgt}    ${start}    ${end}    ${node}=127.0.0.1
 300     [Documentation]    Check if Node contains Bindings specified by range
 301     ${resp}    Get Bindings    ${node}
 302     : FOR    ${num}    IN RANGE    ${start}    ${end}
 303     \    ${ip}    Get Ip From Number    ${num}
 304     \    Should Contain Binding    ${resp}    ${sgt}    ${ip}/32
 305
 306 Check Binding Range Negative
 307     [Arguments]    ${sgt}    ${start}    ${end}    ${node}=127.0.0.1
 308     [Documentation]    Check if Node does not contains Bindings specified by range
 309     ${resp}    Get Bindings    ${node}
 310     : FOR    ${num}    IN RANGE    ${start}    ${end}
 311     \    ${ip}    Get Ip From Number    ${num}
 312     \    Should Not Contain Binding    ${resp}    ${sgt}    ${ip}/32
 313
 314 Setup SXP Environment
 315     [Arguments]    ${node_range}=2
 316     [Documentation]    Create session to Controller, node_range parameter specifies number of nodes to be created plus one
 317     Setup SXP Session
 318     : FOR    ${num}    IN RANGE    1    ${node_range}
 319     \    ${ip}    Get Ip From Number    ${num}
 320     \    ${rnd_retry_time} =    Evaluate    random.randint(1, 10)    modules=random
 321     \    Add Node    ${ip}    retry_open_timer=${rnd_retry_time}
 322     \    Wait Until Keyword Succeeds    20    1    Check Node Started    ${ip}
 323
 324 Check Node Started
 325     [Arguments]    ${node}    ${port}=64999    ${system}=${ODL_SYSTEM_IP}    ${session}=session    ${ip}=${node}
 326     [Documentation]    Verify that SxpNode has data writed to Operational datastore
 327     ${resp}    RequestsLibrary.Get Request    ${session}    /restconf/operational/network-topology:network-topology/topology/sxp/node/${node}/
 328     Should Be Equal As Strings    ${resp.status_code}    200
 329     ${rc}    Run Command On Remote System    ${system}    netstat -tln | grep -q ${ip}:${port} && echo 0 || echo 1    ${ODL_SYSTEM_USER}    ${ODL_SYSTEM_PASSWORD}    prompt=${ODL_SYSTEM_PROMPT}
 330     Should Be Equal As Strings    ${rc}    0
 331
 332 Clean SXP Environment
 333     [Arguments]    ${node_range}=2
 334     [Documentation]    Destroy created sessions
 335     : FOR    ${num}    IN RANGE    1    ${node_range}
 336     \    ${ip}    Get Ip From Number    ${num}
 337     \    Delete Node    ${ip}
 338     Clean SXP Session
 339
 340 Get Routing Configuration From Controller
 341     [Arguments]    ${session}
 342     [Documentation]    Get Routing configuration from config DS
 343     ${resp}    RequestsLibrary.Get Request    ${session}    /restconf/config/sxp-cluster-route:sxp-cluster-route/    headers=${ACCEPT_XML}
 344     ${data}    Set Variable If    "${resp.status_code}" == "200"    ${resp.content}    ${EMPTY}
 345     [Return]    ${data}
 346
 347 Put Routing Configuration To Controller
 348     [Arguments]    ${DATA}    ${session}
 349     [Documentation]    Put Routing configuration to Config DS
 350     ${resp}    RequestsLibrary.Put Request    ${session}    /restconf/config/sxp-cluster-route:sxp-cluster-route/    data=${DATA}    headers=${HEADERS_XML}
 351     Should Match    "${resp.status_code}"    "20?"
 352
 353 Clean Routing Configuration To Controller
 354     [Arguments]    ${session}
 355     [Documentation]    Delete Routing configuration from Config DS
 356     ${resp}    RequestsLibrary.Get Request    ${session}    /restconf/config/sxp-cluster-route:sxp-cluster-route/    headers=${ACCEPT_XML}
 357     Run Keyword If    "${resp.status_code}" == "200"    RequestsLibrary.Delete Request    ${session}    /restconf/config/sxp-cluster-route:sxp-cluster-route/