csit/libraries/Tempest.robot

   1 *** Settings ***
   2 Documentation     General Utils library. This library has broad scope, it can be used by any robot system tests.
   3 Library           SSHLibrary
   4 Resource          DevstackUtils.robot
   5 Resource          OpenStackOperations.robot
   6 Resource          SSHKeywords.robot
   7 Resource          ../variables/Variables.robot
   8
   9 *** Variables ***
  10 @{stable/queens_EXCLUSION_REGEXES}    ${EMPTY}
  11 @{master_EXCLUSION_REGEXES}    ${EMPTY}
  12 ${BLACKLIST_FILE}    /tmp/blacklist.txt
  13 ${TEMPEST_DIR}    /opt/stack/tempest
  14 ${TEMPEST_CONFIG_FILE}    ${TEMPEST_DIR}/etc/tempest.conf
  15 # Parameter values below are based on releng/builder - changing them requires updates in releng/builder as well
  16 ${TEMPEST_TIMEOUT}    420s
  17
  18 *** Keywords ***
  19 Suite Setup
  20     OpenStackOperations.OpenStack Suite Setup
  21     Tempest.Log In To Tempest Executor And Setup Test Environment
  22
  23 Run Tempest Tests
  24     [Arguments]    ${tempest_regex}    ${timeout}=${TEMPEST_TIMEOUT}    ${debug}=False
  25     BuiltIn.Run Keyword If    "${debug}" == "False"    Tempest.Run Tempest Tests Without Debug    ${tempest_regex}    timeout=${timeout}
  26     BuiltIn.Run Keyword If    "${debug}" == "True"    Tempest.Run Tempest Tests With Debug    ${tempest_regex}    timeout=${timeout}
  27     BuiltIn.Run Keyword If    "${debug}" != "True" and "${debug}" != "False"    Fail    debug argument must be True or False
  28
  29 Run Tempest Tests Without Debug
  30     [Arguments]    ${tempest_regex}    ${TEMPEST_DIRectory}=${TEMPEST_DIR}    ${timeout}=${TEMPEST_TIMEOUT}
  31     [Documentation]    Using ostestr will allow us to (by default) run tests in paralllel.
  32     ...    Because of the parallel fashion, we must ensure there is no pause on teardown so that flag in tempest.conf is
  33     ...    explicitly set to False.
  34     BuiltIn.Return From Keyword If    "skip_if_${OPENSTACK_BRANCH}" in @{TEST_TAGS}
  35     BuiltIn.Return From Keyword If    "skip_if_${SECURITY_GROUP_MODE}" in @{TEST_TAGS}
  36     BuiltIn.Return From Keyword If    "skip_if_${ODL_SNAT_MODE}" in @{TEST_TAGS}
  37     ${tempest_conn_id} =    SSHLibrary.Open Connection    ${OS_CNTL_IP}    prompt=${DEFAULT_LINUX_PROMPT_STRICT}
  38     SSHKeywords.Flexible SSH Login    ${OS_USER}    ${DEVSTACK_SYSTEM_PASSWORD}
  39     DevstackUtils.Write Commands Until Prompt    source ${DEVSTACK_DEPLOY_PATH}/openrc admin admin
  40     DevstackUtils.Write Commands Until Prompt    cd ${TEMPEST_DIRectory}
  41     SSHLibrary.Read
  42     Tempest.Tempest Conf Modify Pause On Test Teardown    False
  43     SSHLibrary.Set Client Configuration    timeout=${timeout}
  44     # There are tons of deprecation error messages when we use ostestr in our CSIT environment (openstack via devstack)
  45     # The robot log files are very large and one culprit is all these deprecation warnings. If we redirect stderr to
  46     # /dev/null we should be able to ignore them. We will miss any other errors, however.
  47     ${output} =    DevstackUtils.Write Commands Until Prompt And Log    ostestr --regex ${tempest_regex}    timeout=${timeout}
  48     SSHLibrary.Close Connection
  49     BuiltIn.Should Contain    ${output}    Failed: 0
  50
  51 Run Tempest Tests With Debug
  52     [Arguments]    ${tempest_regex}    ${TEMPEST_DIRectory}=${TEMPEST_DIR}    ${timeout}=${TEMPEST_TIMEOUT}
  53     [Documentation]    After setting pause_teardown=True in tempest.conf, use the python -m testtools.run module to execute
  54     ...    a single tempest test case. We need to run only one tempest test case at a time as there will
  55     ...    be potentional for an unkown number of debug pdb() prompts to catch and continue if we are running multiple
  56     ...    test cases with a single command. Essentially, this keyword only handles one breakpoint at a single teardown.
  57     BuiltIn.Return From Keyword If    "skip_if_${OPENSTACK_BRANCH}" in @{TEST_TAGS}
  58     BuiltIn.Return From Keyword If    "skip_if_${SECURITY_GROUP_MODE}" in @{TEST_TAGS}
  59     BuiltIn.Return From Keyword If    "skip_if_${ODL_SNAT_MODE}" in @{TEST_TAGS}
  60     ${tempest_conn_id} =    SSHLibrary.Open Connection    ${OS_CNTL_IP}    prompt=${DEFAULT_LINUX_PROMPT_STRICT}
  61     SSHKeywords.Flexible SSH Login    ${OS_USER}    ${DEVSTACK_SYSTEM_PASSWORD}
  62     DevstackUtils.Write Commands Until Prompt    source ${DEVSTACK_DEPLOY_PATH}/openrc admin admin
  63     DevstackUtils.Write Commands Until Prompt    cd ${TEMPEST_DIRectory}
  64     SSHLibrary.Read
  65     Tempest Conf Modify Pause On Test Teardown    True
  66     SSHLibrary.Set Client Configuration    timeout=${timeout}
  67     SSHLibrary.Write    python -m testtools.run ${tempest_regex}
  68     ${output} =    SSHLibrary.Read Until Regexp    ${DEFAULT_LINUX_PROMPT_STRICT}|pdb.set_trace()
  69     BuiltIn.Log    ${output}
  70     OpenStackOperations.Show Debugs
  71     OpenStackOperations.Get Test Teardown Debugs
  72     SSHLibrary.Switch Connection    ${tempest_conn_id}
  73     SSHLibrary.Write    continue
  74     ${output} =    SSHLibrary.Read Until Regexp    ${DEFAULT_LINUX_PROMPT_STRICT}|pdb.set_trace()
  75     BuiltIn.Log    ${output}
  76     SSHLibrary.Write    continue
  77     ${output} =    SSHLibrary.Read Until Prompt
  78     BuiltIn.Log    ${output}
  79     SSHLibrary.Close Connection
  80     BuiltIn.Should Contain    ${output}    OK
  81     BuiltIn.Should Not Contain    ${output}    FAILED
  82
  83 Log In To Tempest Executor And Setup Test Environment
  84     [Documentation]    Initialize SetupUtils, open SSH connection to a devstack system and source the openstack
  85     ...    credentials needed to run the tempest tests. The (sometimes empty) tempest blacklist file will be created
  86     ...    and pushed to the tempest executor.
  87     Tempest.Create Blacklist File
  88     # Tempest tests need an existing external network in order to create routers.
  89     OpenStackOperations.Create Network    ${EXTERNAL_NET_NAME}    --external --default --provider-network-type flat --provider-physical-network ${PUBLIC_PHYSICAL_NETWORK}
  90     OpenStackOperations.Create Subnet    ${EXTERNAL_NET_NAME}    ${EXTERNAL_SUBNET_NAME}    ${EXTERNAL_SUBNET}    --gateway ${EXTERNAL_GATEWAY} --allocation-pool ${EXTERNAL_SUBNET_ALLOCATION_POOL}
  91     OpenStackOperations.List Networks
  92     ${control_node_conn_id} =    SSHLibrary.Open Connection    ${OS_CNTL_IP}    prompt=${DEFAULT_LINUX_PROMPT_STRICT}
  93     SSHKeywords.Flexible SSH Login    ${OS_USER}
  94     DevstackUtils.Write Commands Until Prompt And Log    sudo pip install -U --verbose pip    timeout=120s
  95     DevstackUtils.Write Commands Until Prompt And Log    sudo pip install -U --verbose os-testr>=1.0.0    timeout=120s
  96     DevstackUtils.Write Commands Until Prompt And Log    ostestr --version
  97     DevstackUtils.Write Commands Until Prompt And Log    testr init
  98     DevstackUtils.Write Commands Until Prompt    source ${DEVSTACK_DEPLOY_PATH}/openrc admin admin
  99     DevstackUtils.Write Commands Until Prompt    sudo rm -rf /opt/stack/tempest/.testrepository
 100     ${net_id} =    OpenStackOperations.Get Net Id    ${EXTERNAL_NET_NAME}
 101     Tempest.Tempest Conf Add External Network And Floating Network Name    ${net_id}
 102
 103 Tempest Conf Add External Network And Floating Network Name
 104     [Arguments]    ${external_network_id}
 105     [Documentation]    Tempest will be run with a config file - this function will add the
 106     ...    given external network ID to the configuration file.
 107     Tempest.Modify Config In File On Existing SSH Connection    ${TEMPEST_CONFIG_FILE}    set    network    public_network_id    ${external_network_id}
 108     Tempest.Modify Config In File On Existing SSH Connection    ${TEMPEST_CONFIG_FILE}    set    DEFAULT    debug    False
 109     Tempest.Modify Config In File On Existing SSH Connection    ${TEMPEST_CONFIG_FILE}    set    DEFAULT    log_level    INFO
 110     Tempest.Modify Config In File On Existing SSH Connection    ${TEMPEST_CONFIG_FILE}    set    network    floating_network_name    ${EXTERNAL_NET_NAME}
 111     DevstackUtils.Write Commands Until Prompt    sudo cat ${TEMPEST_CONFIG_FILE}
 112     DevstackUtils.Write Commands Until Prompt    sudo chmod 777 ${TEMPEST_CONFIG_FILE}
 113
 114 Tempest Conf Modify Pause On Test Teardown
 115     [Arguments]    ${pause_flag}
 116     [Documentation]    Sets the DEFAULT section flag for pausing the test teardown. If True the tempest test case
 117     ...    being executed will break to a pdb() debug shell when it hits it's teardown() function.
 118     Tempest.Modify Config In File On Existing SSH Connection    ${TEMPEST_CONFIG_FILE}    set    DEFAULT    pause_teardown    ${pause_flag}
 119
 120 Modify Config In File On Existing SSH Connection
 121     [Arguments]    ${config_file}    ${modifier}    ${config_section}    ${config_key}    ${config_value}=${EMPTY}
 122     [Documentation]    uses crudini to populate oslo cofg file.
 123     # this keyword is only one line so seems like extra overhead, but this may be a good candidate to move
 124     # to a library at some point, when/if other suites need to use it, so wanted to make it generic.
 125     DevstackUtils.Write Commands Until Prompt    sudo -E crudini --${modifier} ${config_file} ${config_section} ${config_key} ${config_value}
 126
 127 Create Blacklist File
 128     [Documentation]    For each exclusion regex in the required @{${OPENSTACK_BRANCH}_EXCLUSION_REGEXES} list a new
 129     ...    line will be created in the required ${BLACKLIST_FILE} location. This file is pushed to the OS_CONTROL_NODE
 130     ...    which is assumed to be the tempest executor.
 131     OperatingSystem.Create File    ${BLACKLIST_FILE}
 132     : FOR    ${exclusion}    IN    @{${OPENSTACK_BRANCH}_EXCLUSION_REGEXES}
 133     \    OperatingSystem.Append To File    ${BLACKLIST_FILE}    ${exclusion}\n
 134     OperatingSystem.Log File    ${BLACKLIST_FILE}
 135     SSHKeywords.Copy File To Remote System    ${OS_CNTL_IP}    ${BLACKLIST_FILE}    ${BLACKLIST_FILE}