csit/libraries/TopoprocessingKeywords.robot

   1 *** Settings ***
   2 Variables         ../variables/Variables.py
   3 Variables         ../variables/topoprocessing/Topologies.py
   4 Variables         ../variables/topoprocessing/TopologyRequests.py
   5 Library           RequestsLibrary
   6 Library           SSHLibrary
   7 Library           XML
   8 Resource          KarafKeywords.robot
   9 Resource          SetupUtils.robot
  10 Resource          Utils.robot
  11
  12 *** Variables ***
  13 ${CONFIGURATION_XML}    ${CURDIR}/../suites/topoprocessing/configuration.xml
  14 ${OPERATIONAL_XML}    ${CURDIR}/../suites/topoprocessing/operational.xml
  15 ${CONFIGURATION_CFG}    ${CURDIR}/../suites/topoprocessing/configuration.cfg
  16 ${OPERATIONAL_CFG}    ${CURDIR}/../suites/topoprocessing/operational.cfg
  17 ${REMOTE_XML_FILE}    ${WORKSPACE}/${BUNDLEFOLDER}/etc/opendaylight/karaf/80-topoprocessing-config.xml
  18 ${REMOTE_CFG_FILE}    ${WORKSPACE}/${BUNDLEFOLDER}/etc/org.opendaylight.topoprocessing.cfg
  19 ${OUTPUT_TOPO_NAME}    topo:1
  20 ${OVERLAY_TOPO_URL}    ${TOPOLOGY_URL}/${OUTPUT_TOPO_NAME}
  21
  22 *** Keywords ***
  23 Basic Request Put
  24     [Arguments]    ${request}    ${overlay_topology_url}
  25     [Documentation]    Send a simple HTTP PUT request to Configurational datastore
  26     ${resp}    Put Request    session    ${CONFIG_API}/${overlay_topology_url}    data=${request}
  27     Log    ${CONFIG_API}/${overlay_topology_url}
  28     Should Match    "${resp.status_code}"    "20?"
  29     Wait For Karaf Log    Correlation configuration successfully read
  30     Wait For Karaf Log    Transaction successfully written
  31
  32 Basic Request Get
  33     [Arguments]    ${overlay_topology_url}
  34     [Documentation]    Send a simple HTTP GET request to a given URL
  35     ${resp}    Get Request    session    ${OPERATIONAL_API}/${overlay_topology_url}
  36     Should Be Equal As Strings    ${resp.status_code}    200
  37     [Return]    ${resp}
  38
  39 Send Basic Delete Request
  40     [Arguments]    ${url}
  41     [Documentation]    Sends a HTTP/DELETE request to a given URL
  42     ${resp}    Delete Request    session    ${CONFIG_API}/${url}
  43     Log    Deleting ${CONFIG_API}/${url}
  44     [Return]    ${resp}
  45
  46 Delete Underlay Node
  47     [Arguments]    ${topology-id}    ${node-id}
  48     [Documentation]    Deletes a node from an underlay topology
  49     ${resp}    Send Basic Delete Request    ${TOPOLOGY_URL}/${topology-id}/node/${node-id}
  50     [Return]    ${resp}
  51
  52 Delete Underlay Termination Point
  53     [Arguments]    ${topology-id}    ${node-id}    ${tp-id}
  54     [Documentation]    Deletes a termination point from an underlay topology
  55     ${resp}    Send Basic Delete Request    ${TOPOLOGY_URL}/${topology-id}/node/${node-id}/termination-point/${tp-id}
  56     [Return]    ${resp}
  57
  58 Delete Underlay Link
  59     [Arguments]    ${topology-id}    ${link-id}
  60     [Documentation]    Deletes a link from an underlay topology
  61     ${resp}    Send Basic Delete Request    ${TOPOLOGY_URL}/${topology-id}/link/${link-id}
  62     [Return]    ${resp}
  63
  64 Setup Environment
  65     [Documentation]    Setup karaf enviroment for following tests
  66     Log    ---- Setup Environment ----
  67     SetupUtils.Setup_Utils_For_Setup_And_Teardown
  68     Open Connection    ${ODL_SYSTEM_IP}
  69     Flexible Controller Login
  70     Run Keyword If    '${ODL_STREAM}' == 'carbon'    Put File    ${CONFIGURATION_CFG}    ${REMOTE_CFG_FILE}
  71     Run Keyword Unless    '${ODL_STREAM}' == 'carbon'    Put File    ${CONFIGURATION_XML}    ${REMOTE_XML_FILE}
  72     Close Connection
  73     Wait Until Keyword Succeeds    2x    2s    Issue Command On Karaf Console    log:set DEBUG org.opendaylight.topoprocessing
  74     Install a Feature    odl-restconf-noauth    timeout=30
  75     Create Session    session    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    headers=${SEND_ACCEPT_XML_HEADERS}
  76     Install Features    odl-openflowplugin-nsf-model odl-topoprocessing-framework odl-topoprocessing-network-topology odl-topoprocessing-inventory odl-mdsal-models odl-ovsdb-southbound-impl
  77     Prepare New Feature Installation
  78     Insert Underlay topologies
  79
  80 Install Features
  81     [Arguments]    ${features}    ${timeout}=180
  82     [Documentation]    Install features according to tested distribution
  83     Run Keyword If    '${ODL_STREAM}' == 'beryllium'    Install Features for Beryllium Distribution    ${features}    ${timeout}
  84     ...    ELSE    Install Features for Other Distributions    ${features}    ${timeout}
  85
  86 Install Features for Beryllium Distribution
  87     [Arguments]    ${features}    ${timeout}
  88     [Documentation]    Will wait for features to install only once per run
  89     Install a Feature    ${features}    timeout=${timeout}
  90     Set Global Variable If It Does Not Exist    \${WAIT_FOR_FEATURES_TO_INSTALL}    ${TRUE}
  91     Run Keyword If    ${WAIT_FOR_FEATURES_TO_INSTALL}    Run Keywords    Wait For Karaf Log    Registering Topology Request Listener    ${timeout}
  92     ...    AND    Set Global Variable    \${WAIT_FOR_FEATURES_TO_INSTALL}    ${FALSE}
  93
  94 Install Features for Other Distributions
  95     [Arguments]    ${features}    ${timeout}
  96     [Documentation]    Will wait for features to install only if no topoprocessing feature was installed
  97     ${installed_features}    Issue Command On Karaf Console    feature:list -i
  98     ${lines}    Get Lines Containing String    ${installed_features}    odl-topoprocessing-framework
  99     ${length}    Get Length    ${lines}
 100     Install a Feature    ${features}    timeout=${timeout}
 101     Run Keyword If    ${length} == 0    Wait For Karaf Log    Registering Topology Request Listener    ${timeout}
 102
 103 Clean Environment
 104     [Documentation]    Revert startup changes
 105     Log    ---- Clean Environment ----
 106     Open Connection    ${ODL_SYSTEM_IP}
 107     Flexible Controller Login
 108     Run Keyword If    '${ODL_STREAM}' == 'carbon'    Put File    ${OPERATIONAL_CFG}    ${REMOTE_CFG_FILE}
 109     Run Keyword Unless    '${ODL_STREAM}' == 'carbon'    Put File    ${OPERATIONAL_XML}    ${REMOTE_XML_FILE}
 110     Close Connection
 111     Delete All Sessions
 112
 113 Delete Overlay Topology
 114     [Documentation]    Delete overlay topologies from datastore
 115     Run Keyword If Test Failed    Print Output Topo
 116     Log    ---- Test Teardown ----
 117     Log    Deleting overlay topology from ${CONFIG_API}/${OVERLAY_TOPO_URL}
 118     ${resp}    Delete Request    session    ${CONFIG_API}/${OVERLAY_TOPO_URL}
 119     Should Be Equal As Strings    ${resp.status_code}    200
 120
 121 Print Output Topo
 122     [Documentation]    Waits a while to allow any hanging transactions to finnish and then logs the output topology
 123     Log    ---- Output Topo Dump After Cooldown----
 124     Sleep    2s
 125     ${resp}    Wait Until Keyword Succeeds    5x    250ms    Basic Request Get    ${OVERLAY_TOPO_URL}
 126     Log    ${resp.content}
 127
 128 Refresh Underlay Topologies And Delete Overlay Topology
 129     [Documentation]    Deletes given overlay topology from datastore and overwrites the underlaying ones with initial topologies
 130     Delete Overlay Topology
 131     Insert Underlay Topologies
 132
 133 Prepare New Feature Installation
 134     [Documentation]    Clears karaf logs and CONFIGURATION datastore
 135     ${resp}    Delete Request    session    ${CONFIG_API}/network-topology:network-topology
 136     ${resp}    Delete Request    session    ${CONFIG_API}/opendaylight-inventory:nodes
 137     Issue Command On Karaf Console    log:clear
 138
 139 Insert Underlay Topologies
 140     [Documentation]    Insert underlay topologies used by following tests
 141     Log    Inserting underlay topologies
 142     # Network underlay topologies
 143     : FOR    ${index}    IN RANGE    1    7
 144     \    ${resp}    Put Request    session    ${CONFIG_API}/${TOPOLOGY_URL}/network-topo:${index}    data=${NETWORK_UNDERLAY_TOPOLOGY_${index}}
 145     \    Log    ${resp.content}
 146     \    Should Match    "${resp.status_code}"    "20?"
 147     # Openflow underlay nodes
 148     ${resp}    Put Request    session    ${CONFIG_API}/opendaylight-inventory:nodes    data=${OPENFLOW_UNDERLAY_NODES}
 149     Log    ${resp.content}
 150     Should Match    "${resp.status_code}"    "20?"
 151     # Openflow underlay topologies
 152     : FOR    ${index}    IN RANGE    1    7
 153     \    ${resp}    Put Request    session    ${CONFIG_API}/${TOPOLOGY_URL}/openflow-topo:${index}    data=${OPENFLOW_UNDERLAY_TOPOLOGY_${index}}
 154     \    Log    ${resp.content}
 155     \    Should Match    "${resp.status_code}"    "20?"
 156     Issue Command On Karaf Console    log:clear
 157     Log    ${resp.content}
 158
 159 Prepare Unification Inside Topology Request
 160     [Arguments]    ${request_template}    ${model}    ${correlation_item}    ${underlay_topo1}
 161     [Documentation]    Prepare topology request for unification inside from template
 162     ${request_template}    Set Element Text    ${request_template}    ${model}    xpath=.//correlations/output-model
 163     ${request_template}    Set Element Text    ${request_template}    aggregation-only    xpath=.//correlations/correlation/type
 164     ${request_template}    Set Element Text    ${request_template}    ${correlation_item}    xpath=.//correlation/correlation-item
 165     ${request_template}    Set Element Text    ${request_template}    unification    xpath=.//correlation/aggregation/aggregation-type
 166     ${request_template}    Set Element Text    ${request_template}    ${model}    xpath=.//correlation/aggregation/mapping[1]/input-model
 167     ${request_template}    Set Element Text    ${request_template}    ${underlay_topo1}    xpath=.//correlation/aggregation/mapping[1]/underlay-topology
 168     ${request_template}    Element to String    ${request_template}
 169     [Return]    ${request_template}
 170
 171 Prepare Unification Topology Request
 172     [Arguments]    ${request_template}    ${model}    ${correlation_item}    ${underlay_topo1}    ${underlay_topo2}
 173     [Documentation]    Prepare topology request for unification on two topologies from template
 174     ${request_template}    Prepare Unification Inside Topology Request    ${request_template}    ${model}    ${correlation_item}    ${underlay_topo1}
 175     ${request_template}    Set Element Text    ${request_template}    ${underlay_topo2}    xpath=.//correlation/aggregation/mapping[2]/underlay-topology
 176     ${request_template}    Set Element Text    ${request_template}    ${model}    xpath=.//correlation/aggregation/mapping[2]/input-model
 177     ${request_template}    Element to String    ${request_template}
 178     [Return]    ${request_template}
 179
 180 Prepare Unification Filtration Topology Request
 181     [Arguments]    ${request_template}    ${model}    ${correlation_item}    ${target_field1}    ${underlay_topo1}    ${target_field2}
 182     ...    ${underlay_topo2}
 183     [Documentation]    Prepare topology request for unification on two topologies from template
 184     ${request_template}    Prepare Unification Filtration Inside Topology Request    ${request_template}    ${model}    ${correlation_item}    ${target_field1}    ${underlay_topo1}
 185     ${request_template}    Set Element Text    ${request_template}    ${underlay_topo2}    xpath=.//correlation/aggregation/mapping[2]/underlay-topology
 186     Insert Target Field    ${request_template}    2    ${target_field2}    1
 187     ${request_template}    Set Element Text    ${request_template}    ${model}    xpath=.//correlation/aggregation/mapping[2]/input-model
 188     ${request_template}    Element to String    ${request_template}
 189     [Return]    ${request_template}
 190
 191 Prepare Unification Filtration Inside Topology Request
 192     [Arguments]    ${request_template}    ${model}    ${correlation_item}    ${target-field}    ${underlay_topo}
 193     [Documentation]    Prepare topology request for unification filtration inside from template
 194     ${request_template}    Set Element Text    ${request_template}    ${model}    xpath=.//correlations/output-model
 195     ${request_template}    Set Element Text    ${request_template}    filtration-aggregation    xpath=.//correlations/correlation/type
 196     ${request_template}    Set Element Text    ${request_template}    ${correlation_item}    xpath=.//correlation/correlation-item
 197     ${request_template}    Set Element Text    ${request_template}    unification    xpath=.//correlation/aggregation/aggregation-type
 198     ${request_template}    Set Element Text    ${request_template}    ${model}    xpath=.//correlation/aggregation/mapping[1]/input-model
 199     ${request_template}    Set Element Text    ${request_template}    ${underlay_topo}    xpath=.//correlation/aggregation/mapping[1]/underlay-topology
 200     Insert Target Field    ${request_template}    1    ${target-field}    1
 201     ${request_template}    Set Element Text    ${request_template}    ${underlay_topo}    xpath=.//correlation/filtration/underlay-topology
 202     ${request_template}    Element to String    ${request_template}
 203     [Return]    ${request_template}
 204
 205 Insert Apply Filters
 206     [Arguments]    ${request_template}    ${mapping}    ${filter_id}
 207     ${request_template}    Add Element    ${request_template}    ${APPLY_FILTERS}    xpath=.//correlation/aggregation/mapping[${mapping}]
 208     ${request_template}    Set Element Text    ${request_template}    ${filter_id}    xpath=.//correlation/aggregation/mapping[${mapping}]/apply-filters
 209     [Return]    ${request_template}
 210
 211 Prepare Filtration Topology Request
 212     [Arguments]    ${request_template}    ${model}    ${correlation_item}    ${underlay_topo}
 213     [Documentation]    Prepare topology request for filtration from template
 214     ${request_template}    Set Element Text    ${request_template}    ${model}    xpath=.//correlations/output-model
 215     ${request_template}    Set Element Text    ${request_template}    ${correlation_item}    xpath=.//correlation/correlation-item
 216     ${request_template}    Set Element Text    ${request_template}    ${underlay_topo}    xpath=.//correlation/filtration/underlay-topology
 217     [Return]    ${request_template}
 218
 219 Insert Target Field
 220     [Arguments]    ${request_template}    ${mapping_index}    ${target_field_path}    ${matching_key}
 221     [Documentation]    Add target field to request
 222     ${target_field_template}    Set Element Text    ${TARGET_FIELD}    ${target_field_path}    xpath=.//target-field-path
 223     ${target_field_template}    Set Element Text    ${target_field_template}    ${matching_key}    xpath=.//matching-key
 224     ${request_template}    Add Element    ${request_template}    ${target_field_template}    xpath=.//correlation/aggregation/mapping[${mapping_index}]
 225     ${request_template}    Element to String    ${request_template}
 226     [Return]    ${request_template}
 227
 228 Insert Filter
 229     [Arguments]    ${request_template}    ${filter_template}    ${target_field}
 230     [Documentation]    Add filter to filtration
 231     ${request_template}    Add Element    ${request_template}    ${filter_template}    xpath=.//correlation/filtration
 232     ${model}    Get Element Text    ${request_template}    xpath=.//correlations/output-model
 233     ${request_template}    Set Element Text    ${request_template}    ${model}    xpath=.//correlation/filtration/filter/input-model
 234     ${request_template}    Set Element Text    ${request_template}    ${target_field}    xpath=.//correlation/filtration/filter/target-field
 235     [Return]    ${request_template}
 236
 237 Insert Filter With ID
 238     [Arguments]    ${request_template}    ${filter_template}    ${target_field}    ${filter_id}
 239     [Documentation]    Add filter to filtration with specified id
 240     ${request_template}    Insert Filter    ${request_template}    ${filter_template}    ${target_field}
 241     ${request_template}    Set Element Text    ${request_template}    ${filter_id}    xpath=.//correlation/filtration/filter/filter-id
 242     [Return]    ${request_template}
 243
 244 Set IPV4 Filter
 245     [Arguments]    ${request_template}    ${ip_address}
 246     [Documentation]    Set filter ipv4 address
 247     ${request_template}    Set Element Text    ${request_template}    ${ip_address}    xpath=.//correlation/filtration/filter/ipv4-address-filter/ipv4-address
 248     ${request_template}    Element to String    ${request_template}
 249     [Return]    ${request_template}
 250
 251 Set Range Number Filter
 252     [Arguments]    ${request_template}    ${min_number}    ${max_number}
 253     [Documentation]    Set filter minimum and maximum number values
 254     ${request_template}    Set Element Text    ${request_template}    ${min_number}    xpath=.//correlation/filtration/filter/range-number-filter/min-number-value
 255     ${request_template}    Set Element Text    ${request_template}    ${max_number}    xpath=.//correlation/filtration/filter/range-number-filter/max-number-value
 256     ${request_template}    Element to String    ${request_template}
 257     [Return]    ${request_template}
 258
 259 Set Range String Filter
 260     [Arguments]    ${request_template}    ${min_value}    ${max_value}
 261     [Documentation]    Set filter minimum and maximum string values
 262     ${request_template}    Set Element Text    ${request_template}    ${min_value}    xpath=.//correlation/filtration/filter/range-string-filter/min-string-value
 263     ${request_template}    Set Element Text    ${request_template}    ${max_value}    xpath=.//correlation/filtration/filter/range-string-filter/max-string-value
 264     ${request_template}    Element to String    ${request_template}
 265     [Return]    ${request_template}
 266
 267 Set Specific Number Filter
 268     [Arguments]    ${request_template}    ${number}
 269     [Documentation]    Set filter number value
 270     ${request_template}    Set Element Text    ${request_template}    ${number}    xpath=.//correlation/filtration/filter/specific-number-filter/specific-number
 271     ${request_template}    Element to String    ${request_template}
 272     [Return]    ${request_template}
 273
 274 Set Specific String Filter
 275     [Arguments]    ${request_template}    ${string_value}
 276     [Documentation]    Set filter string value
 277     ${request_template}    Set Element Text    ${request_template}    ${string_value}    xpath=.//correlation/filtration/filter/specific-string-filter/specific-string
 278     ${request_template}    Element to String    ${request_template}
 279     [Return]    ${request_template}
 280
 281 Set IPV6 Filter
 282     [Arguments]    ${request_template}    ${ip_address}
 283     [Documentation]    Set filter ipv6 address
 284     ${request_template}    Set Element Text    ${request_template}    ${ip_address}    xpath=.//correlation/filtration/filter/ipv6-address-filter/ipv6-address
 285     ${request_template}    Element to String    ${request_template}
 286     [Return]    ${request_template}
 287
 288 Set Script Filter
 289     [Arguments]    ${request_template}    ${script_language}    ${script}
 290     [Documentation]    Set filter script
 291     ${request_template}    Set Element Text    ${request_template}    ${script_language}    xpath=.//correlation/filtration/filter/script-filter/scripting/language
 292     ${request_template}    Set Element Text    ${request_template}    ${script}    xpath=.//correlation/filtration/filter/script-filter/scripting/script
 293     ${request_template}    Element to String    ${request_template}
 294     [Return]    ${request_template}
 295
 296 Insert Link Computation Inside
 297     [Arguments]    ${request_template}    ${link_computation_template}    ${input_model}    ${underlay_topology}
 298     [Documentation]    Add link computation to request
 299     ${request_template}    Add Element    ${request_template}    ${link_computation_template}    xpath=.
 300     ${request_template}    Set Element Text    ${request_template}    ${input_model}    xpath=.//link-computation/node-info/input-model
 301     ${request_template}    Set Element Text    ${request_template}    ${input_model}    xpath=.//link-computation/link-info/input-model
 302     ${request_template}    Set Element Text    ${request_template}    ${input_model}    xpath=.//link-computation/output-model
 303     ${request_template}    Set Element Text    ${request_template}    ${underlay_topology}    xpath=.//link-computation/link-info/link-topology
 304     ${request_template}    Set Element Attribute    ${request_template}    xmlns:n    urn:opendaylight:topology:correlation    xpath=./link-computation
 305     ${request_template}    Element to String    ${request_template}
 306     [Return]    ${request_template}
 307
 308 Insert Link Computation
 309     [Arguments]    ${request_template}    ${link_computation_template}    ${input_model}    ${underlay_topology_1}    ${underlay_topology_2}
 310     [Documentation]    Add link computation to request
 311     ${request_template}    Add Element    ${request_template}    ${link_computation_template}    xpath=.
 312     ${request_template}    Set Element Text    ${request_template}    ${input_model}    xpath=.//link-computation/node-info/input-model
 313     ${request_template}    Set Element Text    ${request_template}    ${input_model}    xpath=.//link-computation/link-info[1]/input-model
 314     ${request_template}    Set Element Text    ${request_template}    ${input_model}    xpath=.//link-computation/link-info[2]/input-model
 315     ${request_template}    Set Element Text    ${request_template}    ${input_model}    xpath=.//link-computation/output-model
 316     ${request_template}    Set Element Text    ${request_template}    ${underlay_topology_1}    xpath=.//link-computation/link-info[1]/link-topology
 317     ${request_template}    Set Element Text    ${request_template}    ${underlay_topology_2}    xpath=.//link-computation/link-info[2]/link-topology
 318     ${request_template}    Set Element Attribute    ${request_template}    xmlns:n    urn:opendaylight:topology:correlation    xpath=./link-computation
 319     ${request_template}    Element to String    ${request_template}
 320     [Return]    ${request_template}
 321
 322 Insert Scripting into Request
 323     [Arguments]    ${request}    ${language}    ${script}
 324     [Documentation]    Insert Scripting into Request under aggregation node
 325     ${request}    Add Element    ${request}    ${SCRIPTING}    xpath=.//correlation/aggregation
 326     ${request}    Set Element Text    ${request}    ${script}    xpath=.//correlation/aggregation/scripting/script
 327     ${request}    Set Element Text    ${request}    ${language}    xpath=.//correlation/aggregation/scripting/language
 328     ${request}    Element to String    ${request}
 329     [Return]    ${request}
 330
 331 Create Isis Node
 332     [Arguments]    ${node-id}    ${ovs-version}=23    ${router-id-ipv4}=10.0.0.1
 333     [Documentation]    Create an isis node element with id and ip
 334     ${request}    Set Element Text    ${NODE_ISIS}    ${node-id}    xpath=.//node-id
 335     ${request}    Set Element Text    ${request}    ${ovs-version}    xpath=.//ovs-version
 336     ${request}    Set Element Text    ${request}    ${router-id-ipv4}    xpath=.//igp-node-attributes/isis-node-attributes/ted/te-router-id-ipv4
 337     ${request}    Element to String    ${request}
 338     [Return]    ${request}
 339
 340 Create Openflow Node
 341     [Arguments]    ${node-id}    ${ip-address}=10.0.0.1    ${serial-number}=27
 342     [Documentation]    Create an Openflow node element with id and ip
 343     ${request}    Set Element Text    ${NODE_OPENFLOW}    ${node-id}    xpath=.//id
 344     ${request}    Set Element Text    ${request}    ${ip-address}    xpath=.//ip-address
 345     ${request}    Set Element Text    ${request}    ${serial-number}    xpath=.//serial-number
 346     ${request}    Element to String    ${request}
 347     [Return]    ${request}
 348
 349 Create OVSDB Termination Point
 350     [Arguments]    ${tp-id}    ${ofport}
 351     [Documentation]    Create an OVSDB termination point element with id and port
 352     ${request}    Set Element Text    ${TERMINATION_POINT_OVSDB}    ${tp-id}    xpath=.//tp-id
 353     ${request}    Set Element Text    ${request}    ${ofport}    xpath=.//ofport
 354     ${request}    Element to String    ${request}
 355     [Return]    ${request}
 356
 357 Create Openflow Node Connector
 358     [Arguments]    ${nc-id}    ${port-number}
 359     [Documentation]    Create an Openflow node connector element with id and port number
 360     ${request}    Set Element Text    ${NODE_CONNECTOR_OPENFLOW}    ${nc-id}    xpath=.//id
 361     ${request}    Set Element Text    ${request}    ${port-number}    xpath=.//port-number
 362     ${request}    Element to String    ${request}
 363     [Return]    ${request}
 364
 365 Create Link
 366     [Arguments]    ${link-id}    ${source-node}    ${dest-node}    ${name}    ${metric}
 367     ${request}    Set Element Text    ${LINK}    ${link-id}    xpath=.//link-id
 368     ${request}    Set Element Text    ${request}    ${source-node}    xpath=.//source/source-node
 369     ${request}    Set Element Text    ${request}    ${dest-node}    xpath=.//destination/dest-node
 370     ${request}    Set Element Text    ${request}    ${name}    xpath=.//igp-link-attributes/name
 371     ${request}    Set Element Text    ${request}    ${metric}    xpath=.//igp-link-attributes/metric
 372     ${request}    Element to String    ${request}
 373     [Return]    ${request}
 374
 375 Extract Node from Topology
 376     [Arguments]    ${topology}    ${supp_node_id}
 377     [Documentation]    Returns node that contains supporting node with ID specified in argument supp_node_id
 378     ${xpath}    Set Variable    .//node/supporting-node[node-ref='${supp_node_id}']/..
 379     ${node}    Get Element    ${topology}    xpath=${xpath}
 380     ${node}    Element to String    ${node}
 381     [Return]    ${node}
 382
 383 Extract Termination Point from Topology
 384     [Arguments]    ${model}    ${topology}    ${topo_id}    ${node_id}    ${tp_id}
 385     [Documentation]    Returns termination point that contains supporting termination point from specified topology, node and with specified id
 386     Check Supported Model    ${model}
 387     ${xpath}    Set Variable If    '${model}' == 'network-topology-model' or '${model}' == 'opendaylight-inventory-model'    .//termination-point[tp-ref='/network-topology:network-topology/topology/${topo_id}/node/${node_id}/termination-point/${tp_id}']    .//termination-point/supporting-termination-point[tp-ref='${tp_id}']/..
 388     ${tp}    Get Element    ${topology}    xpath=${xpath}
 389     ${tp}    Element to String    ${tp}
 390     [Return]    ${tp}
 391
 392 Extract Link from Topology
 393     [Arguments]    ${model}    ${topology}    ${topo_id}    ${link_id}
 394     [Documentation]    Returns link that contains supporting link
 395     Check Supported Model    ${model}
 396     ${xpath}    Set Variable If    '${model}' == 'network-topology-model' or '${model}' == 'opendaylight-inventory-model'    .//link/supporting-link[link-ref='/network-topology/topology/${topo_id}/link/${link_id}']/..    .//link/supporting-link[tp-ref='${tp_id}']/..
 397     ${link}    Get Element    ${topology}    xpath=${xpath}
 398     ${link}    Element to String    ${link}
 399     [Return]    ${link}
 400
 401 Check Supported Model
 402     [Arguments]    ${model}
 403     [Documentation]    Checks if model is supported.
 404     Run Keyword If    '${model}' != 'network-topology-model' and '${model}' != 'i2rs-model' and '${model}' != 'opendaylight-inventory-model'    Fail    Not supported model
 405
 406 Check Aggregated Node in Topology
 407     [Arguments]    ${model}    ${topology}    ${tp_count}    @{supp_node_ids}
 408     [Documentation]    Checks number of termination points and concrete supporting nodes in aggregated node and returns overlay node id. Model should be 'network-topology-model', 'opendaylight-inventory-model' or 'i2rs-model'.
 409     Check Supported Model    ${model}
 410     ${node_id}    Get From List    ${supp_node_ids}    0
 411     ${aggregated_node}    Extract Node from Topology    ${topology}    ${node_id}
 412     ${supp_node_count}    Get Length    ${supp_node_ids}
 413     Should Contain X Times    ${aggregated_node}    <supporting-node>    ${supp_node_count}
 414     Should Contain X Times    ${aggregated_node}    <termination-point>    ${tp_count}
 415     Should Contain X Times    ${aggregated_node}    <tp-ref>    ${tp_count}
 416     : FOR    ${supp_node_id}    IN    @{supp_node_ids}
 417     \    Element Text Should Be    ${aggregated_node}    ${supp_node_id}    xpath=.//supporting-node[node-ref='${supp_node_id}']/node-ref
 418     ${overlay_node_id}    Get Element Text    ${aggregated_node}    xpath=./node-id
 419     [Return]    ${overlay_node_id}
 420
 421 Check Aggregated Termination Point in Node
 422     [Arguments]    ${model}    ${topology}    ${topology_id}    ${node_id}    ${tp_id}    @{supp_tp_ids}
 423     [Documentation]    Checks supporting termination points in aggregated termination point. Model should be 'network-topology-model', 'opendaylight-inventory-model' or 'i2rs-model'.
 424     Check Supported Model    ${model}
 425     ${tp}    Extract Termination Point from Topology    ${model}    ${topology}    ${topology_id}    ${node_id}    ${tp_id}
 426     ${supp_tp_count}    Get Length    ${supp_tp_ids}
 427     Should Contain X Times    ${tp}    <tp-ref>    ${supp_tp_count}
 428     : FOR    ${supp_tp_id}    IN    @{supp_tp_ids}
 429     \    Should Contain X Times    ${tp}    ${supp_tp_id}</tp-ref>    1
 430
 431 Check Filtered Nodes in Topology
 432     [Arguments]    ${topology}    ${tp_count}    @{node_ids}
 433     [Documentation]    Checks nodes in filtered topology
 434     : FOR    ${node_id}    IN    @{node_ids}
 435     \    Element Text Should Be    ${topology}    ${node_id}    xpath=.//node/supporting-node[node-ref='${node_id}']/node-ref
 436
 437 Check Filtered Termination Points in Node
 438     [Arguments]    ${topology}    ${supp_node_id}    @{supp_tp_ids}
 439     [Documentation]    Checks termination points in filtered topology
 440     ${node}    Extract Node from Topology    ${topology}    ${supp_node_id}
 441     ${supp_tp_count}    Get Length    ${supp_tp_ids}
 442     Should Contain X Times    ${node}    <supporting-node>    1
 443     Should Contain X Times    ${node}    <termination-point>    ${supp_tp_count}
 444     Should Contain X Times    ${node}    <tp-ref>    ${supp_tp_count}
 445     : FOR    ${supp_tp_id}    IN    @{supp_tp_ids}
 446     \    Should Contain X Times    ${node}    ${supp_tp_id}    1
 447
 448 Check Filtered Links In Topology
 449     [Arguments]    ${topology}    @{supp_link_ids}
 450     [Documentation]    Checks links in filtered topology
 451     : FOR    ${supp_link_id}    IN    @{supp_link_ids}
 452     \    Should Contain X Times    ${topology}    ${supp_link_id}</link-ref>    1
 453
 454 Check Overlay Link Source And Destination
 455     [Arguments]    ${model}    ${topology}    ${topo_id}    ${link_id}    ${expected_source}    ${expected_destination}
 456     [Documentation]    Checks if the overlay link's source and destination specified by a supporting link ref matches given source and destination
 457     ${link}    Extract Link from Topology    ${model}    ${topology}    ${topo_id}    ${link_id}
 458     ${link_source}    Get Element Text    ${link}    xpath=.//source-node
 459     ${link_destination}    Get Element Text    ${link}    xpath=.//dest-node
 460     Should Be Equal As Strings    ${link_source}    ${expected_source}
 461     Should Be Equal As Strings    ${link_destination}    ${expected_destination}
 462
 463 Output Topo Should Be Complete
 464     [Arguments]    ${node_count}=-1    ${supporting-node_count}=-1    ${node-ref_count}=-1    ${tp_count}=-1    ${tp-ref_count}=-1    ${link_count}=-1
 465     ...    ${link-ref_count}=-1
 466     [Documentation]    Verifies that the output topology contains the expected amount of essential elements
 467     ${resp}    Wait Until Keyword Succeeds    5x    250ms    Basic Request Get    ${OVERLAY_TOPO_URL}
 468     Should Contain    ${resp.content}    <topology-id>${OUTPUT_TOPO_NAME}</topology-id>
 469     Run Keyword If    ${node_count}>-1    Should Contain X Times    ${resp.content}    <node>    ${node_count}
 470     Run Keyword If    ${supporting-node_count}>-1    Should Contain X Times    ${resp.content}    <supporting-node>    ${supporting-node_count}
 471     Run Keyword If    ${node-ref_count}>-1    Should Contain X Times    ${resp.content}    <node-ref>    ${node-ref_count}
 472     Run Keyword If    ${link_count}>-1    Should Contain X Times    ${resp.content}    <link>    ${link_count}
 473     Run Keyword If    ${link-ref_count}>-1    Should Contain X Times    ${resp.content}    <link-ref>    ${link-ref_count}
 474     Run Keyword If    ${tp_count}>-1    Should Contain X Times    ${resp.content}    <termination-point>    ${tp_count}
 475     Run Keyword If    ${tp-ref_count}>-1    Should Contain X Times    ${resp.content}    <tp-ref>    ${tp-ref_count}
 476     Log    ---- Output Topo ----
 477     Log    ${resp.content}
 478     [Return]    ${resp}
 479
 480 Set Global Variable If It Does Not Exist
 481     [Arguments]    ${name}    ${value}
 482     ${status}    ${message} =    Run Keyword And Ignore Error    Variable Should Exist    ${name}
 483     Run Keyword If    "${status}" == "FAIL"    Set Global Variable    ${name}    ${value}