csit/libraries/Utils.robot

   1 *** Settings ***
   2 Documentation     General Utils library. This library has broad scope, it can be used by any robot system tests.
   3 Library           SSHLibrary
   4 Library           HttpLibrary.HTTP
   5 Library           String
   6 Library           DateTime
   7 Library           Process
   8 Library           Collections
   9 Library           RequestsLibrary
  10 Library           OperatingSystem
  11 Library           ${CURDIR}/UtilLibrary.py
  12 Resource          ${CURDIR}/SSHKeywords.robot
  13 Resource          ${CURDIR}/TemplatedRequests.robot
  14 Variables         ${CURDIR}/../variables/Variables.py
  15
  16 *** Variables ***
  17 # TODO: Introduce ${tree_size} and use instead of 1 in the next line.
  18 ${start}          sudo mn --controller=remote,ip=${ODL_SYSTEM_IP} --topo tree,1 --switch ovsk,protocols=OpenFlow13
  19
  20 *** Keywords ***
  21 Start Mininet
  22     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${timeout}=30s
  23     [Documentation]    Basic setup/cleanup work that can be done safely before any system
  24     ...    is run.
  25     Log    Start the test on the base edition
  26     Clean Mininet System
  27     ${mininet_conn_id}=    Open Connection    ${system}    prompt=${prompt}    timeout=${timeout}
  28     Set Suite Variable    ${mininet_conn_id}
  29     SSHKeywords.Flexible Mininet Login    user=${user}    password=${password}
  30     Execute Command    sudo ovs-vsctl set-manager ptcp:6644
  31     Write    ${start}
  32     Read Until    mininet>
  33
  34 Stop Mininet
  35     [Arguments]    ${prompt}=${DEFAULT_LINUX_PROMPT}
  36     [Documentation]    Cleanup/Shutdown work that should be done at the completion of all
  37     ...    tests
  38     Log    Stop the test on the base edition
  39     Switch Connection    ${mininet_conn_id}
  40     Read
  41     Write    exit
  42     Read Until    ${prompt}
  43     Close Connection
  44
  45 Report_Failure_Due_To_Bug
  46     [Arguments]    ${number}    ${include_bug_in_tags}=True
  47     [Documentation]    Report that a test failed due to a known Bugzilla bug whose
  48     ...    number is provided as an argument.
  49     ...    Not FAILED (incl. SKIPPED) test are not reported.
  50     ...    This keyword must be used in the [Teardown] setting of the affected test
  51     ...    or as the first line of the test if FastFail module is not being
  52     ...    used. It reports the URL of the bug on console and also puts it
  53     ...    into the Robot log file.
  54     ${test_skipped}=    BuiltIn.Evaluate    len(re.findall('SKIPPED', """${TEST_MESSAGE}""")) > 0    modules=re
  55     BuiltIn.Return From Keyword If    ('${TEST_STATUS}' != 'FAIL') or ${test_skipped}
  56     ${bug_url}=    BuiltIn.Set_Variable    https://bugs.opendaylight.org/show_bug.cgi?id=${number}
  57     ${msg}=    BuiltIn.Set_Variable    This test fails due to ${bug_url}
  58     ${newline}=    BuiltIn.Evaluate    chr(10)
  59     BuiltIn.Set Test Message    ${msg}${newline}${newline}${TEST_MESSAGE}
  60     BuiltIn.Log    ${msg}
  61     BuiltIn.Run_Keyword_If    "${include_bug_in_tags}"=="True"    Set Tags    ${bug_url}
  62
  63 Report_Failure_And_Point_To_Linked_Bugs
  64     [Documentation]    Report that a test failed and point to linked Bugzilla bug(s).
  65     ...    Linked bugs must contain the ${reference} inside comments (workaround
  66     ...    becasue of currently missing suitable field for external references and
  67     ...    not correctly working the CONTENT MATCHES filter).
  68     ...    Not FAILED (incl. SKIPPED) test are not reported.
  69     ...    This keyword must be used in the [Teardown] setting of the affected test
  70     ...    or as the first line of the test if FastFail module is not being
  71     ...    used. It reports the URL of the bug on console and also puts it
  72     ...    into the Robot log file.
  73     ${test_skipped}=    BuiltIn.Evaluate    len(re.findall('SKIPPED', """${TEST_MESSAGE}""")) > 0    modules=re
  74     BuiltIn.Return From Keyword If    ('${TEST_STATUS}' != 'FAIL') or ${test_skipped}
  75     ${newline}=    BuiltIn.Evaluate    chr(10)
  76     ${reference}=    String.Replace_String_Using_Regexp    ${SUITE_NAME}_${TEST_NAME}    [ /\.-]    _
  77     ${reference}=    String.Convert_To_Lowercase    ${reference}
  78     ${msg}=    BuiltIn.Set_Variable    ... click for list of related bugs or create a new one if needed (with the${newline}"${reference}"${newline}reference somewhere inside)
  79     ${bugs}=    BuiltIn.Set_Variable    "https://bugs.opendaylight.org/buglist.cgi?f1=cf_external_ref&o1=substring&v1=${reference}&order=bug_status"
  80     BuiltIn.Set Test Message    ${msg}${newline}${bugs}${newline}${newline}${TEST_MESSAGE}
  81     BuiltIn.Log    ${msg}${newline}${bugs}
  82
  83 Check Nodes Stats
  84     [Arguments]    ${node}    ${session}=session
  85     [Documentation]    A GET on the /node/${node} API is made and specific flow stat
  86     ...    strings are checked for existence.
  87     ${resp}    RequestsLibrary.Get Request    ${session}    ${OPERATIONAL_NODES_API}/node/${node}
  88     Should Be Equal As Strings    ${resp.status_code}    200
  89     Should Contain    ${resp.content}    flow-capable-node-connector-statistics
  90     Should Contain    ${resp.content}    flow-table-statistics
  91
  92 Check For Specific Number Of Elements At URI
  93     [Arguments]    ${uri}    ${element}    ${expected_count}    ${session}=session
  94     [Documentation]    A GET is made to the specified ${URI} and the specific count of a
  95     ...    given element is done (as supplied by ${element} and ${expected_count})
  96     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
  97     Log    ${resp.content}
  98     Should Be Equal As Strings    ${resp.status_code}    200
  99     Should Contain X Times    ${resp.content}    ${element}    ${expected_count}
 100
 101 Check For Elements At URI
 102     [Arguments]    ${uri}    ${elements}    ${session}=session
 103     [Documentation]    A GET is made at the supplied ${URI} and every item in the list of
 104     ...    ${elements} is verified to exist in the response
 105     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
 106     Log    ${resp.content}
 107     Should Be Equal As Strings    ${resp.status_code}    200
 108     : FOR    ${i}    IN    @{elements}
 109     \    Should Contain    ${resp.content}    ${i}
 110
 111 Check For Elements Not At URI
 112     [Arguments]    ${uri}    ${elements}    ${session}=session
 113     [Documentation]    A GET is made at the supplied ${URI} and every item in the list of
 114     ...    ${elements} is verified to NOT exist in the response
 115     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
 116     Log    ${resp.content}
 117     Should Be Equal As Strings    ${resp.status_code}    200
 118     : FOR    ${i}    IN    @{elements}
 119     \    Should Not Contain    ${resp.content}    ${i}
 120
 121 Clean Mininet System
 122     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}
 123     Run Command On Mininet    ${system}    sudo mn -c
 124     Run Command On Mininet    ${system}    sudo ps -elf | egrep 'usr/local/bin/mn' | egrep python | awk '{print "sudo kill -9",$4}' | sh
 125
 126 Clean Up Ovs
 127     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}
 128     [Documentation]    Cleans up the OVS instance and remove any existing common known bridges.
 129     ${output}=    Run Command On Mininet    ${system}    sudo ovs-vsctl list-br
 130     Log    ${output}
 131     : FOR    ${i}    IN    ${output}
 132     \    Run Command On Mininet    ${system}    sudo ovs-vsctl --if-exists del-br ${i}
 133     Run Command On Mininet    ${system}    sudo ovs-vsctl del-manager
 134
 135 Extract Value From Content
 136     [Arguments]    ${content}    ${index}    ${strip}=nostrip
 137     [Documentation]    Will take the given response content and return the value at the given index as a string
 138     ${value}=    Get Json Value    ${content}    ${index}
 139     ${value}=    Convert To String    ${value}
 140     ${value}=    Run Keyword If    '${strip}' == 'strip'    Strip Quotes    ${value}
 141     [Return]    ${value}
 142
 143 Get Process ID Based On Regex On Remote System
 144     [Arguments]    ${system}    ${regex_string_to_match_on}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=30s
 145     [Documentation]    Uses ps to find a process that matches the supplied regex. Returns the PID of that process
 146     ...    The ${regex_string_to_match_on} should produce a unique process otherwise the PID returned may not be
 147     ...    the expected PID
 148     # doing the extra -v grep in this command to exclude the grep process itself from the output
 149     ${cmd}=    Set Variable    ps -elf | grep -v grep | grep ${regex_string_to_match_on} | awk '{print $4}'
 150     ${output}=    Run Command On Remote System    ${system}    ${cmd}    user=${user}    password=${password}    prompt=${prompt}
 151     ...    prompt_timeout=${prompt_timeout}
 152     # ${output} contains the system prompt and all we want is the value of the number
 153     ${pid}=    Fetch From Left    ${output}    \r
 154     # TODO: Get Process * keywords have perhaps non-standard default credentials.
 155     # ...    Should there be * On Mininet and * On Controller specializations?
 156     [Return]    ${pid}
 157
 158 Get Process Thread Count On Remote System
 159     [Arguments]    ${system}    ${pid}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=30s
 160     [Documentation]    Executes the ps command to retrieve the lightweight process (aka thread) count.
 161     ${cmd}=    Set Variable    ps --no-headers -o nlwp ${pid}
 162     ${output}=    Run Command On Remote System    ${system}    ${cmd}    user=${user}    password=${password}    prompt=${prompt}
 163     ...    prompt_timeout=${prompt_timeout}
 164     # ${output} contains the system prompt and all we want is the value of the number
 165     ${thread_count}=    Fetch From Left    ${output}    \r
 166     [Return]    ${thread_count}
 167
 168 Strip Quotes
 169     [Arguments]    ${string_to_strip}
 170     [Documentation]    Will strip ALL quotes from given string and return the new string
 171     ${string_to_return}=    Replace String    ${string_to_strip}    "    \    count=-1
 172     [Return]    ${string_to_return}
 173
 174 Run Command On Remote System
 175     [Arguments]    ${system}    ${cmd}    ${user}=${DEFAULT_USER}    ${password}=${EMPTY}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=${DEFAULT_TIMEOUT}
 176     [Documentation]    Reduces the common work of running a command on a remote system to a single higher level
 177     ...    robot keyword, taking care to log in with a public key and. The command given is written
 178     ...    and the output returned. No test conditions are checked.
 179     ${current_ssh_connection}=    SSHLibrary.Get Connection
 180     BuiltIn.Log    Attempting to execute command "${cmd}" on remote system "${system}" by user "${user}" with keyfile pass "${keyfile_pass}" and prompt "${prompt}"
 181     BuiltIn.Log    ${password}
 182     ${conn_id}=    SSHLibrary.Open Connection    ${system}    prompt=${prompt}    timeout=${prompt_timeout}
 183     SSHKeywords.Flexible SSH Login    ${user}    ${password}
 184     ${stdout}    ${stderr}    SSHLibrary.Execute Command    ${cmd}    return_stderr=True
 185     SSHLibrary.Close Connection
 186     Log    ${stderr}
 187     [Teardown]    SSHKeywords.Restore_Current_SSH_Connection_From_Index    ${current_ssh_connection.index}
 188     [Return]    ${stdout}
 189
 190 Run Command On Mininet
 191     [Arguments]    ${system}=${TOOLS_SYSTEM_IP}    ${cmd}=echo    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${TOOLS_SYSTEM_PROMPT}
 192     [Documentation]    Call Run Comand On Remote System, but with default values suitable for Mininet machine.
 193     BuiltIn.Run Keyword And Return    Run Command On Remote System    ${system}    ${cmd}    ${user}    ${password}    prompt=${prompt}
 194
 195 Run Command On Controller
 196     [Arguments]    ${system}=${ODL_SYSTEM_IP}    ${cmd}=echo    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}
 197     [Documentation]    Call Run Comand On Remote System, but with default values suitable for Controller machine.
 198     BuiltIn.Log    ${password}
 199     BuiltIn.Run Keyword And Return    Run Command On Remote System    ${system}    ${cmd}    ${user}    ${password}    prompt=${prompt}
 200
 201 Verify File Exists On Remote System
 202     [Arguments]    ${system}    ${file}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=5s
 203     [Documentation]    Will create connection with public key and will PASS if the given ${file} exists,
 204     ...    otherwise will FAIL
 205     ${conn_id}=    Open Connection    ${system}    prompt=${prompt}    timeout=${prompt_timeout}
 206     SSHKeywords.Flexible SSH Login    ${user}    ${password}
 207     SSHLibrary.File Should Exist    ${file}
 208     Close Connection
 209
 210 Check Karaf Log File Does Not Have Messages
 211     [Arguments]    ${ip}    ${message}    ${user}=${ODL_SYSTEM_USER}    ${password}=${ODL_SYSTEM_PASSWORD}    ${prompt}=${ODL_SYSTEM_PROMPT}    ${log_file}=${WORKSPACE}/${BUNDLEFOLDER}/data/log/karaf.log
 212     [Documentation]    Fails if the provided ${message} is found in the karaf.log file. Uses grep to search. The
 213     ...    karaf.log file can be overridden with ${log_file} to be any file on the given system @ ${ip}
 214     ${output}=    Run Command On Controller    ${ip}    grep -c '${message}' ${log_file}    user=${user}    password=${password}    prompt=${prompt}
 215     Should Be Equal As Strings    ${output}    0
 216
 217 Verify Controller Is Not Dead
 218     [Arguments]    ${controller_ip}=${ODL_SYSTEM_IP}
 219     [Documentation]    Will execute any tests to verify the controller is not dead. Some checks are
 220     ...    Out Of Memory Execptions.
 221     Check Karaf Log File Does Not Have Messages    ${controller_ip}    java.lang.OutOfMemoryError
 222     # TODO: Should Verify Controller * keywords also accept user, password, prompt and karaf_log arguments?
 223
 224 Verify Controller Has No Null Pointer Exceptions
 225     [Arguments]    ${controller_ip}=${ODL_SYSTEM_IP}
 226     [Documentation]    Will execute any tests to verify the controller is not having any null pointer eceptions.
 227     Check Karaf Log File Does Not Have Messages    ${controller_ip}    java.lang.NullPointerException
 228
 229 Get Epoch Time
 230     [Arguments]    ${time}
 231     [Documentation]    Get the Epoc time from MM/DD/YYYY HH:MM:SS
 232     ${epoch_time}=    Convert Date    ${time}    epoch    exclude_milles=True    date_format=%m/%d/%Y %H:%M:%S
 233     ${epoch_time}=    Convert To Integer    ${epoch_time}
 234     [Return]    ${epoch_time}
 235
 236 Remove Space on String
 237     [Arguments]    ${str}    ${count}=-1
 238     [Documentation]    Remove the empty space from given string.count is optional,if its given
 239     ...    that many occurence of space will be removed from left
 240     ${x}=    Convert To String    ${str}
 241     ${x}=    Replace String    ${str}    ${SPACE}    ${EMPTY}    count=${count}
 242     [Return]    ${x}
 243
 244 Split Value from String
 245     [Arguments]    ${str}    ${splitter}
 246     [Documentation]    Split the String based on given splitter and return as list
 247     @{x}=    Split String    ${str}    ${splitter}
 248     [Return]    @{x}
 249
 250 Concatenate the String
 251     [Arguments]    ${str1}    ${str2}
 252     [Documentation]    Catenate the two non-string objects and return as String
 253     ${str1}=    Convert to String    ${str1}
 254     ${str2}=    Convert to String    ${str2}
 255     ${output}=    Catenate    ${str1}    ${str2}
 256     [Return]    ${output}
 257
 258 Post Elements To URI
 259     [Arguments]    ${rest_uri}    ${data}    ${headers}=${headers}    ${session}=session
 260     [Documentation]    Perform a POST rest operation, using the URL and data provided
 261     ${resp} =    RequestsLibrary.Post Request    ${session}    ${rest_uri}    data=${data}    headers=${headers}
 262     Log    ${resp.content}
 263     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 264
 265 Remove All Elements At URI
 266     [Arguments]    ${uri}    ${session}=session
 267     ${resp}    RequestsLibrary.Delete Request    ${session}    ${uri}
 268     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 269
 270 Remove All Elements At URI And Verify
 271     [Arguments]    ${uri}    ${session}=session
 272     ${resp}    RequestsLibrary.Delete Request    ${session}    ${uri}
 273     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 274     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
 275     Should Be Equal As Strings    ${resp.status_code}    404
 276
 277 Remove All Elements If Exist
 278     [Arguments]    ${uri}    ${session}=session
 279     [Documentation]    Delete all elements from an URI if the configuration was not empty
 280     ${resp}    RequestsLibrary.Get Request    ${session}    ${uri}
 281     Run Keyword If    '${resp.status_code}'!='404'    Remove All Elements At URI    ${uri}    ${session}
 282
 283 Add Elements To URI From File
 284     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 285     ${body}    OperatingSystem.Get File    ${data_file}
 286     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 287     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 288
 289 Add Elements To URI From File And Verify
 290     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 291     ${body}    OperatingSystem.Get File    ${data_file}
 292     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 293     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 294     ${resp}    RequestsLibrary.Get Request    ${session}    ${dest_uri}
 295     Should Not Be Equal    ${resp.status_code}    404
 296
 297 Add Elements To URI And Verify
 298     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 299     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    ${data_file}    headers=${headers}
 300     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 301     ${resp}    RequestsLibrary.Get Request    ${session}    ${dest_uri}
 302     Should Not Be Equal    ${resp.status_code}    404
 303
 304 Add Elements To URI From File And Check Validation Error
 305     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 306     [Documentation]    Shorthand for PUTting data from file and expecting status code 400.
 307     BuiltIn.Comment    TODO: Does this have any benefits, considering TemplatedRequests can also do this in one line?
 308     ${body}    OperatingSystem.Get File    ${data_file}
 309     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 310     Should Contain    ${DATA_VALIDATION_ERROR}    ${resp.status_code}
 311
 312 Add Elements To URI From File And Check Server Error
 313     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 314     [Documentation]    Shorthand for PUTting data from file and expecting status code 500.
 315     ...    Consider opening a Bug against ODL, as in most test cases, 400 is the http code to expect.
 316     BuiltIn.Comment    TODO: Does this have any benefits, considering TemplatedRequests can also do this in one line?
 317     ${body}    OperatingSystem.Get File    ${data_file}
 318     ${resp}    RequestsLibrary.Put Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 319     Should Contain    ${INTERNAL_SERVER_ERROR}    ${resp.status_code}
 320
 321 Post Elements To URI From File
 322     [Arguments]    ${dest_uri}    ${data_file}    ${headers}=${headers}    ${session}=session
 323     ${body}    OperatingSystem.Get File    ${data_file}
 324     ${resp}    RequestsLibrary.Post Request    ${session}    ${dest_uri}    data=${body}    headers=${headers}
 325     Should Contain    ${ALLOWED_STATUS_CODES}    ${resp.status_code}
 326
 327 Run Process With Logging And Status Check
 328     [Arguments]    @{proc_args}
 329     [Documentation]    Execute an OS command, log STDOUT and STDERR output and check exit code to be 0
 330     ${result}=    Run Process    @{proc_args}
 331     Log    ${result.stdout}
 332     Log    ${result.stderr}
 333     Should Be Equal As Integers    ${result.rc}    0
 334     [Return]    ${result}
 335
 336 Get Data From URI
 337     [Arguments]    ${session}    ${uri}    ${headers}=${NONE}
 338     [Documentation]    Issue a GET request and return the data obtained or on error log the error and fail.
 339     ...    Issues a GET request for ${uri} in ${session} using headers from
 340     ...    ${headers}. If the request returns a HTTP error, fails. Otherwise
 341     ...    returns the data obtained by the request.
 342     ${response}=    RequestsLibrary.Get Request    ${session}    ${uri}    ${headers}
 343     Builtin.Return_From_Keyword_If    ${response.status_code} == 200    ${response.text}
 344     Builtin.Log    ${response.text}
 345     Builtin.Fail    The request failed with code ${response.status_code}
 346
 347 No Content From URI
 348     [Arguments]    ${session}    ${uri}    ${headers}=${NONE}
 349     [Documentation]    Issue a GET request and return on error 404 (No content) or will fail and log the content.
 350     ...    Issues a GET request for ${uri} in ${session} using headers from
 351     ...    ${headers}. If the request returns a HTTP error, fails. Otherwise
 352     ...    returns the data obtained by the request.
 353     ${response}=    RequestsLibrary.Get Request    ${session}    ${uri}    ${headers}
 354     Builtin.Return_From_Keyword_If    ${response.status_code} == 404
 355     Builtin.Log    ${response.text}
 356     Builtin.Fail    The request failed with code ${response.status_code}
 357
 358 Get Index From List Of Dictionaries
 359     [Arguments]    ${dictionary_list}    ${key}    ${value}
 360     [Documentation]    Extract index for the dictionary in a list that contains a key-value pair. Returns -1 if key-value is not found.
 361     ${length}=    Get Length    ${dictionary_list}
 362     ${index}=    Set Variable    -1
 363     : FOR    ${i}    IN RANGE    ${length}
 364     \    ${dictionary}=    Get From List    ${dictionary_list}    ${i}
 365     \    Run Keyword If    """&{dictionary}[${key}]""" == """${value}"""    Set Test Variable    ${index}    ${i}
 366     [Return]    ${index}
 367
 368 Check Item Occurrence
 369     [Arguments]    ${string}    ${dictionary_item_occurrence}
 370     [Documentation]    Check string for occurrences of items expressed in a list of dictionaries {item=occurrences}. 0 occurences means item is not present.
 371     : FOR    ${item}    IN    @{dictionary_item_occurrence}
 372     \    Should Contain X Times    ${string}    ${item}    &{dictionary_item_occurrence}[${item}]
 373
 374 Post Log Check
 375     [Arguments]    ${uri}    ${body}    ${status_code}=200    ${session}=session
 376     [Documentation]    Post body to ${uri}, log response content, and check status
 377     ${resp}=    RequestsLibrary.Post Request    ${session}    ${uri}    ${body}
 378     Log    ${resp.content}
 379     Should Be Equal As Strings    ${resp.status_code}    ${status_code}
 380     [Return]    ${resp}
 381
 382 Get Log File Name
 383     [Arguments]    ${testtool}    ${testcase}=${EMPTY}
 384     [Documentation]    Get the name of the suite sanitized to be usable as a part of filename.
 385     ...    These names are used to constructs names of the log files produced
 386     ...    by the testing tools so two suites using a tool wont overwrite the
 387     ...    log files if they happen to run in one job.
 388     ${name}=    BuiltIn.Evaluate    """${SUITE_NAME}""".replace(" ","-").replace("/","-").replace(".","-")
 389     ${suffix}=    BuiltIn.Set_Variable_If    '${testcase}' != ''    --${testcase}    ${EMPTY}
 390     [Return]    ${testtool}--${name}${suffix}.log
 391
 392 Set_User_Configurable_Variable_Default
 393     [Arguments]    ${name}    ${value}
 394     [Documentation]    Set a default value for an user configurable variable.
 395     ...    This keyword is needed if your default value is calculated using
 396     ...    a complex expression which needs BuiltIn.Evaluate or even more
 397     ...    complex keywords. It sets the variable ${name} (the name of the
 398     ...    variable MUST be specified WITHOUT the ${} syntactic sugar due
 399     ...    to limitations of Robot Framework) to ${value} but only if the
 400     ...    variable ${name} was not set previously. This keyword is intended
 401     ...    for user configurable variables which are supposed to be set only
 402     ...    with pybot -v; calling this keyword on a variable that was already
 403     ...    set by another keyword will silently turn the call into a NOP and
 404     ...    thus is a bug in the suite or resource trying to call this
 405     ...    keyword.
 406     # TODO: Figure out how to make the ${value} evaluation "lazy" (meaning
 407     #    evaluating it only when the user did not set anything and thus the
 408     #    default is needed). This might be needed to avoid potentially costly
 409     #    keyword invocations when they are not needed. Currently no need for
 410     #    this was identified, thus leaving it here as a TODO. Based on
 411     #    comments the best approach would be to create another keyword that
 412     #    expects a ScalarClosure in the place of ${value} and calls the
 413     #    closure to get the value but only if the value is needed).
 414     #    The best idea how to implement this "laziness" would be to have the
 415     #    used to define another keyword that will be responsible for getting
 416     #    the default value and then passing the name of this getter keyword
 417     #    to this keyword. Then this keyword would call the getter (to obtain
 418     #    the expensive default value) only if it discovers that this value
 419     #    is really needed (because the variable is not set yet).
 420     # TODO: Is the above TODO really necessary? Right now we don't have any
 421     #    examples of "expensive default values" where to obtain the default
 422     #    value is so expensive on resources (e.g. need to SSH somewhere to
 423     #    check something) that we would want to skip the calculation if the
 424     #    variable for which it is needed has a value already provided by the
 425     #    user using "pybot -v" or something. One example would be
 426     #    JAVA_HOME if it would be designed as user-configurable variable
 427     #    (currently it is not; users can specify "use jdk7" or "use jdk8"
 428     #    but not "use the jdk over there"; and there actually is no JAVA_HOME
 429     #    present in the resource, rather the Java invocation command uses the
 430     #    Java invocation with a full path). The default value of JAVA_HOME
 431     #    has to be obtained by issuing commands on the SSH connection where
 432     #    the resulting Java invocation command will be used (to check
 433     #    multiple candidate paths until one that fits is found) and we could
 434     #    skip all this checking if a JAVA_HOME was supplied by the user using
 435     #    "pybot -v".
 436     ${value}=    BuiltIn.Get_Variable_Value    \${${name}}    ${value}
 437     BuiltIn.Set_Suite_Variable    \${${name}}    ${value}
 438
 439 Convert_To_Minutes
 440     [Arguments]    ${time}
 441     [Documentation]    Convert a Robot time string to an integer expressing the time in minutes, rounded up
 442     ...    This is a wrapper around DateTime.Convert_Time which does not
 443     ...    provide this functionality directly nor is even able to produce
 444     ...    an integer directly. It is needed for RestPerfClient which
 445     ...    cannot accept floats for its --timeout parameter and interprets
 446     ...    the value supplied in this parameter in minutes.
 447     ${seconds}=    DateTime.Convert_Time    ${time}    result_format=number
 448     ${minutes}=    BuiltIn.Evaluate    int(math.ceil(${seconds}/60.0))    modules=math
 449     [Return]    ${minutes}
 450
 451 Write Commands Until Expected Prompt
 452     [Arguments]    ${cmd}    ${prompt}    ${timeout}=30s
 453     [Documentation]    quick wrapper for Write and Read Until Prompt Keywords to make test cases more readable
 454     SSHLibrary.Set Client Configuration    timeout=${timeout}
 455     SSHLibrary.Read
 456     SSHLibrary.Write    ${cmd}
 457     ${output}=    SSHLibrary.Read Until    ${prompt}
 458     [Return]    ${output}
 459
 460 Install Package On Ubuntu System
 461     [Arguments]    ${package_name}    ${system}=${TOOLS_SYSTEM_IP}    ${user}=${TOOLS_SYSTEM_USER}    ${password}=${TOOLS_SYSTEM_PASSWORD}    ${prompt}=${DEFAULT_LINUX_PROMPT}    ${prompt_timeout}=30s
 462     [Documentation]    Keyword to install packages for testing to Ubuntu Mininet VM
 463     Log    Keyword to install package to Mininet Ubuntu VM
 464     Open Connection    ${system}    prompt=${prompt}    timeout=${prompt_timeout}
 465     SSHKeywords.Flexible Mininet Login    user=${user}    password=${password}
 466     Write    sudo apt-get install -y ${package_name}
 467     Read Until    ${prompt}
 468
 469 Json Parse From String
 470     [Arguments]    ${plain_string_with_json}
 471     [Documentation]    Parse given plain string into json (dictionary)
 472     ${json_data}    Evaluate    json.loads('''${plain_string_with_json}''')    json
 473     [Return]    ${json_data}
 474
 475 Json Parse From File
 476     [Arguments]    ${json_file}
 477     [Documentation]    Parse given file content into json (dictionary)
 478     ${json_plain_string}    Get file    ${json_file}
 479     ${json_data}    Json Parse From String    ${json_plain_string}
 480     [Return]    ${json_data}