csit/suites/bgpcep/bgpclustering/PrefixcountKeywords.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is NOT used.
   3 ...
   4 ...               Copyright (c) 2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 Library           SSHLibrary    timeout=10s
  10 Library           RequestsLibrary
  11 Variables         ${CURDIR}/../../../variables/Variables.py
  12 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  13 Resource          ${CURDIR}/../../../libraries/BGPcliKeywords.robot
  14 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  15 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  16 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  17 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  18 Resource          ${CURDIR}/../../../libraries/ClusterManagement.robot
  19 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  20 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  21
  22 *** Variables ***
  23 ${BGP_TOOL_LOG_LEVEL}    info
  24 ${BGP_PEER_FOLDER}    ${CURDIR}/../../../variables/bgpclustering/bgp_peer_openconf    # used for configuration of bgp peer via openconfig
  25 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpclustering/bgp_peer    # used for configuration of bgp peer vie netconf connector
  26 ${BGP_VARIABLES_FOLDER_OP}    ${CURDIR}/../../../variables/bgpclustering/bgp_peer_operational
  27 ${NETCONF_DEV_FOLDER}    ${CURDIR}/../../../variables/netconf/device/full-uri-device
  28 ${NETCONF_MOUNT_FOLDER}    ${CURDIR}/../../../variables/netconf/device/full-uri-mount
  29 ${CHECK_PERIOD}    10
  30 ${HOLDTIME}       180
  31 ${INSERT}         1
  32 ${KARAF_LOG_LEVEL}    INFO
  33 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  34 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  35 ${PREFILL}        0
  36 ${REPETITIONS}    1
  37 ${RESULTS_FILE_NAME}    bgp.csv
  38 ${TEST_DURATION_MULTIPLIER}    1
  39 ${UPDATE}         single
  40 ${WITHDRAW}       0
  41 ${INITIAL_RESTCONF_TIMEOUT}    30s
  42 ${KARAF_HOME}     ${WORKSPACE}/${BUNDLEFOLDER}
  43 ${SHARD_DEFAULT_CONFIG}    shard-default-config
  44 ${SHARD_DEFAULT_OPERATIONAL}    shard-default-operational
  45 ${CONFIG_SESSION}    config-session
  46 ${CONFIGURATION_1}    operational-1
  47 ${CONFIGURATION_2}    operational-2
  48 ${CONFIGURATION_3}    operational-3
  49 ${EXAMPLE_IPV4_TOPOLOGY}    example-ipv4-topology
  50 ${DEVICE_NAME}    peer-controller-config
  51 ${DEVICE_CHECK_TIMEOUT}    60s
  52 ${RIB_INSTANCE}    example-bgp-rib
  53 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  54 ${BGP_PEER_NAME}    example-bgp-peer
  55 ${PEER_CHECK_URL}    /restconf/operational/bgp-rib:bgp-rib/rib/example-bgp-rib/peer/bgp:%2F%2F
  56
  57 *** Keywords ***
  58 Setup_Everything
  59     [Documentation]    Setup imported resources, SSH-login to tools system,
  60     ...    create HTTP session, put Python tool to tools system.
  61     SetupUtils.Setup_Utils_For_Setup_And_Teardown
  62     RequestsLibrary.Create_Session    ${CONFIGURATION_1}    http://${ODL_SYSTEM_1_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
  63     RequestsLibrary.Create_Session    ${CONFIGURATION_2}    http://${ODL_SYSTEM_2_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
  64     RequestsLibrary.Create_Session    ${CONFIGURATION_3}    http://${ODL_SYSTEM_3_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
  65     PrefixCounting.PC_Setup
  66     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
  67     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
  68     Utils.Flexible_Mininet_Login
  69     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
  70     # TODO: Alternatively, create variable in Variables which starts with http.
  71     # Both TODOs would probably need to update every suite relying on current Variables.
  72     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
  73     SSHKeywords.Require_Python
  74     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
  75     # Calculate the timeout value based on how many routes are going to be pushed
  76     # TODO: Replace 35 with some formula from period and repetitions.
  77     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER} * (${COUNT} * 6.0 / 10000 + 35)
  78     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
  79     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${bgp_filling_timeout*3.0/4}
  80     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
  81
  82 Teardown_Everything
  83     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
  84     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
  85     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
  86     RequestsLibrary.Delete_All_Sessions
  87     SSHLibrary.Close_All_Connections
  88
  89 Configure_Netconf_Device_And_Check_Mounted
  90     [Arguments]    ${mapping}
  91     [Documentation]    Configures netconf device
  92     TemplatedRequests.Put_As_Xml_Templated    ${NETCONF_DEV_FOLDER}    mapping=${mapping}    session=${CONFIG_SESSION}
  93     BuiltIn.Wait_Until_Keyword_Succeeds    10x    3s    TemplatedRequests.Get_As_Xml_Templated    ${NETCONF_MOUNT_FOLDER}    mapping=${mapping}    session=${CONFIG_SESSION}
  94
  95 Start_Bgp_Peer
  96     [Arguments]    ${peerip}=${rib_owner_node_id}
  97     [Documentation]    Starts bgp peer and verifies that the peer runs.
  98     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${peerip} --peerport=${ODL_BGP_PORT} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
  99
 100 Start_Bgp_Peer_And_Verify_Connected
 101     [Arguments]    ${connection_retries}=${1}    ${peerip}=${rib_owner_node_id}
 102     [Documentation]    Starts the peer and verifies its connection. The verification is done by checking the presence
 103     ...    of the peer in the bgp rib.
 104     : FOR    ${idx}    IN RANGE    ${connection_retries}
 105     \    Start_Bgp_Peer    peerip=${peerip}
 106     \    ${status}    ${value}=    BuiltIn.Run_Keyword_And_Ignore_Error    BuiltIn.Wait_Until_Keyword_Succeeds    3x    3s
 107     \    ...    Verify_Bgp_Peer_Connection    ${CONFIG_SESSION}    ${TOOLS_SYSTEM_IP}    connected=${True}
 108     \    BuiltIn.Run_Keyword_Unless    "${status}" == "PASS"    BGPSpeaker.Kill_BGP_Speaker
 109     \    BuiltIn.Return_From_Keyword_If    "${status}" == "PASS"
 110     BuiltIn.Fail    Unable to connect bgp peer to ODL
 111
 112 Verify_Bgp_Peer_Connection
 113     [Arguments]    ${session}    ${peer_ip}    ${connected}=${True}
 114     [Documentation]    Checks peer presence in operational datastore
 115     ${exp_status_code}=    BuiltIn.Set_Variable_If    ${connected}    ${200}    ${404}
 116     ${rsp}=    RequestsLibrary.Get Request    ${session}    ${PEER_CHECK_URL}${peer_ip}
 117     BuiltIn.Log    ${rsp.content}
 118     BuiltIn.Should_Be_Equal_As_Numbers    ${exp_status_code}    ${rsp.status_code}