csit/suites/bgpcep/bgpingest/bgp_app_peer_prefixcount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 BGP application peer
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               Test suite performs basic BGP performance test cases for
  11 ...               BGP application peer. BGP application peer introduces routes -
  12 ...               using restconf - in two steps:
  13 ...               1. introduces the ${PREFILL} number of routes in one POST request
  14 ...               2. POSTs the rest of routes (up to the ${COUNT} number) one by one
  15 ...               Test suite checks that the prefixes are propagated to
  16 ...               IPv4 topology and announced to BGP peer via updates. Test case
  17 ...               where the BGP peer is disconnected and reconnected and all routes
  18 ...               are deleted by BGP application peer are performed as well.
  19 ...               Brief description how to configure BGP application peer and
  20 ...               how to use restconf application peer interface:
  21 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:User_Guide#BGP_Application_Peer
  22 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:Programmer_Guide#BGP
  23 ...               http://docs.opendaylight.org/en/stable-boron/user-guide/bgp-user-guide.html#bgp-peering
  24 ...               http://docs.opendaylight.org/en/stable-boron/user-guide/bgp-user-guide.html#application-peer-configuration
  25 ...
  26 ...               Reported bugs:
  27 ...               Bug 4689 - Not a reasonable duration of 1M prefix introduction from BGP application peer via restconf
  28 ...               Bug 4791 - BGPSessionImpl: Failed to send message Update logged even all UPDATE mesages received by iBGP peer
  29 Suite Setup       Setup_Everything
  30 Suite Teardown    Teardown_Everything
  31 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  32 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  33 Force Tags        critical
  34 Library           SSHLibrary    timeout=10s
  35 Library           RequestsLibrary
  36 Resource          ../../../libraries/BGPcliKeywords.robot
  37 Resource          ../../../libraries/BGPSpeaker.robot
  38 Resource          ../../../libraries/FailFast.robot
  39 Resource          ../../../libraries/KarafKeywords.robot
  40 Resource          ../../../libraries/KillPythonTool.robot
  41 Resource          ../../../libraries/PrefixCounting.robot
  42 Resource          ../../../libraries/SetupUtils.robot
  43 Resource          ../../../libraries/SSHKeywords.robot
  44 Resource          ../../../libraries/TemplatedRequests.robot
  45 Resource          ../../../libraries/Utils.robot
  46 Resource          ../../../variables/Variables.robot
  47
  48 *** Variables ***
  49 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  50 ${HOLDTIME}       180
  51 ${HOLDTIME_APP_PEER_PREFIX_COUNT}    ${HOLDTIME}
  52 ${COUNT}          200000
  53 ${PREFILL}        100000
  54 ${COUNT_APP_PEER_PREFIX_COUNT}    ${COUNT}
  55 ${CHECK_PERIOD}    10
  56 ${CHECK_PERIOD_APP_PEER_PREFIX_COUNT}    ${CHECK_PERIOD}
  57 ${REPETITIONS_APP_PEER_PREFIX_COUNT}    1
  58 ${BGP_PEER_LOG_LEVEL}    info
  59 ${BGP_APP_PEER_LOG_LEVEL}    info
  60 ${ODL_LOG_LEVEL}    INFO
  61 ${ODL_BGP_LOG_LEVEL}    DEFAULT
  62 ${BGP_PEER_COMMAND}    python play.py --amount 0 --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --${BGP_PEER_LOG_LEVEL}
  63 ${BGP_PEER_OPTIONS}    &>bgp_peer.log
  64 ${BGP_APP_PEER_ID}    10.0.0.10
  65 ${BGP_APP_PEER_INITIAL_COMMAND}    python bgp_app_peer.py --host ${ODL_SYSTEM_IP} --port ${RESTCONFPORT} --command post --count ${PREFILL} --prefix 8.0.0.0 --prefixlen 28 --${BGP_APP_PEER_LOG_LEVEL} --stream=${ODL_STREAM}
  66 ${BGP_APP_PEER_PUT_COMMAND}    python bgp_app_peer.py --host ${ODL_SYSTEM_IP} --port ${RESTCONFPORT} --command put --count ${PREFILL} --prefix 8.0.0.0 --prefixlen 28 --${BGP_APP_PEER_LOG_LEVEL} --stream=${ODL_STREAM}
  67 ${BGP_APP_PEER_DELETE_ALL_COMMAND}    python bgp_app_peer.py --host ${ODL_SYSTEM_IP} --port ${RESTCONFPORT} --command delete-all --${BGP_APP_PEER_LOG_LEVEL} --stream=${ODL_STREAM}
  68 ${BGP_APP_PEER_GET_COMMAND}    python bgp_app_peer.py --host ${ODL_SYSTEM_IP} --port ${RESTCONFPORT} --command get --${BGP_APP_PEER_LOG_LEVEL} --stream=${ODL_STREAM}
  69 ${BGP_APP_PEER_OPTIONS}    &>bgp_app_peer.log
  70 ${TEST_DURATION_MULTIPLIER}    30
  71 ${last_prefix_count}    -1
  72 ${DEVICE_NAME}    controller-config
  73 ${BGP_PEER_NAME}    example-bgp-peer
  74 ${RIB_INSTANCE}    example-bgp-rib
  75 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  76
  77 *** Test Cases ***
  78 Check_For_Empty_Ipv4_Topology_Before_Starting
  79     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  80     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  81
  82 Reconfigure_ODL_To_Accept_Connection
  83     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  84     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME_APP_PEER_PREFIX_COUNT}    PEER_PORT=${BGP_TOOL_PORT}
  85     ...    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  86     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
  87
  88 Reconfigure_ODL_To_Accept_BGP_Application_Peer
  89     [Documentation]    Configure BGP application peer module.
  90     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer-app    RIB_INSTANCE_NAME=${RIB_INSTANCE}    IP=${BGP_APP_PEER_ID}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
  91     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_application_peer    mapping=${mapping}
  92
  93 Connect_BGP_Peer
  94     [Documentation]    Start BGP peer tool
  95     SSHLibrary.Switch Connection    bgp_peer_console
  96     Start_Console_Tool    ${BGP_PEER_COMMAND}    ${BGP_PEER_OPTIONS}
  97     Read_And_Fail_If_Prompt_Is_Seen
  98
  99 BGP_Application_Peer_Prefill_Routes
 100     [Documentation]    Start BGP application peer tool and prefill routes.
 101     SSHLibrary.Switch Connection    bgp_app_peer_console
 102     Start_Console_Tool    ${BGP_APP_PEER_INITIAL_COMMAND} ${script_uri_opt}    ${BGP_APP_PEER_OPTIONS}
 103     Wait_Until_Console_Tool_Finish    ${bgp_filling_timeout}
 104     Store_File_To_Workspace    bgp_app_peer.log    bgp_app_peer_prefill.log
 105
 106 Wait_For_Ipv4_Topology_Is_Prefilled
 107     [Documentation]    Wait until example-ipv4-topology reaches the target prfix count.
 108     BuiltIn.Wait Until Keyword Succeeds    ${bgp_filling_timeout}    10s    PrefixCounting.Check_Ipv4_Topology_Count    ${PREFILL}
 109
 110 Check_Bgp_Peer_Updates_For_Prefilled_Routes
 111     [Documentation]    Count the routes introduced by updates.
 112     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
 113     BuiltIn.Wait Until Keyword Succeeds    ${bgp_filling_timeout}    1s    Check_File_For_Word_Count    bgp_peer.log    total_received_nlri_prefix_counter: ${PREFILL}    2
 114
 115 BGP_Application_Peer_Introduce_Single_Routes
 116     [Documentation]    Start BGP application peer tool and introduce routes.
 117     SSHLibrary.Switch Connection    bgp_app_peer_console
 118     Start_Console_Tool    python bgp_app_peer.py --host ${ODL_SYSTEM_IP} --port ${RESTCONFPORT} --command add --count ${remaining_prefixes} --prefix 12.0.0.0 --prefixlen 28 --${BGP_APP_PEER_LOG_LEVEL} --stream=${ODL_STREAM} ${script_uri_opt}    ${BGP_APP_PEER_OPTIONS}
 119     Wait_Until_Console_Tool_Finish    ${bgp_filling_timeout}
 120     Store_File_To_Workspace    bgp_app_peer.log    bgp_app_peer_singles.log
 121
 122 Wait_For_Ipv4_Topology_Is_Filled
 123     [Documentation]    Wait until example-ipv4-topology reaches the target prfix count.
 124     BuiltIn.Wait Until Keyword Succeeds    ${bgp_filling_timeout}    10s    PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_APP_PEER_PREFIX_COUNT}
 125
 126 Check_Bgp_Peer_Updates_For_All_Routes
 127     [Documentation]    Count the routes introduced by updates.
 128     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
 129     BuiltIn.Wait Until Keyword Succeeds    ${bgp_filling_timeout}    1s    Check_File_For_Word_Count    bgp_peer.log    total_received_nlri_prefix_counter: ${COUNT_APP_PEER_PREFIX_COUNT}    2
 130
 131 Disconnect_BGP_Peer
 132     [Documentation]    Stop BGP peer tool
 133     SSHLibrary.Switch Connection    bgp_peer_console
 134     Stop_Console_Tool
 135     Store_File_To_Workspace    bgp_peer.log    bgp_peer_reconnect.log
 136
 137 Reconnect_BGP_Peer
 138     [Documentation]    Start BGP peer tool
 139     SSHLibrary.Switch Connection    bgp_peer_console
 140     Start_Console_Tool    ${BGP_PEER_COMMAND}    ${BGP_PEER_OPTIONS}
 141     Read_And_Fail_If_Prompt_Is_Seen
 142
 143 Check_Bgp_Peer_Updates_For_Reintroduced_Routes
 144     [Documentation]    Count the routes introduced by updates.
 145     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
 146     BuiltIn.Wait Until Keyword Succeeds    ${bgp_filling_timeout}    1s    Check_File_For_Word_Count    bgp_peer.log    total_received_nlri_prefix_counter: ${COUNT_APP_PEER_PREFIX_COUNT}    2
 147
 148 BGP_Application_Peer_Delete_All_Routes
 149     [Documentation]    Start BGP application peer tool and delete all routes.
 150     SSHLibrary.Switch Connection    bgp_app_peer_console
 151     Start_Console_Tool    ${BGP_APP_PEER_DELETE_ALL_COMMAND} --stream=${ODL_STREAM} ${script_uri_opt}    ${BGP_APP_PEER_OPTIONS}
 152     Wait_Until_Console_Tool_Finish    ${bgp_emptying_timeout}
 153     Store_File_To_Workspace    bgp_app_peer.log    bgp_app_peer_delete_all.log
 154
 155 Wait_For_Stable_Topology_After_Deletion
 156     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 157     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_APP_PEER_PREFIX_COUNT}    repetitions=${REPETITIONS_APP_PEER_PREFIX_COUNT}    excluded_count=${COUNT_APP_PEER_PREFIX_COUNT}
 158
 159 Check_For_Empty_Ipv4_Topology_After_Deleting
 160     [Documentation]    Example-ipv4-topology should be empty now.
 161     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 162
 163 Check_Bgp_Peer_Updates_For_Prefix_Withdrawals
 164     [Documentation]    Count the routes withdrawn by updates.
 165     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
 166     BuiltIn.Wait Until Keyword Succeeds    ${bgp_emptying_timeout}    1s    Check_File_For_Word_Count    bgp_peer.log    total_received_withdrawn_prefix_counter: ${COUNT_APP_PEER_PREFIX_COUNT}    2
 167
 168 Stop_BGP_Peer
 169     [Documentation]    Stop BGP peer tool
 170     SSHLibrary.Switch Connection    bgp_peer_console
 171     Stop_Console_Tool
 172     Store_File_To_Workspace    bgp_peer.log    bgp_peer_reconnect.log
 173
 174 Delete_Bgp_Peer_Configuration
 175     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 176     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 177     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 178
 179 Delete_Bgp_Application_Peer_Configuration
 180     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 181     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-bgp-peer-app    IP=${BGP_APP_PEER_ID}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 182     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_application_peer    mapping=${mapping}
 183
 184 Check_Bug_4791
 185     [Documentation]    Check controller's log for errors
 186     Check Karaf Log File Does Not Have Messages    ${ODL_SYSTEM_IP}    Failed to send message Update
 187
 188 *** Keywords ***
 189 Setup_Everything
 190     [Documentation]    Setup imported resources, SSH-login to tools system,
 191     ...    create HTTP session, put Python tool to tools system.
 192     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 193     TemplatedRequests.Create_Default_Session
 194     PrefixCounting.PC_Setup
 195     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 196     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    timeout=125    max_retries=0
 197     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 198     # TODO: Alternatively, create variable in Variables which starts with http.
 199     # Both TODOs would probably need to update every suite relying on current Variables.
 200     Open_BGP_Peer_Console
 201     Open_BGP_Aplicationp_Peer_Console
 202     SSHKeywords.Require_Python
 203     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 204     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 205     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/bgp_app_peer.py
 206     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/ipv4-routes-template.xml*
 207     # Calculate the timeout value based on how many routes are going to be pushed.
 208     # The offset (20) is set for keeping reasonable timeout for low COUNT values.
 209     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER} * ${COUNT_APP_PEER_PREFIX_COUNT} * 3.0 / 10000 + 20
 210     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 211     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${bgp_filling_timeout*3.0/4}
 212     ${result} =    BuiltIn.Evaluate    str(int(${COUNT_APP_PEER_PREFIX_COUNT}) - int(${PREFILL}))
 213     Builtin.Set_Suite_Variable    ${remaining_prefixes}    ${result}
 214     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_LOG_LEVEL}
 215     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_BGP_LOG_LEVEL} org.opendaylight.bgpcep
 216     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_BGP_LOG_LEVEL} org.opendaylight.protocol
 217     ${script_uri_opt}=    Set Variable    --uri config/bgp-rib:application-rib/${BGP_APP_PEER_ID}/tables/bgp-types:ipv4-address-family/bgp-types:unicast-subsequent-address-family/
 218     BuiltIn.Set_Suite_Variable    ${script_uri_opt}
 219
 220 Teardown_Everything
 221     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 222     SSHLibrary.Switch Connection    bgp_peer_console
 223     KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 224     KillPythonTool.Search_And_Kill_Remote_Python    'bgp_app_peer\.py'
 225     BuiltIn.Run_Keyword_And_Ignore_Error    Utils.Get_Sysstat_Statistics
 226     RequestsLibrary.Delete_All_Sessions
 227     SSHLibrary.Close_All_Connections
 228
 229 Open_BGP_Peer_Console
 230     [Documentation]    Create a session for BGP peer.
 231     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}    alias=bgp_peer_console
 232     SSHKeywords.Flexible_Mininet_Login
 233
 234 Open_BGP_Aplicationp_Peer_Console
 235     [Documentation]    Create a session for BGP peer.
 236     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}    alias=bgp_app_peer_console
 237     SSHKeywords.Flexible_Mininet_Login