csit/suites/bgpcep/bgpingest/singlepeer_changecount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py as single iBGP peer.
  12 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  13 ...
  14 ...               This suite requires odl-bgpcep-data-change-counter to be installed so
  15 ...               make sure it is added to "install-features" of any jobs that are going
  16 ...               to invoke it.
  17 ...
  18 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  19 ...               Data change counter is a lightweight way to detect "work is being done".
  20 ...               WaitUtils provide a nice Keyword to wait for stability, but it needs
  21 ...               initial value, that is why Store_Change_Count appears just before work-inducing action.
  22 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  23 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  24 ...
  25 ...               Brief description how to configure BGP peer can be found here:
  26 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:User_Guide#BGP_Peer
  27 ...               http://docs.opendaylight.org/en/stable-boron/user-guide/bgp-user-guide.html#bgp-peering
  28 ...
  29 ...               TODO: Currently, if a bug causes zero increase of data changes,
  30 ...               affected test cases will wait for max time. Reconsider.
  31 ...               If zero increase is allowed as stable, higher number of repetitions should be required.
  32 ...
  33 ...               Additionally this test suite is not compatible with Helium and Hydrogen
  34 ...               releases as they don't include data change counter feature.
  35 ...               Use the other version of the suite (singlepeer_prefixcount.robot) to test them.
  36 Suite Setup       Setup_Everything
  37 Suite Teardown    Teardown_Everything
  38 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  39 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  40 Library           SSHLibrary    timeout=10s
  41 Library           RequestsLibrary
  42 Resource          ${CURDIR}/../../../variables/Variables.robot
  43 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  44 Resource          ${CURDIR}/../../../libraries/ChangeCounter.robot
  45 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  46 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  47 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  48 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  49 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  50 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  51
  52 *** Variables ***
  53 ${BGP_TOOL_LOG_LEVEL}    info
  54 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  55 ${CHECK_PERIOD}    1
  56 ${CHECK_PERIOD_CHANGE_COUNT}    ${CHECK_PERIOD}
  57 ${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    ${CHECK_PERIOD_CHANGE_COUNT}
  58 ${COUNT}          1000000
  59 ${COUNT_CHANGE_COUNT}    ${COUNT}
  60 ${COUNT_CHANGE_COUNT_SINGLE}    ${COUNT_CHANGE_COUNT}
  61 ${HOLDTIME}       180
  62 ${HOLDTIME_CHANGE_COUNT}    ${HOLDTIME}
  63 ${HOLDTIME_CHANGE_COUNT_SINGLE}    ${HOLDTIME_CHANGE_COUNT}
  64 ${INSERT}         1
  65 ${KARAF_LOG_LEVEL}    INFO
  66 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  67 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  68 ${PREFILL}        0
  69 ${REPETITIONS}    1
  70 ${REPETITIONS_CHANGE_COUNT}    ${REPETITIONS}
  71 ${REPETITIONS_CHANGE_COUNT_SINGLE}    ${REPETITIONS_CHANGE_COUNT}
  72 ${RESULTS_FILE_NAME}    bgp.csv
  73 ${TEST_DURATION_MULTIPLIER}    1
  74 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}    ${TEST_DURATION_MULTIPLIER}
  75 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_SINGLE}    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}
  76 ${UPDATE}         single
  77 ${WITHDRAW}       0
  78 ${RIB_INSTANCE}    example-bgp-rib
  79 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  80 ${DEVICE_NAME}    controller-config
  81 ${BGP_PEER_NAME}    example-bgp-peer
  82 # TODO: Option names can be better.
  83 ${last_change_count_single}    -1
  84
  85 *** Test Cases ***
  86 Check_For_Empty_Ipv4_Topology_Before_Talking
  87     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  88     [Tags]    critical
  89     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  90     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  91
  92 Reconfigure_ODL_To_Accept_Connection
  93     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  94     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME_CHANGE_COUNT_SINGLE}    PEER_PORT=${BGP_TOOL_PORT}
  95     ...    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  96     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
  97
  98 Reconfigure_Data_Change_Counter
  99     [Documentation]    Configure data change counter to count transactions in example-ipv4-topology instead of example-linkstate-topology.
 100     ChangeCounter.Reconfigure_Topology_Name    example-ipv4-topology
 101
 102 Verify_Data_Change_Counter_Ready
 103     [Documentation]    Data change counter might have been slower to start than ipv4 topology, wait for it.
 104     BuiltIn.Wait_Until_Keyword_Succeeds    5s    1s    ChangeCounter.Get_Change_Count
 105
 106 Change_Karaf_Logging_Levels
 107     [Documentation]    We may want to set more verbose logging here after configuration is done.
 108     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
 109
 110 Start_Talking_BGP_Speaker
 111     [Documentation]    Start Python speaker to connect to ODL.
 112     Store_Change_Count
 113     # Myport value is needed for checking whether connection at precise port was established.
 114     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT_SINGLE} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 115
 116 Wait_For_Stable_Talking_Ipv4_Topology
 117     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking the change counter.
 118     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 119
 120 Check_Talking_Ipv4_Topology_Count
 121     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 122     [Tags]    critical
 123     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 124     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_SINGLE}
 125
 126 Kill_Talking_BGP_Speaker
 127     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 128     [Tags]    critical
 129     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 130     Store_Change_Count
 131     BGPSpeaker.Kill_BGP_Speaker
 132     FailFast.Do_Not_Fail_Fast_From_Now_On
 133     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 134     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 135
 136 Store_Results_For_Talking_BGP_Speaker
 137     [Documentation]    Store results for plotting
 138     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 139     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 140     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 141     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-talking-totals-${RESULTS_FILE_NAME}
 142     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-talking-performance-${RESULTS_FILE_NAME}
 143
 144 Wait_For_Stable_Ipv4_Topology_After_Talking
 145     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 146     [Tags]    critical
 147     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 148
 149 Check_For_Empty_Ipv4_Topology_After_Talking
 150     [Documentation]    Example-ipv4-topology should be empty now.
 151     [Tags]    critical
 152     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 153     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 154
 155 Start_Listening_BGP_Speaker
 156     [Documentation]    Start Python speaker in listening mode.
 157     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT_SINGLE} --listen --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 158
 159 Reconfigure_ODL_To_Initiate_Connection
 160     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
 161     Store_Change_Count
 162     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME_CHANGE_COUNT_SINGLE}    PEER_PORT=${BGP_TOOL_PORT}
 163     ...    INITIATE=true    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=false    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 164     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 165
 166 Wait_For_Stable_Listening_Ipv4_Topology
 167     [Documentation]    Wait until example-ipv4-topology becomes stable.
 168     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 169
 170 Check_Listening_Ipv4_Topology_Count
 171     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 172     [Tags]    critical
 173     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 174     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_SINGLE}
 175
 176 Kill_Listening_BGP_Speaker
 177     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 178     [Tags]    critical
 179     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 180     Store_Change_Count
 181     BGPSpeaker.Kill_BGP_Speaker
 182     FailFast.Do_Not_Fail_Fast_From_Now_On
 183     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 184     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 185
 186 Store_Results_For_Listening_BGP_Speaker
 187     [Documentation]    Store results for plotting
 188     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 189     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 190     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 191     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-listening-totals-${RESULTS_FILE_NAME}
 192     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-listening-performance-${RESULTS_FILE_NAME}
 193
 194 Wait_For_Stable_Ipv4_Topology_After_Listening
 195     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 196     [Tags]    critical
 197     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 198
 199 Check_For_Empty_Ipv4_Topology_After_Listening
 200     [Documentation]    Example-ipv4-topology should be empty now.
 201     [Tags]    critical
 202     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 203     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 204
 205 Restore_Karaf_Logging_Levels
 206     [Documentation]    Set logging on bgpcep and protocol to the global value.
 207     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 208
 209 Restore_Data_Change_Counter_Configuration
 210     [Documentation]    Configure data change counter back to count transactions affecting example-linkstate-topology.
 211     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 212     ChangeCounter.Reconfigure_Topology_Name    example-linkstate-topology
 213
 214 Delete_Bgp_Peer_Configuration
 215     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 216     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 217     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 218     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 219
 220 *** Keywords ***
 221 Setup_Everything
 222     [Documentation]    Setup imported resources, SSH-login to tools system,
 223     ...    create HTTP session, put Python tool to tools system.
 224     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 225     TemplatedRequests.Create_Default_Session
 226     ChangeCounter.CC_Setup
 227     PrefixCounting.PC_Setup
 228     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}    timeout=125    max_retries=0
 229     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 230     # TODO: Alternatively, create variable in Variables which starts with http.
 231     # Both TODOs would probably need to update every suite relying on current Variables.
 232     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 233     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
 234     SSHKeywords.Flexible_Mininet_Login
 235     SSHKeywords.Require_Python
 236     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 237     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 238     # Calculate the timeout value based on how many routes are going to be pushed
 239     # TODO: Unify formulas with other suites in this directory.
 240     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_SINGLE} * (${COUNT_CHANGE_COUNT_SINGLE} * 9.0 / 10000 + 20)
 241     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 242     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${bgp_filling_timeout*3.0/4}
 243     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 244
 245 Teardown_Everything
 246     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 247     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 248     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 249     RequestsLibrary.Delete_All_Sessions
 250     SSHLibrary.Close_All_Connections
 251
 252 Store_Change_Count
 253     [Documentation]    Get the count of changes from BGP change counter. Ignore error or store the value.
 254     ${status}    ${count} =    BuiltIn.Run_Keyword_And_Ignore_Error    ChangeCounter.Get_Change_Count
 255     BuiltIn.Run_Keyword_If    '${status}' == 'PASS'    BuiltIn.Set_Suite_Variable    ${last_change_count_single}    ${count}
 256
 257 Store_File_To_Workspace
 258     [Arguments]    ${src_file_name}    ${dst_file_name}
 259     [Documentation]    Store the provided file from the SSH client to workspace.
 260     ${files}=    SSHLibrary.List Files In Directory    .
 261     ${output_log}=    SSHLibrary.Execute_Command    cat ${src_file_name}
 262     BuiltIn.Log    ${output_log}
 263     Create File    ${dst_file_name}    ${output_log}