csit/suites/bgpcep/bgpingest/singlepeer_changecount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py as single iBGP peer.
  12 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  13 ...
  14 ...               This suite requires odl-bgpcep-data-change-counter to be installed so
  15 ...               make sure it is added to "install-features" of any jobs that are going
  16 ...               to invoke it.
  17 ...
  18 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  19 ...               Data change counter is a lightweight way to detect "work is being done".
  20 ...               WaitUtils provide a nice Keyword to wait for stability, but it needs
  21 ...               initial value, that is why Store_Change_Count appears just before work-inducing action.
  22 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  23 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  24 ...
  25 ...               Brief description how to configure BGP peer can be found here:
  26 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:User_Guide#BGP_Peer
  27 ...               http://docs.opendaylight.org/en/stable-boron/user-guide/bgp-user-guide.html#bgp-peering
  28 ...               The peer configuration depends on the ${ODL_STREAM}. For "boron" and older streams it uses netconf connector and
  29 ...               for carbon and further it configures peer via openconfig.
  30 ...
  31 ...               TODO: Currently, if a bug causes zero increase of data changes,
  32 ...               affected test cases will wait for max time. Reconsider.
  33 ...               If zero increase is allowed as stable, higher number of repetitions should be required.
  34 ...
  35 ...               Additionally this test suite is not compatible with Helium and Hydrogen
  36 ...               releases as they don't include data change counter feature.
  37 ...               Use the other version of the suite (singlepeer_prefixcount.robot) to test them.
  38 Suite Setup       Setup_Everything
  39 Suite Teardown    Teardown_Everything
  40 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  41 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_And_Start_Fast_Failing_If_Test_Failed
  42 Library           SSHLibrary    timeout=10s
  43 Library           RequestsLibrary
  44 Variables         ${CURDIR}/../../../variables/Variables.py
  45 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  46 Resource          ${CURDIR}/../../../libraries/ChangeCounter.robot
  47 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  48 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  49 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  50 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  51 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  52 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  53
  54 *** Variables ***
  55 ${BGP_TOOL_LOG_LEVEL}    info
  56 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  57 ${CHECK_PERIOD}    1
  58 ${CHECK_PERIOD_CHANGE_COUNT}    ${CHECK_PERIOD}
  59 ${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    ${CHECK_PERIOD_CHANGE_COUNT}
  60 ${COUNT}          1000000
  61 ${COUNT_CHANGE_COUNT}    ${COUNT}
  62 ${COUNT_CHANGE_COUNT_SINGLE}    ${COUNT_CHANGE_COUNT}
  63 ${HOLDTIME}       180
  64 ${HOLDTIME_CHANGE_COUNT}    ${HOLDTIME}
  65 ${HOLDTIME_CHANGE_COUNT_SINGLE}    ${HOLDTIME_CHANGE_COUNT}
  66 ${INSERT}         1
  67 ${KARAF_LOG_LEVEL}    INFO
  68 ${KARAF_BGPCEP_LOG_LEVEL}    ${KARAF_LOG_LEVEL}
  69 ${KARAF_PROTOCOL_LOG_LEVEL}    ${KARAF_BGPCEP_LOG_LEVEL}
  70 ${PREFILL}        0
  71 ${REPETITIONS}    1
  72 ${REPETITIONS_CHANGE_COUNT}    ${REPETITIONS}
  73 ${REPETITIONS_CHANGE_COUNT_SINGLE}    ${REPETITIONS_CHANGE_COUNT}
  74 ${RESULTS_FILE_NAME}    bgp.csv
  75 ${TEST_DURATION_MULTIPLIER}    1
  76 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}    ${TEST_DURATION_MULTIPLIER}
  77 ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_SINGLE}    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT}
  78 ${UPDATE}         single
  79 ${WITHDRAW}       0
  80 ${RIB_INSTANCE}    example-bgp-rib
  81 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  82 ${DEVICE_NAME}    controller-config
  83 ${BGP_PEER_NAME}    example-bgp-peer
  84 # TODO: Option names can be better.
  85 ${last_change_count_single}    -1
  86
  87 *** Test Cases ***
  88 Check_For_Empty_Ipv4_Topology_Before_Talking
  89     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  90     [Tags]    critical
  91     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  92     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  93
  94 Reconfigure_ODL_To_Accept_Connection
  95     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  96     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME_CHANGE_COUNT_SINGLE}    PEER_PORT=${BGP_TOOL_PORT}
  97     ...    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  98     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
  99
 100 Wait_For_Data_Change_Counter_Ready
 101     [Documentation]    Data change counter might have been slower to start than ipv4 topology, wait for it.
 102     BuiltIn.Wait_Until_Keyword_Succeeds    180s    1s    ChangeCounter.Get_Change_Count
 103
 104 Reconfigure_Data_Change_Counter
 105     [Documentation]    Configure data change counter to count transactions in example-ipv4-topology instead of example-linkstate-topology.
 106     ChangeCounter.Reconfigure_Topology_Name    example-ipv4-topology
 107
 108 Change_Karaf_Logging_Levels
 109     [Documentation]    We may want to set more verbose logging here after configuration is done.
 110     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_BGPCEP_LOG_LEVEL}    protocol_level=${KARAF_PROTOCOL_LOG_LEVEL}
 111
 112 Start_Talking_BGP_Speaker
 113     [Documentation]    Start Python speaker to connect to ODL.
 114     Store_Change_Count
 115     # Myport value is needed for checking whether connection at precise port was established.
 116     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT_SINGLE} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 117
 118 Wait_For_Stable_Talking_Ipv4_Topology
 119     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking the change counter.
 120     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 121
 122 Check_Talking_Ipv4_Topology_Count
 123     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 124     [Tags]    critical
 125     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 126     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_SINGLE}
 127
 128 Kill_Talking_BGP_Speaker
 129     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 130     [Tags]    critical
 131     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 132     Store_Change_Count
 133     BGPSpeaker.Kill_BGP_Speaker
 134     FailFast.Do_Not_Fail_Fast_From_Now_On
 135     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 136     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 137
 138 Store_Results_For_Talking_BGP_Speaker
 139     [Documentation]    Store results for plotting
 140     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 141     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 142     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 143     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-talking-totals-${RESULTS_FILE_NAME}
 144     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-talking-performance-${RESULTS_FILE_NAME}
 145
 146 Wait_For_Stable_Ipv4_Topology_After_Talking
 147     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 148     [Tags]    critical
 149     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 150
 151 Check_For_Empty_Ipv4_Topology_After_Talking
 152     [Documentation]    Example-ipv4-topology should be empty now.
 153     [Tags]    critical
 154     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 155     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 156
 157 Start_Listening_BGP_Speaker
 158     [Documentation]    Start Python speaker in listening mode.
 159     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_CHANGE_COUNT_SINGLE} --listen --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 160
 161 Reconfigure_ODL_To_Initiate_Connection
 162     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
 163     Store_Change_Count
 164     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME_CHANGE_COUNT_SINGLE}    PEER_PORT=${BGP_TOOL_PORT}
 165     ...    INITIATE=true    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=false    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 166     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 167
 168 Wait_For_Stable_Listening_Ipv4_Topology
 169     [Documentation]    Wait until example-ipv4-topology becomes stable.
 170     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 171
 172 Check_Listening_Ipv4_Topology_Count
 173     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 174     [Tags]    critical
 175     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 176     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_CHANGE_COUNT_SINGLE}
 177
 178 Kill_Listening_BGP_Speaker
 179     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 180     [Tags]    critical
 181     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 182     Store_Change_Count
 183     BGPSpeaker.Kill_BGP_Speaker
 184     FailFast.Do_Not_Fail_Fast_From_Now_On
 185     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 186     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 187
 188 Store_Results_For_Listening_BGP_Speaker
 189     [Documentation]    Store results for plotting
 190     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 191     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 192     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 193     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    changecount-listening-totals-${RESULTS_FILE_NAME}
 194     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    changecount-listening-performance-${RESULTS_FILE_NAME}
 195
 196 Wait_For_Stable_Ipv4_Topology_After_Listening
 197     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 198     [Tags]    critical
 199     ChangeCounter.Wait_For_Change_Count_To_Become_Stable    timeout=${bgp_emptying_timeout}    period=${CHECK_PERIOD_CHANGE_COUNT_SINGLE}    repetitions=${REPETITIONS_CHANGE_COUNT_SINGLE}    count_to_overcome=${last_change_count_single}
 200
 201 Check_For_Empty_Ipv4_Topology_After_Listening
 202     [Documentation]    Example-ipv4-topology should be empty now.
 203     [Tags]    critical
 204     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 205     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 206
 207 Restore_Karaf_Logging_Levels
 208     [Documentation]    Set logging on bgpcep and protocol to the global value.
 209     KarafKeywords.Set_Bgpcep_Log_Levels    bgpcep_level=${KARAF_LOG_LEVEL}    protocol_level=${KARAF_LOG_LEVEL}
 210
 211 Restore_Data_Change_Counter_Configuration
 212     [Documentation]    Configure data change counter back to count transactions affecting example-linkstate-topology.
 213     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 214     ChangeCounter.Reconfigure_Topology_Name    example-linkstate-topology
 215
 216 Delete_Bgp_Peer_Configuration
 217     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 218     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 219     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 220     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 221
 222 *** Keywords ***
 223 Setup_Everything
 224     [Documentation]    Setup imported resources, SSH-login to tools system,
 225     ...    create HTTP session, put Python tool to tools system.
 226     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 227     TemplatedRequests.Create_Default_Session
 228     ChangeCounter.CC_Setup
 229     PrefixCounting.PC_Setup
 230     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 231     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 232     # TODO: Alternatively, create variable in Variables which starts with http.
 233     # Both TODOs would probably need to update every suite relying on current Variables.
 234     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 235     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
 236     Utils.Flexible_Mininet_Login
 237     SSHKeywords.Require_Python
 238     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 239     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 240     # Calculate the timeout value based on how many routes are going to be pushed
 241     # TODO: Unify formulas with other suites in this directory.
 242     ${timeout} =    BuiltIn.Evaluate    ${TEST_DURATION_MULTIPLIER_CHANGE_COUNT_SINGLE} * (${COUNT_CHANGE_COUNT_SINGLE} * 9.0 / 10000 + 20)
 243     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${timeout}
 244     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${bgp_filling_timeout*3.0/4}
 245     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${KARAF_LOG_LEVEL}
 246
 247 Teardown_Everything
 248     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 249     # Environment issue may have dropped the SSH connection, but we do not want Teardown to fail.
 250     BuiltIn.Run_Keyword_And_Ignore_Error    KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 251     RequestsLibrary.Delete_All_Sessions
 252     SSHLibrary.Close_All_Connections
 253
 254 Store_Change_Count
 255     [Documentation]    Get the count of changes from BGP change counter. Ignore error or store the value.
 256     ${status}    ${count} =    BuiltIn.Run_Keyword_And_Ignore_Error    ChangeCounter.Get_Change_Count
 257     BuiltIn.Run_Keyword_If    '${status}' == 'PASS'    BuiltIn.Set_Suite_Variable    ${last_change_count_single}    ${count}
 258
 259 Store_File_To_Workspace
 260     [Arguments]    ${src_file_name}    ${dst_file_name}
 261     [Documentation]    Store the provided file from the SSH client to workspace.
 262     ${files}=    SSHLibrary.List Files In Directory    .
 263     ${output_log}=    SSHLibrary.Execute_Command    cat ${src_file_name}
 264     BuiltIn.Log    ${output_log}
 265     Create File    ${dst_file_name}    ${output_log}