csit/suites/bgpcep/bgpingest/singlepeer_prefixcount.robot

   1 *** Settings ***
   2 Documentation     BGP performance of ingesting from 1 iBGP peer, data change counter is NOT used.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This suite uses play.py as single iBGP peer.
  12 ...               The suite only looks at example-ipv4-topology, so RIB is not examined.
  13 ...
  14 ...               The suite consists of two halves, differing on which side initiates BGP connection.
  15 ...               State of "work is being done" is detected by increasing value of prefixes in topology.
  16 ...               The time for Wait_For_Stable_* cases to finish is the main performance metric.
  17 ...               After waiting for stability is done, full check on number of prefixes present is performed.
  18 ...
  19 ...               TODO: Currently, if a bug causes prefix count to remain at zero,
  20 ...               affected test cases will wait for max time. Reconsider.
  21 ...               If zero is allowed as stable, higher period or repetitions would be required.
  22 ...
  23 ...               The prefix counting is quite heavyweight and may induce large variation in time.
  24 ...               Try the other version of the suite (singlepeer_changecount.robot) to get better precision.
  25 Suite Setup       Setup_Everything
  26 Suite Teardown    Teardown_Everything
  27 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Fast_Failing
  28 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  29 Library           SSHLibrary    timeout=10s
  30 Library           RequestsLibrary
  31 Variables         ${CURDIR}/../../../variables/Variables.py
  32 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  33 Resource          ${CURDIR}/../../../libraries/ConfigViaRestconf.robot
  34 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  35 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  36 Resource          ${CURDIR}/../../../libraries/PrefixCounting.robot
  37 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  38
  39 *** Variables ***
  40 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  41 ${HOLDTIME}       180
  42 ${HOLDTIME_PREFIX_COUNT}    ${HOLDTIME}
  43 ${COUNT}          1000000
  44 ${COUNT_PREFIX_COUNT}    ${COUNT}
  45 ${CHECK_PERIOD}    1
  46 ${CHECK_PERIOD_PREFIX_COUNT}    ${CHECK_PERIOD}
  47 ${REPETITIONS_PREFIX_COUNT}    1
  48 ${INSERT}         1
  49 ${WITHDRAW}       0
  50 ${PREFILL}        0
  51 ${UPDATE}         single
  52 ${BGP_TOOL_LOG_LEVEL}    info
  53 ${CONTROLLER_LOG_LEVEL}    INFO
  54 ${CONTROLLER_BGP_LOG_LEVEL}    DEFAULT
  55 ${RESULTS_FILE_NAME}    bgp.csv
  56 # TODO: Option names can be better.
  57 ${last_prefix_count}    -1
  58
  59 *** Test Cases ***
  60 Check_For_Empty_Ipv4_Topology_Before_Talking
  61     [Documentation]    Wait for example-ipv4-topology to come up and empty. Give large timeout for case when BGP boots slower than restconf.
  62     [Tags]    critical
  63     # TODO: Choose which tags to assign and make sure they are assigned correctly.
  64     BuiltIn.Wait_Until_Keyword_Succeeds    120s    1s    PrefixCounting.Check_Ipv4_Topology_Is_Empty
  65
  66 Reconfigure_ODL_To_Accept_Connection
  67     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  68     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_PREFIX_COUNT}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'false'}
  69     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
  70
  71 Start_Talking_BGP_Speaker
  72     [Documentation]    Start Python speaker to connect to ODL.
  73     # Myport value is needed for checking whether connection at precise port was established.
  74     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_PREFIX_COUNT} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
  75
  76 Wait_For_Stable_Talking_Ipv4_Topology
  77     [Documentation]    Wait until example-ipv4-topology becomes stable. This is done by checking stability of prefix count.
  78     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT}    repetitions=${REPETITIONS_PREFIX_COUNT}    excluded_count=0
  79
  80 Check_Talking_Ipv4_Topology_Count
  81     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
  82     [Tags]    critical
  83     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_PREFIX_COUNT}
  84
  85 Kill_Talking_BGP_Speaker
  86     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
  87     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  88     BGPSpeaker.Kill_BGP_Speaker
  89     FailFast.Do_Not_Fail_Fast_From_Now_On
  90     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
  91     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
  92
  93 Store_Results_For_Talking_BGP_Speaker
  94     [Documentation]    Store results for plotting
  95     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  96     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
  97     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
  98     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    prefixcount-talking-totals-${RESULTS_FILE_NAME}
  99     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    prefixcount-talking-performance-${RESULTS_FILE_NAME}
 100
 101 Wait_For_Stable_Ipv4_Topology_After_Talking
 102     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 103     [Tags]    critical
 104     # TODO: Is is possible to have failed at Check_Talking_Ipv4_Topology_Count and still have initial period of constant count?
 105     # FIXME: If yes, do count here to get the initial value and use it (if nonzero).
 106     # TODO: If yes, decide whether access to the FailFast state should have keyword or just variable name.
 107     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT}    repetitions=${REPETITIONS_PREFIX_COUNT}    excluded_count=${COUNT_PREFIX_COUNT}
 108
 109 Check_For_Empty_Ipv4_Topology_After_Talking
 110     [Documentation]    Example-ipv4-topology should be empty now.
 111     [Tags]    critical
 112     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 113
 114 Start_Listening_BGP_Speaker
 115     [Documentation]    Start Python speaker in listening mode.
 116     BGPSpeaker.Start_BGP_Speaker    --amount ${COUNT_PREFIX_COUNT} --listen --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --insert=${INSERT} --withdraw=${WITHDRAW} --prefill ${PREFILL} --update ${UPDATE} --${BGP_TOOL_LOG_LEVEL} --results ${RESULTS_FILE_NAME}
 117
 118 Reconfigure_ODL_To_Initiate_Connection
 119     [Documentation]    Replace BGP peer config module, now with initiate-connection set to true.
 120     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer', 'IP': '${TOOLS_SYSTEM_IP}', 'HOLDTIME': '${HOLDTIME_PREFIX_COUNT}', 'PEER_PORT': '${BGP_TOOL_PORT}', 'INITIATE': 'true'}
 121     ConfigViaRestconf.Put_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 122
 123 Wait_For_Stable_Listening_Ipv4_Topology
 124     [Documentation]    Wait until example-ipv4-topology becomes stable.
 125     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT}    repetitions=${REPETITIONS_PREFIX_COUNT}    excluded_count=0
 126
 127 Check_Listening_Ipv4_Topology_Count
 128     [Documentation]    Count the routes in example-ipv4-topology and fail if the count is not correct.
 129     [Tags]    critical
 130     PrefixCounting.Check_Ipv4_Topology_Count    ${COUNT_PREFIX_COUNT}
 131
 132 Kill_Listening_BGP_Speaker
 133     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 134     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 135     BGPSpeaker.Kill_BGP_Speaker
 136     FailFast.Do_Not_Fail_Fast_From_Now_On
 137     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 138     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 139
 140 Store_Results_For_Listening_BGP_Speaker
 141     [Documentation]    Store results for plotting
 142     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 143     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    totals-${RESULTS_FILE_NAME}
 144     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    performance-${RESULTS_FILE_NAME}
 145     Store_File_To_Workspace    totals-${RESULTS_FILE_NAME}    prefixcount-listening-totals-${RESULTS_FILE_NAME}
 146     Store_File_To_Workspace    performance-${RESULTS_FILE_NAME}    prefixcount-listening-performance-${RESULTS_FILE_NAME}
 147
 148 Wait_For_Stable_Ipv4_Topology_After_Listening
 149     [Documentation]    Wait until example-ipv4-topology becomes stable again.
 150     [Tags]    critical
 151     PrefixCounting.Wait_For_Ipv4_Topology_Prefixes_To_Become_Stable    timeout=${bgp_filling_timeout}    period=${CHECK_PERIOD_PREFIX_COUNT}    repetitions=${REPETITIONS_PREFIX_COUNT}    excluded_count=${COUNT_PREFIX_COUNT}
 152
 153 Check_For_Empty_Ipv4_Topology_After_Listening
 154     [Documentation]    Example-ipv4-topology should be empty now.
 155     [Tags]    critical
 156     PrefixCounting.Check_Ipv4_Topology_Is_Empty
 157
 158 Delete_Bgp_Peer_Configuration
 159     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 160     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 161     ${template_as_string} =    BuiltIn.Set_Variable    {'NAME': 'example-bgp-peer'}
 162     ConfigViaRestconf.Delete_Xml_Template_Folder_Config_Via_Restconf    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    ${template_as_string}
 163
 164 *** Keywords ***
 165 Setup_Everything
 166     [Documentation]    Setup imported resources, SSH-login to tools system,
 167     ...    create HTTP session, put Python tool to tools system.
 168     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 169     ConfigViaRestconf.Setup_Config_Via_Restconf
 170     PrefixCounting.PC_Setup
 171     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 172     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
 173     Utils.Flexible_Mininet_Login
 174     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 175     # TODO: Do not include slash in ${OPERATIONAL_TOPO_API}, having it typed here is more readable.
 176     # TODO: Alternatively, create variable in Variables which starts with http.
 177     # Both TODOs would probably need to update every suite relying on current Variables.
 178     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 179     # Calculate the timeout value based on how many routes are going to be pushed
 180     ${count} =    Builtin.Convert_To_Integer    ${COUNT_PREFIX_COUNT}
 181     # TODO: Replace 20 with some formula from period and repetitions.
 182     Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${count*3/10000+20}
 183     Builtin.Set_Suite_Variable    ${bgp_emptying_timeout}    ${bgp_filling_timeout*3/4}
 184     # Timeout in case of doubled number of updates per iteration (per prefix count increase in the simplest mixed scenario)
 185     Builtin.Run_Keyword_If    '${UPDATE}' == 'mixed'    Builtin.Set_Suite_Variable    ${bgp_filling_timeout}    ${count*6/10000+20}
 186     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_LOG_LEVEL}
 187     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_BGP_LOG_LEVEL} org.opendaylight.bgpcep
 188     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_BGP_LOG_LEVEL} org.opendaylight.protocol
 189
 190 Teardown_Everything
 191     [Documentation]    Make sure Python tool was killed and tear down imported Resources.
 192     KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 193     ConfigViaRestconf.Teardown_Config_Via_Restconf
 194     RequestsLibrary.Delete_All_Sessions
 195     SSHLibrary.Close_All_Connections
 196
 197 Store_File_To_Workspace
 198     [Arguments]    ${src_file_name}    ${dst_file_name}
 199     [Documentation]    Store the provided file from the SSH client to workspace.
 200     ${files}=    SSHLibrary.List Files In Directory    .
 201     ${output_log}=    SSHLibrary.Execute_Command    cat ${src_file_name}
 202     BuiltIn.Log    ${output_log}
 203     Create File    ${dst_file_name}    ${output_log}