csit/suites/bgpcep/bgpuser/ebgp_peers_basic.robot

   1 *** Settings ***
   2 Documentation     Basic tests for eBGP application peers.
   3 ...
   4 ...               Copyright (c) 2015-2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               Test suite performs basic eBGP functional tests:
  11 ...               Two eBGP peers advertise the same group of prefixes (aka BGP HA)
  12 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:BGP
  13 ...               Reported bugs:
  14 ...               Bug 4834 - ODL controller announces the same route twice (two eBGP scenario aka HA)
  15 ...               Bug 4835 - Routes not withdrawn when eBGP peers are disconnected (the same prefixes announced)
  16 ...
  17 ...               TODO: Extend testsuite by tests dedicated to path selection algorithm
  18 ...               TODO: Choose keywords used by more than one test suite to be placed in a common place.
  19 Suite Setup       Setup_Everything
  20 Suite Teardown    Teardown_Everything
  21 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  22 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  23 Library           Collections
  24 Library           OperatingSystem
  25 Library           RequestsLibrary
  26 Variables         ${CURDIR}/../../../variables/Variables.py
  27 Variables         ${CURDIR}/../../../variables/bgpuser/variables.py    ${TOOLS_SYSTEM_IP}    ${ODL_STREAM}
  28 Resource          ${CURDIR}/../../../libraries/BGPcliKeywords.robot
  29 Resource          ${CURDIR}/../../../libraries/BGPSpeaker.robot
  30 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  31 Resource          ${CURDIR}/../../../libraries/KillPythonTool.robot
  32 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  33 Resource          ${CURDIR}/../../../libraries/SSHKeywords.robot
  34 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  35 Resource          ${CURDIR}/../../../libraries/Utils.robot
  36 Resource          ${CURDIR}/../../../libraries/WaitForFailure.robot
  37
  38 *** Variables ***
  39 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  40 ${HOLDTIME}       180
  41 ${BGP_PEER_LOG_LEVEL}    debug
  42 ${CONTROLLER_LOG_LEVEL}    INFO
  43 ${CONTROLLER_BGP_LOG_LEVEL}    DEFAULT
  44 ${iBGP_PEER1_IP}    127.0.0.1
  45 ${eBGP_PEER1_IP}    127.0.0.3
  46 ${eBGP_PEER2_IP}    127.0.0.4
  47 ${iBGP_PEER1_FIRST_PREFIX_IP}    8.1.0.0
  48 ${eBGP_PEERS_FIRST_PREFIX_IP}    8.0.0.0
  49 ${eBGP_PEER1_FIRST_PREFIX_IP}    ${eBGP_PEERS_FIRST_PREFIX_IP}
  50 ${eBGP_PEER2_FIRST_PREFIX_IP}    ${eBGP_PEERS_FIRST_PREFIX_IP}
  51 ${eBGP_PEER1_NEXT_HOP}    1.1.1.1
  52 ${eBGP_PEER2_NEXT_HOP}    2.2.2.2
  53 ${PREFIX_LEN}     28
  54 ${iBGP_PEER1_PREFIX_LEN}    ${PREFIX_LEN}
  55 ${eBGP_PEER1_PREFIX_LEN}    ${PREFIX_LEN}
  56 ${eBGP_PEER2_PREFIX_LEN}    ${PREFIX_LEN}
  57 ${PREFIX_COUNT}    2
  58 ${iBGP_PEER1_PREFIX_COUNT}    0
  59 ${eBGP_PEER1_PREFIX_COUNT}    ${PREFIX_COUNT}
  60 ${eBGP_PEER2_PREFIX_COUNT}    ${PREFIX_COUNT}
  61 ${eBGP_PEERS_AS}    32768
  62 ${eBGP_PEER1_AS}    ${eBGP_PEERS_AS}
  63 ${eBGP_PEER2_AS}    ${eBGP_PEERS_AS}
  64 ${iBGP_PEER1_LOG_FILE}    bgp_peer1.log
  65 ${eBGP_PEER1_LOG_FILE}    ebgp_peer1.log
  66 ${eBGP_PEER2_LOG_FILE}    ebgp_peer2.log
  67 ${iBGP_PEER1_COMMAND}    python play.py --firstprefix ${iBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${iBGP_PEER1_PREFIX_LEN} --amount ${iBGP_PEER1_PREFIX_COUNT} --myip=${iBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --${BGP_PEER_LOG_LEVEL} --logfile ${iBGP_PEER1_LOG_FILE}
  68 ${eBGP_PEER1_COMMAND}    python play.py --firstprefix ${eBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${eBGP_PEER1_PREFIX_LEN} --amount ${eBGP_PEER1_PREFIX_COUNT} --myip=${eBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --nexthop ${eBGP_PEER1_NEXT_HOP} --asnumber ${eBGP_PEER1_AS} --${BGP_PEER_LOG_LEVEL} --logfile ${eBGP_PEER1_LOG_FILE}
  69 ${eBGP_PEER2_COMMAND}    python play.py --firstprefix ${eBGP_PEER2_FIRST_PREFIX_IP} --prefixlen ${eBGP_PEER2_PREFIX_LEN} --amount ${eBGP_PEER2_PREFIX_COUNT} --myip=${eBGP_PEER2_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --nexthop ${eBGP_PEER2_NEXT_HOP} --asnumber ${eBGP_PEER2_AS} --${BGP_PEER_LOG_LEVEL} --logfile ${eBGP_PEER2_LOG_FILE}
  70 ${iBGP_PEER1_OPTIONS}    &>${iBGP_PEER1_LOG_FILE}
  71 ${eBGP_PEER1_OPTIONS}    &>${eBGP_PEER1_LOG_FILE}
  72 ${eBGP_PEER2_OPTIONS}    &>${eBGP_PEER2_LOG_FILE}
  73 ${DEFAULT_LOG_CHECK_TIMEOUT}    20s
  74 ${DEFAULT_LOG_CHECK_PERIOD}    1s
  75 ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    10s
  76 ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    1s
  77 ${RIB_INSTANCE}    example-bgp-rib
  78 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  79 ${DEVICE_NAME}    controller-config
  80
  81 *** Test Cases ***
  82 Configure_BGP_Peers
  83     [Documentation]    Configure an iBGP and two eBGP peers
  84     [Tags]    critical
  85     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ibgp-peer1    IP=${iBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  86     ...    PEER_ROLE=ibgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  87     ...    RR_CLIENT=false
  88     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}
  89     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ebgp-peer1    IP=${eBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  90     ...    PEER_ROLE=ebgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  91     ...    RR_CLIENT=false    AS_NUMBER=${eBGP_PEER1_AS}
  92     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
  93     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ebgp-peer2    IP=${eBGP_PEER2_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  94     ...    PEER_ROLE=ebgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  95     ...    RR_CLIENT=false    AS_NUMBER=${eBGP_PEER2_AS}
  96     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
  97
  98 Connect_iBGP_Peer1
  99     [Documentation]    Connect BGP peer
 100     [Tags]    critical
 101     SSHLibrary.Switch Connection    ibgp_peer1_console
 102     Start_Console_Tool    ${iBGP_PEER1_COMMAND}    ${iBGP_PEER1_OPTIONS}
 103     Read_And_Fail_If_Prompt_Is_Seen
 104     Check_Example_IPv4_Topology_Does_Not_Contain    prefix
 105
 106 Connect_eBGP_Peer1
 107     [Documentation]    Connect BGP peer
 108     [Tags]    critical
 109     SSHLibrary.Switch Connection    ebgp_peer1_console
 110     Start_Console_Tool    ${eBGP_PEER1_COMMAND}    ${eBGP_PEER1_OPTIONS}
 111     Read_And_Fail_If_Prompt_Is_Seen
 112
 113 Check_IPv4_Topology_For_First_Path
 114     [Documentation]    The IPv4 topology shall contain the route announced by the first eBGP
 115     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    Check_Example_IPv4_Topology_Content    "node-id":"${eBGP_PEER1_NEXT_HOP}"
 116     Check_Example_IPv4_Topology_Content    "prefix":"${eBGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}"
 117
 118 iBGP_Check_Log_For_Introduced_Prefixes
 119     [Documentation]    Check incomming updates for introduced routes
 120     [Tags]    critical
 121     SSHLibrary.Switch Connection    ibgp_peer1_console
 122     ${total_prefix_count}=    BuiltIn.Evaluate    ${eBGP_PEER1_PREFIX_COUNT}
 123     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${total_prefix_count}
 124     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER1_NEXT_HOP}
 125     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER1_PREFIX_COUNT}
 126     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER2_NEXT_HOP}
 127     BuiltIn.Should_Be_Equal_As_Integers    ${count}    0
 128
 129 Connect_eBGP_Peer2
 130     [Documentation]    Connect BGP peer and check empty topology
 131     [Tags]    critical
 132     SSHLibrary.Switch Connection    ebgp_peer2_console
 133     Start_Console_Tool    ${eBGP_PEER2_COMMAND}    ${eBGP_PEER2_OPTIONS}
 134     Read_And_Fail_If_Prompt_Is_Seen
 135
 136 Disconnect_eBGP_Peer1
 137     [Documentation]    Stop BGP peer, log topology and store logs
 138     [Tags]    critical
 139     SSHLibrary.Switch Connection    ebgp_peer1_console
 140     Stop_Console_Tool
 141     Store_File_To_Workspace    ${eBGP_PEER1_LOG_FILE}    ${eBGP_PEER1_LOG_FILE}
 142
 143 Check_IPv4_Topology_For_Second_Path
 144     [Documentation]    The IPv4 topology shall contain the route announced by the second eBGP now
 145     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    Check_Example_IPv4_Topology_Content    "node-id":"${eBGP_PEER2_NEXT_HOP}"
 146     Check_Example_IPv4_Topology_Content    "prefix":"${eBGP_PEER2_FIRST_PREFIX_IP}/${PREFIX_LEN}"
 147
 148 iBGP_Check_Log_For_Updated_Prefixes
 149     [Documentation]    Check incomming updates for updated routes
 150     [Tags]    critical
 151     SSHLibrary.Switch Connection    ibgp_peer1_console
 152     ${total_prefix_count}=    BuiltIn.Evaluate    ${eBGP_PEER1_PREFIX_COUNT} + ${eBGP_PEER2_PREFIX_COUNT}
 153     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${total_prefix_count}
 154     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER1_NEXT_HOP}
 155     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER1_PREFIX_COUNT}
 156     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER2_NEXT_HOP}
 157     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER2_PREFIX_COUNT}
 158     [Teardown]    Report_Failure_Due_To_Bug    4834
 159
 160 Disconnect_eBGP_Peer2
 161     [Documentation]    Stop BGP peer, store logs and wait for empty topology
 162     [Tags]    critical
 163     SSHLibrary.Switch Connection    ebgp_peer2_console
 164     Stop_Console_Tool
 165     Store_File_To_Workspace    ${eBGP_PEER2_LOG_FILE}    ${eBGP_PEER2_LOG_FILE}
 166
 167 Check_For_Empty_IPv4_Topology
 168     [Documentation]    The IPv4 topology shall be empty
 169     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    Check_Example_IPv4_Topology_Does_Not_Contain    prefix
 170     [Teardown]    Report_Failure_Due_To_Bug    4835
 171
 172 iBGP_Check_Log_For_Withdrawn_Prefixes
 173     [Documentation]    Check incomming updates for withdrawn routes
 174     [Tags]    critical
 175     SSHLibrary.Switch Connection    ibgp_peer1_console
 176     ${prefixes_to_be_removed}=    BuiltIn.Evaluate    max(${eBGP_PEER1_PREFIX_COUNT}, ${eBGP_PEER2_PREFIX_COUNT})
 177     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    withdrawn_prefix_received:    ${prefixes_to_be_removed}
 178     [Teardown]    Report_Failure_Due_To_Bug    4835
 179
 180 Disconnect_iBGP_Peer1
 181     [Documentation]    Stop BGP peer, log topology and store logs
 182     [Tags]    critical
 183     SSHLibrary.Switch Connection    ibgp_peer1_console
 184     Stop_Console_Tool
 185     Store_File_To_Workspace    ${iBGP_PEER1_LOG_FILE}    ${iBGP_PEER1_LOG_FILE}
 186
 187 Delete_BGP_Peers_Configuration
 188     [Documentation]    Delete all previously configured BGP peers.
 189     [Tags]    critical
 190     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ibgp-peer1    IP=${iBGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 191     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}
 192     Collections.Set To Dictionary    ${mapping}    NAME=example-ebgp-peer1    IP=${eBGP_PEER1_IP}
 193     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 194     Collections.Set To Dictionary    ${mapping}    NAME=example-ebgp-peer2    IP=${eBGP_PEER2_IP}
 195     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 196
 197 *** Keywords ***
 198 Setup_Everything
 199     [Documentation]    Initialize SetupUtils. SSH-login to mininet machine, create HTTP session,
 200     ...    prepare directories for responses, put Python tool to mininet machine, setup imported resources.
 201     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 202     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 203     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ibgp_peer1_console
 204     Utils.Flexible_Controller_Login
 205     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ebgp_peer1_console
 206     Utils.Flexible_Controller_Login
 207     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ebgp_peer2_console
 208     Utils.Flexible_Controller_Login
 209     SSHKeywords.Require_Python
 210     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 211     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 212     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_TOPO_API}    auth=${AUTH}
 213     TemplatedRequests.Create_Default_Session
 214     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_LOG_LEVEL}
 215     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_BGP_LOG_LEVEL} org.opendaylight.bgpcep
 216     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_BGP_LOG_LEVEL} org.opendaylight.protocol
 217
 218 Teardown_Everything
 219     [Documentation]    Create and Log the diff between expected and actual responses, make sure Python tool was killed.
 220     ...    Tear down imported Resources.
 221     KillPythonTool.Search_And_Kill_Remote_Python    'play\.py'
 222     RequestsLibrary.Delete_All_Sessions
 223     SSHLibrary.Close_All_Connections
 224
 225 Read_Text_Before_Prompt
 226     [Documentation]    Log text gathered by SSHLibrary.Read_Until_Prompt.
 227     ...    This needs to be a separate keyword just because how Read_And_Fail_If_Prompt_Is_Seen is implemented.
 228     ${text}=    SSHLibrary.Read_Until_Prompt
 229     BuiltIn.Log    ${text}
 230
 231 Check_Example_IPv4_Topology_Content
 232     [Arguments]    ${string_to_check}=${EMPTY}
 233     [Documentation]    Check the example-ipv4-topology content for string
 234     ${response}=    RequestsLibrary.Get Request    operational    topology/example-ipv4-topology
 235     BuiltIn.Log    ${response.status_code}
 236     BuiltIn.Log    ${response.text}
 237     BuiltIn.Should_Contain    ${response.text}    ${string_to_check}
 238
 239 Check_Example_IPv4_Topology_Does_Not_Contain
 240     [Arguments]    ${string_to_check}
 241     [Documentation]    Check the example-ipv4-topology does not contain the string
 242     ${response}=    RequestsLibrary.Get Request    operational    topology/example-ipv4-topology
 243     BuiltIn.Log    ${response.status_code}
 244     BuiltIn.Log    ${response.text}
 245     BuiltIn.Should_Not_Contain    ${response.text}    ${string_to_check}
 246
 247 Store_File_To_Workspace
 248     [Arguments]    ${source_file_name}    ${target_file_name}
 249     [Documentation]    Store the ${source_file_name} to the workspace as ${target_file_name}.
 250     ${output_log}=    SSHLibrary.Execute_Command    cat ${source_file_name}
 251     BuiltIn.Log    ${output_log}
 252     Create File    ${target_file_name}    ${output_log}