csit/suites/bgpcep/bgpuser/ebgp_peers_basic.robot

   1 *** Settings ***
   2 Documentation     Basic tests for eBGP application peers.
   3 ...
   4 ...               Copyright (c) 2015-2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               Test suite performs basic eBGP functional tests:
  11 ...               Two eBGP peers advertise the same group of prefixes (aka BGP HA)
  12 ...               https://wiki.opendaylight.org/view/BGP_LS_PCEP:BGP
  13 ...               Reported bugs:
  14 ...               Bug 4834 - ODL controller announces the same route twice (two eBGP scenario aka HA)
  15 ...               Bug 4835 - Routes not withdrawn when eBGP peers are disconnected (the same prefixes announced)
  16 ...
  17 ...               For versions Fluorine and above, there are test cases:
  18 ...               TC_LAS (test case local AS)
  19 ...               - configuration of ebgp with local-as and ibgp without local-as
  20 ...               - connect bgp speakers (play.py) to both peers and check their connection
  21 ...               - check adj-rib-out on both peers, expecting local-as in as-sequence on both peers.
  22 ...
  23 ...               TODO: Extend testsuite by tests dedicated to path selection algorithm
  24 ...               TODO: Choose keywords used by more than one test suite to be placed in a common place.
  25 Suite Setup       Setup_Everything
  26 Suite Teardown    BgpOperations.Teardown_Everything
  27 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  28 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  29 Library           Collections
  30 Library           OperatingSystem
  31 Library           RequestsLibrary
  32 Resource          ../../../libraries/BGPcliKeywords.robot
  33 Resource          ../../../libraries/BgpOperations.robot
  34 Resource          ../../../libraries/BGPSpeaker.robot
  35 Resource          ../../../libraries/CompareStream.robot
  36 Resource          ../../../libraries/FailFast.robot
  37 Resource          ../../../libraries/SetupUtils.robot
  38 Resource          ../../../libraries/SSHKeywords.robot
  39 Resource          ../../../libraries/TemplatedRequests.robot
  40 Resource          ../../../variables/Variables.robot
  41
  42 *** Variables ***
  43 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  44 ${BGP_PEER_LOG_LEVEL}    debug
  45 ${CONFIG_SESSION}    config-session
  46 ${HOLDTIME}       180
  47 ${ODL_LOG_LEVEL}    INFO
  48 ${ODL_BGP_LOG_LEVEL}    DEFAULT
  49 ${iBGP_PEER1_IP}    127.0.0.1
  50 ${eBGP_PEER1_IP}    127.0.0.3
  51 ${eBGP_PEER2_IP}    127.0.0.4
  52 ${iBGP_PEER1_FIRST_PREFIX_IP}    8.1.0.0
  53 ${eBGP_PEERS_FIRST_PREFIX_IP}    8.0.0.0
  54 ${eBGP_PEER1_FIRST_PREFIX_IP}    ${eBGP_PEERS_FIRST_PREFIX_IP}
  55 ${eBGP_PEER2_FIRST_PREFIX_IP}    ${eBGP_PEERS_FIRST_PREFIX_IP}
  56 ${eBGP_PEER1_NEXT_HOP}    1.1.1.1
  57 ${eBGP_PEER2_NEXT_HOP}    2.2.2.2
  58 ${PREFIX_LEN}     28
  59 ${iBGP_PEER1_PREFIX_LEN}    ${PREFIX_LEN}
  60 ${eBGP_PEER1_PREFIX_LEN}    ${PREFIX_LEN}
  61 ${eBGP_PEER2_PREFIX_LEN}    ${PREFIX_LEN}
  62 ${PREFIX_COUNT}    2
  63 ${iBGP_PEER1_PREFIX_COUNT}    0
  64 ${eBGP_PEER1_PREFIX_COUNT}    ${PREFIX_COUNT}
  65 ${eBGP_PEER2_PREFIX_COUNT}    ${PREFIX_COUNT}
  66 ${eBGP_PEERS_AS}    32768
  67 ${eBGP_PEER1_AS}    ${eBGP_PEERS_AS}
  68 ${eBGP_PEER2_AS}    ${eBGP_PEERS_AS}
  69 ${iBGP_PEER1_LOG_FILE}    bgp_peer1.log
  70 ${eBGP_PEER1_LOG_FILE}    ebgp_peer1.log
  71 ${eBGP_PEER2_LOG_FILE}    ebgp_peer2.log
  72 ${iBGP_PEER1_COMMAND}    python play.py --firstprefix ${iBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${iBGP_PEER1_PREFIX_LEN} --amount ${iBGP_PEER1_PREFIX_COUNT} --myip=${iBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --${BGP_PEER_LOG_LEVEL} --logfile ${iBGP_PEER1_LOG_FILE}
  73 ${eBGP_PEER1_COMMAND}    python play.py --firstprefix ${eBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${eBGP_PEER1_PREFIX_LEN} --amount ${eBGP_PEER1_PREFIX_COUNT} --myip=${eBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --nexthop ${eBGP_PEER1_NEXT_HOP} --asnumber ${eBGP_PEER1_AS} --${BGP_PEER_LOG_LEVEL} --logfile ${eBGP_PEER1_LOG_FILE}
  74 ${eBGP_PEER2_COMMAND}    python play.py --firstprefix ${eBGP_PEER2_FIRST_PREFIX_IP} --prefixlen ${eBGP_PEER2_PREFIX_LEN} --amount ${eBGP_PEER2_PREFIX_COUNT} --myip=${eBGP_PEER2_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --nexthop ${eBGP_PEER2_NEXT_HOP} --asnumber ${eBGP_PEER2_AS} --${BGP_PEER_LOG_LEVEL} --logfile ${eBGP_PEER2_LOG_FILE}
  75 ${iBGP_PEER1_OPTIONS}    &>${iBGP_PEER1_LOG_FILE}
  76 ${eBGP_PEER1_OPTIONS}    &>${eBGP_PEER1_LOG_FILE}
  77 ${eBGP_PEER2_OPTIONS}    &>${eBGP_PEER2_LOG_FILE}
  78 ${DEFAULT_LOG_CHECK_TIMEOUT}    20s
  79 ${DEFAULT_LOG_CHECK_PERIOD}    1s
  80 ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    10s
  81 ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    1s
  82 ${RIB_INSTANCE}    example-bgp-rib
  83 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  84 ${DEVICE_NAME}    controller-config
  85 ${DEFAULT_AS}     64496
  86 ${LOCAL_AS}       65432
  87 ${eBGP_AS}        64497
  88
  89 *** Test Cases ***
  90 Configure_BGP_Peers
  91     [Documentation]    Configure an iBGP and two eBGP peers
  92     [Tags]    critical
  93     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ibgp-peer1    IP=${iBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  94     ...    PEER_ROLE=ibgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  95     ...    RR_CLIENT=false
  96     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}
  97     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ebgp-peer1    IP=${eBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  98     ...    PEER_ROLE=ebgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  99     ...    RR_CLIENT=false    AS_NUMBER=${eBGP_PEER1_AS}
 100     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 101     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ebgp-peer2    IP=${eBGP_PEER2_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
 102     ...    PEER_ROLE=ebgp    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
 103     ...    RR_CLIENT=false    AS_NUMBER=${eBGP_PEER2_AS}
 104     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 105
 106 Connect_iBGP_Peer1
 107     [Documentation]    Connect BGP peer
 108     [Tags]    critical
 109     SSHLibrary.Switch Connection    ibgp_peer1_console
 110     Start_Console_Tool    ${iBGP_PEER1_COMMAND}    ${iBGP_PEER1_OPTIONS}
 111     Read_And_Fail_If_Prompt_Is_Seen
 112     BgpOperations.Check_Example_IPv4_Topology_Does_Not_Contain    ${CONFIG_SESSION}    prefix
 113
 114 Connect_eBGP_Peer1
 115     [Documentation]    Connect BGP peer
 116     [Tags]    critical
 117     SSHLibrary.Switch Connection    ebgp_peer1_console
 118     Start_Console_Tool    ${eBGP_PEER1_COMMAND}    ${eBGP_PEER1_OPTIONS}
 119     Read_And_Fail_If_Prompt_Is_Seen
 120
 121 Check_IPv4_Topology_For_First_Path
 122     [Documentation]    The IPv4 topology shall contain the route announced by the first eBGP
 123     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    ${CONFIG_SESSION}    "node-id":"${eBGP_PEER1_NEXT_HOP}"
 124     BgpOperations.Check_Example_IPv4_Topology_Content    ${CONFIG_SESSION}    "prefix":"${eBGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}"
 125
 126 iBGP_Check_Log_For_Introduced_Prefixes
 127     [Documentation]    Check incomming updates for introduced routes
 128     [Tags]    critical
 129     SSHLibrary.Switch Connection    ibgp_peer1_console
 130     ${total_prefix_count}=    BuiltIn.Evaluate    ${eBGP_PEER1_PREFIX_COUNT}
 131     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${total_prefix_count}
 132     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER1_NEXT_HOP}
 133     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER1_PREFIX_COUNT}
 134     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER2_NEXT_HOP}
 135     BuiltIn.Should_Be_Equal_As_Integers    ${count}    0
 136
 137 Connect_eBGP_Peer2
 138     [Documentation]    Connect BGP peer and check empty topology
 139     [Tags]    critical
 140     SSHLibrary.Switch Connection    ebgp_peer2_console
 141     Start_Console_Tool    ${eBGP_PEER2_COMMAND}    ${eBGP_PEER2_OPTIONS}
 142     Read_And_Fail_If_Prompt_Is_Seen
 143
 144 Disconnect_eBGP_Peer1
 145     [Documentation]    Stop BGP peer, log topology and store logs
 146     [Tags]    critical
 147     SSHLibrary.Switch Connection    ebgp_peer1_console
 148     Stop_Console_Tool
 149     Store_File_To_Workspace    ${eBGP_PEER1_LOG_FILE}    ${eBGP_PEER1_LOG_FILE}
 150
 151 Check_IPv4_Topology_For_Second_Path
 152     [Documentation]    The IPv4 topology shall contain the route announced by the second eBGP now
 153     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Content    ${CONFIG_SESSION}    "node-id":"${eBGP_PEER2_NEXT_HOP}"
 154     BgpOperations.Check_Example_IPv4_Topology_Content    ${CONFIG_SESSION}    "prefix":"${eBGP_PEER2_FIRST_PREFIX_IP}/${PREFIX_LEN}"
 155
 156 iBGP_Check_Log_For_Updated_Prefixes
 157     [Documentation]    Check incomming updates for updated routes
 158     [Tags]    critical
 159     SSHLibrary.Switch Connection    ibgp_peer1_console
 160     ${total_prefix_count}=    BuiltIn.Evaluate    ${eBGP_PEER1_PREFIX_COUNT} + ${eBGP_PEER2_PREFIX_COUNT}
 161     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    nlri_prefix_received:    ${total_prefix_count}
 162     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER1_NEXT_HOP}
 163     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER1_PREFIX_COUNT}
 164     ${count}=    Count_Key_Value_Pairs    ${iBGP_PEER1_LOG_FILE}    Network Address of Next Hop    ${eBGP_PEER2_NEXT_HOP}
 165     BuiltIn.Should_Be_Equal_As_Integers    ${count}    ${eBGP_PEER2_PREFIX_COUNT}
 166     [Teardown]    Report_Failure_Due_To_Bug    4834
 167
 168 Disconnect_eBGP_Peer2
 169     [Documentation]    Stop BGP peer, store logs and wait for empty topology
 170     [Tags]    critical
 171     SSHLibrary.Switch Connection    ebgp_peer2_console
 172     Stop_Console_Tool
 173     Store_File_To_Workspace    ${eBGP_PEER2_LOG_FILE}    ${eBGP_PEER2_LOG_FILE}
 174
 175 Check_For_Empty_IPv4_Topology
 176     [Documentation]    The IPv4 topology shall be empty
 177     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    BgpOperations.Check_Example_IPv4_Topology_Does_Not_Contain    ${CONFIG_SESSION}    prefix
 178     [Teardown]    Report_Failure_Due_To_Bug    4835
 179
 180 iBGP_Check_Log_For_Withdrawn_Prefixes
 181     [Documentation]    Check incomming updates for withdrawn routes
 182     [Tags]    critical
 183     SSHLibrary.Switch Connection    ibgp_peer1_console
 184     ${prefixes_to_be_removed}=    BuiltIn.Evaluate    max(${eBGP_PEER1_PREFIX_COUNT}, ${eBGP_PEER2_PREFIX_COUNT})
 185     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_LOG_CHECK_TIMEOUT}    ${DEFAULT_LOG_CHECK_PERIOD}    Check_File_For_Word_Count    ${iBGP_PEER1_LOG_FILE}    withdrawn_prefix_received:    ${prefixes_to_be_removed}
 186     [Teardown]    Report_Failure_Due_To_Bug    4835
 187
 188 Disconnect_iBGP_Peer1
 189     [Documentation]    Stop BGP peer, log topology and store logs
 190     [Tags]    critical
 191     SSHLibrary.Switch Connection    ibgp_peer1_console
 192     Stop_Console_Tool
 193     Store_File_To_Workspace    ${iBGP_PEER1_LOG_FILE}    ${iBGP_PEER1_LOG_FILE}
 194
 195 Delete_BGP_Peers_Configuration
 196     [Documentation]    Delete all previously configured BGP peers.
 197     [Tags]    critical
 198     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    NAME=example-ibgp-peer1    IP=${iBGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 199     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ibgp_peers    mapping=${mapping}
 200     Collections.Set To Dictionary    ${mapping}    NAME=example-ebgp-peer1    IP=${eBGP_PEER1_IP}
 201     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 202     Collections.Set To Dictionary    ${mapping}    NAME=example-ebgp-peer2    IP=${eBGP_PEER2_IP}
 203     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}ebgp_peers    mapping=${mapping}
 204
 205 TC_LAS_Reconfigure_Odl_To_Accept_Connection
 206     [Documentation]    Configure neighbors. One ibgp and one ebgp neighbor with local-as configured.
 207     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 208     &{mapping}    Create Dictionary    IP=${iBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 209     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 210     &{mapping}    Create Dictionary    IP=${eBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 211     ...    AS_NUMBER=${LOCAL_AS}    PEER_AS=${eBGP_AS}
 212     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}local_as/ebgp_peer    mapping=${mapping}
 213     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 214
 215 TC_LAS_Start_iBgp_Speaker_And_Verify_Connected
 216     [Documentation]    Verify that peer is present in odl's rib. Peer is configured with local-as.
 217     [Tags]    critical
 218     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 219     SSHLibrary.Switch Connection    ibgp_peer1_console
 220     ${speaker_args}    BuiltIn.Set_Variable    --firstprefix ${iBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${PREFIX_LEN} --amount 1 --myip=${iBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --debug
 221     ${output}    BGPSpeaker.Start_BGP_Speaker_And_Verify_Connected    ${speaker_args}    session=default    speaker_ip=${iBGP_PEER1_IP}
 222     BuiltIn.Log    ${output}
 223
 224 TC_LAS_Start_eBgp_Speaker_And_Verify_Connected
 225     [Documentation]    Verify that peer is present in odl's rib. Peer is configured with local-as.
 226     [Tags]    critical
 227     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 228     SSHLibrary.Switch Connection    ebgp_peer1_console
 229     ${speaker_args}    BuiltIn.Set_Variable    --firstprefix ${eBGP_PEER1_FIRST_PREFIX_IP} --prefixlen ${PREFIX_LEN} --amount 1 --asnumber=${eBGP_AS} --myip=${eBGP_PEER1_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --debug
 230     ${output}    BGPSpeaker.Start_BGP_Speaker_And_Verify_Connected    ${speaker_args}    session=default    speaker_ip=${eBGP_PEER1_IP}
 231     BuiltIn.Log    ${output}
 232
 233 TC_LAS_Verify_iBGP_Rib_Out
 234     [Documentation]    Verifies iBGP's adj-rib-out output. Expects local-as, and ebgp peer-as presence.
 235     [Tags]    critical
 236     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 237     &{mapping}    Create Dictionary    IP=${iBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 238     ...    AS_NUMBER=${LOCAL_AS}    PEER_AS=${eBGP_AS}    PREFIXLEN=${eBGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}
 239     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    TemplatedRequests.Get_As_Json_Templated    ${BGP_VARIABLES_FOLDER}${/}local_as/adj_rib_out    mapping=${mapping}    verify=True
 240
 241 TC_LAS_Verify_eBGP_Rib_Out
 242     [Documentation]    Verifies eBGP's adj-rib-out output. Expects local-as, and ibgp peer-as presence.
 243     [Tags]    critical
 244     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 245     &{mapping}    Create Dictionary    IP=${eBGP_PEER1_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 246     ...    AS_NUMBER=${LOCAL_AS}    PEER_AS=${DEFAULT_AS}    PREFIXLEN=${iBGP_PEER1_FIRST_PREFIX_IP}/${PREFIX_LEN}
 247     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_TOPOLOGY_CHECK_TIMEOUT}    ${DEFAULT_TOPOLOGY_CHECK_PERIOD}    TemplatedRequests.Get_As_Json_Templated    ${BGP_VARIABLES_FOLDER}${/}local_as/adj_rib_out    mapping=${mapping}    verify=True
 248
 249 TC_LAS_Kill_iBgp_Speaker_After_Talking
 250     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 251     [Tags]    critical
 252     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 253     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 254     SSHLibrary.Switch Connection    ibgp_peer1_console
 255     BGPSpeaker.Kill_BGP_Speaker
 256     FailFast.Do_Not_Fail_Fast_From_Now_On
 257     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 258     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 259
 260 TC_LAS_Kill_eBgp_Speaker_After_Talking
 261     [Documentation]    Abort the Python speaker. Also, attempt to stop failing fast.
 262     [Tags]    critical
 263     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 264     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 265     SSHLibrary.Switch Connection    ebgp_peer1_console
 266     BGPSpeaker.Kill_BGP_Speaker
 267     FailFast.Do_Not_Fail_Fast_From_Now_On
 268     # NOTE: It is still possible to remain failing fast, if both previous and this test have failed.
 269     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 270
 271 TC_LAS_Delete_Bgp_Peer_Configurations
 272     [Documentation]    Delete peer configuration.
 273     CompareStream.Run_Keyword_If_Less_Than_Fluorine    BuiltIn.Pass_Execution    Test case valid only for versions fluorine and above.
 274     &{mapping}    Create Dictionary    IP=${iBGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 275     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}
 276     &{mapping}    Create Dictionary    IP=${eBGP_PEER1_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 277     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}${/}local_as/ebgp_peer    mapping=${mapping}
 278     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
 279
 280 *** Keywords ***
 281 Setup_Everything
 282     [Documentation]    Initialize SetupUtils. SSH-login to mininet machine, create HTTP session,
 283     ...    prepare directories for responses, put Python tool to mininet machine, setup imported resources.
 284     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 285     SSHLibrary.Set_Default_Configuration    prompt=${ODL_SYSTEM_PROMPT}
 286     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ibgp_peer1_console
 287     SSHKeywords.Flexible_Controller_Login
 288     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ebgp_peer1_console
 289     SSHKeywords.Flexible_Controller_Login
 290     SSHLibrary.Open_Connection    ${ODL_SYSTEM_IP}    alias=ebgp_peer2_console
 291     SSHKeywords.Flexible_Controller_Login
 292     SSHKeywords.Require_Python
 293     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 294     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 295     RequestsLibrary.Create_Session    ${CONFIG_SESSION}    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}
 296     TemplatedRequests.Create_Default_Session
 297     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_LOG_LEVEL}
 298     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_BGP_LOG_LEVEL} org.opendaylight.bgpcep
 299     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${ODL_BGP_LOG_LEVEL} org.opendaylight.protocol
 300
 301 Read_Text_Before_Prompt
 302     [Documentation]    Log text gathered by SSHLibrary.Read_Until_Prompt.
 303     ...    This needs to be a separate keyword just because how Read_And_Fail_If_Prompt_Is_Seen is implemented.
 304     ${text}=    SSHLibrary.Read_Until_Prompt
 305     BuiltIn.Log    ${text}
 306
 307 Store_File_To_Workspace
 308     [Arguments]    ${source_file_name}    ${target_file_name}
 309     [Documentation]    Store the ${source_file_name} to the workspace as ${target_file_name}.
 310     ${output_log}=    SSHLibrary.Execute_Command    cat ${source_file_name}
 311     BuiltIn.Log    ${output_log}
 312     Create File    ${target_file_name}    ${output_log}