csit/suites/bgpcep/bgpuser/ibgp_peer_lsp.robot

   1 *** Settings ***
   2 Documentation     Basic tests for iBGP peers.
   3 ...
   4 ...               Copyright (c) 2015-2016 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               Test suite performs basic iBGP functional test case for
  11 ...               carrying LSP State Information in BGP as described in
  12 ...               http://tools.ietf.org/html/draft-ietf-idr-te-lsp-distribution-03
  13 Suite Setup       Setup_Everything
  14 Suite Teardown    BgpOperations.Teardown_Everything
  15 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  16 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  17 Library           OperatingSystem
  18 Library           RequestsLibrary
  19 Library           DateTime
  20 Resource          ../../../libraries/BGPcliKeywords.robot
  21 Resource          ../../../libraries/BgpOperations.robot
  22 Resource          ../../../libraries/KarafKeywords.robot
  23 Resource          ../../../libraries/SetupUtils.robot
  24 Resource          ../../../libraries/SSHKeywords.robot
  25 Resource          ../../../libraries/TemplatedRequests.robot
  26 Resource          ../../../libraries/WaitForFailure.robot
  27 Resource          ../../../variables/Variables.robot
  28
  29 *** Variables ***
  30 ${BGP_VARIABLES_FOLDER}    ${CURDIR}/../../../variables/bgpuser/
  31 ${COUNT}          1
  32 ${HOLDTIME}       180
  33 ${BGP_PEER_LOG_FILE}    bgp_peer.log
  34 ${BGP_PEER_COMMAND}    python play.py --amount ${COUNT} --myip=${TOOLS_SYSTEM_IP} --myport=${BGP_TOOL_PORT} --peerip=${ODL_SYSTEM_IP} --peerport=${ODL_BGP_PORT} --${BGP_PEER_LOG_LEVEL} --logfile ${BGP_PEER_LOG_FILE} --bgpls True
  35 ${BGP_PEER_OPTIONS}    &>${BGP_PEER_LOG_FILE}
  36 ${DEFAULT_RIB_CHECK_PERIOD}    1s
  37 ${DEFAULT_RIB_CHECK_TIMEOUT}    10s
  38 ${BGP_PEER_LOG_LEVEL}    debug
  39 ${JSONKEYSTR}     "linkstate-route"
  40 ${BGP_PEER_NAME}    example-bgp-peer
  41 ${DEVICE_NAME}    controller-config
  42 ${CONFIG_SESSION}    config-session
  43 ${SKIP_PARAMS}    --skipattr
  44 ${RIB_INSTANCE}    example-bgp-rib
  45 ${PROTOCOL_OPENCONFIG}    ${RIB_INSTANCE}
  46
  47 *** Test Cases ***
  48 TC1_Configure_iBGP_Peer
  49     [Documentation]    Configure BGP peer module with initiate-connection set to false.
  50     [Tags]    critical
  51     &{mapping}    Create Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  52     ...    INITIATE=false    BGP_RIB=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}    RIB_INSTANCE_NAME=${RIB_INSTANCE}
  53     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}${/}bgp_peer    mapping=${mapping}    session=${CONFIG_SESSION}
  54
  55 TC1_Check_Example_Bgp_Rib_Is_Empty
  56     [Documentation]    Check RIB for none linkstate-routes
  57     [Tags]    critical
  58     BgpOperations.Check_Example_Bgp_Rib_Does_Not_Contain    ${CONFIG_SESSION}    ${JSONKEYSTR}
  59
  60 TC1_Connect_BGP_Peer
  61     [Documentation]    Connect BGP peer with advertising the routes without mandatory params like LOC_PREF.
  62     [Tags]    critical
  63     BuiltIn.Run_Keyword_And_Ignore_Error    KarafKeywords.Log_Message_To_Controller_Karaf    Error = WELL_KNOWN_ATTR_MISSING is EXPECTED in this test case, and should be thrown when missing mandatory attributes.
  64     BGPcliKeywords.Start_Console_Tool    ${BGP_PEER_COMMAND} ${SKIP_PARAMS}    ${BGP_PEER_OPTIONS}
  65     BGPcliKeywords.Read_And_Fail_If_Prompt_Is_Seen
  66
  67 TC1_Check_Example_Bgp_Rib
  68     [Documentation]    Check RIB for not containig linkstate-route(s), because update messages were not good.
  69     [Tags]    critical
  70     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    ${DEFAULT_RIB_CHECK_TIMEOUT}    ${DEFAULT_RIB_CHECK_PERIOD}    BgpOperations.Check_Example_Bgp_Rib_Does_Not_Contain    ${CONFIG_SESSION}    ${JSONKEYSTR}
  71
  72 TC1_Disconnect_BGP_Peer
  73     [Documentation]    Stop BGP peer & store logs
  74     [Tags]    critical
  75     BGPcliKeywords.Stop_Console_Tool
  76     BGPcliKeywords.Store_File_To_Workspace    ${BGP_PEER_LOG_FILE}    tc1_${BGP_PEER_LOG_FILE}
  77
  78 TC1_Deconfigure_iBGP_Peer
  79     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
  80     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
  81     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}/bgp_peer    mapping=${mapping}    session=${CONFIG_SESSION}
  82
  83 TC2_Configure_iBGP_Peer
  84     [Documentation]    Configures BGP peer module with initiate-connection set to false.
  85     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    HOLDTIME=${HOLDTIME}    PEER_PORT=${BGP_TOOL_PORT}
  86     ...    INITIATE=false    RIB_INSTANCE_NAME=${RIB_INSTANCE}    PASSIVE_MODE=true    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
  87     TemplatedRequests.Put_As_Xml_Templated    ${BGP_VARIABLES_FOLDER}/bgp_peer    mapping=${mapping}    session=${CONFIG_SESSION}
  88
  89 TC2_Check_Example_Bgp_Rib_Is_Empty
  90     [Documentation]    Check RIB for none linkstate-routes
  91     [Tags]    critical
  92     BgpOperations.Check_Example_Bgp_Rib_Does_Not_Contain    ${CONFIG_SESSION}    ${JSONKEYSTR}
  93
  94 TC2_Connect_BGP_Peer
  95     [Documentation]    Connect BGP peer
  96     [Tags]    critical
  97     BGPcliKeywords.Start_Console_Tool    ${BGP_PEER_COMMAND}    ${BGP_PEER_OPTIONS}
  98     BGPcliKeywords.Read_And_Fail_If_Prompt_Is_Seen
  99
 100 TC2_Check_Example_Bgp_Rib
 101     [Documentation]    Check RIB for linkstate-route(s) and check all of their attributes.
 102     [Tags]    critical
 103     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}
 104     BuiltIn.Wait_Until_Keyword_Succeeds    ${DEFAULT_RIB_CHECK_TIMEOUT}    ${DEFAULT_RIB_CHECK_PERIOD}    TemplatedRequests.Get_As_Json_Templated    ${BGP_VARIABLES_FOLDER}/lsp/effective_rib_in    mapping=${mapping}    session=${CONFIG_SESSION}
 105     ...    verify=True
 106
 107 TC2_Disconnect_BGP_Peer
 108     [Documentation]    Stop BGP peer & store logs
 109     [Tags]    critical
 110     BGPcliKeywords.Stop_Console_Tool
 111     BGPcliKeywords.Store_File_To_Workspace    ${BGP_PEER_LOG_FILE}    tc2_${BGP_PEER_LOG_FILE}
 112
 113 TC2_Deconfigure_iBGP_Peer
 114     [Documentation]    Revert the BGP configuration to the original state: without any configured peers.
 115     &{mapping}    BuiltIn.Create_Dictionary    DEVICE_NAME=${DEVICE_NAME}    BGP_NAME=${BGP_PEER_NAME}    IP=${TOOLS_SYSTEM_IP}    BGP_RIB_OPENCONFIG=${PROTOCOL_OPENCONFIG}
 116     TemplatedRequests.Delete_Templated    ${BGP_VARIABLES_FOLDER}/bgp_peer    mapping=${mapping}    session=${CONFIG_SESSION}
 117
 118 *** Keywords ***
 119 Setup_Everything
 120     [Documentation]    Initialize SetupUtils. SSH-login to mininet machine, create HTTP session,
 121     ...    prepare directories for responses, put Python tool to mininet machine, setup imported resources.
 122     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 123     SSHLibrary.Set_Default_Configuration    prompt=${TOOLS_SYSTEM_PROMPT}
 124     SSHLibrary.Open_Connection    ${TOOLS_SYSTEM_IP}
 125     SSHKeywords.Flexible_Mininet_Login
 126     SSHKeywords.Require_Python
 127     SSHKeywords.Assure_Library_Ipaddr    target_dir=.
 128     SSHLibrary.Put_File    ${CURDIR}/../../../../tools/fastbgp/play.py
 129     RequestsLibrary.Create_Session    ${CONFIG_SESSION}    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}
 130     KarafKeywords.Setup_Karaf_Keywords