csit/suites/bgpcep/tcpmd5user/tcpmd5user.robot

   1 *** Settings ***
   2 Documentation     TCPMD5 user-facing feature system tests, using PCEP.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               Test suite performs basic pcep md5 password authorization test cases:
  11 ...               (Run entire basic PCEP suite without passwords.)
  12 ...               Start pcc-mock (reconnecting mode): 1 pcc, 1 lsp, password set, check pcep-topology stays empty.
  13 ...               Use restconf to change PCEP configuration to use a wrong password, check pcep-topology stays empty.
  14 ...               Change ODL PCEP configuration to use the correct password, check pcep-topology shows the lsp.
  15 ...               Stop pcc-mock, check pcep-topology stays empty.
  16 ...               Start pcc-mock with new password, check pcep-topology stays empty.
  17 ...               Change ODL PCEP configuration to use the correct password, check pcep-topology shows the lsp.
  18 ...               Update the lsp, check a change in pcep-topology.
  19 ...               Change ODL PCEP configuration to not use password, pcep-topology empties, kill pcep-pcc-mock.
  20 ...
  21 ...               Stable/carbon and stable/nitrogen are using netconf-connector-ssh to send restconf requests.
  22 ...               Oxygen test cases no longer need netconf-connector-ssh, and they include comparison of
  23 ...               pcep-session-state, which is exclusive to oxygen.
  24 Suite Setup       Set_It_Up
  25 Suite Teardown    Tear_It_Down
  26 Test Setup        FailFast.Fail_This_Fast_On_Previous_Error
  27 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  28 Library           OperatingSystem
  29 Library           RequestsLibrary
  30 Library           SSHLibrary    prompt=]>
  31 Resource          ../../../libraries/FailFast.robot
  32 Resource          ../../../libraries/KarafKeywords.robot
  33 Resource          ../../../libraries/NexusKeywords.robot
  34 Resource          ../../../libraries/TemplatedRequests.robot
  35 Resource          ../../../libraries/WaitForFailure.robot
  36 Resource          ../../../libraries/RemoteBash.robot
  37 Resource          ../../../libraries/CompareStream.robot
  38
  39 *** Variables ***
  40 ${DIR_WITH_TEMPLATES}    ${CURDIR}/../../../variables/tcpmd5user/
  41 ${CONFIG_SESSION}    session
  42 ${CONNECTOR_FEATURE}    odl-netconf-connector-all
  43 ${PCEP_FEATURE}    odl-bgpcep-pcep
  44 ${RESTCONF_FEATURE}    odl-restconf-all
  45
  46 *** Test Cases ***
  47 Topology_Precondition
  48     [Documentation]    Compare current pcep-topology to empty one.
  49     ...    Timeout is long enough to see that pcep is ready, with no PCC connected.
  50     [Tags]    critical
  51     BuiltIn.Wait_Until_Keyword_Succeeds    300s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_off    session=${CONFIG_SESSION}    verify=True
  52
  53 Start_Secure_Pcc_Mock
  54     [Documentation]    Execute pcc-mock on Mininet with password set, fail if pcc-mock promptly exits. Keep pcc-mock running for next test cases.
  55     Start_Pcc_Mock_Tool_With_Password    password=topsecret
  56
  57 Topology_Unauthorized_1
  58     [Documentation]    Try to catch a glimpse of pcc-mock in pcep-topology. Pass if no change from Precondition is detected over 10 seconds.
  59     [Tags]    critical
  60     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    10s    1s    Test_Unauthorized
  61
  62 Set_Wrong_Password
  63     [Documentation]    Configure password in pcep dispatcher for client with Mininet IP address.
  64     ...    This password does not match what pcc-mock uses.
  65     CompareStream.Run_Keyword_If_At_Least_Oxygen    Replace_Password_On_Pcep_Node    password=changeme
  66     CompareStream.Run_Keyword_If_Less_Than_Oxygen    Set_Password_Less_Than_Oxygen    password=changeme
  67
  68 Topology_Unauthorized_2
  69     [Documentation]    The same logic as Topology_Unauthorized_1 as incorrect password was provided to ODL.
  70     [Tags]    critical
  71     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    10s    1s    Test_Unauthorized
  72
  73 Set_Correct_Password
  74     [Documentation]    Configure password in pcep dispatcher for client with Mininet IP address.
  75     ...    This password finally matches what pcc-mock uses.
  76     CompareStream.Run_Keyword_If_At_Least_Oxygen    Replace_Password_On_Pcep_Node    password=topsecret
  77     CompareStream.Run_Keyword_If_Less_Than_Oxygen    Set_Password_Less_Than_Oxygen    password=topsecret
  78
  79 Topology_Intercondition
  80     [Documentation]    Compare pcep-topology/path-computation-client to filled one, which includes a tunnel from pcc-mock.
  81     ...    For oxygen compares full pcep-topology including pcep-session-state
  82     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    CODE=${pcc_name_code}    NAME=${pcc_name}    IP_ODL=${ODL_SYSTEM_IP}
  83     BuiltIn.Wait_Until_Keyword_Succeeds    10s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_on    ${mapping}    ${CONFIG_SESSION}
  84     ...    verify=True
  85     CompareStream.Run_Keyword_If_At_Least_Oxygen    BuiltIn.Wait_Until_Keyword_Succeeds    30s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_on_state    ${mapping}
  86     ...    ${CONFIG_SESSION}    verify=True
  87
  88 Stop_Pcc_Mock_1
  89     [Documentation]    Stops First instance of pcc-mock.
  90     [Setup]    FailFast.Run_Even_When_Failing_Fast
  91     Stop_Pcc_Mock_Tool
  92     FailFast.Do_Not_Fail_Fast_From_Now_On
  93     # NOTE: It is still possible to remain failing, if both previous and this test failed.
  94     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
  95
  96 Topology_Unauthorized_3
  97     [Documentation]    The same logic as Topology_Unauthorized_1, with no pcc-mock running.
  98     [Tags]    critical
  99     BuiltIn.Wait_Until_Keyword_Succeeds    10s    1s    Test_Unauthorized
 100
 101 Start_Secure_Pcc_Mock_2
 102     [Documentation]    Execute pcc-mock on Mininet with new password set, fail if pcc-mock promptly exits. Keep pcc-mock running for next test cases.
 103     Start_Pcc_Mock_Tool_With_Password    password=newtopsecret
 104
 105 Topology_Unauthorized_4
 106     [Documentation]    The same logic as Topology_Unauthorized_1, but ODL password became incorrect with new pcc-mock running.
 107     [Tags]    critical
 108     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    10s    1s    Test_Unauthorized
 109
 110 Set_Correct_Password_2
 111     [Documentation]    Configure password in pcep dispatcher for client with Mininet IP address.
 112     ...    This password again matches what second pcc-mock instance uses.
 113     CompareStream.Run_Keyword_If_At_Least_Oxygen    Replace_Password_On_Pcep_Node    password=newtopsecret
 114     CompareStream.Run_Keyword_If_Less_Than_Oxygen    Set_Password_Less_Than_Oxygen    password=newtopsecret
 115
 116 Topology_Intercondition_2
 117     [Documentation]    Compare pcep-topology/path-computation-client to filled one, which includes a tunnel from pcc-mock.
 118     ...    For oxygen compares full pcep-topology including pcep-session-state
 119     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    CODE=${pcc_name_code}    NAME=${pcc_name}    IP_ODL=${ODL_SYSTEM_IP}
 120     BuiltIn.Wait_Until_Keyword_Succeeds    10s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_on    ${mapping}    ${CONFIG_SESSION}
 121     ...    verify=True
 122     CompareStream.Run_Keyword_If_At_Least_Oxygen    BuiltIn.Wait_Until_Keyword_Succeeds    30s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_on_state    ${mapping}
 123     ...    ${CONFIG_SESSION}    verify=True
 124
 125 Update_Delegated
 126     [Documentation]    Perform update-lsp on the mocked tunnel, check response is success.
 127     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    NAME=${pcc_name}
 128     ${response}=    TemplatedRequests.Post_As_Xml_Templated    ${DIR_WITH_TEMPLATES}${/}update_delegated    ${mapping}    ${CONFIG_SESSION}    verify=True
 129     Log    ${response}
 130
 131 Topology_Updated
 132     [Documentation]    Compare pcep-topology/path-computation-client to default_on_updated, which includes the updated tunnel.
 133     ...    For oxygen compares full pcep-topology including pcep-session-state
 134     [Tags]    critical
 135     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    CODE=${pcc_name_code}    NAME=${pcc_name}    IP_ODL=${ODL_SYSTEM_IP}
 136     BuiltIn.Wait_Until_Keyword_Succeeds    10s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_on_updated    ${mapping}    ${CONFIG_SESSION}
 137     ...    verify=True
 138     CompareStream.Run_Keyword_If_At_Least_Oxygen    BuiltIn.Wait_Until_Keyword_Succeeds    30s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_on_updated_state    ${mapping}
 139     ...    ${CONFIG_SESSION}    verify=True
 140
 141 Unset_Password
 142     [Documentation]    De-configure password for pcep dispatcher for client with Mininet IP address.
 143     [Setup]    FailFast.Run_Even_When_Failing_Fast
 144     CompareStream.Run_Keyword_If_At_Least_Oxygen    Unset_Password_On_Pcep_Node
 145     CompareStream.Run_Keyword_If_Less_Than_Oxygen    Replace_Password_Xml_Element_In_Pcep_Client_Module_Less_Than_Oxygen
 146     FailFast.Do_Not_Fail_Fast_From_Now_On
 147     # NOTE: It is still possible to remain failing, if both previous and this test failed.
 148     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 149
 150 Topology_Unauthorized_5
 151     [Documentation]    Wait for pcep-topology to become empty again.
 152     [Tags]    critical
 153     BuiltIn.Wait_Until_Keyword_Succeeds    10s    1s    Test_Unauthorized
 154
 155 Stop_Pcc_Mock_2
 156     [Documentation]    Stops second instance of pcc-mock
 157     [Setup]    FailFast.Run_Even_When_Failing_Fast
 158     Stop_Pcc_Mock_Tool
 159     FailFast.Do_Not_Fail_Fast_From_Now_On
 160     # NOTE: It is still possible to remain failing, if both previous and this test failed.
 161     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 162
 163 Topology_Postcondition
 164     [Documentation]    Verify that pcep-topology stays empty.
 165     [Tags]    critical
 166     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    10s    1s    Test_Unauthorized
 167
 168 Delete_Pcep_Client_Module
 169     [Documentation]    Delete Pcep client module.
 170     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}
 171     CompareStream.Run_Keyword_If_At_Least_Oxygen    TemplatedRequests.Delete_Templated    ${DIR_WITH_TEMPLATES}${/}pcep_topology_node    ${mapping}
 172     CompareStream.Run_Keyword_If_Less_Than_Oxygen    TemplatedRequests.Delete_Templated    ${DIR_WITH_TEMPLATES}${/}pcep_topology_client_module    ${mapping}
 173
 174 *** Keywords ***
 175 Set_It_Up
 176     [Documentation]    Create SSH session to Mininet machine, prepare HTTP client session to Controller.
 177     ...    Figure out latest pcc-mock version and download it from Nexus to Mininet.
 178     ...    Also, delete and create directories for json diff handling.
 179     ...    Sets up netconf-connector on odl-streams less than oxygen.
 180     KarafKeywords.Setup_Karaf_Keywords
 181     TemplatedRequests.Create_Default_Session
 182     BuiltIn.Run_Keyword_If    """${USE_NETCONF_CONNECTOR}""" == """False"""    CompareStream.Run_Keyword_If_Less_Than_Oxygen    Install_Netconf_Connector
 183     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
 184     ${current_connection}=    SSHLibrary.Get_Connection
 185     ${current_prompt}=    BuiltIn.Set_Variable    ${current_connection.prompt}
 186     BuiltIn.Log    ${current_prompt}
 187     BuiltIn.Set_Suite_Variable    ${prompt}    ${current_prompt}
 188     RequestsLibrary.Create_Session    ${CONFIG_SESSION}    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}
 189     ${name}=    NexusKeywords.Deploy_Test_Tool    bgpcep    pcep-pcc-mock
 190     BuiltIn.Set_Suite_Variable    ${filename}    ${name}
 191     #Setting Pcc Name and its code for mapping for templates
 192     BuiltIn.Set_Suite_Variable    ${pcc_name}    pcc_${TOOLS_SYSTEM_IP}_tunnel_1
 193     ${code}=    Evaluate    binascii.b2a_base64('${pcc_name}')[:-1]    modules=binascii
 194     BuiltIn.Set_Suite_Variable    ${pcc_name_code}    ${code}
 195     FailFast.Do_Not_Fail_Fast_From_Now_On
 196
 197 Tear_It_Down
 198     [Documentation]    Download pccmock.log and Log its contents.
 199     ...    Compute and Log the diff between expected and actual normalized responses.
 200     ...    Close both HTTP client session and SSH connection to Mininet.
 201     SSHLibrary.Get_File    pccmock.log
 202     ${pccmocklog}=    OperatingSystem.Run    cat pccmock.log
 203     BuiltIn.Log    ${pccmocklog}
 204     BuiltIn.Run_Keyword_If    """${USE_NETCONF_CONNECTOR}""" == """False"""    CompareStream.Run_Keyword_If_Less_Than_Oxygen    Uninstall_Netconf_Connector
 205     RequestsLibrary.Delete_All_Sessions
 206     SSHLibrary.Close_All_Connections
 207
 208 Install_Netconf_Connector
 209     [Documentation]    Installs ${CONNECTOR_FEATURE} feature.
 210     # During the netconf connector installation the karaf's ssh is restarted and connection to karaf console is droped. This is causing an error
 211     # which is ignored, because the feature should be installed anyway.
 212     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    KarafKeywords.Install_A_Feature    ${CONNECTOR_FEATURE}
 213     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    KarafKeywords.Install_A_Feature    ${PCEP_FEATURE}
 214     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    KarafKeywords.Install_A_Feature    ${RESTCONF_FEATURE}
 215     BuiltIn.Log    ${results}
 216     BuiltIn.Wait_Until_Keyword_Succeeds    240s    3s    Check_Netconf_Up_And_Running
 217
 218 Check_Netconf_Up_And_Running
 219     [Documentation]    Make a request to netconf connector's mounted pcep module and expect it is mounted.
 220     TemplatedRequests.Get_From_Uri    restconf/config/network-topology:network-topology/topology/topology-netconf/node/controller-config/yang-ext:mount/config:modules/module/odl-pcep-topology-provider-cfg:pcep-topology-provider/pcep-topology
 221
 222 Uninstall_Netconf_Connector
 223     [Documentation]    Uninstalls ${CONNECTOR_FEATURE} feature.
 224     ${status}    ${results} =    BuiltIn.Run_Keyword_And_Ignore_Error    KarafKeywords.Uninstall_A_Feature    ${CONNECTOR_FEATURE}
 225     BuiltIn.Log    ${results}
 226
 227 Test_Unauthorized
 228     [Documentation]    Try to access pcep topology with wrong password, should get empty topology
 229     TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_off    session=${CONFIG_SESSION}    verify=True
 230
 231 Set_Password_Less_Than_Oxygen
 232     [Arguments]    ${password}=${EMPTY}
 233     ${password_line}=    Construct_Password_Element_Line_Using_Password    password=${password}
 234     Replace_Password_Xml_Element_In_Pcep_Client_Module_Less_Than_Oxygen    ${password_line}
 235
 236 Read_Text_Before_Prompt
 237     [Documentation]    Log text gathered by SSHLibrary.Read_Until_Prompt.
 238     ...    This needs to be a separate keyword just because how Read_And_Fail_If_Prompt_Is_Seen is implemented.
 239     ${text}=    SSHLibrary.Read_Until_Prompt
 240     BuiltIn.Log    ${text}
 241
 242 Replace_Password_On_Pcep_Node
 243     [Arguments]    ${password}
 244     [Documentation]    Send restconf PUT to replace the config module specifying PCEP password element.
 245     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    PASSWD=${password}
 246     TemplatedRequests.Put_As_Xml_Templated    ${DIR_WITH_TEMPLATES}${/}pcep_topology_node    mapping=${mapping}
 247
 248 Unset_Password_On_Pcep_Node
 249     [Documentation]    Send restconf PUT to unset the config module.
 250     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}
 251     TemplatedRequests.Put_As_Xml_Templated    ${DIR_WITH_TEMPLATES}${/}pcep_topology_node_empty    mapping=${mapping}
 252
 253 Construct_Password_Element_Line_Using_Password
 254     [Arguments]    ${password}
 255     [Documentation]    Return line with password XML element containing given password, whitespace is there so that data to send looks neat.
 256     ${element}=    String.Replace_String    ${SPACE}${SPACE}<password>$PASSWORD</password>${\n}    $PASSWORD    ${password}
 257     BuiltIn.Log    ${element}
 258     [Return]    ${element}
 259
 260 Replace_Password_Xml_Element_In_Pcep_Client_Module_Less_Than_Oxygen
 261     [Arguments]    ${password_element}=${EMPTY}
 262     [Documentation]    Send restconf PUT to replace the config module specifying PCEP password element (may be empty=missing).
 263     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    PASSWD=${password_element}
 264     TemplatedRequests.Put_As_Xml_Templated    ${DIR_WITH_TEMPLATES}${/}pcep_topology_client_module    mapping=${mapping}
 265
 266 Stop_Pcc_Mock_Tool
 267     [Documentation]    Send ctrl+c to pcc-mock, fails if no prompt is seen
 268     ...    after 3 seconds (the default for SSHLibrary)
 269     RemoteBash.Write_Bare_Ctrl_C
 270     ${output}=    SSHLibrary.Read_Until_Prompt
 271     BuiltIn.Log    ${output}
 272
 273 Start_Pcc_Mock_Tool_With_Password
 274     [Arguments]    ${password}
 275     [Documentation]    Starts pcc-mock with password argument.
 276     ${command}=    NexusKeywords.Compose_Full_Java_Command    -jar ${filename} --password ${password} --reconnect 1 --local-address ${TOOLS_SYSTEM_IP} --remote-address ${ODL_SYSTEM_IP} 2>&1 | tee pccmock.log
 277     BuiltIn.Log    ${command}
 278     SSHLibrary.Write    ${command}