csit/suites/bgpcep/tcpmd5user/tcpmd5user.robot

   1 *** Settings ***
   2 Documentation     TCPMD5 user-facing feature system tests, using PCEP.
   3 ...
   4 ...               Copyright (c) 2015 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               Test suite performs basic pcep md5 password authorization test cases:
  11 ...               (Run entire basic PCEP suite without passwords.)
  12 ...               Start pcc-mock (reconnecting mode): 1 pcc, 1 lsp, password set, check pcep-topology stays empty.
  13 ...               Use restconf to change PCEP configuration to use a wrong password, check pcep-topology stays empty.
  14 ...               Change ODL PCEP configuration to use the correct password, check pcep-topology shows the lsp.
  15 ...               Stop pcc-mock, check pcep-topology stays empty.
  16 ...               Start pcc-mock with new password, check pcep-topology stays empty.
  17 ...               Change ODL PCEP configuration to use the correct password, check pcep-topology shows the lsp.
  18 ...               Update the lsp, check a change in pcep-topology.
  19 ...               Change ODL PCEP configuration to not use password, pcep-topology empties, kill pcep-pcc-mock.
  20 ...
  21 ...               Test cases no longer need netconf-connector-ssh, and they include comparison of
  22 ...               pcep-session-state.
  23 Suite Setup       Set_It_Up
  24 Suite Teardown    Tear_It_Down
  25 Test Setup        FailFast.Fail_This_Fast_On_Previous_Error
  26 Test Teardown     FailFast.Start_Failing_Fast_If_This_Failed
  27 Library           OperatingSystem
  28 Library           RequestsLibrary
  29 Library           SSHLibrary    prompt=]>
  30 Resource          ../../../libraries/CompareStream.robot
  31 Resource          ../../../libraries/FailFast.robot
  32 Resource          ../../../libraries/KarafKeywords.robot
  33 Resource          ../../../libraries/NexusKeywords.robot
  34 Resource          ../../../libraries/TemplatedRequests.robot
  35 Resource          ../../../libraries/RemoteBash.robot
  36 Resource          ../../../libraries/WaitForFailure.robot
  37 Resource          ../../../variables/Variables.robot
  38 Variables         ../../../variables/tcpmd5user/${ODL_STREAM}/variables.py    ${TOOLS_SYSTEM_IP}
  39
  40 *** Variables ***
  41 ${DIR_WITH_TEMPLATES}    ${CURDIR}/../../../variables/tcpmd5user/${ODL_STREAM}
  42 ${CONFIG_SESSION}    session
  43 ${OLD_ERROR_ARGS}    \n"last-received-error": {},\n"last-sent-error": {},
  44 ${NEW_ERROR_ARGS}    ${EMPTY}
  45
  46 *** Test Cases ***
  47 Topology_Precondition
  48     [Documentation]    Compare current pcep-topology to empty one.
  49     ...    Timeout is long enough to see that pcep is ready, with no PCC connected.
  50     [Tags]    critical
  51     BuiltIn.Wait_Until_Keyword_Succeeds    300s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_off    session=${CONFIG_SESSION}    verify=True
  52
  53 Start_Secure_Pcc_Mock
  54     [Documentation]    Execute pcc-mock on Mininet with password set, fail if pcc-mock promptly exits. Keep pcc-mock running for next test cases.
  55     Start_Pcc_Mock_Tool_With_Password    password=topsecret
  56
  57 Topology_Unauthorized_1
  58     [Documentation]    Try to catch a glimpse of pcc-mock in pcep-topology. Pass if no change from Precondition is detected over 10 seconds.
  59     [Tags]    critical
  60     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    10s    1s    Test_Unauthorized
  61
  62 Set_Wrong_Password
  63     [Documentation]    Configure password in pcep dispatcher for client with Mininet IP address.
  64     ...    This password does not match what pcc-mock uses.
  65     Replace_Password_On_Pcep_Node    password=changeme
  66
  67 Topology_Unauthorized_2
  68     [Documentation]    The same logic as Topology_Unauthorized_1 as incorrect password was provided to ODL.
  69     [Tags]    critical
  70     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    10s    1s    Test_Unauthorized
  71
  72 Set_Correct_Password
  73     [Documentation]    Configure password in pcep dispatcher for client with Mininet IP address.
  74     ...    This password finally matches what pcc-mock uses.
  75     Replace_Password_On_Pcep_Node    password=topsecret
  76
  77 Topology_Intercondition
  78     [Documentation]    Compare pcep-topology/path-computation-client to filled one, which includes a tunnel from pcc-mock.
  79     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    CODE=${pcc_name_code}    NAME=${pcc_name}    IP_ODL=${ODL_SYSTEM_IP}    ERRORS=${ERROR_ARGS}
  80     BuiltIn.Wait_Until_Keyword_Succeeds    30s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_on_state    ${mapping}    ${CONFIG_SESSION}
  81     ...    verify=True
  82
  83 Stop_Pcc_Mock_1
  84     [Documentation]    Stops First instance of pcc-mock.
  85     [Setup]    FailFast.Run_Even_When_Failing_Fast
  86     Stop_Pcc_Mock_Tool
  87     FailFast.Do_Not_Fail_Fast_From_Now_On
  88     # NOTE: It is still possible to remain failing, if both previous and this test failed.
  89     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
  90
  91 Topology_Unauthorized_3
  92     [Documentation]    The same logic as Topology_Unauthorized_1, with no pcc-mock running.
  93     [Tags]    critical
  94     BuiltIn.Wait_Until_Keyword_Succeeds    10s    1s    Test_Unauthorized
  95
  96 Start_Secure_Pcc_Mock_2
  97     [Documentation]    Execute pcc-mock on Mininet with new password set, fail if pcc-mock promptly exits. Keep pcc-mock running for next test cases.
  98     Start_Pcc_Mock_Tool_With_Password    password=newtopsecret
  99
 100 Topology_Unauthorized_4
 101     [Documentation]    The same logic as Topology_Unauthorized_1, but ODL password became incorrect with new pcc-mock running.
 102     [Tags]    critical
 103     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    10s    1s    Test_Unauthorized
 104
 105 Set_Correct_Password_2
 106     [Documentation]    Configure password in pcep dispatcher for client with Mininet IP address.
 107     ...    This password again matches what second pcc-mock instance uses.
 108     Replace_Password_On_Pcep_Node    password=newtopsecret
 109
 110 Topology_Intercondition_2
 111     [Documentation]    Compare pcep-topology/path-computation-client to filled one, which includes a tunnel from pcc-mock.
 112     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    CODE=${pcc_name_code}    NAME=${pcc_name}    IP_ODL=${ODL_SYSTEM_IP}    ERRORS=${ERROR_ARGS}
 113     BuiltIn.Wait_Until_Keyword_Succeeds    30s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_on_state    ${mapping}    ${CONFIG_SESSION}
 114     ...    verify=True
 115
 116 Update_Delegated
 117     [Documentation]    Perform update-lsp on the mocked tunnel, check response is success.
 118     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    NAME=${pcc_name}
 119     ${response}=    TemplatedRequests.Post_As_Xml_Templated    ${DIR_WITH_TEMPLATES}${/}update_delegated    ${mapping}    ${CONFIG_SESSION}    verify=False
 120     Log    ${response}
 121
 122 Topology_Updated
 123     [Documentation]    Compare pcep-topology/path-computation-client to default_on_updated, which includes the updated tunnel.
 124     [Tags]    critical
 125     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    CODE=${pcc_name_code}    NAME=${pcc_name}    IP_ODL=${ODL_SYSTEM_IP}    ERRORS=${ERROR_ARGS}
 126     BuiltIn.Wait_Until_Keyword_Succeeds    30s    1s    TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_on_updated_state    ${mapping}    ${CONFIG_SESSION}
 127     ...    verify=True
 128
 129 Unset_Password
 130     [Documentation]    De-configure password for pcep dispatcher for client with Mininet IP address.
 131     [Setup]    FailFast.Run_Even_When_Failing_Fast
 132     Unset_Password_On_Pcep_Node
 133     FailFast.Do_Not_Fail_Fast_From_Now_On
 134     # NOTE: It is still possible to remain failing, if both previous and this test failed.
 135     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 136
 137 Topology_Unauthorized_5
 138     [Documentation]    Wait for pcep-topology to become empty again.
 139     [Tags]    critical
 140     BuiltIn.Wait_Until_Keyword_Succeeds    10s    1s    Test_Unauthorized
 141
 142 Stop_Pcc_Mock_2
 143     [Documentation]    Stops second instance of pcc-mock
 144     [Setup]    FailFast.Run_Even_When_Failing_Fast
 145     Stop_Pcc_Mock_Tool
 146     FailFast.Do_Not_Fail_Fast_From_Now_On
 147     # NOTE: It is still possible to remain failing, if both previous and this test failed.
 148     [Teardown]    FailFast.Do_Not_Start_Failing_If_This_Failed
 149
 150 Topology_Postcondition
 151     [Documentation]    Verify that pcep-topology stays empty.
 152     [Tags]    critical
 153     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    10s    1s    Test_Unauthorized
 154
 155 Delete_Pcep_Client_Module
 156     [Documentation]    Delete Pcep client module.
 157     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}
 158     TemplatedRequests.Delete_Templated    ${DIR_WITH_TEMPLATES}${/}pcep_topology_node    ${mapping}
 159
 160 *** Keywords ***
 161 Set_It_Up
 162     [Documentation]    Create SSH session to Mininet machine, prepare HTTP client session to Controller.
 163     ...    Figure out latest pcc-mock version and download it from Nexus to Mininet.
 164     ...    Also, delete and create directories for json diff handling.
 165     KarafKeywords.Setup_Karaf_Keywords
 166     TemplatedRequests.Create_Default_Session
 167     NexusKeywords.Initialize_Artifact_Deployment_And_Usage
 168     ${current_connection}=    SSHLibrary.Get_Connection
 169     ${current_prompt}=    BuiltIn.Set_Variable    ${current_connection.prompt}
 170     BuiltIn.Log    ${current_prompt}
 171     BuiltIn.Set_Suite_Variable    ${prompt}    ${current_prompt}
 172     RequestsLibrary.Create_Session    ${CONFIG_SESSION}    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}
 173     ${name}=    NexusKeywords.Deploy_Test_Tool    bgpcep    pcep-pcc-mock
 174     BuiltIn.Set_Suite_Variable    ${filename}    ${name}
 175     #Setting Pcc Name and its code for mapping for templates
 176     FailFast.Do_Not_Fail_Fast_From_Now_On
 177     ${ERROR_ARGS} =    CompareStream.Set_Variable_If_At_Least_Neon    ${NEW_ERROR_ARGS}    ${OLD_ERROR_ARGS}
 178     BuiltIn.Set_Suite_Variable    ${ERROR_ARGS}
 179
 180 Tear_It_Down
 181     [Documentation]    Download pccmock.log and Log its contents.
 182     ...    Compute and Log the diff between expected and actual normalized responses.
 183     ...    Close both HTTP client session and SSH connection to Mininet.
 184     SSHLibrary.Get_File    pccmock.log
 185     ${pccmocklog}=    OperatingSystem.Run    cat pccmock.log
 186     BuiltIn.Log    ${pccmocklog}
 187     RequestsLibrary.Delete_All_Sessions
 188     SSHLibrary.Close_All_Connections
 189
 190 Test_Unauthorized
 191     [Documentation]    Try to access pcep topology with wrong password, should get empty topology
 192     TemplatedRequests.Get_As_Json_Templated    ${DIR_WITH_TEMPLATES}${/}default_off    session=${CONFIG_SESSION}    verify=True
 193
 194 Read_Text_Before_Prompt
 195     [Documentation]    Log text gathered by SSHLibrary.Read_Until_Prompt.
 196     ...    This needs to be a separate keyword just because how Read_And_Fail_If_Prompt_Is_Seen is implemented.
 197     ${text} =    SSHLibrary.Read_Until_Prompt
 198     BuiltIn.Log    ${text}
 199
 200 Replace_Password_On_Pcep_Node
 201     [Arguments]    ${password}
 202     [Documentation]    Send restconf PUT to replace the config module specifying PCEP password element.
 203     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}    PASSWD=${password}
 204     TemplatedRequests.Put_As_Xml_Templated    ${DIR_WITH_TEMPLATES}${/}pcep_topology_node    mapping=${mapping}
 205
 206 Unset_Password_On_Pcep_Node
 207     [Documentation]    Send restconf PUT to unset the config module.
 208     &{mapping}    BuiltIn.Create_Dictionary    IP=${TOOLS_SYSTEM_IP}
 209     TemplatedRequests.Put_As_Xml_Templated    ${DIR_WITH_TEMPLATES}${/}pcep_topology_node_empty    mapping=${mapping}
 210
 211 Stop_Pcc_Mock_Tool
 212     [Documentation]    Send ctrl+c to pcc-mock, fails if no prompt is seen
 213     ...    after 3 seconds (the default for SSHLibrary)
 214     RemoteBash.Write_Bare_Ctrl_C
 215     ${output}=    SSHLibrary.Read_Until_Prompt
 216     BuiltIn.Log    ${output}
 217
 218 Start_Pcc_Mock_Tool_With_Password
 219     [Arguments]    ${password}
 220     [Documentation]    Starts pcc-mock with password argument.
 221     ${command}=    NexusKeywords.Compose_Full_Java_Command    -jar ${filename} --password ${password} --reconnect 1 --local-address ${TOOLS_SYSTEM_IP} --remote-address ${ODL_SYSTEM_IP} 2>&1 | tee pccmock.log
 222     BuiltIn.Log    ${command}
 223     SSHLibrary.Write    ${command}