csit/suites/controller/Clustering_Datastore/car_failover_crud_isolation.robot

   1 *** Settings ***
   2 Documentation     Suite mixing basic operations with isolation of car Leader.
   3 ...
   4 ...               Copyright (c) 2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               This test isolates the current leader of the "car" shard and then executes CRD
  12 ...               operations on the new leader and a new follower. The isolated member is brought back.
  13 ...               This suite uses 3 different car sets, same size but different starting ID.
  14 ...
  15 ...               Other models and shards (people, car-people) are not accessed by this suite.
  16 ...
  17 ...               All data is deleted at the end of the suite.
  18 ...               This suite expects car module to have a separate Shard.
  19 Suite Setup       Setup
  20 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  21 Default Tags      clustering    carpeople    critical
  22 Library           Collections
  23 Resource          ${CURDIR}/../../../libraries/CarPeople.robot
  24 Resource          ${CURDIR}/../../../libraries/ClusterManagement.robot
  25 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  26 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  27 Variables         ${CURDIR}/../../../variables/Variables.py
  28
  29 *** Variables ***
  30 ${CAR_ITEMS}      30
  31 ${FOLLOWER_2NODE_START_I}    300
  32 ${LEADER_2NODE_START_I}    200
  33 ${MEMBER_START_TIMEOUT}    300s
  34 ${ORIGINAL_START_I}    100
  35 ${SHARD_TYPE}     config
  36 ${SHARD_NAME}     car
  37 @{SHARD_NAME_LIST}    ${SHARD_NAME}
  38 ${VAR_DIR}        ${CURDIR}/../../../variables/carpeople/crud
  39
  40 *** Test Cases ***
  41 Add_Original_Cars_On_Old_Leader_And_Verify
  42     [Documentation]    Add initial cars on car Leader.
  43     TemplatedRequests.Put_As_Json_Templated    folder=${VAR_DIR}/cars    session=${car_leader_session}    iterations=${CAR_ITEMS}    iter_start=${ORIGINAL_START_I}
  44     : FOR    ${session}    IN    @{ClusterManagement__session_list}
  45     \    TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${ORIGINAL_START_I}
  46
  47 Isolate_Original_Car_Leader
  48     [Documentation]    Isolate the car Leader to cause a new leader to get elected.
  49     ClusterManagement.Isolate_Member_From_List_Or_All    ${car_leader_index}
  50
  51 Wait_For_New_Leader
  52     [Documentation]    Wait until new car Leader is elected.
  53     BuiltIn.Wait_Until_Keyword_Succeeds    30s    2s    ClusterManagement.Verify_Shard_Leader_Elected    ${SHARD_NAME}    ${SHARD_TYPE}    ${True}
  54     ...    ${car_leader_index}    member_index_list=${car_follower_indices}
  55     CarPeople.Set_Tmp_Variables_For_Shard_For_Nodes    member_index_list=${car_follower_indices}    shard_name=${SHARD_NAME}    shard_type=${SHARD_TYPE}
  56
  57 See_Original_Cars_On_New_Leader
  58     [Documentation]    GET cars from new Leader, should be the initial ones.
  59     TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${ORIGINAL_START_I}
  60
  61 See_Original_Cars_On_New_Followers
  62     [Documentation]    The same check on other existing member(s).
  63     : FOR    ${session}    IN    @{new_follower_sessions}
  64     \    TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${ORIGINAL_START_I}
  65
  66 Delete_Original_Cars_On_New_Leader
  67     [Documentation]    Delete cars on the new Leader.
  68     TemplatedRequests.Delete_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}
  69
  70 Add_Leader_Cars_On_New_Leader
  71     [Documentation]    Add cars on the new Leader.
  72     TemplatedRequests.Put_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}    iterations=${CAR_ITEMS}    iter_start=${LEADER_2NODE_START_I}
  73
  74 See_Leader_Cars_On_New_Leader
  75     [Documentation]    GET cars from new Leader, should be the new ones.
  76     TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${LEADER_2NODE_START_I}
  77
  78 See_Leader_Cars_On_New_Followers
  79     [Documentation]    The same check on other existing members.
  80     : FOR    ${session}    IN    @{new_follower_sessions}
  81     \    TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${LEADER_2NODE_START_I}
  82
  83 Delete_Leader_Cars_On_New_First_Follower
  84     [Documentation]    Delete cars in new first Follower.
  85     TemplatedRequests.Delete_Templated    folder=${VAR_DIR}/cars    session=${new_first_follower_session}
  86
  87 Add_Follower_Cars_On_New_First_Follower
  88     [Documentation]    Add cars on the new first Follower.
  89     TemplatedRequests.Put_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_first_follower_session}    iterations=${CAR_ITEMS}    iter_start=${FOLLOWER_2NODE_START_I}
  90
  91 See_Folower_Cars_On_New_Leader
  92     [Documentation]    Get cars from the new Leader, should be the ones added on follower.
  93     TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${FOLLOWER_2NODE_START_I}
  94
  95 See_Follower_Cars_On_New_Followers
  96     [Documentation]    The same check on other existing members.
  97     : FOR    ${session}    IN    @{new_follower_sessions}
  98     \    TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${FOLLOWER_2NODE_START_I}
  99
 100 Rejoin_Old_Car_Leader
 101     [Documentation]    Rejoin the isolated member without deleting the persisted data.
 102     ClusterManagement.Rejoin_Member_From_List_Or_All    ${car_leader_index}
 103     BuiltIn.Wait_Until_Keyword_Succeeds    30s    2s    ClusterManagement.Verify_Leader_Exists_For_Each_Shard    shard_name_list=${SHARD_NAME_LIST}    shard_type=config
 104
 105 See_Folower_Cars_On_Old_Leader
 106     [Documentation]    GET cars from the restarted member, should be the ones added on follower.
 107     TemplatedRequests.Get_As_Json_Templated    folder=${VAR_DIR}/cars    session=${car_leader_session}    verify=True    iterations=${CAR_ITEMS}    iter_start=${FOLLOWER_2NODE_START_I}
 108
 109 Delete_Follower_Cars_On_New_Leader
 110     [Documentation]    Delete cars on the last Leader.
 111     TemplatedRequests.Delete_Templated    folder=${VAR_DIR}/cars    session=${new_leader_session}
 112
 113 *** Keywords ***
 114 Setup
 115     [Documentation]    Initialize resources, memorize car shard leader and followers.
 116     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 117     CarPeople.Set_Variables_For_Shard    shard_name=car