csit/suites/controller/OneNode_Datastore/010_crud_mdsal_perf.robot

   1 *** Settings ***
   2 Documentation     Test for measuring execution time of MD-SAL DataStore operations.
   3 ...
   4 ...               Copyright (c) 2015-2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               This test suite requires odl-restconf and odl-clustering-test-app modules.
  11 ...               The script cluster_rest_script.py is used for generating requests for
  12 ...               operations on people, car and car-people DataStore test models.
  13 ...               (see the https://wiki.opendaylight.org/view/MD-SAL_Clustering_Test_Plan)
  14 ...
  15 ...               TODO: Decide whether keyword names should contain spaces or underscores.
  16 Suite Setup       Start Suite
  17 Suite Teardown    Stop Suite
  18 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  19 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  20 Library           RequestsLibrary
  21 Library           SSHLibrary
  22 Library           XML
  23 Variables         ../../../variables/Variables.py
  24 Resource          ../../../libraries/Utils.robot
  25 Resource          ../../../libraries/SetupUtils.robot
  26
  27 *** Variables ***
  28 ${ITEM_COUNT}     ${10000}
  29 ${ITEM_BATCH}     ${10000}
  30 ${PROCEDURE_TIMEOUT}    11m
  31 ${addcarcmd}      python cluster_rest_script.py --host ${ODL_SYSTEM_IP} --port ${RESTCONFPORT} add --itemtype car --itemcount ${ITEM_COUNT} --ipr ${ITEM_BATCH}
  32 ${addpeoplecmd}    python cluster_rest_script.py --host ${ODL_SYSTEM_IP} --port ${RESTCONFPORT} add-rpc --itemtype people --itemcount ${ITEM_COUNT} --threads 5
  33 ${purchasecmd}    python cluster_rest_script.py --host ${ODL_SYSTEM_IP} --port ${RESTCONFPORT} add-rpc --itemtype car-people --itemcount ${ITEM_COUNT} --threads 5
  34 ${carurl}         /restconf/config/car:cars
  35 ${peopleurl}      /restconf/config/people:people
  36 ${carpeopleurl}    /restconf/config/car-people:car-people
  37 ${CONTROLLER_LOG_LEVEL}    INFO
  38 ${TOOL_OPTIONS}    ${EMPTY}
  39
  40 *** Test Cases ***
  41 Add Cars
  42     [Documentation]    Request to add ${ITEM_COUNT} cars (timeout in ${PROCEDURE_TIMEOUT}).
  43     Start Tool    ${addcarcmd}    ${TOOL_OPTIONS}
  44     ${output}=    Wait Until Tool Finish    ${PROCEDURE_TIMEOUT}
  45     BuiltIn.Log    ${output}
  46     BuiltIn.Should Not Contain    ${output}    ERROR
  47
  48 Verify Cars
  49     [Documentation]    Store logs and verify result
  50     Stop Tool
  51     Store File To Workspace    cluster_rest_script.log    cluster_rest_script_add_cars.log
  52     ${rsp}=    RequestsLibrary.Get Request    session    ${carurl}    headers=${ACCEPT_XML}
  53     ${count}=    XML.Get Element Count    ${rsp.content}    xpath=car-entry
  54     Should Be Equal As Numbers    ${count}    ${ITEM_COUNT}
  55
  56 Add People
  57     [Documentation]    Request to add ${ITEM_COUNT} people (timeout in ${PROCEDURE_TIMEOUT}).
  58     Start Tool    ${addpeoplecmd}    ${TOOL_OPTIONS}
  59     Wait Until Tool Finish    ${PROCEDURE_TIMEOUT}
  60
  61 Verify People
  62     [Documentation]    Store logs and verify result
  63     Stop Tool
  64     Store File To Workspace    cluster_rest_script.log    cluster_rest_script_add_people.log
  65     ${rsp}=    RequestsLibrary.Get Request    session    ${peopleurl}    headers=${ACCEPT_XML}
  66     ${count}=    XML.Get Element Count    ${rsp.content}    xpath=person
  67     Should Be Equal As Numbers    ${count}    ${ITEM_COUNT}
  68
  69 Purchase Cars
  70     [Documentation]    Request to purchase ${ITEM_COUNT} cars (timeout in ${PROCEDURE_TIMEOUT}).
  71     Start Tool    ${purchasecmd}    ${TOOL_OPTIONS}
  72     Wait Until Tool Finish    ${PROCEDURE_TIMEOUT}
  73
  74 Verify Purchases
  75     [Documentation]    Store logs and verify result
  76     Stop Tool
  77     Store File To Workspace    cluster_rest_script.log    cluster_rest_script_purchase_cars.log
  78     Wait Until Keyword Succeeds    ${PROCEDURE_TIMEOUT}    1    Purchase Is Completed    ${ITEM_COUNT}
  79
  80 Delete Cars
  81     [Documentation]    Remove cars from the datastore
  82     ${rsp}=    RequestsLibrary.Delete Request    session    ${carurl}
  83     Should Be Equal As Numbers    200    ${rsp.status_code}
  84     ${rsp}=    RequestsLibrary.Get Request    session    ${carurl}
  85     Should Be Equal As Numbers    404    ${rsp.status_code}
  86
  87 Delete People
  88     [Documentation]    Remove people from the datastore
  89     ${rsp}=    RequestsLibrary.Delete Request    session    ${peopleurl}
  90     Should Be Equal As Numbers    200    ${rsp.status_code}
  91     ${rsp}=    RequestsLibrary.Get Request    session    ${peopleurl}
  92     Should Be Equal As Numbers    404    ${rsp.status_code}
  93
  94 Delete CarPeople
  95     [Documentation]    Remove car-people entries from the datastore
  96     ${rsp}=    RequestsLibrary.Delete Request    session    ${carpeopleurl}
  97     Should Be Equal As Numbers    200    ${rsp.status_code}
  98     ${rsp}=    RequestsLibrary.Get Request    session    ${carpeopleurl}
  99     Should Be Equal As Numbers    404    ${rsp.status_code}
 100
 101 *** Keywords ***
 102 Start Suite
 103     [Documentation]    Suite setup keyword.
 104     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 105     KarafKeywords.Execute_Controller_Karaf_Command_On_Background    log:set ${CONTROLLER_LOG_LEVEL}
 106     ${mininet_conn_id}=    SSHLibrary.Open Connection    ${TOOLS_SYSTEM_IP}    prompt=${TOOLS_SYSTEM_PROMPT}    timeout=6s
 107     Builtin.Set Suite Variable    ${mininet_conn_id}
 108     Utils.Flexible Mininet Login    ${TOOLS_SYSTEM_USER}
 109     SSHLibrary.Put File    ${CURDIR}/../../../../tools/odl-mdsal-clustering-tests/scripts/cluster_rest_script.py    .
 110     ${stdout}    ${stderr}    ${rc}=    SSHLibrary.Execute Command    ls    return_stdout=True    return_stderr=True
 111     ...    return_rc=True
 112     RequestsLibrary.Create Session    session    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}    auth=${AUTH}
 113
 114 Stop Suite
 115     [Documentation]    Suite teardown keyword
 116     SSHLibrary.Close All Connections
 117     RequestsLibrary.Delete All Sessions
 118
 119 Start_Tool
 120     [Arguments]    ${command}    ${tool_opt}
 121     [Documentation]    Start the tool ${command} ${tool_opt}
 122     BuiltIn.Log    ${command}
 123     ${output}=    SSHLibrary.Write    ${command} ${tool_opt}
 124     BuiltIn.Log    ${output}
 125
 126 Wait_Until_Tool_Finish
 127     [Arguments]    ${timeout}
 128     [Documentation]    Wait ${timeout} for the tool exit, return the printed output.
 129     BuiltIn.Run Keyword And Return    BuiltIn.Wait Until Keyword Succeeds    ${timeout}    1s    SSHLibrary.Read Until Prompt
 130
 131 Purchase Is Completed
 132     [Arguments]    ${item_count}
 133     [Documentation]    Check purchase of ${item_count} is completed.
 134     ${rsp}=    RequestsLibrary.Get Request    session    ${carpeopleurl}    headers=${ACCEPT_XML}
 135     ${count}=    XML.Get Element Count    ${rsp.content}    xpath=car-person
 136     Should Be Equal As Numbers    ${count}    ${item_count}
 137
 138 Stop_Tool
 139     [Documentation]    Stop the tool if still running.
 140     Utils.Write_Bare_Ctrl_C
 141     ${output}=    SSHLibrary.Read    delay=1s
 142     BuiltIn.Log    ${output}
 143
 144 Store_File_To_Workspace
 145     [Arguments]    ${source_file_name}    ${target_file_name}
 146     [Documentation]    Store the ${source_file_name} to the workspace as ${target_file_name}.
 147     ${output_log}=    SSHLibrary.Execute_Command    cat ${source_file_name}
 148     BuiltIn.Log    ${output_log}
 149     Create File    ${target_file_name}    ${output_log}