csit/suites/controller/dom_data_broker/client_isolation_prefbasedshard.robot

   1 *** Settings ***
   2 Documentation       DOMDataBroker testing: Client Isolation
   3 ...
   4 ...                 Copyright (c) 2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...                 This program and the accompanying materials are made available under the
   7 ...                 terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...                 and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...                 The purpose of this test is to ascertain that the failure modes of
  11 ...                 cds-access-client work as expected. This is performed by having a steady
  12 ...                 stream of transactions flowing from the frontend and isolating the node hosting
  13 ...                 the frontend from the rest of the cluster.
  14
  15 Library             SSHLibrary
  16 Resource            ${CURDIR}/../../../libraries/controller/DdbCommons.robot
  17 Resource            ${CURDIR}/../../../libraries/SetupUtils.robot
  18
  19 Suite Setup         SetupUtils.Setup_Utils_For_Setup_And_Teardown    http_timeout=125
  20 Suite Teardown      SSHLibrary.Close_All_Connections
  21 Test Setup          BuiltIn.Run_Keywords    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  22 ...                     AND    DdbCommons.Create_Prefix_Based_Shard_And_Verify
  23 Test Teardown       BuiltIn.Run_Keywords    DdbCommons.Remove_Prefix_Based_Shard_And_Verify
  24 ...                     AND    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  25 Test Template       DdbCommons.Client_Isolation_PrefBasedShard_Test_Templ
  26
  27 Default Tags        critical
  28
  29
  30 *** Test Cases ***
  31 Producer_On_Shard_Leader_Node_Isolated_Transactions
  32     [Documentation]    Client isolation with producer on shard leader with isolated transactions flag set.
  33     leader    ${ISOLATED_TRANS_TRUE}
  34 Restart1
  35     [Documentation]    Restart odl.
  36     [Template]    ${EMPTY}
  37     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  38     DdbCommons.Restart_Test_Templ
  39     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  40 Producer_On_Shard_Leader_Node_Nonisolated_Transactions
  41     [Documentation]    Client isolation with producer on shard leader with isolated transactions flag unset.
  42     leader    ${ISOLATED_TRANS_FALSE}
  43 Restart2
  44     [Documentation]    Restart odl.
  45     [Template]    ${EMPTY}
  46     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  47     DdbCommons.Restart_Test_Templ
  48     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  49 Producer_On_Shard_Non_Leader_Node_Isolated_Transactions
  50     [Documentation]    Client isolation with producer on shard non-leader with isolated transactions flag set.
  51     non-leader    ${ISOLATED_TRANS_TRUE}
  52 Restart3
  53     [Documentation]    Restart odl
  54     [Template]    ${EMPTY}
  55     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  56     DdbCommons.Restart_Test_Templ
  57     [Teardown]    SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  58 Producer_On_Shard_Non_Leader_Node_Nonisolated_Transactions
  59     [Documentation]    Client isolation with producer on shard non-leader with isolated transactions flag unset.
  60     non-leader    ${ISOLATED_TRANS_FALSE}