csit/suites/controller/dom_rpc_broker/rpc_provider_precedence.robot

   1 *** Settings ***
   2 Documentation     DOMRpcBroker testing: RPC Provider Precedence
   3 ...
   4 ...               Copyright (c) 2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...               The aim is to establish that remote RPC implementations have lower priority
  11 ...               than local ones, which is to say that any movement of RPCs on remote nodes
  12 ...               does not affect routing as long as a local implementation is available.
  13 Suite Setup       Setup_Keyword
  14 Suite Teardown    SSHLibrary.Close_All_Connections
  15 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  16 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  17 Default Tags      critical
  18 Library           SSHLibrary
  19 Resource          ${CURDIR}/../../../libraries/controller/DrbCommons.robot
  20 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  21
  22 *** Variables ***
  23 ${UNREGISTERED_RPC_NODE}    ${1}
  24
  25 *** Test Cases ***
  26 Register_Rpc_On_Each_Node
  27     [Documentation]    Register global rpc on each node of the cluster.
  28     DrbCommons.Register_Rpc_On_Nodes    ${all_indices}
  29
  30 Invoke_Rpc_On_Each_Node
  31     [Documentation]    Verify that the rpc response comes from the local node.
  32     DrbCommons.Verify_Constant_On_Registered_Nodes    ${all_indices}
  33
  34 Unregister_Rpc_On_Node
  35     [Documentation]    Unregister the rpc on one of the cluster nodes.
  36     DrbCommons.Unregister_Rpc_And_Update_Possible_Constants    ${UNREGISTERED_RPC_NODE}
  37
  38 Invoke_Rpc_On_Node_With_Unregistered_Rpc
  39     [Documentation]    Invoke rcp on the node with unregistered rpc. The response is expected
  40     ...    to come from other nodes where the rpc remained registered.
  41     DrbCommons.Verify_Constant_On_Unregistered_Node    ${UNREGISTERED_RPC_NODE}
  42
  43 Invoke_Rpc_On_Remaining_Nodes
  44     [Documentation]    Verify that the rpc response comes from the local node.
  45     DrbCommons.Verify_Constant_On_Registered_Nodes    ${registered_indices}
  46
  47 Reregister_Rpc_On_Node
  48     [Documentation]    Reregister the rpc.
  49     DrbCommons.Register_Rpc_And_Update_Possible_Constants    ${UNREGISTERED_RPC_NODE}
  50
  51 Invoke_Rpc_On_Each_Node_Again
  52     [Documentation]    Verify that the rpc response comes from the local node.
  53     DrbCommons.Verify_Constant_On_Registered_Nodes    ${all_indices}
  54
  55 Unregister_Rpc_On_Each_Node
  56     [Documentation]    Unregister rpc on every node.
  57     DrbCommons.Unregister_Rpc_On_Nodes    ${all_indices}
  58
  59 *** Keywords ***
  60 Setup_Keyword
  61     [Documentation]    Create a list of possible constant responses on the node with unregistered rpc.
  62     SetupUtils.Setup_Utils_For_Setup_And_Teardown
  63     DrbCommons.DrbCommons_Init