csit/suites/controller/singleton_service/global_rpc_isolate.robot

   1 *** Settings ***
   2 Documentation     Controller functional HA testing of global singleton rpcs.
   3 ...
   4 ...               Copyright (c) 2017 Cisco Systems, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 Suite Setup       Setup_Suite
  10 Suite Teardown    SSHLibrary.Close_All_Connections
  11 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  12 Test Teardown     SetupUtils.Teardown_Test_Show_Bugs_If_Test_Failed
  13 Default Tags      critical
  14 Resource          ${CURDIR}/../../../libraries/ClusterManagement.robot
  15 Resource          ${CURDIR}/../../../libraries/KarafKeywords.robot
  16 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  17 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  18 Resource          ${CURDIR}/../../../variables/Variables.robot
  19 Resource          ${CURDIR}/../../../libraries/WaitForFailure.robot
  20
  21 *** Variables ***
  22 ${RPC_URL}        /restconf/operations/basic-rpc-test:basic-global
  23 &{EMPTY_DICT}
  24 ${SERVICE}        Basic-rpc-test']
  25 ${TEST_LOG_LEVEL}    info
  26 @{TEST_LOG_COMPONENTS}    org.opendaylight.controller.remote.rpc
  27 ${EOS_URL}        /restconf/operational/entity-owners:entity-owners
  28 ${RPC_STATUS_ISOLATED}    501
  29 @{NO_TAGS}
  30
  31 *** Test Cases ***
  32 Get_Basic_Rpc_Test_Owner
  33     [Documentation]    Find a service owner and successors.
  34     [Tags]    @{NO_TAGS}
  35     Get_Present_Brt_Owner_And_Successors    1    store=${True}
  36
  37 Rpc_Before_Isolation_On_Owner
  38     [Documentation]    Run rpc on the service owner.
  39     Run_Rpc    ${brt_owner}
  40
  41 Rpc_Before_Isolation_On_Successors
  42     [Documentation]    Run rpc on non owher cluster nodes.
  43     : FOR    ${idx}    IN    @{brt_successors}
  44     \    Run_Rpc    ${idx}
  45
  46 Isolate_Current_Owner_Member
  47     [Documentation]    Isolating cluster node which is the owner.
  48     [Tags]    @{NO_TAGS}
  49     ClusterManagement.Isolate_Member_From_List_Or_All    ${brt_owner}
  50     BuiltIn.Set Suite variable    ${old_brt_owner}    ${brt_owner}
  51     BuiltIn.Set Suite variable    ${old_brt_successors}    ${brt_successors}
  52
  53 Verify_New_Basic_Rpc_Test_Owner_Elected
  54     [Documentation]    Verify new owner of the service is elected.
  55     ${idx}=    Collections.Get_From_List    ${old_brt_successors}    0
  56     BuiltIn.Wait_Until_Keyword_Succeeds    5x    2s    Verify_Owner_Elected    ${True}    ${old_brt_owner}    ${idx}
  57     Get_Present_Brt_Owner_And_Successors    ${idx}    store=${True}
  58
  59 Rpc_On_Isolated_Node
  60     [Documentation]    Run rpc on isolated cluster node.
  61     ${session} =    Resolve_Http_Session_For_Member    member_index=${old_brt_owner}
  62     ${out} =    TemplatedRequests.Get_From_Uri    ${EOS_URL}    session=${session}
  63     KarafKeywords.Log_Message_To_Controller_Karaf    EOS rest resp: ${out}
  64     ${resp} =    RequestsLibrary.Post Request    ${session}    ${RPC_URL}    data=${EMPTY}
  65     BuiltIn.Should_Be_Equal_As_Numbers    ${resp.status_code}    ${RPC_STATUS_ISOLATED}
  66
  67 Rpc_On_Non_Isolated_Cluster_Nodes
  68     [Documentation]    Run rpc on remained cluster nodes.
  69     : FOR    ${idx}    IN    @{old_brt_successors}
  70     \    Run_Rpc    ${idx}
  71
  72 Rejoin_Isolated_Member
  73     [Documentation]    Rejoin isolated node
  74     [Tags]    @{NO_TAGS}
  75     ClusterManagement.Rejoin_Member_From_List_Or_All    ${old_brt_owner}
  76
  77 Verify_New_Owner_Remained_After_Rejoin
  78     [Documentation]    Verify no owner change happened after rejoin.
  79     WaitForFailure.Verify_Keyword_Does_Not_Fail_Within_Timeout    15s    2s    Verify_Owner_Elected    ${False}    ${brt_owner}    ${brt_owner}
  80
  81 Rpc_After_Rejoin_On_New_Owner
  82     [Documentation]    Run rpc on the new service owner node.
  83     Run_Rpc    ${brt_owner}
  84
  85 Rpc_After_Rejoin_On_Old_Owner
  86     [Documentation]    Run rpc on rejoined cluster node.
  87     Run_Rpc    ${old_brt_owner}
  88
  89 Rpc_After_Rejoin_On_All
  90     [Documentation]    Run rpc again on all nodes.
  91     Run_Rpc    ${brt_owner}
  92     : FOR    ${idx}    IN    @{brt_successors}
  93     \    Run_Rpc    ${idx}
  94
  95 *** Keywords ***
  96 Setup_Suite
  97     SetupUtils.Setup_Utils_For_Setup_And_Teardown
  98     SetupUtils.Setup_Logging_For_Debug_Purposes_On_List_Or_All    ${TEST_LOG_LEVEL}    ${TEST_LOG_COMPONENTS}
  99
 100 Run_Rpc
 101     [Arguments]    ${node_idx}
 102     [Documentation]    Run rpc and log the entity ownership service details to karaf log.
 103     ...    Logging the details was a developer's request during the implementation to improve debugging.
 104     ${session} =    Resolve_Http_Session_For_Member    member_index=${node_idx}
 105     ${out} =    TemplatedRequests.Get_From_Uri    ${EOS_URL}    session=${session}
 106     KarafKeywords.Log_Message_To_Controller_Karaf    EOS rest resp: ${out}
 107     TemplatedRequests.Post_To_Uri    ${RPC_URL}    ${EMPTY}    ${EMPTY_DICT}    ${EMPTY_DICT}    session=${session}
 108
 109 Verify_Owner_Elected
 110     [Arguments]    ${new_elected}    ${old_owner}    ${node_to_ask}
 111     [Documentation]    Verify new owner was elected or remained the same.
 112     ${owner}    ${successors}=    Get_Present_Brt_Owner_And_Successors    ${node_to_ask}
 113     BuiltIn.Run_Keyword_If    ${new_elected}    BuiltIn.Should_Not_Be_Equal_As_Numbers    ${old_owner}    ${owner}
 114     BuiltIn.Run_Keyword_Unless    ${new_elected}    BuiltIn.Should_Be_Equal_As_numbers    ${old_owner}    ${owner}
 115
 116 Get_Present_Brt_Owner_And_Successors
 117     [Arguments]    ${node_to_ask}    ${store}=${False}
 118     [Documentation]    Find a basic rpc test service owner and successors and store them if indicated.
 119     ${brt_owner}    ${brt_successors}=    ClusterManagement.Get_Owner_And_Successors_For_Device    ${SERVICE}    org.opendaylight.mdsal.ServiceEntityType    ${node_to_ask}
 120     BuiltIn.Run_Keyword_If    ${store}    BuiltIn.Set_Suite_Variable    ${brt_owner}    ${brt_owner}
 121     BuiltIn.Run_Keyword_If    ${store}    BuiltIn.Set_Suite_Variable    ${brt_successors}    ${brt_successors}
 122     BuiltIn.Return_From_Keyword    ${brt_owner}    ${brt_successors}