csit/suites/groupbasedpolicy/GBP/3-node/__init__.robot

   1 *** Settings ***
   2 Documentation       Setup/teardown for GBP 3-node topology
   3
   4 Library             SSHLibrary
   5 Library             RequestsLibrary
   6 Resource            ../../../../libraries/Utils.robot
   7 Resource            ../../../../libraries/GBP/ConnUtils.robot
   8 Variables           ../../../../variables/Variables.py
   9 Resource            Variables.robot
  10
  11 Suite Setup         Setup Everything
  12 Suite Teardown      Teardown Everything
  13
  14
  15 *** Variables ***
  16 ${timeout}      10s
  17
  18
  19 *** Keywords ***
  20 Setup Everything
  21     Log    start_suite_in_3_node
  22     Create Session    session    http://${ODL}:${RESTCONFPORT}    auth=${AUTH}    headers=${HEADERS}
  23     Wait Until Keyword Succeeds
  24     ...    10x
  25     ...    30 s
  26     ...    Get Data From URI
  27     ...    session
  28     ...    ${OF_OVERLAY_CONFIG_PATH}
  29     ...    headers=${headers}
  30     Delete All Sessions
  31     FOR    ${GBP}    IN    @{GBPs}
  32         ConnUtils.Connect and Login    ${GBP}    timeout=${timeout}
  33         ${stderr}    SSHLibrary.Execute Command
  34         ...    virtualenv --system-site-packages ${VE_DIR}
  35         ...    return_stdout=False
  36         ...    return_stderr=True
  37         ...    return_rc=False
  38         Should Be Empty    ${stderr}
  39         SSHLibrary.Put File
  40         ...    ${CURDIR}/../../common_scripts/*
  41         ...    ${VM_HOME_FOLDER}${/}${VM_SCRIPTS_FOLDER}/
  42         ...    mode=0755
  43         ${stdout}    ${stderr}    ${rc}    ConnUtils.Execute in VE
  44         ...    pip freeze | grep ipaddr -q || pip install ipaddr
  45         ...    timeout=${timeout}
  46         Should Be Equal As Numbers    ${rc}    0
  47         SSHLibrary.Close Connection
  48     END
  49     Init Variables
  50
  51 Teardown Everything
  52     Log    stop_suite_in_3_node
  53     FOR    ${GBP}    IN    @{GBPs}
  54         ConnUtils.Connect and Login    ${GBP}    timeout=${timeout}
  55         SSHLibrary.Execute Command    sudo rm -rf ${VM_SCRIPTS_FOLDER}
  56         SSHLibrary.Close Connection
  57     END