csit/suites/l2switch/Maximum_Hosts/010__finding_max_hosts.robot

   1 *** Settings ***
   2 Documentation       Test suite for finding out max number of switches
   3
   4 Library             OperatingSystem
   5 Resource            ../../../variables/Variables.robot
   6 Resource            ../../../libraries/WorkflowsL2switch.robot
   7 Resource            ../../../libraries/KarafKeywords.robot
   8
   9 Suite Setup         Workflow Setup
  10 Suite Teardown      Workflow Teardown
  11
  12
  13 *** Variables ***
  14 ${MIN_HOSTS}            50
  15 ${MAX_HOSTS}            1000
  16 ${STEP_HOSTS}           50
  17 ${HOSTS_RESULT_FILE}    hosts.csv
  18 ${TIME_RESULT_FILE}     time.csv
  19
  20
  21 *** Test Cases ***
  22 Find Max Supported Hosts
  23     [Documentation]    Find max number of hosts starting from ${MIN_HOSTS} till reaching ${MAX_HOSTS} in steps of ${STEP_HOSTS}
  24     ${error_message}=    BuiltIn.Set Variable    Fail initializing suite
  25     ${maximum_hosts}=    BuiltIn.Set Variable    ${0}
  26     ${discover_time}=    BuiltIn.Set Variable    0
  27     ${start}=    BuiltIn.Convert to Integer    ${MIN_HOSTS}
  28     ${stop}=    BuiltIn.Convert to Integer    ${MAX_HOSTS}
  29     ${step}=    BuiltIn.Convert to Integer    ${STEP_HOSTS}
  30     FOR    ${hosts}    IN RANGE    ${start}    ${stop+1}    ${step}
  31         ${status}
  32         ...    ${error_message}
  33         ...    ${host_discover_time}=
  34         ...    WorkflowsL2switch.Workflow Single Switch Multiple Hosts
  35         ...    ${hosts}
  36         IF    '${status}' == 'FAIL'            BREAK
  37         ${maximum_hosts}=    BuiltIn.Set variable    ${hosts}
  38         ${discover_time}=    BuiltIn.Set Variable    ${host_discover_time}
  39     END
  40     BuiltIn.Log to console    ${\n}
  41     BuiltIn.Log To Console    Execution stopped because: ${error_message}
  42     BuiltIn.Log To Console    Max Hosts: ${maximum_hosts}
  43     OperatingSystem.Append To File    ${HOSTS_RESULT_FILE}    Max Hosts\n
  44     OperatingSystem.Append To File    ${HOSTS_RESULT_FILE}    ${maximum_hosts}\n
  45     OperatingSystem.Append To File    ${TIME_RESULT_FILE}    Discover Time\n
  46     OperatingSystem.Append To File    ${TIME_RESULT_FILE}    ${discover_time}\n