csit/suites/netconf/CRUD/CRUD-RPC.robot

   1 *** Settings ***
   2 Documentation     netconf-connector CRUD test suite.
   3 ...
   4 ...               Copyright (c) 2017 Lumina Networks, Inc. and others. All rights reserved.
   5 ...
   6 ...               This program and the accompanying materials are made available under the
   7 ...               terms of the Eclipse Public License v1.0 which accompanies this distribution,
   8 ...               and is available at http://www.eclipse.org/legal/epl-v10.html
   9 ...
  10 ...
  11 ...               Perform basic operations (Create, Read, Update and Delete or CRUD) on device
  12 ...               data mounted onto a netconf connector using RPC for node addition and see if
  13 ...               they work.
  14 ...
  15 ...               FIXME: Replace the BuiltIn.Should_[Not_]Contain instances in the test cases
  16 ...               that check the car list related data with calls to keywords of a Resource
  17 ...               aimed at getting interesting pieces of data from the XML files and checking
  18 ...               them against expected data sets. See MDSAL/northbound.robot suite for
  19 ...               additional information.
  20 Suite Setup       Setup_Everything
  21 Suite Teardown    Teardown_Everything
  22 Test Setup        SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  23 Library           Collections
  24 Library           RequestsLibrary
  25 Library           OperatingSystem
  26 Library           String
  27 Library           SSHLibrary    timeout=10s
  28 Resource          ${CURDIR}/../../../libraries/FailFast.robot
  29 Resource          ${CURDIR}/../../../libraries/NetconfKeywords.robot
  30 Resource          ${CURDIR}/../../../libraries/SetupUtils.robot
  31 Resource          ${CURDIR}/../../../libraries/TemplatedRequests.robot
  32 Resource          ${CURDIR}/../../../libraries/CompareStream.robot
  33 Resource          ${CURDIR}/../../../variables/Variables.robot
  34
  35 *** Variables ***
  36 ${directory_with_template_folders}    ${CURDIR}/../../../variables/netconf/CRUD
  37 ${device_name}    netconf-test-device
  38 ${device_type_rpc}    rpc-device
  39 ${device_type_rpc_create}    rpc-create-device
  40 ${device_type_rpc_delete}    rpc-delete-device
  41 ${USE_NETCONF_CONNECTOR}    ${False}
  42 ${delete_location}    delete_location
  43
  44 *** Test Cases ***
  45 Start_Testtool
  46     [Documentation]    Deploy and start test tool, then wait for all its devices to become online.
  47     NetconfKeywords.Install_And_Start_Testtool    device-count=1    schemas=${CURDIR}/../../../variables/netconf/CRUD/schemas
  48
  49 Check_Device_Is_Not_Configured_At_Beginning
  50     [Documentation]    Sanity check making sure our device is not there. Fail if found.
  51     [Tags]    critical
  52     NetconfKeywords.Check_Device_Has_No_Netconf_Connector    ${device_name}
  53
  54 Configure_Device_On_Netconf
  55     [Documentation]    Make request to configure a testtool device on Netconf connector.
  56     [Tags]    critical
  57     NetconfKeywords.Configure_Device_In_Netconf    ${device_name}    device_type=${device_type}    http_timeout=2    http_method=post
  58
  59 Check_ODL_Has_Netconf_Connector_For_Device
  60     [Documentation]    Get the list of configured devices and search for our device there. Fail if not found.
  61     [Tags]    critical
  62     ${count}    NetconfKeywords.Count_Netconf_Connectors_For_Device    ${device_name}
  63     Builtin.Should_Be_Equal_As_Strings    ${count}    1
  64
  65 Wait_For_Device_To_Become_Connected
  66     [Documentation]    Wait until the device becomes available through Netconf.
  67     NetconfKeywords.Wait_Device_Connected    ${device_name}
  68
  69 Check_Device_Data_Is_Empty
  70     [Documentation]    Get the device data and make sure it is empty.
  71     Run_Keyword_If_Less_Than_Neon    Check_Config_Data    <data xmlns\="${ODL_NETCONF_NAMESPACE}"></data>
  72     Run_Keyword_If_At_Least_Neon    Check_Config_Data    <data xmlns\="${ODL_NETCONF_NAMESPACE}"/>
  73
  74 Create_Device_Data_Label_Via_Xml
  75     [Documentation]    Send a sample test data label into the device and check that the request went OK.
  76     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  77     TemplatedRequests.Post_As_Xml_Templated    ${directory_with_template_folders}${/}dataorig    ${template_as_string}
  78
  79 Check_Device_Data_Label_Is_Created
  80     [Documentation]    Get the device data label and make sure it contains the created content.
  81     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content</l></cont></data>
  82
  83 Modify_Device_Data_Label_Via_Xml
  84     [Documentation]    Send a request to change the sample test data label and check that the request went OK.
  85     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
  86     TemplatedRequests.Put_As_Xml_Templated    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
  87
  88 Check_Device_Data_Label_Is_Modified
  89     [Documentation]    Get the device data label and make sure it contains the modified content.
  90     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Modified Content</l></cont></data>
  91
  92 Deconfigure_Device_From_Netconf_Temporarily
  93     [Documentation]    Make request to deconfigure the testtool device on Netconf connector.
  94     ...    This is the first part of the "configure/deconfigure" cycle of the device
  95     ...    The purpose of cycling the device like this is to see that the configuration
  96     ...    data was really stored in the device.
  97     [Tags]    critical
  98     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
  99     CompareStream.Run_Keyword_If_At_Most_Nitrogen    NetconfKeywords.Remove_Device_From_Netconf    ${device_name}    location=${delete_location}
 100     CompareStream.Run_Keyword_If_At_Least_Oxygen    NetconfKeywords.Configure_Device_In_Netconf    ${device_name}    device_type=${device_type_rpc_delete}    http_timeout=2    http_method=post
 101
 102 Wait_For_Device_To_Be_Gone
 103     [Documentation]    Wait for the device to completely disappear.
 104     NetconfKeywords.Wait_Device_Fully_Removed    ${device_name}
 105
 106 Configure_The_Device_Back
 107     [Documentation]    Configure the device again.
 108     ...    This is the second step of the device configuration.
 109     [Tags]    critical
 110     NetconfKeywords.Configure_Device_In_Netconf    ${device_name}    device_type=${device_type}    http_timeout=2    http_method=post
 111
 112 Wait_For_Device_To_Reconnect
 113     [Documentation]    Wait until the device becomes available through Netconf.
 114     NetconfKeywords.Wait_Device_Connected    ${device_name}
 115
 116 Check_Modified_Device_Data_Is_Still_There
 117     [Documentation]    Get the device data and make sure it contains the created content.
 118     BuiltIn.Wait_Until_Keyword_Succeeds    60s    1s    Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Modified Content</l></cont></data>
 119
 120 Modify_Device_Data_Again
 121     [Documentation]    Send a request to change the sample test data and check that the request went OK.
 122     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 123     TemplatedRequests.Put_As_Xml_Templated    ${DIRECTORY_WITH_TEMPLATE_FOLDERS}${/}datamod2    ${template_as_string}
 124
 125 Check_Device_Data_Is_Modified_Again
 126     [Documentation]    Get the device data and make sure it contains the created content.
 127     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Another Modified Content</l></cont></data>
 128
 129 Modify_Device_Data_Label_Via_Json
 130     [Documentation]    Send a JSON request to change the sample test data label and check that the request went OK.
 131     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 132     TemplatedRequests.Put_As_Json_Templated    ${directory_with_template_folders}${/}datamodjson    ${template_as_string}
 133
 134 Check_Device_Data_Label_Is_Modified_Via_Json
 135     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
 136     Check_Config_Data    <data xmlns="${ODL_NETCONF_NAMESPACE}"><cont xmlns="urn:opendaylight:test:netconf:crud"><l>Content Modified via JSON</l></cont></data>
 137
 138 Create_Car_List
 139     [Documentation]    Send a request to create a list of cars in the sample test data label and check that the request went OK.
 140     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 141     TemplatedRequests.Post_As_Xml_Templated    ${directory_with_template_folders}${/}cars    ${template_as_string}
 142
 143 Check_Car_List_Created
 144     [Documentation]    Get the device data label as XML and make sure it matches the content posted as JSON in the previous case.
 145     ${data}=    Get_Config_Data
 146     BuiltIn.Should_Contain    ${data}    <id>KEEP</id>
 147     BuiltIn.Should_Not_Contain    ${data}    <id>SMALL</id>
 148     BuiltIn.Should_Not_Contain    ${data}    <model>Isetta</model>
 149     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>BMW</manufacturer>
 150     BuiltIn.Should_Not_Contain    ${data}    <year>1953</year>
 151     BuiltIn.Should_Not_Contain    ${data}    <category>microcar</category>
 152     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 153     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 154     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 155     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 156     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 157
 158 Add_Device_Data_Item_1_Via_XML_Post
 159     [Documentation]    Send a request to create a data item in the test list and check that the request went OK.
 160     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 161     TemplatedRequests.Post_As_Xml_Templated    ${directory_with_template_folders}${/}item1    ${template_as_string}
 162
 163 Check_Item1_Is_Created
 164     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 165     ${data}=    Get_Config_Data
 166     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 167     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 168     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 169     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 170     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 171     BuiltIn.Should_Not_Contain    ${data}    <id>TOYOTA</id>
 172     BuiltIn.Should_Not_Contain    ${data}    <model>Camry</model>
 173     BuiltIn.Should_Not_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 174     BuiltIn.Should_Not_Contain    ${data}    <year>1982</year>
 175     BuiltIn.Should_Not_Contain    ${data}    <category>sedan</category>
 176
 177 Add_Device_Data_Item_2_Via_JSON_Post
 178     [Documentation]    Send a JSON request to change the sample test data and check that the request went OK.
 179     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 180     TemplatedRequests.Post_As_Json_Templated    ${directory_with_template_folders}${/}item2    ${template_as_string}
 181
 182 Check_Item2_Is_Created
 183     [Documentation]    Get the device data as XML and make sure it matches the content posted as JSON in the previous case.
 184     ${data}=    Get_Config_Data
 185     BuiltIn.Should_Contain    ${data}    <id>SMALL</id>
 186     BuiltIn.Should_Contain    ${data}    <model>Isetta</model>
 187     BuiltIn.Should_Contain    ${data}    <manufacturer>BMW</manufacturer>
 188     BuiltIn.Should_Contain    ${data}    <year>1953</year>
 189     BuiltIn.Should_Contain    ${data}    <category>microcar</category>
 190     BuiltIn.Should_Contain    ${data}    <id>TOYOTA</id>
 191     BuiltIn.Should_Contain    ${data}    <model>Camry</model>
 192     BuiltIn.Should_Contain    ${data}    <manufacturer>Toyota</manufacturer>
 193     BuiltIn.Should_Contain    ${data}    <year>1982</year>
 194     BuiltIn.Should_Contain    ${data}    <category>sedan</category>
 195
 196 Delete_Device_Data
 197     [Documentation]    Send a request to delete the sample test data on the device and check that the request went OK.
 198     ${template_as_string}=    BuiltIn.Set_Variable    {'DEVICE_NAME': '${device_name}'}
 199     TemplatedRequests.Delete_Templated    ${directory_with_template_folders}${/}datamod1    ${template_as_string}
 200     TemplatedRequests.Delete_Templated    ${directory_with_template_folders}${/}item1    ${template_as_string}
 201
 202 Check_Device_Data_Is_Deleted
 203     [Documentation]    Get the device data and make sure it is empty again.
 204     Run_Keyword_If_Less_Than_Neon    Check_Config_Data    <data xmlns\="${ODL_NETCONF_NAMESPACE}"></data>
 205     Run_Keyword_If_At_Least_Neon    Check_Config_Data    <data xmlns\="${ODL_NETCONF_NAMESPACE}"/>
 206
 207 Deconfigure_Device_From_Netconf
 208     [Documentation]    Make request to deconfigure the testtool device on Netconf connector.
 209     [Tags]    critical
 210     [Setup]    SetupUtils.Setup_Test_With_Logging_And_Without_Fast_Failing
 211     CompareStream.Run_Keyword_If_At_Most_Nitrogen    NetconfKeywords.Remove_Device_From_Netconf    ${device_name}    location=${delete_location}
 212     CompareStream.Run_Keyword_If_At_Least_Oxygen    NetconfKeywords.Configure_Device_In_Netconf    ${device_name}    device_type=${device_type_rpc_delete}    http_timeout=2    http_method=post
 213
 214 Check_Device_Going_To_Be_Gone_After_Deconfiguring
 215     [Documentation]    Check that the device is really going to be gone. Fail
 216     ...    if found after one minute. This is an expected behavior as the
 217     ...    delete request is sent to the config subsystem which then triggers
 218     ...    asynchronous destruction of the netconf connector referring to the
 219     ...    device and the device's data. This test makes sure this
 220     ...    asynchronous operation does not take unreasonable amount of time
 221     ...    by making sure that both the netconf connector and the device's
 222     ...    data is gone before reporting success.
 223     [Tags]    critical
 224     NetconfKeywords.Wait_Device_Fully_Removed    ${device_name}
 225
 226 *** Keywords ***
 227 Setup_Everything
 228     [Documentation]    Initialize SetupUtils. Setup everything needed for the test cases.
 229     # Setup resources used by the suite.
 230     SetupUtils.Setup_Utils_For_Setup_And_Teardown
 231     RequestsLibrary.Create_Session    operational    http://${ODL_SYSTEM_IP}:${RESTCONFPORT}${OPERATIONAL_API}    auth=${AUTH}
 232     NetconfKeywords.Setup_Netconf_Keywords
 233     ${device_type_rpc}=    BuiltIn.Set_Variable_If    """${USE_NETCONF_CONNECTOR}""" == """True"""    default    ${device_type_rpc}
 234     ${device_type}    CompareStream.Set_Variable_If_At_Most_Nitrogen    ${device_type_rpc}    ${device_type_rpc_create}
 235     BuiltIn.Set_Suite_Variable    ${device_type}
 236
 237 Teardown_Everything
 238     [Documentation]    Teardown the test infrastructure, perform cleanup and release all resources.
 239     RequestsLibrary.Delete_All_Sessions
 240     BuiltIn.Run_Keyword_And_Ignore_Error    NetconfKeywords.Stop_Testtool
 241
 242 Get_Config_Data
 243     [Documentation]    Get and return the config data from the device.
 244     ${url}=    Builtin.Set_Variable    ${CONFIG_API}/network-topology:network-topology/topology/topology-netconf/node/${device_name}/yang-ext:mount
 245     ${data}=    TemplatedRequests.Get_As_Xml_From_Uri    ${url}
 246     [Return]    ${data}
 247
 248 Check_Config_Data
 249     [Arguments]    ${expected}    ${contains}=False
 250     ${data}=    Get_Config_Data
 251     BuiltIn.Run_Keyword_Unless    ${contains}    BuiltIn.Should_Be_Equal_As_Strings    ${data}    ${expected}
 252     BuiltIn.Run_Keyword_If    ${contains}    BuiltIn.Should_Contain    ${data}    ${expected}